unageanu-jiji 0.1.0

data/swf/chart/fx/chart/ui/Window.as

@@ -0,0 +1,96 @@
+package fx.chart.ui {
+  
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import fx.chart.*;
+  import fx.util.*;
+  import flash.events.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.filters.*;
+  
+  /**
+   * ウインドウ
+   */
+  public class Window extends AbstractChartUI  {
+    
+    internal static const LINE_COLOR:uint = 0xFFFFFF;
+    internal static const FILL_COLOR:uint = 0xFFFFFF;
+    internal static const FILL_COLOR_DARK:uint = 0xF2F2EE;
+    internal static const LINE_COLOR_HIGH:uint = 0x939390;
+    internal static const LINE_COLOR_LOW:uint = 0xa3a3a0;
+    internal static const LINE_COLOR_AURA:uint = 0x76afaa;
+    
+    /**ウインドウを描画するスプライト*/
+    public var window:Sprite;
+    
+    public function Window( model:Model, controller:Controller, 
+        rc:RenderingContext, layer:Sprite, width:int, height:int ) {
+      
+      super( model,controller,rc );
+      
+      var stageWidth:int = rc.stage.width;
+      var stageHeight:int = rc.stage.height;
+      
+      // 情報ウインドウ
+      window = new Sprite();
+      var g:Graphics = window.graphics;
+      
+      // 本体
+      var matrix:Matrix = new Matrix();
+      matrix.createGradientBox(250, 250, 0, -50, -60);
+      g.beginGradientFill(
+          GradientType.RADIAL,
+          [FILL_COLOR, FILL_COLOR_DARK], 
+          [1,0.65], 
+          [0x00, 0xFF],
+          matrix, SpreadMethod.PAD,
+          InterpolationMethod.RGB, 0)
+      g.drawRect( 0, 0, width, height );
+      g.endFill();
+      
+      // 周りの白
+      g.lineStyle( 0, LINE_COLOR, 1, 
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.drawRect( 0, 0, width, height );
+      
+      // 内線
+      g.lineStyle( 2, LINE_COLOR_AURA, 0.2, 
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.drawRect( -2, -2, width+5, height+5 );
+      
+      // 左上辺
+      g.lineStyle( 0, LINE_COLOR_HIGH, 1, 
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.moveTo( -1, height+1 );
+      g.lineTo( -1, -1 );
+      g.lineTo( width+1, -1 );
+      
+      // 右下辺
+      g.lineStyle( 0, LINE_COLOR_LOW, 1, 
+          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      g.moveTo( 0, height+1 );
+      g.lineTo( width+1, height+1 );
+      g.lineTo( width+1, 0 );
+      
+      
+      
+      // 内線
+//      g.lineStyle( 0, LINE_COLOR_HIGH, 0.8, 
+//          true, LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+
+//      g.moveTo( 6, 1 );
+//      g.lineTo( width-6, 1 );
+//      g.lineTo( width-1, 6 );
+//      g.lineTo( width-1, height-6 );
+//      g.lineTo( width-6, height-1 );
+//      g.lineTo( 6, height-1 );
+//      g.lineTo( 1, height-6 );
+//      g.lineTo( 1, 6 );
+//      g.lineTo( 6, 1 );
+      
+      layer.addChild( window );
+    }
+  }
+}

data/swf/chart/fx/chart/ui/candle/Axis.as

@@ -0,0 +1,112 @@
+package fx.chart.ui.candle {
+
+  import fx.util.*;
+  import fx.chart.Chart;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * 軸
+   */
+  internal class Axis extends AbstractChartUI {
+
+    /**ローソク足を描画するスプライト*/
+    private var axis:Sprite;
+    private var lowAxis:Sprite;
+    private var axisY:Sprite;
+    private var lowAxisY:Sprite;
+
+    public function Axis( model:Model,controller:Controller, rc:RenderingContext,
+        main:Sprite, axis:Sprite, axisY:Sprite, lowAxis:Sprite, lowAxisY:Sprite ) {
+      super( model,controller,rc );
+      this.axis = axis;
+      this.lowAxis = lowAxis;
+      this.axisY = axisY;
+      this.lowAxisY = lowAxisY;
+    }
+
+    public function init( ):void {
+
+      var max:Number = model.positionManager.rateMax;
+      var min:Number = model.positionManager.rateMin;
+
+      var ctrl:Rectangle = rc.stage.ctrl;
+      var candle:Rectangle = rc.stage.candle;
+      var trade:Rectangle = rc.stage.trade;
+      var xAxis:Rectangle = rc.stage.xAxis;
+      var profit:Rectangle = rc.stage.profit;
+
+      // 軸の線を描画
+      var gb:Graphics = lowAxis.graphics;
+
+      // y軸メモリ
+      gb.lineStyle( 0, Constants.COLOR_AXIS_RIGHT, 1, true,
+          LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+
+      var diff:Number = max-min;
+      var step:Number = Math.pow(0.1, 3-int( max == 0 ? 1 : Math.log(max)*Math.LOG10E) );
+      if ((diff / step) > 5) {
+        step *= int( diff / step / 5);
+      }
+      var start:Number = Math.ceil( min / step ) * step;
+      for( var tmp:Number=start; tmp<=max; tmp+=step) {
+        var y:int = candle.bottom
+          - model.positionManager.fromRate(tmp,candle.height);
+        gb.moveTo( candle.left, y );
+        gb.lineTo( candle.right, y );
+
+        var scaleText:TextField = new TextField();
+        scaleText.selectable = false;
+        scaleText.text = tmp.toFixed( 4-(max == 0 ? 1 : Math.log(max)*Math.LOG10E) );
+        scaleText.width = candle.left-2;
+        scaleText.setTextFormat( Constants.TEXT_FORMAT_SCALE_Y );
+        scaleText.y = y-8;
+        scaleText.x = 0;
+
+        lowAxis.addChild(scaleText);
+      }
+
+      // x軸メモリの描画準備
+      var sf:ScaleFormatter = new ScaleFormatter( model.scale );
+      sf.start( Util.createDate( model.startDate.getTime()/1000 ) );
+      start = model.startDate.getTime()/1000;
+      var end:Number = model.endDate.getTime()/1000;
+      var next:Number = sf.nextDate().getTime()/1000;
+
+      while ( next < end ) {
+
+        var x:int = candle.left +
+          model.positionManager.fromDate( next );
+
+        // x軸のメモリを書く
+        lowAxisY.graphics.lineStyle( 0, Constants.COLOR_AXIS_RIGHT, 1, true,
+            LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+
+        var str:String = sf.format( Util.createDate(next) );
+        lowAxisY.graphics.moveTo( x, candle.top );
+        lowAxisY.graphics.lineTo( x, xAxis.top );
+        lowAxisY.graphics.moveTo( x, xAxis.bottom );
+        lowAxisY.graphics.lineTo( x, profit.bottom );
+
+        scaleText = new TextField();
+        scaleText.selectable = false;
+        scaleText.text = str;
+        scaleText.width = 100;
+        scaleText.setTextFormat( Constants.TEXT_FORMAT_SCALE_X );
+        scaleText.y = xAxis.top+0;
+        scaleText.x = x-50;
+
+        lowAxisY.addChild(scaleText);
+
+        next = sf.nextDate().getTime()/1000;
+      }
+    }
+    public function drawCandle( data:Object ):void {}
+  }
+
+}

data/swf/chart/fx/chart/ui/candle/Candle.as

@@ -0,0 +1,79 @@
+package fx.chart.ui.candle {
+
+  import fx.util.*;
+  import fx.chart.Chart;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * ローソク足
+   */
+  internal class Candle extends AbstractChartUI  {
+
+    private var main:Sprite;
+
+    public function Candle( model:Model,controller:Controller, rc:RenderingContext,
+        main:Sprite, axis:Sprite, axisY:Sprite, lowAxis:Sprite, lowAxisY:Sprite ) {
+      super( model,controller,rc );
+      this.main = main;
+    }
+
+    public function init( ):void {
+
+    }
+    public function drawCandle( data:Object ):void {
+
+      var pm:PositionManager = model.positionManager;
+      var g:Graphics = main.graphics;
+
+      // 中心位置なので2を引いて蝋の左辺にする
+      var x:int = pm.fromDate( data[5] ) + rc.stage.candle.left - 2;
+
+      g.lineStyle( 0, Constants.COLOR_CANDLE, 1, true,
+          LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+
+      // 蝋
+      var up:Boolean = data[1] >= data[0];
+      var low:Number  = !up  ? data[1] : data[0];
+      var high:Number = up ? data[1] : data[0];
+
+      var height:int = rc.stage.candle.height;
+
+      var y:int = pm.fromRate( high, height ); // int((max - high) * hp );
+      var h:int = y - pm.fromRate( low, height );
+//      var matr:Matrix = new Matrix();
+//      matr.createGradientBox(10, h, Math.PI / 2, 0, y+PADDING);
+      g.moveTo( x, rc.stage.candle.bottom - y );
+      g.beginFill( up ? Constants.COLOR_ROW_UP_HIGH : Constants.COLOR_ROW_DOWN_LOW, 1.0 );
+//      g.beginGradientFill(
+//          GradientType.LINEAR,
+//          up ? [COLOR_ROW_UP_HIGH, COLOR_ROW_UP_LOW]
+//             : [COLOR_ROW_DOWN_HIGH, COLOR_ROW_DOWN_LOW],
+//          [1,1],
+//          [0x00, 0xFF],
+//          matr,
+//          SpreadMethod.PAD)
+      g.drawRect( x, rc.stage.candle.bottom - y, 4, h );
+      g.endFill();
+
+      // 火
+      if ( data[2] != high ) {
+        var y2:int =  pm.fromRate( data[2], height ); //int((max - data[2]) * hp );
+        g.moveTo( x+2, rc.stage.candle.bottom - y2 );
+        g.lineTo( x+2, rc.stage.candle.bottom - y );
+      }
+      if ( data[3] != low ) {
+        var y3:int = pm.fromRate( data[3], height ); // int((max - data[3]) * hp );
+        g.moveTo( x+2, rc.stage.candle.bottom - (y-h) );
+        g.lineTo( x+2, rc.stage.candle.bottom - y3 );
+      }
+      //x += 2;
+    }
+  }
+
+}

data/swf/chart/fx/chart/ui/candle/CandleChart.as

@@ -0,0 +1,81 @@
+package fx.chart.ui.candle {
+
+  import fx.util.*;
+  import fx.chart.Chart;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * ローソク足チャート
+   */
+  public class CandleChart extends AbstractDrawChartUI {
+
+    private var elements:Array;
+
+    /**
+     * コンストラクタ
+     */
+    public function CandleChart(model:Model,
+        controller:Controller, rc:RenderingContext) {
+      super( model,controller,rc );
+
+      elements = [ 
+          new Axis(   model,controller,rc,main,axis,axisY,lowAxis,lowAxisY ),
+          new Candle( model,controller,rc,main,axis,axisY,lowAxis,lowAxisY ) ];
+    }
+
+    public function onCandleDataChanged( ev:Event ):void {
+
+      // データ数から、各データあたりの幅を算出
+      var graphWidth:Number = rc.stage.candle.width;
+      var graphHeight:Number = rc.stage.candle.height;
+
+
+      // レイヤーを初期化
+      ([main, axis,axisY,lowAxis,lowAxisY]).forEach( function(l:*,i:*,arr:Array):void{
+          l.x = 0;
+          Util.clear( l );
+      } );
+      
+      var ctrl:Rectangle = rc.stage.ctrl;
+      var candle:Rectangle = rc.stage.candle;
+      var trade:Rectangle = rc.stage.trade;
+      var xAxis:Rectangle = rc.stage.xAxis;
+      var profit:Rectangle = rc.stage.profit;
+
+      // 軸の線を描画
+      var g:Graphics = axis.graphics;
+      var gb:Graphics = lowAxis.graphics;
+
+      // 軸
+      g.lineStyle( 0, Constants.COLOR_AXIS_HI );
+      g.moveTo( candle.left+1, candle.top);
+      g.lineTo( candle.left+1, profit.bottom-1 );
+      g.moveTo( candle.left+1, xAxis.top+1 );
+      g.lineTo( candle.right,  xAxis.top+1);
+
+      g.lineStyle( 0, Constants.COLOR_AXIS );
+      g.moveTo( candle.left, candle.top);
+      g.lineTo( candle.left, profit.bottom );
+      g.moveTo( candle.left, xAxis.top );
+      g.lineTo( candle.right,  xAxis.top);
+      
+      if ( model.rateDatas.getDatas().length <= 0 ) { return; }
+
+      for (var i:int=0; i < elements.length; i++) {
+        elements[i].init();
+      }
+      var datas:Array = model.rateDatas.getDatas();
+      for (var j:int=0; j < datas.length; j++) {
+        for (i=0; i < elements.length; i++) {
+          elements[i].drawCandle( datas[j] );
+        }
+      }
+    }
+  }
+}

data/swf/chart/fx/chart/ui/graph/Graph.as

@@ -0,0 +1,198 @@
+package fx.chart.ui.graph {
+
+  import fx.util.*;
+  import fx.chart.Chart;
+  import fx.chart.ui.*;
+  import fx.chart.model.*;
+  import fx.chart.ctrl.*;
+  import flash.display.*;
+  import flash.text.*;
+  import flash.geom.*;
+  import flash.external.*;
+
+  /**
+   * グラフ
+   */
+  public class Graph extends AbstractDrawChartUI {
+
+    public function Graph( model:Model,
+        controller:Controller, rc:RenderingContext ) {
+      super( model,controller,rc );
+    }
+
+    public function draw( data:Object, colors:Array ):void {
+      main.x = 0;
+      Util.clear( main );
+
+      // データ数分のスプライトを作成
+      if ( !data["datas"] || data["datas"].length <= 0 ) { return; }
+      var sprites:Array = [];
+      for ( var i:int=0; i< data.datas[0].length; i++ ) {
+        var s:Sprite = new Sprite();
+        main.addChild( s );
+        sprites.push( s );
+      }
+      if ( data["options"]["graph_type"] == "rate" ) {
+        drawWithRate( data, colors, sprites );
+      } else if ( data["options"]["graph_type"] == "zero_base" ) {
+        drawZeroBase( data, colors, sprites );
+      } else {
+        drawBasic( data, colors, sprites );
+      }
+    }
+
+    /**
+     * レートにあわせてグラフを書く
+     */
+    private function drawWithRate( data:Object, colors:Array, sprites:Array ):void {
+
+      var pm:PositionManager = model.positionManager;
+      var height:int = rc.stage.candle.height;
+      var f:Function = function(value:*):int {
+        return  rc.stage.candle.bottom - pm.fromRate( value, height ); 
+      }
+      // グラフ
+      drawLineGraph( data, f, colors, sprites  );
+    }
+
+    /**
+     * 0を中心とするグラフを書く
+     */
+    private function drawZeroBase( data:Object, colors:Array, sprites:Array ):void {
+
+      var pm:PositionManager = model.positionManager;
+      var rect:Rectangle = rc.stage.graph;
+      var middle:int = rect.top + rect.height/2;
+        
+      var range:Array = range( data );
+      var m:Number = Math.max( Math.abs(range[0]), Math.abs(range[1]) );
+      var valueParPixel:Number = m*2 / rect.height;
+      
+      var f:Function = function(value:*):int {
+        return middle - int(value / valueParPixel); 
+      }
+    
+      // 背景線を引く
+      drawAxis( data, f );
+      
+      // 0
+      lowAxis.graphics.lineStyle( 0, Constants.COLOR_CANDLE, 1, true,
+        LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      var y:int = middle;
+      lowAxis.graphics.moveTo( rect.left,  y);
+      lowAxis.graphics.lineTo( rect.right,  y);
+      createText( "0", axis, Constants.TEXT_FORMAT_SCALE_Y,  0, middle-8, rect.left-2 );
+      
+      // グラフ
+      drawLineGraph( data, f , colors, sprites );
+    }
+
+    /**
+     * 最大値と最小値をマッピングするグラフを書く
+     */
+    private function drawBasic( data:Object, colors:Array, sprites:Array ):void {
+      var pm:PositionManager = model.positionManager;
+      var rect:Rectangle = rc.stage.graph;
+ 
+      var range:Array = range( data );
+      var diff:Number = range[1] - range[0];
+      var valueParPixel:Number = diff / rect.height;
+      
+      var f:Function = function(value:*):int {
+        return rc.stage.graph.bottom - int((value-range[0]) / valueParPixel); 
+      }
+      
+      // 背景線を引く
+      drawAxis( data, f );
+        
+      // グラフ
+      drawLineGraph( data, f , colors, sprites );
+    }
+    /**
+     * 描画用のスプライトを造る。
+     */
+    private function createSprites( colors:Array,  sprites:Array ):Array {
+      var gs:Array = [];
+      for ( var i:int =0; i < sprites.length; i++ ) {
+        var g: Graphics = sprites[i].graphics;
+        g.lineStyle( 0, i < colors.length ? colors[i] : 0x557777, 0.8, false,
+          LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+        gs.push( g );
+      }
+      return gs;
+    }
+    
+    /**
+     * 最大値、最小値を取得する
+     */
+    private function range( data:Object ):Array {
+
+      var max:Number = Number.MIN_VALUE;
+      var min:Number = Number.MAX_VALUE;
+
+      // 線
+      if ( data["options"]["lines"] ) {
+        data["options"]["lines"].forEach( function( item:*,i:int,arr:Array ):void{
+          max = Math.max( max, item );
+          min = Math.min( min, item );
+        } );
+      }
+
+      // データ
+      data.datas.forEach( function( item:*, i:int, arr:Array ):void {
+        for ( var j:int =0; j < item.length-3; j++ ) {
+          max = Math.max( max, item[j] );
+          min = Math.min( min, item[j] );
+        }
+      } );
+
+      // マージンを上下に確保
+      if ( max == min ) {
+        var d:Number = max * 0.01;
+        min = max - d;
+        max = max + d;
+      } else {
+        max += (max - min ) * 0.1;
+        min -= (max - min ) * 0.1;
+      }
+      return [min,max];
+    }
+
+    /**
+     * 背景線を描画する。
+     */
+    private function drawAxis( data:Object, f:Function ):void {
+      var rect:Rectangle = rc.stage.graph;
+      lowAxis.graphics.lineStyle( 0, Constants.COLOR_AXIS_RIGHT, 1, true,
+        LineScaleMode.NONE, CapsStyle.NONE, JointStyle.BEVEL );
+      if ( data["options"]["lines"] ) {
+        data["options"]["lines"].forEach( function( item:*,i:int,arr:Array ):void{
+            var y:int = f(item); 
+            lowAxis.graphics.moveTo( rect.left,  y);
+            lowAxis.graphics.lineTo( rect.right,  y);
+            createText( String(item), axis,  Constants.TEXT_FORMAT_SCALE_Y,  0, y-3, rect.left-5 );
+        } );
+      }
+    }
+    
+    /**
+     * 線グラフを描画する。
+     */
+    private function drawLineGraph( data:Object, f:Function, colors:Array, sprites:Array ):void {
+      if ( data.datas.length <= 0 ) { return; }
+      var pm:PositionManager = model.positionManager;
+      var gs:Array =createSprites( colors, sprites );
+      data.datas.forEach( function( item:*, i:int, arr:Array ):void {
+        var x:int =  pm.fromDate( item[item.length-1] ) + rc.stage.candle.left;
+        for ( var j:int =0; j < item.length-3; j++ ) {
+          var y:int = f( item[j] );
+          if ( i == 0 ) {
+            gs[j].moveTo( x, y )
+          } else {
+            gs[j].lineTo( x, y )
+          }
+        }
+      });
+    }
+  }
+}