michaelforrest-tidy 0.1.1

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/Collection.as

@@ -0,0 +1,296 @@
+package com.lbi.mvc.collection {
+	use namespace AS3;
+	import com.lbi.mvc.model.EventMapper;
+	import com.lbi.mvc.model.IEventMapper;
+
+	import flash.events.Event;
+	public dynamic class Collection extends Array implements IEventMapper{
+		public static var CHANGED : String = "changed";
+		private function dispatchChanged():void {event_mapper.dispatchEvent(new Event(CHANGED));}
+
+		public static var INCREASED : String = "increased";
+		private function dispatchIncreased():void {event_mapper.dispatchEvent(new Event(INCREASED));}
+
+		public static var DECREASED : String = "decreased";
+		private function dispatchDecreased():void {event_mapper.dispatchEvent(new Event(DECREASED));}
+
+		public static var CHANGED_SIZE : String = "changed_size";
+		private function dispatchChangedSize():void {event_mapper.dispatchEvent(new Event(CHANGED_SIZE));}
+
+		public var event_mapper : EventMapper;
+
+		private var __index:Number;
+		private var __previous_index:Number = 0;
+
+		private function get _index():Number{
+			return __index;
+		}
+		private function set _index(v:Number):void{
+			__previous_index = __index;
+			__index = v;
+			_current = this[__index];
+		}
+
+		private var __current:Object;
+		private function get _current():Object{
+			return __current;
+		}
+		private function set _current(v:Object):void{
+			__current = v;
+			try{
+				__current.select();
+			}catch(e : Error){
+				throw new Error("You probably need to make " + __current + " extend Selectable. " + e);
+			}
+		}
+
+		public var loop : Boolean;
+
+		private var __id__ : Number;
+		private static var __next_id__ : Number = 0;
+		function Collection(...$init_items){//$array: Array,$loop:Boolean) {
+			super();
+			//importArray($array);
+			//loop = $loop;
+			event_mapper = new EventMapper();
+			//EventMapper.initialize(this);
+			__id__ = __next_id__++;
+			if($init_items && $init_items[0]) {
+				for (var i : Number = 0; i < $init_items[0].length; i++) {
+					var item:Object = $init_items[0][i];
+					add(item);
+				}
+			}
+		}
+		public function selectFirst() :void{
+			select(first());
+		}
+		/**
+		 * Copies a normal array into this collection.
+		 */
+		public function importArray($array : Array) :void{
+			while(length>0) pop();
+			for (var i : Number = 0; i < $array.length; i++) {
+				push($array[i]);
+			}
+		}
+		/**
+		 * Returns currently selected item
+		 */
+		public function current() : Object {
+			//if(!_current) Log.warn("nothing is yet selected in " + this);
+			return _current;
+		}
+		public function previouslySelected() : Object{
+			return this[getPreviousIndex()];
+		}
+		public function hasNext() : Boolean {
+			return _index+1 < length && length > 0;
+		}
+		/**
+		 * If there is another item in the collection after the current (or the collection is looped) then
+		 * this method selects the next item and dispatches Collection.INCREASED, then Collection.CHANGED
+	 	 * The selected item conventionally dispatches SELECTED and DESELECTED events, encouraged via the use of the ISelectable interface.
+		 */
+		public function next() : void {
+			if(!hasNext() && !loop) return;
+			ISelectable(current()).deselect();
+			if(hasNext()){
+				_index++;
+				dispatchIncreased();
+			}
+			else{
+				_index = 0;
+			}
+			dispatchChanged();
+		}
+
+		public function hasPrev() : Boolean {
+			return _index > 0;
+		}
+		/**
+		 * If there is another item in the collection before the current (or the collection is looped) then
+		 * this method selects the previous item and dispatches Collection.DECREASED, then Collection.CHANGED.
+		 * The selected item conventionally dispatches SELECTED and DESELECTED events, encouraged via the use of the ISelectable interface.
+		 */
+		public function previous() : void {
+			if(!hasPrev() && !loop) return;
+			ISelectable(current()).deselect();
+			if(hasPrev()){
+				_index --;
+				dispatchDecreased();
+			}
+			else{
+				_index = length-1;
+			}
+			dispatchChanged();
+		}
+		/**
+		 * selects the required item by reference.
+		 * This is useful when you have a button in your view that holds a reference to an item model.
+		 * The view can simply call collection.select(model) and the collection will be updated.
+		 */
+		public function select($item:Object):void{
+			if(current()) ISelectable(current()).deselect();
+			for (var i : Number = 0; i < this.length; i++) {
+				var item : Object = this[i];
+				if(item === $item) {
+					_index = i; // selects the current item
+				}
+			}
+			dispatchChanged();
+		}
+		/*
+		 * Sets selection to null
+		 */
+		public function deselect():void{
+			if(current()) ISelectable(current()).deselect();
+			__index = NaN;
+			__current = null;
+			//dispatchChanged();
+		}
+
+		/**
+		 * Removes an item from the collection
+		 */
+		public function remove($item:Object) : Object{
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item===$item) {
+					AS3::splice(i,1);
+//					_index = getIndex(current());
+					dispatchChangedSize();
+					return item;
+				}
+			}
+			return null;
+		}
+		/**
+		 * finds (without selecting) an item in the array based on the object reference.
+		 */
+		public function find($item:Object) : Object{
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item===$item) {
+					return item;
+				}
+			}
+			return null;
+		}
+		public function first() : Object{
+			return this[0];
+		}
+		public function last() : Object{
+			return this[length-1];
+		}
+
+		public function getCurrentIndex() :Number{
+			return _index;
+		}
+		/**
+		 * Returns the index of the specified item in this array.
+		 */
+		public function getIndex($item:Object) : Number{
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item==$item) return i;
+			}
+			return Number.NaN;
+			//Log.error("Couldn't find item " + $item + " in Collection " + this);
+		}
+		public function toString() :String{
+			var result : String = "[Collection id:" + __id__ ;
+			for (var i : Number = 0; i < length; i++) {
+				var item:Object = this[i];
+				result += item.toString() + ",";
+			}
+			return result +"]";
+		}
+
+		public function registerEvents(view : Object, events : Array) : void {
+			event_mapper.registerEvents(view, events);
+		}
+
+		public function findByProperty($property : String, value : Object) : Object {
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item[$property]==value) return item;
+			}
+			return null;
+		}
+
+		public function findByExactProperty($property : String, value : Object) : Object {
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item[$property]===value) return item;
+			}
+			return null;
+		}
+		public function append(collection:Collection) : void{
+			for (var i : Number = 0; i < collection.length; i++) {
+				var item:Object = collection[i];
+				push(item);
+			}
+		}
+
+		public function push(value:Object):Number{
+			var result : Number = super.push(value);
+			dispatchChangedSize();
+			return result;
+		}
+		public function add(value:Object) : Number{
+			var result : Number = super.push(value);
+			dispatchChangedSize();
+			return result;
+		}
+
+		public function getPreviousIndex() : Number {
+			return __previous_index;
+		}
+		public function clone() : Collection{
+			return new Collection(this);
+		}
+		public function reverse() : Collection{
+			return new Collection(super. reverse());
+		}
+
+		public function dispatchEvent(event : Event) : Boolean {
+			return event_mapper.dispatchEvent(event);
+		}
+
+		public function hasEventListener(type : String) : Boolean {
+			return event_mapper.hasEventListener(type);
+		}
+
+		public function willTrigger(type : String) : Boolean {
+			return event_mapper.willTrigger(type);
+		}
+
+		public function removeEventListener(type : String, listener : Function, useCapture : Boolean = false) : void {
+			event_mapper.removeEventListener(type, listener);
+		}
+
+		public function addEventListener(type : String, listener : Function, useCapture : Boolean = false, priority : int = 0, useWeakReference : Boolean = false) : void {
+			event_mapper.addEventListener(type, listener,false,0,true);
+		}
+
+		public function unregisterEvents(view : Object, events : Array) : void {
+			event_mapper.unregisterEvents(view, events);
+		}
+//		override public function toString() : String {
+//			return "[Collection" + join(",") + "]";
+//		}
+		public function findAll(query : String) : Collection {
+			var results : Collection = new Collection();
+			try{
+				for (var i : int = 0; i < this.length; i++) {
+					var item : Matchable = this[i];
+					if(item.matches(query)) results.add(item);
+				}
+			} catch(e :Error){
+				throw new Error("You probably need to make " + this[0] + " implement Matchable. "+ e);
+			}
+			return results; 
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/ISearchable.as

@@ -0,0 +1,10 @@
+package com.lbi.mvc.collection {
+	/**
+	 * @author michaelforrest
+	 */
+	public interface ISearchable {
+		function findByProperty($property : String, $value : Object) : Object;
+		function findByValue($value : Object) : Object;
+		//function push(object : Object) : Number;
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/ISelectable.as

@@ -0,0 +1,10 @@
+package com.lbi.mvc.collection {
+	/**
+	 * @author michaelforrest
+	 */
+	public interface ISelectable {
+		function select():void;
+		function deselect():void;
+		function isSelected():Boolean;
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/Matchable.as

@@ -0,0 +1,9 @@
+package com.lbi.mvc.collection {
+
+	/**
+	 * @author michaelforrest
+	 */
+	public interface Matchable {
+		function matches(query : String) : Boolean;
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/Searchable.as

@@ -0,0 +1,56 @@
+package com.lbi.mvc.collection {
+
+	/**
+		LBi Useful ActionScript 2 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+	
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+	
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+	
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA 
+	 */
+	use namespace AS3;
+	public dynamic class Searchable extends Array implements ISearchable{
+	
+		public static function initialize($searchable : ISearchable) : void {
+			var instance : Searchable = new Searchable([]);
+			$searchable["findByProperty"] = instance.findByProperty;
+			$searchable["findByValue"] = instance.findByValue;
+		}
+		
+		public function Searchable($array: Array ) {
+			for (var i : Number = 0; i < $array.length; i++) {
+				var item:Object = $array[i];
+				push(item);
+			}
+		}
+		
+		public function findByProperty($property : String, $value : Object) : Object {
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item[$property]==$value) return item;
+			}
+			return null;
+		}
+	
+	
+	
+		public function findByValue($value : Object) : Object {
+			for (var i : Number = 0; i < this.length; i++) {
+				var item:Object = this[i];
+				if(item==$value) return item;
+			}
+			return null;
+		}
+	
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/collection/Selectable.as

@@ -0,0 +1,49 @@
+package com.lbi.mvc.collection {
+	import flash.events.Event;
+
+	import com.lbi.mvc.model.EventMapper;
+	public class Selectable extends EventMapper implements ISelectable{
+
+		public static const SELECTED : String = "selected";
+
+		// Gonna see how easy this makes testing!
+		public static var lastSelectedThing : Selectable;
+
+
+
+
+		protected function dispatchSelected():void {dispatchEvent(new Event(SELECTED));}
+		public static const DESELECTED : String = "deselected";
+
+		protected function dispatchDeselected():void {dispatchEvent( new Event(DESELECTED));}
+
+		protected var __selected__ : Boolean = false;
+
+		public function Selectable() {
+		}
+
+		public function select() : void {
+			if(__selected__) return;
+			__selected__ = true;
+			lastSelectedThing = this;
+			dispatchSelected();
+		}
+
+		public function deselect() : void {
+			__selected__ = false;
+			dispatchDeselected();
+		}
+
+		public function isSelected() : Boolean {
+			return __selected__;
+		}
+		public static function initialize(object:ISelectable) : void{
+			var inst : Selectable = new Selectable();
+			//object["__selected__"] = inst["__selected__"];
+			object["select"] = inst.select;
+			object["deselect"] = inst.deselect;
+			object["isSelected"] = inst.isSelected;
+		}
+
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/helper/Cloner.as

@@ -0,0 +1,15 @@
+package com.lbi.mvc.helper {
+	import flash.utils.ByteArray;	
+	/**
+	 * @author michaelforrest
+	 */
+	public class Cloner {
+		// from kirupa
+		public static function clone(source:Object):* {
+		    var copier:ByteArray = new ByteArray();
+		    copier.writeObject(source);
+		    copier.position = 0;
+		    return(copier.readObject());
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/helper/TypographyBase.as

@@ -0,0 +1,194 @@
+package com.lbi.mvc.helper {
+	import flash.display.DisplayObject;
+	import flash.display.Sprite;
+	import flash.geom.Rectangle;
+	import flash.text.TextField;
+	import flash.text.TextFormat;
+	/**
+	LBi Useful ActionScript 3 Library (ported from AS2 Library equivalent)
+    Copyright (C) 2007 LBi / Michael Forrest
+
+    This library is free software; you can redistribute it and/or
+    modify it under the terms of the GNU Lesser General Public
+    License as published by the Free Software Foundation; either
+    version 2.1 of the License, or (at your option) any later version.
+
+    This library is distributed in the hope that it will be useful,
+    but WITHOUT ANY WARRANTY; without even the implied warranty of
+    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+    Lesser General Public License for more details.
+
+    You should have received a copy of the GNU Lesser General Public
+    License along with this library; if not, write to the Free Software
+    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+ * This class eschews the usual naming conventions in favour of something
+ * that looks a bit more like CSS. Override the Defaults() method to set the defaults.
+ * <pre>
+ * class app.helpers.Typography extends TypographyBase {
+
+	private var WHITE : Number = 0xFFFFFF;
+
+	private var ORANGE : Number = 0xF68B1E;
+
+	function Typography(style:String) {
+		super(style);
+	}
+	private function Defaults() : void{
+		font = Linkages.ARIAL;
+		colour = WHITE;
+	}
+	private function H1() : void{
+		font_size = 24;
+	}
+	private function P() : void{
+		font_size = 12;
+	}
+	private function Footer() : void{
+		font_size = 16;
+	}
+	private function ItemHeading() : void{
+		font_size = 16;
+		bold = true;
+		colour = ORANGE;
+	}
+
+}
+ * </pre>
+ *
+ */
+	public class TypographyBase {
+
+		public function TypographyBase(style:String = "") {
+			Defaults();
+			if(style && this[style]!=null) {
+				this[style]();
+			}
+		}
+		public function changeStyle(txt : TextField, style : Function) : void {
+			this[style]();
+			var formats:Object = getTextFieldParams();
+			for(var i:String in formats) txt[i] = formats[i];
+
+			var fmt:TextFormat = getTextFormat();
+			txt.setTextFormat(fmt);
+			txt.text = txt.text;
+		}
+
+		public function System() : void {
+			embed_fonts = false;
+			font = "_sans";
+			font_size = 11;
+			background = true;
+		}
+
+		public static function getSystemFont() : TypographyBase{
+			return new TypographyBase("System");
+		}
+
+		/*
+		 * TextFormat stuff
+		 */
+		public var font_size : Number = 12;
+		public var font : String = "Bodyfont";
+		public var colour : Number = 0;
+		public var bold : Boolean = false;
+		public var italic : Boolean = false;
+		public var underline : Boolean = false;
+		public var url : String = "";
+		public var target : String = "";
+		public var align : String = "left";
+		public var left_margin : Number = 0;
+		public var right_margin : Number = 0;
+		public var indent : Number = 0;
+		public var leading : Number = 0;
+
+		/*
+		 * TextField parameters
+		 */
+		public var auto_size : String = "left";
+		public var background : Boolean = false;
+		//public var html : Boolean = false;
+		public var word_wrap : Boolean = true;
+		public var multiline : Boolean = true;
+		public var condense_white : Boolean = true;
+		public var border : Boolean = false;
+		public var selectable : Boolean = false;
+		public var embed_fonts : Boolean = true;
+		public var type : String = "dynamic";
+		/**
+		 * Flash 8 only
+		 * Can be "normal" or "advanced".
+		 * @see gridFitType, thickness and sharpness
+		 */
+		public var antiAliasType:String = "normal";
+		/**
+		 * Flash 8 only
+		 * Can be "none", "pixel" or "subpixel"
+		 */
+		public var gridFitType:String = "none";
+		/**
+		 * Flash 8 only
+		 * In range -200 to 200
+		 * The thickness of the glyph edges in this TextField
+		 * instance. This property applies only
+		 * when antiAliasType() is set to "advanced".
+		 */
+		public var thickness:Number = 0;
+		public var max_chars : Number;
+		/**
+		 * Flash 8 only
+		 * The range for sharpness is a number from -400 to 400.
+		 */
+		public var sharpness:Number = 0;
+		/**
+		 * Flash 8 only
+		 * The amount of space that is uniformly distributed between characters.
+		 */
+		public var letterSpacing : Number = 0;
+
+		protected function Defaults() : void {
+		}
+
+		public function getTextFormat() : TextFormat{
+			var tf : TextFormat = new TextFormat(font, font_size, colour,
+									bold, italic, underline, url,target, align,
+									left_margin, right_margin, indent, leading);
+			tf.letterSpacing = letterSpacing;
+			return tf;
+		}
+		public function getTextFieldParams():Object{
+			var t:Object = new Object(); // TextField
+			t.background = background;
+			t.embedFonts = embed_fonts;
+			t.selectable = selectable;
+			t.border = border;
+			t.condenseWhite = condense_white;
+			t.multiline = multiline;
+			t.wordWrap = word_wrap;
+			//t.html = html;
+			t.autoSize = auto_size;
+			t.type = type;
+			t.antiAliasType = antiAliasType;
+			t.gridFitType = gridFitType;
+			t.thickness = thickness;
+			t.sharpness = sharpness;
+			t.maxChars = max_chars;
+			return t;
+		}
+
+		public static function createTextField(style : TypographyBase, rectangle : Rectangle) : TextField {
+			var txt : TextField = new TextField();
+			txt.x = rectangle.x;
+			txt.y = rectangle.y;
+			txt.width = rectangle.width;
+			txt.height = rectangle.height;
+			var formats:Object = style.getTextFieldParams();
+			for(var i:String in formats) txt[i] = formats[i];
+
+			var fmt : TextFormat = style.getTextFormat();
+			txt.defaultTextFormat = fmt;
+			txt.setTextFormat(fmt);
+			return txt;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/helper/preloading/LoadProgressEvent.as

@@ -0,0 +1,18 @@
+package com.lbi.mvc.helper.preloading {
+	import com.lbi.mvc.model.SequentialDependencyLoader;
+
+	import flash.events.Event;
+	/**
+	 * @author michaelforrest
+	 */
+	public class LoadProgressEvent extends Event {
+
+		public static const PROGRESS : String = "progress";
+		public var loader : SequentialDependencyLoader;
+
+		public function LoadProgressEvent(dependencyLoader : SequentialDependencyLoader) {
+			super(PROGRESS);
+			loader = dependencyLoader;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/mvc/model/Application.as

@@ -0,0 +1,45 @@
+package com.lbi.mvc.model {
+	import com.lbi.mvc.model.EventMapper;
+	import com.lbi.mvc.model.SequentialDependencyLoader;
+
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.utils.getQualifiedClassName;
+	/**
+	 * @author michaelforrest
+	 */
+	public class Application extends EventMapper {
+		public static var READY : String = "ready";
+		public function dispatchReady() : void {dispatchEvent(new Event(READY));
+		}
+
+		private var dependencyLoader : SequentialDependencyLoader;
+
+		protected var dependencies : Array;
+
+		public function Application() {
+			setup();
+			dependencyLoader  = new SequentialDependencyLoader( dependencies);//.map(prepare));
+			dependencyLoader.addEventListener(SequentialDependencyLoader.READY, onXMLReady,false,0,true);
+		}
+
+
+
+		private function prepare(element : *, index : int, arr : Array) : EventDispatcher {
+			if(!element.prepare) throw new Error("Please create a prepare() : EventDispatcher {} event on class " +  getQualifiedClassName(element));
+			return element.prepare();
+		}
+
+		protected function setup() : void {
+			dependencies = [];
+		}
+		private function onXMLReady(event : Event) : void {
+			afterLoaded();
+			dispatchReady();
+		}
+
+		protected function afterLoaded() : void {
+		}
+
+	}
+}