unageanu-jiji 0.1.0

data/swf/build.xml

@@ -0,0 +1,23 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<project name="fx-swf-build" default="build.chart" basedir=".">
+  
+  <property name="dist.dir" value="../html/swf" />
+
+  <property name="FLEX_HOME" value="../tool/flex_sdk_3.1.0.2710" />
+  <taskdef resource="flexTasks.tasks" />
+ 
+  <target name="build.chart" depends="clean">
+    <mxmlc file="chart/FxChart.mxml"
+    	     debug="true"
+           output="${dist.dir}/chart.swf">
+    	<compiler.library-path dir="." append="true">
+    		<include name="lib" />
+      </compiler.library-path>
+    </mxmlc>
+  </target>
+
+  <target name="clean">
+    <delete file="${dist.dir}/chart.swf" />
+  </target>
+
+</project>

data/swf/chart/FxChart-config.xml

@@ -0,0 +1,9 @@
+<flex-config>
+  <output>bin/Chart.swf</output>
+  <default-size>
+    <width>780</width>
+    <height>450</height>
+  </default-size>
+  <default-frame-rate>24</default-frame-rate>
+  <default-background-color>0xE8E8E8</default-background-color>
+</flex-config>

data/swf/chart/FxChart.mxml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="utf-8"?>
+<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
+  layout="absolute" applicationComplete="main()" >
+
+  <mx:Canvas id="canvas" width="780" height="450" backgroundColor="#E8E8E8" >
+  </mx:Canvas>
+  <mx:Script>
+      <![CDATA[
+          import fx.chart.*;
+          // メイン
+          public function main():void {
+              new Chart(canvas);
+          }
+      ]]>
+  </mx:Script>
+
+</mx:Application>

data/swf/chart/fx/chart/Chart.as

@@ -0,0 +1,155 @@
+package fx.chart {
+
+  import flash.display.*;
+  import flash.text.*;
+  import flash.external.*;
+  import flash.net.*;
+  import flash.events.Event;
+  import mx.core.*;
+  import mx.controls.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.ui.candle.*;
+  import fx.chart.ui.graph.*;
+  import fx.chart.ui.*;
+  import fx.util.*;
+
+  /**
+   * チャート
+   */
+  public class Chart {
+
+    private var candleChart:CandleChart;
+    private var pointer:Pointer;
+    private var scaleSelector:ScaleSelector;
+    private var tradeResult:TradeResult;
+    private var scroll:Scroll;
+    private var graphManager:GraphManager;
+
+    private var model:Model;
+    private var ctrl:Controller;
+    private var rc:RenderingContext;
+    private var autoUpdate:AutoUpdate;
+    private var check:CheckBox;
+
+    public function Chart(canvas:UIComponent){
+    
+      model = new Model();
+      ctrl = new Controller(model);
+      rc = new RenderingContext( canvas );
+
+      autoUpdate = new AutoUpdate( model, ctrl );
+      check = new CheckBox();
+      check.x = 490;
+      check.y = 10;
+      check.label = "自動更新";
+      rc.canvas.addChild( check );
+      check.addEventListener( flash.events.Event.CHANGE, function():void {
+          if ( check.selected ) {
+              autoUpdate.start();
+          } else {
+              autoUpdate.stop();
+          }
+          var so:SharedObject = SharedObject.getLocal("chartInfo");
+          so.data.autoupdate =  check.selected;
+          so.flush();
+      });
+      ctrl.addEventListener( fx.chart.ctrl.Event.SCALE_CHANGED,
+              autoUpdate.onScaleChanged, autoUpdate);
+      var so:SharedObject = SharedObject.getLocal("chartInfo");
+      check.selected = so.data.autoupdate;
+
+      try {
+        var loading:Loading = new Loading( model, ctrl, rc );
+        ctrl.stubFactory.listenerSupport.addEventListener( fx.chart.ctrl.Event.REQUEST_COUNT_CHANGED,
+              loading.onRequestCountChanged, loading  );
+      
+        tradeResult = new TradeResult( model, ctrl, rc );
+        ctrl.addEventListener( fx.chart.ctrl.Event.TRADE_DATA_CHANGED,
+            tradeResult.onTradeDataChanged, tradeResult);
+        ctrl.addEventListener( fx.chart.ctrl.Event.PROFIT_DATA_CHANGED,
+            tradeResult.onProfitDataChanged, tradeResult);
+        
+        candleChart = new CandleChart( model, ctrl, rc );
+        ctrl.addEventListener( fx.chart.ctrl.Event.CANDLE_DATA_CHANGED,
+            candleChart.onCandleDataChanged, candleChart);
+
+        pointer = new Pointer( model, ctrl, rc );
+        scaleSelector = new ScaleSelector( model, ctrl, rc );
+
+        scroll = new Scroll( model, ctrl, rc );
+        ctrl.addEventListener( fx.chart.ctrl.Event.RANGE_CHANGED,
+            scroll.onRangeChanged, scroll);
+        ctrl.addEventListener( fx.chart.ctrl.Event.SCALE_CHANGED,
+            scroll.onScaleChanged, scroll);
+
+        graphManager = new GraphManager( model, ctrl, rc );
+        ctrl.addEventListener( fx.chart.ctrl.Event.CANDLE_DATA_CHANGED,
+            graphManager.onCandleDataChanged, graphManager);
+        ctrl.addEventListener( fx.chart.ctrl.Event.OUTPUT_LIST_CHANGED,
+            graphManager.onGraphListChanged, graphManager);
+        
+        registExternalInterface();
+        ExternalInterface.call( "onChartLoaded" );
+
+
+      } catch ( ex:Error ) {
+        log(ex.message + ":" + ex.getStackTrace());
+      }
+    }
+    /**
+     * 外部インターフェイスを登録
+     */
+    private function registExternalInterface():void {
+        ExternalInterface.addCallback("initializeChart", this.initializeChart );
+        ExternalInterface.addCallback("setDate", function( date:Number ):void {
+            ctrl.changeDate( Util.createDate(date) );
+        } );
+        ExternalInterface.addCallback("setGraphVisible", this.setGraphVisible );
+        ExternalInterface.addCallback("setGraphColors", this.setGraphColors );
+    }
+    /**
+     * グラフを初期化する
+     */
+    private function initializeChart( processId:String, pair:String, scale:String, date:Number ):void {
+        if ( processId == "rmt" ) {
+            this.check.enabled = true;
+        } else {
+            this.check.enabled = false;
+        }
+        var so:SharedObject = SharedObject.getLocal("chartInfo");
+        pair = pair || so.data.pair || "EURJPY"; 
+        scale = scale || so.data.scale || "10m",
+        this.scaleSelector.init( pair, scale );
+        this.ctrl.init( processId, pair, scale, 
+                date ? Util.createDate(date) : null );
+        
+        if ( check.selected && check.enabled ) {
+            this.autoUpdate.start();
+        } else {
+            this.autoUpdate.stop();
+        }
+        
+        // 設定を記録
+        if ( pair ) {  so.data.pair = pair; }
+        if ( scale ) {  so.data.scale = scale; }
+        so.flush();
+    }
+    /**
+     * グラフの表示/非表示を設定
+     */
+    private function setGraphVisible( name:Array, visible:Boolean  ):void {
+        if ( visible ) {
+            this.graphManager.on( name );
+        } else {
+            this.graphManager.off( name );
+        }
+    }
+    /**
+     * グラフの色を設定
+     */
+    private function setGraphColors( name:Array, colors:Array  ):void {
+        this.graphManager.setGraphColors( name, colors );
+    }
+  }
+}

data/swf/chart/fx/chart/ctrl/AutoUpdate.as

@@ -0,0 +1,96 @@
+package fx.chart.ctrl {
+
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.net.*;
+  import fx.util.*;
+  import flash.utils.Timer;
+  import flash.events.TimerEvent;
+  
+  /**
+   * 自動更新
+   */
+  public class AutoUpdate {
+
+    /**
+     * タイマー。未起動の場合null
+     */
+    private var timer:Timer;
+
+    /**
+     * 自動更新を有効化するかどうか
+     */
+    private var enable:Boolean;
+
+    /**
+     * モデル
+     */
+    private var model:Model;
+
+    /**
+     * コントローラー
+     */
+    private var ctrl:Controller;
+
+    public function AutoUpdate( model:Model,
+        controller:Controller ) {
+        this.model = model;
+        this.ctrl = controller;
+    }
+
+    /**
+     * 自動更新を開始する。
+     */
+    public function start():void {
+        
+      // タイマーを作成。
+      timer = new Timer(model.scaleTime*1000, 0);
+
+      // チャートを更新。
+      timer.addEventListener("timer", function(ev:TimerEvent):void {
+          ctrl.init( model.processId, model.pair, model.scale, null );
+      });
+      // タイマーを開始
+      timer.start();
+    }
+
+    /**
+     * 自動更新を停止する。
+     */
+    public function stop():void  {
+      if ( timer ) {
+        timer.stop();
+        timer = null;
+      }
+    }
+
+    /**
+     * スケールが変更された
+     */
+    public function onScaleChanged( ev:Event ):void {
+      // タイマーを再起動
+      stop();
+      start();
+    }
+
+    /**
+     * 日時の範囲が更新された
+     */
+    public function onRangeChanged( ev:Event ):void {
+        // 自動更新フラグが立っていれば日付を再設定
+        // 最新のデータが表示されるようにマージンを取る
+        if ( enable ) {
+          ctrl.changeDate(
+            Util.createDate( model.range.last * 1000 - model.scaleTime * 25 ) );
+        }
+    }
+
+    /**
+     * 自動更新を行なうかどうか。
+     */
+    public function setEnable( enable:Boolean ):void {
+      this.enable = enable;
+    }
+
+  }
+}

data/swf/chart/fx/chart/ctrl/Controller.as

@@ -0,0 +1,258 @@
+package fx.chart.ctrl {
+
+  import fx.chart.*;
+  import fx.chart.model.*;
+  import fx.net.*;
+  import fx.util.*;
+  import flash.net.*;
+
+  /**
+   * コントローラー
+   */
+  public class Controller {
+
+    private var model:Model;
+    private var listener:ListenerSupport = new ListenerSupport();
+  
+    private var rateService:*;
+    private var outputService:*;
+    private var tradeResultService:*;
+    private var processService:*;
+    
+    public var stubFactory:StubFactory;
+  
+    /**
+     * コンストラクタ
+     */
+    public function Controller(model:Model) {
+      this.model = model;
+
+      stubFactory = new StubFactory("./json");
+      rateService = stubFactory.create("rate");
+      tradeResultService = stubFactory.create("trade_result");
+      outputService = stubFactory.create("output");
+      processService = stubFactory.create("process");
+    }
+
+    /**
+     * イベントリスナを追加する。
+     */
+    public function addEventListener( type:String,
+      listener:Function, self:*=null, priority:int=0 ):void {
+        this.listener.addEventListener( type,listener,self, priority);
+    }
+    
+    /**
+     * イベントリスナを削除する。
+     */
+    public function removeEventListener( type:String,
+      listener:Function ):void {
+        this.listener.removeEventListener( type,listener);
+    }
+    
+    /**
+     * イベントをキックする
+     */
+    public function fire( type:String ):void {
+        var ev:Event = new Event( type, model );
+        listener.fire( type, ev );
+    }
+
+    /**
+     * プロセスIDを更新する
+     */
+    public function changeProcessId( pid:String ):void {
+      if ( model.processId != pid ) {
+        model.processId = pid;
+        updateChartData( );
+        updateEnableData( );
+        updateOutputList( );
+        fire( Event.PROCESS_ID_CHANGED );
+      }
+    }
+
+    /**
+     * 通貨ペアを更新する
+     */
+    public function changePair( pair:String ):void {
+      if ( model.pair != pair ) {
+        model.pair = pair;
+        save( "pair",  pair);
+        updateChartData( );
+        updateEnableData( );
+      }
+    }
+
+    /**
+     * スケールを更新する
+     */
+    public function changeScale( scale:String ):void {
+      if ( model.scale != scale ) {
+        model.scale = scale;
+        save( "scale",  scale );
+        updateAll();
+        fire( Event.SCALE_CHANGED );
+      }
+    }
+
+    /**
+     * 表示日時を更新する
+     */
+    public function changeDate( date:Date ):void {
+      if ( model.date != date ) {
+        model.date = date;
+        updateChartData( );
+        updateTradeData( );
+        updateProfitData( );
+        fire( Event.DATE_CHANGED );
+      }
+    }
+    
+    /**
+     * 指定されたデータでチャートを初期化する。
+     * dateがnullの場合、利用可能な日時を取得し「最新の日時が真ん中あたりに来る」ように調整する。
+     * 
+     */
+    public function init( processId:String, pair:String, scale:String, date:Date ):void {
+        
+        // 調整不要なデータは先に設定。(利用可能範囲の取得で少なくともprocessIDは必要。)
+        model.processId = processId;
+        model.pair = pair;
+        model.scale = scale;
+        
+        _updateEnableData( function( range:Object ):void {
+            model.range = range;
+            var date:Number =  model.range.last - Model.COUNT/2*model.scaleTime;
+            model.date = Util.createDate(date);
+
+            // チャートを更新
+            updateChartData( );
+            updateTradeData( );
+            updateProfitData( );
+            updateOutputList( );
+            // 利用可能データ更新イベントをキックして、スクロールバーを更新。
+            fire( Event.RANGE_CHANGED );
+        });
+    }
+    
+    /**
+     * すべてを更新する
+     */
+    public function updateAll():void {
+      updateChartData( );
+      updateTradeData( );
+      updateProfitData( );
+      updateEnableData( );
+      updateOutputList( );
+    }
+
+    /**
+     * ローソク足チャートを更新する
+     */
+    public function updateChartData():void {
+      rateService.list( model.pair, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.rateDatas = model.createTimedDatas(datas, 5);
+            fire( Event.CANDLE_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+    /**
+     * 取引データを更新する
+     */
+    public function updateTradeData( ):void {
+      tradeResultService.list( model.processId, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.tradeDatas = model.createTimedDatas(datas, 10);
+            fire( Event.TRADE_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+    /**
+     * 損益データを更新する
+     */
+    public function updateProfitData( ):void {
+      tradeResultService.list_profit_or_loss( model.processId, model.scale,
+          model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+          function( datas:Array ):void {
+            model.profitDatas = model.createTimedDatas(datas, 4);
+            fire( Event.PROFIT_DATA_CHANGED );
+          }, function(error:*):void {
+            log(error); // TODO
+          } );
+    }
+
+
+    /**
+     * outputsデータ一覧を更新する
+     */
+    public function updateOutputList( ):void {
+        var names:Array = [];
+        outputService.list_outputs( model.processId,
+            function( datas:Object ):void {
+              model.graphs = datas;
+              fire( Event.OUTPUT_LIST_CHANGED );
+            }, function(error:*):void {
+              log(error); // TODO
+            } );
+    }
+
+    /**
+     * 表示可能な期間を更新する
+     */
+    public function updateEnableData( ):void {
+        _updateEnableData( function( range:Object ):void {
+            model.range = range;
+            fire( Event.RANGE_CHANGED );
+        });
+    }
+    /**
+     * 表示可能な期間を更新する
+     */
+    private function _updateEnableData( f:Function ):void {
+
+      // rmtの場合、サーバーから取得
+      if ( model.processId == "rmt" ) {
+          rateService.range( model.pair,
+              f, function(error:*):void {
+                log(error); // TODO
+              } );
+      } else {
+          // back_testの場合、指定されているはずの日時を使う。
+          processService.get( model.processId,
+              function( p:Object ):void {
+                var range:Object =  { 
+                  "first":p.start_date,
+                  "last":p.end_date 
+                };
+                f.call( null,  range );
+              }, function(error:*):void {
+                log(error); // TODO
+              } );
+      }
+    }
+    /**
+     * outputsデータを取得する
+     */
+    public function requestOutputDatas( names:Array, callback:Function ):void {
+        outputService.list_datas( model.processId, names, model.scale,
+            model.startDate.getTime()/1000, model.endDate.getTime()/1000,
+            function( datas:Object ):void {
+              callback.call( null, datas );
+            }, function(error:*):void {
+              log(error); // TODO
+            } );
+    }
+    /**設定を記録する*/
+    public function save( name:String, value:Object ):void {
+        var so:SharedObject = SharedObject.getLocal("chartInfo");
+        so.data[name]  = value;
+        so.flush();
+    }
+  }
+
+}