michaelforrest-tidy 0.1.1

data/lib/aslibs/as3/lbi/com/lbi/animation/util/GroupCommon.as

@@ -0,0 +1,62 @@
+package com.lbi.animation.util {
+	import com.lbi.animation.single.OrphanEvent;
+	import flash.events.EventDispatcher;
+	import flash.events.IEventDispatcher;
+
+	import com.lbi.animation.single.MethodWithCompleteEvent;
+	import com.lbi.animation.util.IAnimation;
+	/**
+	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	*/
+	public class GroupCommon extends EventDispatcher {
+		protected var items:/*IAnimation*/ Array;
+		private var label:String = "";
+		public function GroupCommon(...$items) {
+			items = new Array();
+			//TODO: make the initialization work (I don't  really get these ... arguments yet.. sorry - MF)
+			/*
+			for(var i:Number=0; i<$items.length; i++){
+				var item : Animation = $items[i];
+				if(item != null) addAnimation(item);
+			}*/
+		}
+		/**
+		 * The only requirement is that the object:IEvent dispatches an event
+		 * named in complete_event when it's finished its thang
+		 * If you set complete_event to null or undefined, then the method is called synchronously.
+		 * @param - the object executing the method
+		 * @param - a delegate for the method to execute
+		 */
+		public function addMethod(object : IEventDispatcher, method:Function, complete_event:String , ...args) : void {
+			var new_method : MethodWithCompleteEvent = new MethodWithCompleteEvent(object,method,complete_event,args);
+			addItem(new_method);
+		}
+		protected function addItem(animation : IAnimation) : void {
+			items.push(animation);
+		}
+		public function addAnimation(animation:IAnimation) : void {
+			addItem(animation);
+		}
+		public function addLabel(l:String) : void {
+			this.label = l;
+		}
+		public function waitForEvent(object : IEventDispatcher, event : String) : void {
+			addItem(new OrphanEvent(object, event));
+		}
+	}
+	}

data/lib/aslibs/as3/lbi/com/lbi/animation/util/IAnimation.as

@@ -0,0 +1,30 @@
+package com.lbi.animation.util {
+	import flash.events.IEventDispatcher;
+
+	/**
+	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	* IAnimation is used for any class that you can tell go() and dispatches "complete" when it has finished doing whatever it was doing
+	 */
+	[Event("complete")]
+	public interface IAnimation extends IEventDispatcher {
+		function go() : void;
+		function destroy() : void;
+		function stop(dispatchComplete:Boolean = false) : void;
+		function isComplete():Boolean;
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/DraggyClip.as

@@ -0,0 +1,96 @@
+package com.lbi.debug {
+	import flash.display.Sprite;
+	import flash.events.Event;
+	import flash.events.KeyboardEvent;
+	import flash.events.MouseEvent;
+	import flash.ui.Keyboard;
+	/**
+	 * @author michaelforrest
+	 */
+	public class DraggyClip {
+		public static function initialize(sprite : Sprite) : void {
+
+			sprite.mouseChildren = false;
+			sprite.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown,false,0,true);
+			sprite.addEventListener(MouseEvent.MOUSE_UP, onMouseUp,false,0,true)	;
+			sprite.addEventListener(MouseEvent.ROLL_OVER, addKeyListener,false,0,true);
+			sprite.addEventListener(MouseEvent.ROLL_OUT, removeKeyListener,false,0,true);
+
+		}
+		public static function addKeyListener(event:Event):void {
+			var sprite : Sprite = event.target as Sprite;
+			sprite.addEventListener(KeyboardEvent.KEY_DOWN, _onKeyPress);
+
+			sprite.alpha = 50;
+			//SimpleDrawing.outline( sprite, 0xFF0000);
+		}
+		public static function removeKeyListener(event:Event):void{
+			var sprite : Sprite = event.target as Sprite;
+			//sprite.graphics.clear();
+			sprite.removeEventListener(KeyboardEvent.KEY_DOWN, _onKeyPress);
+		}
+		public static function onMouseDown(event:MouseEvent):void{
+			var sprite : Sprite = event.target as Sprite;
+			if(!sprite) throw new Error(event.target + " was not a sprite ");
+			sprite.startDrag();
+		}
+		public static function onMouseUp(event:MouseEvent):void{
+			var sprite : Sprite = event.target as Sprite;
+			sprite.stopDrag();
+			trace("released ", sprite, " at ", sprite.x+","+sprite.y);
+		}
+		public static function _onKeyPress(event:KeyboardEvent):void{
+			var sprite : Sprite = event.target as Sprite;
+			var key_ascii : Number = event.keyCode;
+
+			trace("pressed ", key_ascii);
+
+			// = (equals) key
+			if(key_ascii==0x3D){
+				sprite.scaleX = sprite.scaleY = sprite.scaleX + 5;
+			}
+			// - (minus) key
+			if(key_ascii==0x2d){
+				sprite.scaleX = sprite.scaleY = sprite.scaleX - 5;
+			}
+			// _ (shift + minus) key
+			if(key_ascii==0x2b){
+				sprite.scaleX = sprite.scaleY = sprite.scaleX + .5;
+			}
+			// + (shift + plus) key
+			if(key_ascii==0x5F){
+				sprite.scaleX = sprite.scaleY = sprite.scaleX - .5;
+			}
+			// p ("print") key
+			if(key_ascii==0x70){
+				trace("Point(" + Math.round(sprite.x) + ", " + Math.round(sprite.y) +"), scale=" + sprite.scaleX + "("+  sprite + ")");
+			}
+			// t ("transparent") key
+			if(key_ascii==0x74){
+				sprite.alpha = 50;
+			}
+			// T ("untransparent") key
+			if(key_ascii==0x54){
+				sprite.alpha = 100;
+			}
+			var increment:Number = 1;
+			if(event.ctrlKey){
+				increment = 10;
+			}
+			if(key_ascii == Keyboard.LEFT) {
+
+				sprite.x -= increment;
+			}
+			if(key_ascii == Keyboard.RIGHT) {
+				sprite.x += increment;
+			}
+			if(key_ascii == Keyboard.UP){
+				sprite.y -= increment;
+			}
+			if(key_ascii == Keyboard.DOWN){
+				sprite.y += increment;
+			}
+
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/FPSView.as

@@ -0,0 +1,48 @@
+package com.lbi.debug {
+	import com.lbi.mvc.helper.TypographyBase;
+	import com.lbi.mvc.view.ViewBase;
+
+	import flash.events.Event;
+	import flash.geom.Rectangle;
+	import flash.text.TextField;
+	import flash.utils.getTimer;
+
+	/**
+	 * @author michaelforrest
+	 * (based on http://kaioa.com/node/83)
+	 */
+	public class FPSView extends ViewBase {
+		private var last : uint = getTimer();
+		private var ticks : uint = 0;
+		private var label : TextField;
+
+		public function FPSView() {
+			super();
+			addEventListener(Event.ADDED_TO_STAGE, onAddedToStage,false,0,true);
+		}
+
+		private function onAddedToStage(event : Event) : void {
+			trace("made fps view");
+			var style : TypographyBase = new TypographyBase();
+			style.embed_fonts = false;
+			style.font = "_sans";
+			style.align = "right";
+			columnWidth = stage.stageWidth;
+			label = addTextField(style, new Rectangle(0,0,100,30));
+			
+			addEventListener(Event.ENTER_FRAME, onEnterFrame,false,0,true);
+		}
+
+		private function onEnterFrame(event : Event) : void {
+			ticks++;
+			var now : uint = getTimer();
+			var delta : uint = now - last;
+			if (delta >= 500) {
+				var fps : Number = ticks / delta * 1000;
+				label.text = fps.toFixed(1) + " fps";
+				ticks = 0;
+				last = now;
+			}
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/KeySequenceTrigger.as

@@ -0,0 +1,60 @@
+package com.lbi.debug {
+	import flash.display.Stage;
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.events.KeyboardEvent;
+	/**
+	 * @author michaelforrest
+	 */
+	public class KeySequenceTrigger extends EventDispatcher {
+		private var trigger : String;
+
+		private var next_character_index : Number = 0;
+		private static var stage : Stage;
+		public static const TRIGGERED : String = "triggered";
+
+		function KeySequenceTrigger($trigger : String) {
+			super();
+			if(!stage) throw new Error("Sorry - you need to initialise KeySequenceTrigger in your app so that it can listen to the stage. Do this in AppView after it has been instantiated");
+			trigger = $trigger;
+			stage.addEventListener(KeyboardEvent.KEY_UP,onKeyUp,false,0,true);
+
+		}
+
+		private function onKeyUp(e : KeyboardEvent) : void {
+			if(e.charCode==getNextCharacterCode()){
+				if(isLastCharacter()){
+					dispatchEvent(new Event(TRIGGERED));
+					reset();
+				}
+			}
+			else{
+				reset();
+			}
+		}
+		private function getNextCharacterCode() : Number {
+			var c:Number = trigger.charCodeAt(next_character_index);
+			next_character_index++;
+			return c;
+		}
+
+		private function isLastCharacter() : Boolean {
+			return next_character_index >= trigger.length;
+		}
+
+		private function reset() : void {
+			next_character_index = 0;
+		}
+
+		public static function init($stage : Stage) : void {
+			stage = $stage;
+		}
+
+		public static function makeTriggers(triggers : Array) : void {
+			for (var i : Number = 0; i < triggers.length; i++) {
+				var trigger:Object = triggers[i];
+				new KeySequenceTrigger(trigger.trigger).addEventListener(TRIGGERED, trigger.action,false,0,true);
+			}
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/Log.as

@@ -0,0 +1,168 @@
+package com.lbi.debug {
+	import com.lbi.debug.LogItemType;
+	/**
+	 * @author chrgio
+	 */
+	public class Log
+	{
+		// these are set in the logger as well
+		private static const DEFAULT_BACKGROUND : Number = 0xFFFFFF;
+		private static const DEFAULT_FOREGROUND : Number = 0x000000;
+
+		private static var DEFAULT_LEVEL : Number = 5;
+		private static var log_level : Number;
+
+		public static function setLogLevel( level : Number ) : void
+		{
+			log_level = level;
+		}
+
+		public static function getLogLevel() : Number
+		{
+//			if(isNaN(log_level)){
+//				// In this first iteration I wasn't able to get the parameter from the html :S
+//				var app : Object = Application.application;
+//				var level : Number;
+//				if(app != null) level = app["parameters"]["log_level"] as Number;
+//				log_level = (!isNaN(level) ? level : DEFAULT_LEVEL);
+//			}
+			return log_level;
+		}
+
+		private static var items : Array;
+		private static var last_message : String;
+		private static var last_message_type : LogType;
+
+		public static function debug(message : String) : void
+		{
+			output(LogType.DEBUG, message);
+		}
+
+		public static function info(message : String) : void
+		{
+			output(LogType.INFO, message);
+		}
+
+		public static function warn(message : String) : void
+		{
+			output(LogType.WARNING, message);
+		}
+
+		public static function error(message : String) : void
+		{
+			output(LogType.ERROR, message);
+		}
+
+		public static function fatal(message : String) : void
+		{
+			output(LogType.FATAL, message);
+		}
+
+		private static function output(type : LogType, message : String) : void
+		{
+			if(getLogLevel() < type.level) return;
+			last_message_type = type;
+			last_message = message;
+			trace("[" + type + "] " + message);
+		}
+
+		public static function getLastMessage() : String
+		{
+			return last_message;
+		}
+
+		public static function getLastMessageType() : LogType
+		{
+			return last_message_type;
+		}
+
+		public static function clear() : void
+		{
+			last_message = null;
+			last_message_type = null;
+		}
+
+		public static function custom( message : String, foreground_colour : Number = DEFAULT_FOREGROUND, background_colour : Number = DEFAULT_BACKGROUND, bold : Boolean = false, level : Number = 0 ) : void
+		{
+			if(getLogLevel() < level) return;
+			var command : String = "[custom";
+			if(foreground_colour != DEFAULT_FOREGROUND) 	command += " foreground=#" + foreground_colour.toString(16);
+			if(background_colour != DEFAULT_BACKGROUND) 	command += " background=#" + background_colour.toString(16);
+			if(bold == true)  								command += " bold=true";
+			command += "] " + message;
+
+			last_message_type = LogType.CUSTOM;
+			last_message = command;
+
+			trace(command);
+		}
+
+		public static function createGroup(id : String, foreground_colour : Number = DEFAULT_FOREGROUND, background_colour : Number = DEFAULT_BACKGROUND, bold : Boolean = false, level : Number = 0) : void
+		{
+			createItemCommand(LogItemType.GROUP, id, foreground_colour, background_colour, bold, level);
+		}
+
+		public static function group( id : String, message : String ) : void
+		{
+			item(LogItemType.GROUP, id, message);
+		}
+
+		public static function createElement(id : String, foreground_colour : Number = DEFAULT_FOREGROUND, background_colour : Number = DEFAULT_BACKGROUND, bold : Boolean = false, level : Number = 0) : void
+		{
+			createItemCommand(LogItemType.ELEMENT, id, foreground_colour, background_colour, bold, level);
+		}
+
+		public static function element( id : String, message : String ) : void
+		{
+			item(LogItemType.ELEMENT, id, message);
+		}
+
+		private static function createItemCommand(type : LogItemType, id : String, foreground_colour : Number, background_colour : Number, bold : Boolean, level : Number = 0 ) : void
+		{
+			if(id.split(" ").length > 1) {
+				error("Log::createItemCommand, id shouldn't contain empty spaces");
+				return;
+			}
+			var command : String = "[setup-" + type + " " + id;
+			if(foreground_colour != DEFAULT_FOREGROUND) 	command += " foreground=#" + getHex(foreground_colour);
+			if(background_colour != DEFAULT_BACKGROUND) 	command += " background=#" + getHex(background_colour);
+			if(bold == true)  								command += " bold=true";
+			command += "]";
+
+			registerItem(type, id, level);
+
+			last_message_type = LogType.CUSTOM;
+			last_message = command;
+
+			trace(command);
+		}
+
+		private static function registerItem(type : LogItemType, id : String, level : Number) : void
+		{
+			if(items == null) items = [];
+			items[getItemId(type, id)] = level;
+		}
+
+		private static function getHex( colour : Number ) : String
+		{
+			var hex : String = colour.toString(16);
+			for (var i : Number = hex.length;i < 6; i++)  hex = "0" + hex;
+			return hex;
+		}
+
+		private static function item(type : LogItemType, id : String, message : String) : void
+		{
+			var item_level : Number = items[getItemId(type, id)] || 0;
+			if(getLogLevel() < item_level) return;
+
+			last_message_type = LogType.CUSTOM;
+			last_message = "[" + type + " " + id + "] " + message;
+			trace(last_message);
+		}
+
+		private static function getItemId( type : LogItemType, id : String ) : String
+		{
+			return type + "-" + id;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/LogItemType.as

@@ -0,0 +1,23 @@
+package com.lbi.debug 
+{
+	/**
+	 * @author chrgio
+	 */
+	public class LogItemType
+	{
+		public static var GROUP : LogItemType = new LogItemType("group");
+		public static var ELEMENT : LogItemType = new LogItemType("element");
+		
+		private var value : String;
+		
+		function LogItemType(value : String) 
+		{
+			this.value = value;
+		}
+		
+		public function toString () : String
+		{
+			return this.value;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/LogType.as

@@ -0,0 +1,31 @@
+package com.lbi.debug 
+{
+	/**
+	 * @author chrgio
+	 */
+	public class LogType
+	{
+		public static var FATAL : LogType = new LogType("fatal", 0);
+		public static var ERROR : LogType = new LogType("error", 1);
+		public static var WARNING : LogType = new LogType("warning", 2);
+		public static var INFO : LogType = new LogType("info", 3);
+		public static var DEBUG : LogType = new LogType("debug", 4);
+		
+		public static var CUSTOM : LogType = new LogType("custom", 0);
+		
+		public var level : Number;		
+		private var value : String;
+		
+		
+		function LogType(value : String, level : Number) 
+		{
+			this.value = value.toUpperCase();
+			this.level = level;
+		}
+		
+		public function toString () : String
+		{
+			return value;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/debug/ViewAnalysis.as

@@ -0,0 +1,24 @@
+package com.lbi.debug {
+	import flash.display.DisplayObject;
+	import flash.display.DisplayObjectContainer;
+	/**
+	 * @author michaelforrest
+	 */
+	public class ViewAnalysis {
+		public static function allViewsInside(top : DisplayObjectContainer) : String {
+			var result : String = "";
+			result += childrenOf(top);
+			return result;
+		}
+
+		private static function childrenOf(top : DisplayObjectContainer, tabs : String = "") : String {
+			var result : String = "";
+			result += ("\n" + tabs + top.toString());
+			for (var i : Number = 0; i < top.numChildren; i++) {
+				var item : DisplayObject = top.getChildAt(i);
+				result += ("\n" + tabs + childrenOf(item as DisplayObjectContainer, tabs + "\t"));
+			}
+			return result;
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/media/IBufferable.as

@@ -0,0 +1,16 @@
+package com.lbi.media {
+	import flash.media.SoundLoaderContext;
+	import flash.net.URLRequest;	
+	/**
+	 * @author michaelforrest
+	 */
+	public interface IBufferable {
+		function get bytesLoaded() : uint;
+
+		function get bytesTotal() : int;
+
+		function get isBuffering() : Boolean;
+
+		function load(stream : URLRequest, context : SoundLoaderContext = null) : void;
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/media/ITransportControllable.as

@@ -0,0 +1,11 @@
+package com.lbi.media {
+	import flash.media.SoundChannel;
+	import flash.media.SoundTransform;	
+	/**
+	 * @author michaelforrest
+	 */
+	public interface ITransportControllable {
+		function play(startTime : Number = 0, loops : int = 0, sndTransform : SoundTransform = null) : SoundChannel;
+		function pause() : void;
+	}
+}