michaelforrest-tidy 0.1.1

data/lib/aslibs/as3/lbi/com/lbi/animation/single/Animation.as

@@ -0,0 +1,173 @@
+package com.lbi.animation.single {
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+
+	import com.lbi.animation.util.Engine;
+	import com.lbi.animation.util.IAnimation;
+	//import com.framfab.debug.Console;
+	[Event("complete")]
+	/**
+	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	*/
+	public class Animation extends EventDispatcher implements IAnimation {
+		private var anim_function:Function;
+
+		protected var num_frames:Number;
+		private var current_frame:Number;
+		private var start:Number;
+		private var end:Number;
+		private var increment:Number;
+		private var isPlaying:Boolean = false;
+
+		private var label:String = "";
+
+		protected var is_complete:Boolean = true;
+
+		private var __complete_event : Event;
+		private var engine : Engine;
+
+		public function get complete_event():Event{
+			return __complete_event;
+		}
+		public function set complete_event(v:Event):void{
+			__complete_event = v;
+		}
+
+		/**
+		 * Animation class
+		 * Version 1.1
+		 * Enterframe function can now take the _previous_ value as its second parameter
+		 * Example:
+		 * <pre>
+	 		private var my_animation:Animation;
+			public function startAnimation(){
+				my_animation = new Animation(this, myFrameAnimation, 0, 1, 15);
+				my_animation.addEventListener("animationComplete", myCompleteFunction);
+			}
+			private function myFrameAnimation(n:Number){
+			 	// use the appropriate easing function here
+			 	// in this example, the _alpha value of my_mc needs to go from
+			 	// 50 to 100 with easeInQuad
+				n = Tweens.easeInQuad(n);
+				my_mc._alpha = 50 + (50 * n);
+			}
+			private function myCompleteFunction(){
+				trace("Animation complete!!");
+			}
+		 * </pre>
+		 *
+		 * @param instance - the instance to animate
+		 * @param anim_function - a function that will be called each frame, with one argument (the current position in the animation)
+		 * @param start - value to start with
+		 * @param end - value to finish on
+		 * @param num_frames - the number of frames in the animation
+		 */
+		function Animation($anim_function:Function, start:Number, end:Number, num_frames:Number){
+			engine = Engine.getInstance();
+			this.complete_event = new Event("complete");
+			anim_function = $anim_function;
+			/** make sure it's integer, and >=1 **/
+			this.num_frames = Math.round(num_frames);
+			this.num_frames = Math.max(this.num_frames, 1);
+			setStart(start);
+			setEnd(end);
+
+		}
+		public function setStart(n:Number) : void {
+			start = n;
+		}
+		public function setEnd(n:Number) : void {
+			end = n;
+		}
+		public function go() : void {
+			is_complete =false;
+			increment = (end - start) / num_frames;
+			this.current_frame = 0;
+			engine.addEventListener(Event.ENTER_FRAME, doAnimation,false,0,true);
+			isPlaying = true;
+		}
+		public function destroy() : void {
+			engine.removeEventListener(Event.ENTER_FRAME, doAnimation);
+			delete this;
+		}
+		private function doAnimation(e:Event) : void {
+			var p:Number = start + (current_frame * increment);
+			current_frame ++;
+			var n:Number = start + (current_frame * increment);
+			anim_function(n,p);
+			if(current_frame == num_frames){
+				engine.removeEventListener(Event.ENTER_FRAME, doAnimation);
+				isPlaying = false;
+				is_complete = true;
+				dispatchCompleteEvent();
+				destroy();
+			}
+		}
+		public function pause() : void {
+			if(	isPlaying){
+				engine.removeEventListener(Event.ENTER_FRAME, doAnimation);
+			}else{
+				engine.addEventListener(Event.ENTER_FRAME, doAnimation,false,0,true);
+			}
+		}
+		public function stop(dispatchComplete:Boolean = false) : void {
+			engine.removeEventListener(Event.ENTER_FRAME, doAnimation);
+			isPlaying = false;
+			is_complete = true;
+			if(dispatchComplete) dispatchCompleteEvent();
+		}
+
+		public function addLabel(l:String) : void {
+			label = l;
+		}
+		public function isComplete():Boolean{
+			return is_complete;
+		}
+		public function setFrames(n:Number) : void {
+			this.num_frames = n;
+		}
+		public function getFrames():Number{
+			return num_frames;
+		}
+		public function getCurrentFrame():Number{
+			return current_frame;
+		}
+		override public function toString() : String {
+			return getType() + " "  + label + ", playing: "+ isPlaying;
+		}
+		public function getType():String {
+			return "animation " ;
+		}
+		private function dispatchCompleteEvent() : void {
+			dispatchEvent(complete_event);
+		}
+
+		public function getStructure() : String {
+			return toString();
+		}
+
+		public function setCompleteDelegate(delegate : Function) : void {
+
+		}
+
+		public function getCompleteDelegate() : Function {
+			return null;
+		}
+
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/animation/single/Message.as

@@ -0,0 +1,36 @@
+package com.lbi.animation.single {
+	import com.lbi.animation.single.MethodWithCompleteEvent;
+	import com.lbi.debug.Log;	
+	/**
+	 	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+	
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+	
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+	
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA 
+	*/
+	public class Message extends MethodWithCompleteEvent {
+	
+		private var message : String;
+		
+		public function Message(message:String) {
+			super();
+			this.message = message;
+		}
+		override public function go() : void {
+			complete = false;
+			Log.info(message);
+			onComplete(null);
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/animation/single/MethodWithCompleteEvent.as

@@ -0,0 +1,75 @@
+package com.lbi.animation.single {
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.events.IEventDispatcher;
+
+	import com.lbi.animation.util.IAnimation;
+
+	[Event("complete")]
+	/**
+	 	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	*/
+	public class MethodWithCompleteEvent extends EventDispatcher implements IAnimation {
+		private var object : IEventDispatcher;
+		private var method:Function;
+		protected var complete:Boolean = false;
+
+		private var complete_event : String;
+
+		private var __arguments : Array;
+
+		public function MethodWithCompleteEvent($object : IEventDispatcher = null, $method : Function = null, $complete_event : String = null, $args: Array = null){
+			complete_event = $complete_event;
+			object = $object;
+			method = $method;
+			__arguments = $args;
+		}
+		public function go() : void {
+			if(complete_event) object.addEventListener(complete_event, onComplete,false,0,true);
+			complete = false;
+			if(method != null) method.apply(object,__arguments);
+			if(!complete_event) onComplete(null);
+		}
+		protected function onComplete(e:Event) : void {
+			complete = true;
+			dispatchEvent(new Event("complete"));
+		}
+		public function destroy() : void {
+			delete this;
+		}
+
+		public function stop(dispatchComplete : Boolean = false) : void {
+			//my_object.stop();
+			if(dispatchComplete) onComplete(null);
+		}
+
+		public function isComplete():Boolean{
+			return complete;
+		}
+		public function setFrames(frames : Number) : void {
+		}
+		override public function toString():String{
+			return "QueueMethod: ";
+		}
+		public function getStructure() : String {
+			return toString();
+		}
+
+	}
+
+}

data/lib/aslibs/as3/lbi/com/lbi/animation/single/OrphanEvent.as

@@ -0,0 +1,78 @@
+package com.lbi.animation.single {
+	import com.lbi.animation.util.IAnimation;
+
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.events.IEventDispatcher;
+	/**
+	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	*/
+	public class OrphanEvent extends EventDispatcher implements  IAnimation{
+		public var is_complete:Boolean = false;
+		private var object:IEventDispatcher;
+		private var event:String;
+		private var timeCreated:Number;
+		public function get EventObject():IEventDispatcher{
+			return object;
+		}
+		public function get EventName():String{
+			return event;
+		}
+
+		public function OrphanEvent($object:IEventDispatcher, $event:String){
+			object = $object;
+			event = $event;
+			object.addEventListener(event, dispatchCompleteEvent,false,0,true);
+		}
+		public function stop(dispatchComplete:Boolean = false) : void {
+			destroy();
+			if(dispatchComplete) dispatchCompleteEvent();
+		}
+		private function dispatchCompleteEvent(e : Event = null) : void {
+			is_complete = true;
+			dispatchEvent(new Event("complete"));
+		}
+		/**
+		 *  go() does nothing, hence "Orphan".
+		 */
+		public function go() : void {
+			is_complete = false;
+		}
+
+		public function isComplete():Boolean{
+			return is_complete;
+		}
+		public function destroy() : void {
+			object.removeEventListener(event, dispatchCompleteEvent);
+		}
+		override public function toString() : String {
+			return object + " OrphanEvent " + timeCreated + ":"  + event ;
+		}
+		public function isOrphanEvent():Boolean{
+			return true;
+		}
+		public function setFrames(frames : Number) : void {
+			// don't do anything though.
+		}
+
+		public function getStructure() : String {
+			return toString();
+		}
+
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/animation/single/Pause.as

@@ -0,0 +1,35 @@
+package com.lbi.animation.single {
+	import com.lbi.animation.single.Animation;
+	/**
+		LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
+	 */
+	public class Pause extends Animation {
+
+		private var ease:Function;
+		/**
+		 * Pause creates a pause for a certain number of frames. This class can be used in conjunction with Queue.
+		 * @see com.lbi.animation.Animation
+		 * @see com.lbi.animation.Queue
+		 */
+		function Pause(frames:Number){
+			super(pauseCheck, 0, 1, frames);
+		}
+		private function pauseCheck(n:Number, p:Number) : void {
+		}
+	}
+}

data/lib/aslibs/as3/lbi/com/lbi/animation/single/Tween.as

@@ -0,0 +1,73 @@
+package com.lbi.animation.single {
+	import flash.display.DisplayObject;
+	
+	import com.lbi.animation.single.Animation;
+	import com.lbi.animation.util.Easing;	
+	/**
+	 	LBi Useful ActionScript 3 Library
+	    Copyright (C) 2007 LBi / Michael Forrest
+	
+	    This library is free software; you can redistribute it and/or
+	    modify it under the terms of the GNU Lesser General Public
+	    License as published by the Free Software Foundation; either
+	    version 2.1 of the License, or (at your option) any later version.
+	
+	    This library is distributed in the hope that it will be useful,
+	    but WITHOUT ANY WARRANTY; without even the implied warranty of
+	    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+	    Lesser General Public License for more details.
+	
+	    You should have received a copy of the GNU Lesser General Public
+	    License along with this library; if not, write to the Free Software
+	    Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA 
+	*/
+	public class Tween extends Animation{
+		private var property_name:String;
+		private var property_start:Number;
+		private var property_end:Number;
+		private var delta:Number;
+		private var object:Object;
+		private var ease:Function;
+		/**
+		 * Tween handles simple MovieClip property animations - all animations will start from the property's current value
+		 * Example:
+		 * <pre>
+		 * var fade_animation:Tween = new Tween(my_mc, "_alpha", 50, 20, Easing.easeInCubic);
+		 * fade_animation.go();
+		 * </pre>
+		 * @see com.lbi.animation.Animation
+		 */
+		function Tween(object:DisplayObject, property_name:String, target_value:Number, frames:Number, easing:Function = null) {
+			super(tweenValue, 0, 1, frames);
+			if(easing == null) ease = Easing.linearTween;
+			this.object = object;
+			this.property_name = property_name;
+			property_end = target_value;
+			
+		}
+		public function setTargetValue(v:Number) : void {
+			property_end = v;	
+		}
+		override public function go() : void {
+			is_complete = false;
+			this.property_start = object[property_name];	
+			this.delta = (property_end - object[property_name]);
+			super.go();	
+		}
+		private function tweenValue(n:Number,p:Number) : void {
+			n = ease(n);
+			object[property_name] = (n * delta ) + property_start; 
+		}
+		
+		public function getTweenValues ( ) : Array
+		{
+			property_start = object[property_name];	
+			delta = (property_end - property_start);
+			var res_arr:Array = [];
+			for(var i:Number=0; i<num_frames; i++){
+				res_arr.push( ease(i / (num_frames + 1)) * delta + property_start );
+			}
+			return res_arr;
+		}
+	}
+	}

data/lib/aslibs/as3/lbi/com/lbi/animation/util/Easing.as

@@ -0,0 +1,158 @@
+package com.lbi.animation.util {
+
+	// see http://hosted.zeh.com.br/mctween/animationtypes.html
+
+	public class Easing {
+		public static function linearTween(t:Number):Number {
+			return 1*t/1;
+		};
+
+		public static function easeInQuad(t:Number):Number {
+			return 1*(t/=1)*t;
+		};
+		public static function easeOutQuad(t:Number):Number {
+			return -1 *(t/=1)*(t-2);
+		};
+		public static function easeInOutQuad(t:Number):Number {
+			if ((t/=1/2) < 1) return 1/2*t*t;
+			return -1/2 * ((--t)*(t-2) - 1);
+		};
+		public static function easeInCubic(t:Number):Number {
+			return 1*(t/=1)*t*t;
+		};
+		public static function easeOutCubic(t:Number):Number {
+			return 1*((t=t/1-1)*t*t + 1);
+		};
+		public static function easeInOutCubic(t:Number):Number {
+			if ((t/=1/2) < 1) return 1/2*t*t*t;
+			return 1/2*((t-=2)*t*t + 2);
+		};
+		public static function easeInQuart(t:Number):Number {
+			return 1*(t/=1)*t*t*t;
+		};
+		public static function easeOutQuart(t:Number):Number {
+			return -1 * ((t=t/1-1)*t*t*t - 1);
+		};
+		public static function easeInOutQuart(t:Number):Number {
+			if ((t/=1/2) < 1) return 1/2*t*t*t*t;
+			return -1/2 * ((t-=2)*t*t*t - 2);
+		};
+		public static function easeInQuint(t:Number):Number {
+			return 1*(t/=1)*t*t*t*t;
+		};
+		public static function easeOutQuint(t:Number):Number {
+			return 1*((t=t/1-1)*t*t*t*t + 1);
+		};
+		public static function easeInOutQuint(t:Number):Number {
+			if ((t/=1/2) < 1) return 1/2*t*t*t*t*t;
+			return 1/2*((t-=2)*t*t*t*t + 2);
+		};
+		public static function easeInSine(t:Number):Number {
+			return -1 * Math.cos(t/1 * (Math.PI/2)) + 1;
+		};
+		public static function easeOutSine(t:Number):Number {
+			return 1 * Math.sin(t/1 * (Math.PI/2));
+		};
+		public static function easeInOutSine(t:Number):Number {
+			return -1/2 * (Math.cos(Math.PI*t/1) - 1);
+		};
+		public static function easeInExpo(t:Number):Number {
+			return (t==0) ? 0 : 1 * Math.pow(2, 10 * (t/1 - 1));
+		};
+		public static function easeOutExpo(t:Number):Number {
+			return (t==1) ? 1 : 1 * (-Math.pow(2, -10 * t/1) + 1);
+		};
+		public static function easeInOutExpo(t:Number):Number {
+			if (t==0) return 0;
+			if (t==1) return 1;
+			if ((t/=1/2) < 1) return 1/2 * Math.pow(2, 10 * (t - 1));
+			return 1/2 * (-Math.pow(2, -10 * --t) + 2);
+		};
+		public static function easeInCirc(t:Number):Number {
+			return -1 * (Math.sqrt(1 - (t/=1)*t) - 1);
+		};
+		public static function easeOutCirc(t:Number):Number {
+			return 1 * Math.sqrt(1 - (t=t/1-1)*t);
+		};
+		public static function easeInOutCirc(t:Number):Number {
+			if ((t/=1/2) < 1) return -1/2 * (Math.sqrt(1 - t*t) - 1);
+			return 1/2 * (Math.sqrt(1 - (t-=2)*t) + 1);
+		};
+		public static function easeInElastic(t:Number, a:Number = 10, p:Number= 10):Number {
+			var s:Number;
+			if (t==0) return 0;  if ((t/=1)==1) return 1;  if (!p) p=1*.3;
+			if (a < Math.abs(1)) { a=1;  s=p/4; }
+			else s = p/(2*Math.PI) * Math.asin (1/a);
+			return -(a*Math.pow(2,10*(t-=1)) * Math.sin( (t*1-s)*(2*Math.PI)/p ));
+		};
+
+		public static function easeOutElastic(t:Number, a:Number=1, p:Number =1.05):Number {
+			var s:Number;
+			if (t==0) return 0;  if ((t/=1)==1) return 1;
+			if (a < Math.abs(1)) { a=1;  s=p/4; }
+			else  s = p/(2*Math.PI) * Math.asin (1/a);
+			return a*Math.pow(2,-10*t) * Math.sin( (t*1-s)*(2*Math.PI)/p ) + 1;
+		};
+
+		public static function easeInOutElastic(t:Number, a:Number = 1, p:Number=1*(.3*1.5)):Number {
+			var s:Number;
+			if (t==0) return 1;  if ((t/=1/2)==2) return 1;
+			if (a < Math.abs(1)) { a=1;  s=p/4; }
+			else s = p/(2*Math.PI) * Math.asin (1/a);
+			if (t < 1) return -.5*(a*Math.pow(2,10*(t-=1)) * Math.sin( (t*1-s)*(2*Math.PI)/p ));
+			return a*Math.pow(2,-10*(t-=1)) * Math.sin( (t*1-s)*(2*Math.PI)/p )*.5 + 1;
+		};
+		public static function easeInBack(t:Number, s:Number):Number {
+			if (isNaN(s)) s = 1.70158;
+			return 1*(t/=1)*t*((s+1)*t - s);
+		};
+		public static function easeOutBack(t:Number, s:Number):Number {
+			if (isNaN(s)) s = 1.70158;
+			return 1*((t=t/1-1)*t*((s+1)*t + s) + 1);
+		};
+		public static function easeInOutBack(t:Number, s:Number):Number {
+			if (isNaN(s)) s = 1.70158;
+			if ((t/=1/2) < 1) return 1/2*(t*t*(((s*=(1.525))+1)*t - s));
+			return 1/2*((t-=2)*t*(((s*=(1.525))+1)*t + s) + 2);
+		};
+		public static function easeInBounce(t:Number):Number {
+			return 1 - Easing.easeOutBounce (1-t);
+		};
+		public static function easeOutBounce(t:Number):Number {
+			if ((t/=1) < (1/2.75)) {
+				return 1*(7.5625*t*t);
+			} else if (t < (2/2.75)) {
+				return 1*(7.5625*(t-=(1.5/2.75))*t + .75);
+			} else if (t < (2.5/2.75)) {
+				return 1*(7.5625*(t-=(2.25/2.75))*t + .9375);
+			} else {
+				return 1*(7.5625*(t-=(2.625/2.75))*t + .984375);
+			}
+		}
+		public static function easeInOutBounce(t:Number):Number {
+			if (t < 1/2) return Easing.easeInBounce (t*2) * .5;
+			return Easing.easeOutBounce (t*2-1) * .5 + 1*.5;
+		}
+		public static function cubBezier(mu:Number,p2:Number,p3:Number):Number {
+			var mum1:Number,mum13:Number,mu3:Number,p1:Number,p4:Number;
+			p1 = 0;
+			p4 = 1;
+			var p:Number;
+			mum1 = 1 - mu;
+			mum13 = mum1 * mum1 * mum1;
+			mu3 = mu * mu * mu;
+			var mu4:Number = 3*mu*mum1*mum1;
+			var mu5:Number = 3*mu*mu*mum1;
+			p = mum13*p1 + mu4*p2 + mu5*p3 + mu3*p4;
+			return p;
+		}
+		public static function quadBezier(mu:Number,p2:Number):Number {
+			var p:Number;
+			var mum1:Number = 2*(1 - mu);
+			var p1:Number = 0;
+			var p3:Number = 1;
+			p = p1 + mu*(mum1*(p2-p1) + mu*(p3 - p1));
+			return p;
+		}
+	}
+	}

data/lib/aslibs/as3/lbi/com/lbi/animation/util/Engine.as

@@ -0,0 +1,35 @@
+package com.lbi.animation.util {
+	import flash.events.Event;
+	import flash.events.EventDispatcher;
+	import flash.events.TimerEvent;
+	import flash.utils.Timer;
+	/**
+	 * @author michaelforrest
+	 */
+	public class Engine extends EventDispatcher {
+		private static var instance : Engine;
+		private var timer : Timer;
+
+		public function Engine() {
+			timer = new Timer(1000/30);
+			timer.addEventListener(TimerEvent.TIMER, advanceFrame,false,0,true);
+			timer.start();
+		}
+
+		public static function getInstance() : Engine {
+			if(!instance) instance = new Engine();
+			return instance;
+		}
+		public static function advanceFrames(number_of_frames : Number) : void {
+			if(!instance) getInstance();
+			for (var i : Number = 0; i < number_of_frames; i++) {
+				instance.advanceFrame();
+				
+			}
+		}
+
+		private function advanceFrame(e:TimerEvent = null) : void {
+			dispatchEvent(new Event(Event.ENTER_FRAME));
+		}
+	}
+}