lc_alchemy_cms 3.2.0

data/app/assets/javascripts/alchemy/alchemy.dirty.js.coffee

@@ -0,0 +1,70 @@
+window.Alchemy = {} if typeof (window.Alchemy) is "undefined"
+
+$.extend Alchemy,
+
+  ElementDirtyObserver: (selector) ->
+    $elements = $(selector)
+    $elements.find('input[type="text"], select').change ->
+      $this = $(this)
+      $this.addClass('dirty')
+      Alchemy.setElementDirty $this.parents(".element_editor")
+    $elements.find('.element_foot input[type="checkbox"]').click ->
+      $this = $(this)
+      $this.addClass "dirty"
+      Alchemy.setElementDirty $this.parents(".element_editor")
+
+  setElementDirty: (element) ->
+    $element = $(element)
+    $element
+      .addClass('dirty')
+      .find('.element_head .icon[class*="element_"]')
+      .addClass('element_dirty')
+    window.onbeforeunload = @pageUnload
+
+  pageUnload: ->
+    Alchemy.pleaseWaitOverlay(false)
+    Alchemy._t('page_dirty_notice')
+
+  setElementClean: (element) ->
+    $element = $(element)
+    $element
+      .removeClass('dirty')
+      .find('.element_foot input[type="checkbox"], input[type="text"], select')
+      .removeClass('dirty')
+    $element.find('.element_head .icon').removeClass('element_dirty')
+    window.onbeforeunload = undefined
+
+  isPageDirty: ->
+    $('#element_area').find('.element_editor.dirty').length > 0
+
+  isElementDirty: (element) ->
+    $(element).hasClass('dirty')
+
+  checkPageDirtyness: (element) ->
+    callback = undefined
+    if $(element).is("form")
+      callback = ->
+        $form = $("<form action=\"#{element.action}\" method=\"POST\" style=\"display: none\" />")
+        $form.append $(element).find("input")
+        $form.appendTo "body"
+        $form.submit()
+    else if $(element).is("a")
+      callback = ->
+        window.location.href = element.pathname
+    if Alchemy.isPageDirty()
+      Alchemy.openConfirmDialog Alchemy._t('page_dirty_notice'),
+        title: Alchemy._t('warning')
+        ok_label: Alchemy._t('ok')
+        cancel_label: Alchemy._t('cancel')
+        on_ok: ->
+          window.onbeforeunload = undefined
+          Alchemy.pleaseWaitOverlay()
+          callback()
+      false
+    else
+      true
+
+  PageLeaveObserver: ->
+    $('#main_navi a').click (event) ->
+      unless Alchemy.checkPageDirtyness(event.currentTarget)
+        event.preventDefault()

data/app/assets/javascripts/alchemy/alchemy.dragndrop.js.coffee

@@ -0,0 +1,84 @@
+#= require jquery-ui/draggable
+#= require jquery-ui/sortable
+#
+window.Alchemy = {} if typeof (window.Alchemy) is "undefined"
+
+$.extend Alchemy,
+
+  SortableElements: (page_id, form_token, selector = '#element_area .sortable_cell') ->
+
+    getTinymceIDs = (ui) ->
+      ids = []
+      $textareas = ui.item.find('textarea.default_tinymce, textarea.custom_tinymce')
+      $($textareas).each ->
+        id = this.id.replace(/tinymce_/, '')
+        ids.push parseInt(id, 10)
+      return ids
+
+    $(selector).sortable
+      items: "div.element_editor"
+      handle: ".element_handle"
+      axis: "y"
+      placeholder: "droppable_element_placeholder"
+      forcePlaceholderSize: true
+      dropOnEmpty: true
+      opacity: 0.5
+      cursor: "move"
+      tolerance: "pointer"
+      update: (event, ui) ->
+        ids = $.map $(this).children(), (child) ->
+          $(child).attr "data-element-id"
+        params_string = ""
+        cell_id = $(this).attr("data-cell-id")
+        $(event.target).css "cursor", "progress"
+        params_string = "page_id=" + page_id + "&authenticity_token=" + encodeURIComponent(form_token) + "&" + $.param(element_ids: ids)
+        params_string += "&cell_id=" + cell_id  if cell_id
+        $.ajax
+          url: Alchemy.routes.order_admin_elements_path
+          type: "POST"
+          data: params_string
+          complete: ->
+            $(event.target).css "cursor", "auto"
+            Alchemy.TrashWindow.refresh page_id
+
+      start: (event, ui) ->
+        Alchemy.Tinymce.remove getTinymceIDs(ui)
+
+      stop: (event, ui) ->
+        Alchemy.Tinymce.init getTinymceIDs(ui)
+
+  SortableContents: (selector, token) ->
+    $(selector).sortable
+      items: "div.dragable_picture"
+      handle: "div.picture_handle"
+      opacity: 0.5
+      cursor: "move"
+      tolerance: "pointer"
+      containment: "parent"
+      update: (event, ui) ->
+        ids = $.map $(this).children("div.dragable_picture"), (child) ->
+          child.id.replace /essence_picture_/, ""
+        $(event.originalTarget).css "cursor", "progress"
+        $.ajax
+          url: Alchemy.routes.order_admin_contents_path
+          type: "POST"
+          data: "authenticity_token=" + encodeURIComponent(token) + "&" + $.param(content_ids: ids)
+          complete: ->
+            $(event.originalTarget).css "cursor", "move"
+
+  DraggableTrashItems: (items_n_cells) ->
+    $("#trash_items div.draggable").each ->
+      cell_classes = ""
+      cell_names = items_n_cells[@id]
+      $.each cell_names, (i) ->
+        cell_classes += "." + this + "_cell" + ", "
+      $(this).draggable
+        helper: "clone"
+        iframeFix: "iframe#alchemy_preview_window"
+        connectToSortable: cell_classes.replace(/,.$/, "")
+        start: (event, ui) ->
+          $(this).hide().addClass("dragged")
+          ui.helper.css("width", "300px")
+        stop: (event, ui) ->
+          $(this).show().removeClass("dragged")
+          ui.helper.css("width", "")

data/app/assets/javascripts/alchemy/alchemy.element_editors.js.coffee

@@ -0,0 +1,138 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# Handlers for element editors.
+#
+# It provides folding of element editors and
+# selecting element editors from the preview frame
+# and the elenents window.
+#
+Alchemy.ElementEditors =
+
+  # Binds all events to element editor partials.
+  #
+  # Calles once per page load.
+  #
+  init: ->
+    $elements = $("#element_area .element_editor")
+    self = Alchemy.ElementEditors
+    self.reinit $elements
+
+  # Binds events to all given element editors.
+  #
+  # Called after replacing element editors via ajax.
+  #
+  reinit: (elements) ->
+    self = Alchemy.ElementEditors
+    $elements = $(elements)
+    $elements.each ->
+      self.bindEvent this
+    $elements.find(".element_head").click self.onClickElement
+    $elements.find(".element_head").dblclick ->
+      id = $(this).parent().attr("id").replace(/\D/g, "")
+      self.toggle id
+    Alchemy.ElementEditors.observeToggler($elements)
+    Alchemy.ElementEditors.missingContentsObserver($elements)
+
+  # Click event handler.
+  #
+  # Also triggers custom 'Alchemy.SelectElement' event on target element in preview frame.
+  #
+  onClickElement: (e) ->
+    self = Alchemy.ElementEditors
+    $element = $(this).parent(".element_editor")
+    id = $element.attr("id").replace(/\D/g, "")
+    e.preventDefault()
+    $("#element_area .element_editor").removeClass "selected"
+    $element.addClass "selected"
+    self.scrollToElement this
+    self.selectElementInPreview id
+
+  # Selects and scrolls to element with given id in the preview window.
+  #
+  selectElementInPreview: (id) ->
+    $frame_elements = document.getElementById("alchemy_preview_window").contentWindow.jQuery("[data-alchemy-element]")
+    $selected_element = $frame_elements.closest("[data-alchemy-element='#{id}']")
+    $selected_element.trigger "Alchemy.SelectElement"
+
+  # Binds the custom 'Alchemy.SelectElementEditor' event.
+  #
+  # Triggered, if an element gets selected inside the preview iframe.
+  #
+  bindEvent: (element) ->
+    self = Alchemy.ElementEditors
+    $(element).bind "Alchemy.SelectElementEditor", self.selectElement
+
+  # Selects an element in the element window.
+  #
+  # Expands the element, if necessary.
+  # Also chooses the right cell, if necessary.
+  # Can be triggered through custom event 'Alchemy.SelectElementEditor'
+  # Used by the elements on click events in the preview frame.
+  #
+  selectElement: (e) ->
+    self = Alchemy.ElementEditors
+    id = @id.replace(/\D/g, "")
+    $element = $(this)
+    $elements = $("#element_area .element_editor")
+    $cells = $("#cells .sortable_cell")
+    e.preventDefault()
+    $elements.removeClass "selected"
+    $element.addClass "selected"
+    if $cells.size() > 0
+      $cell = $element.parent(".sortable_cell")
+      $("#cells").tabs "option", "active", $cells.index($cell)
+    if $element.hasClass("folded")
+      self.toggleFold id
+    else
+      self.scrollToElement this
+
+  # Scrolls the element window to given element editor dom element.
+  #
+  scrollToElement: (el) ->
+    $("#element_area").scrollTo el,
+      duration: 400
+      offset: -10
+
+  # Expands or folds a element editor
+  #
+  # If the element is dirty (has unsaved changes) it displays a warning.
+  #
+  toggle: (id, text) ->
+    el = $("#element_#{id}")
+    if Alchemy.isElementDirty(el)
+      Alchemy.openConfirmDialog Alchemy._t('element_dirty_notice'),
+        title: Alchemy._t('warning')
+        ok_label: Alchemy._t('ok')
+        cancel_label: Alchemy._t('cancel')
+        on_ok: =>
+          @toggleFold id
+      false
+    else
+      @toggleFold id
+
+  # Folds or expands the element editor with the given id.
+  #
+  toggleFold: (id) ->
+    spinner = Alchemy.Spinner.small()
+    element = $('.ajax_folder', "#element_#{id}")
+    $("#element_#{id}_folder").hide()
+    element.prepend spinner.spin().el
+    $.post Alchemy.routes.fold_admin_element_path(id), =>
+      $("#element_#{id}_folder").show()
+      spinner.stop()
+      @scrollToElement "#element_#{id}"
+
+  observeToggler: (scope) ->
+    $('[data-element-toggle]', scope).click ->
+      Alchemy.ElementEditors.toggle $(this).data('element-toggle')
+
+  # Handles the missing content links.
+  # Ensures that the links query string is converted into post body and send
+  # the request via a real ajax post to server, to allow long query strings.
+  missingContentsObserver: (scope) ->
+    $('[data-create-missing-content]', scope).click ->
+      $link = $(this)
+      url = this.pathname
+      querystring = this.search.replace(/\?/, '')
+      $.post url, querystring
+      return false

data/app/assets/javascripts/alchemy/alchemy.elements_window.js.coffee

@@ -0,0 +1,89 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# Adds buttons into a toolbar inside of overlay windows
+Alchemy.ToolbarButton = (options) ->
+  $btn = $('<div class="button_with_label" />')
+  if options.buttonId
+    $btn.attr(id: options.buttonId)
+  $lnk = $("<a title='#{options.title}' class='icon_button' href='#' />")
+  if options.hotkey
+    $lnk.attr('data-alchemy-hotkey', options.hotkey)
+  $lnk.click (e) ->
+    e.preventDefault()
+    options.onClick(e)
+    false
+  $lnk.append "<span class='icon #{options.iconClass}' />"
+  $btn.append $lnk
+  $btn.append "<br><label>#{options.label}</label>"
+  $btn
+
+Alchemy.ElementsWindow =
+
+  init: (url, options, callback) ->
+    @hidden = false
+    @element_window = $('<div id="alchemy_elements_window"/>')
+    @element_area = $('<div id="element_area"/>')
+    @url = url
+    @options = options
+    @callback = callback
+    @element_window.append @createToolbar(options.toolbarButtons)
+    @element_window.append @element_area
+    @button = $('#element_window_button')
+    @button.click =>
+      @hide()
+      false
+    height = @resize()
+    window.requestAnimationFrame =>
+      spinner = Alchemy.Spinner.medium()
+      spinner.spin @element_area[0]
+    $('#main_content').append(@element_window)
+    @reload()
+
+  createToolbar: (buttons) ->
+    @toolbar = $('<div id="overlay_toolbar"/>')
+    for btn in buttons
+      @toolbar.append Alchemy.ToolbarButton(btn)
+    @toolbar
+
+  resize: ->
+    height = $(window).height() - 73
+    @element_window.css
+      height: height
+    @element_area.css
+      height: height - 46
+    height
+
+  reload: ->
+    $.get @url, (data) =>
+      @element_area.html data
+      Alchemy.GUI.init(@element_area)
+      if @callback
+        @callback.call()
+    .fail (xhr, status, error) =>
+      Alchemy.AjaxErrorHandler @element_area, xhr.status, status, error
+
+  hide: ->
+    @element_window.css(right: -400)
+    @hidden = true
+    @toggleButton()
+    Alchemy.PreviewWindow.resize()
+
+  show: ->
+    @element_window.css(right: 0)
+    @hidden = false
+    @toggleButton()
+    Alchemy.PreviewWindow.resize()
+
+  toggleButton: ->
+    if @hidden
+      @button.find('label').text(@options.texts.showElements)
+      @button.off('click')
+      @button.click =>
+        @show()
+        false
+    else
+      @button.find('label').text(@options.texts.hideElements)
+      @button.off('click')
+      @button.click =>
+        @hide()
+        false

data/app/assets/javascripts/alchemy/alchemy.file_progress.js.coffee

@@ -0,0 +1,63 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+Alchemy.FileProgress = (file) ->
+
+    # Build Wrapper
+    @$fileProgressWrapper = $('<div class="progressWrapper"/>')
+
+    # Build Container
+    @$fileProgressElement = $('<div class="progressContainer"/>')
+
+    # Append Cancel Button
+    @$fileProgressCancel = $('<a href="javascript:void(0);" class="progressCancel"/>')
+    @$fileProgressElement.append @$fileProgressCancel
+
+    # Append Filename
+    @$fileProgressElement.append "<div class=\"progressName\">" + file.name + "</div>"
+
+    # Append Progressbar Status Text
+    @$fileProgressStatus = $('<div class="progressBarStatus">&nbsp;</div>')
+    @$fileProgressElement.append @$fileProgressStatus
+
+    # Build Progressbar Container
+    $progressBarContainer = $('<div class="progressBarContainer"/>')
+
+    # Build Progressbar
+    @$progressBar = $('<div class="progressBarInProgress"/>')
+
+    # Knit all together
+    $progressBarContainer.append @$progressBar
+    @$fileProgressElement.append $progressBarContainer
+    @$fileProgressWrapper.append @$fileProgressElement
+    $('#uploadProgressContainer').append @$fileProgressWrapper
+    this
+
+Alchemy.FileProgress::reset = ->
+  @$fileProgressStatus.html '&nbsp;'
+  @$progressBar.removeClass().addClass 'progressBarInProgress'
+  @$progressBar.css width: '0%'
+
+Alchemy.FileProgress::setProgress = (percentage) ->
+  @$progressBar.removeClass().addClass 'progressBarInProgress'
+  @$progressBar.css width: percentage + '%'
+
+Alchemy.FileProgress::setComplete = ->
+  @$progressBar.removeClass().addClass 'progressBarComplete'
+  @$progressBar.css width: '100%'
+  @$fileProgressCancel.hide()
+  @$fileProgressWrapper.delay(1500).fadeOut ->
+    $(this).remove()
+
+Alchemy.FileProgress::setError = ->
+  @$progressBar.removeClass().addClass 'progressBarError'
+  @$progressBar.css width: '100%'
+
+Alchemy.FileProgress::setCancelled = ->
+  @$progressBar.removeClass().addClass 'progressBarCanceled'
+  @$progressBar.css width: '100%'
+  @$fileProgressCancel.hide()
+  @$fileProgressWrapper.delay(1500).fadeOut ->
+    $(this).remove()
+
+Alchemy.FileProgress::setStatus = (status) ->
+  @$fileProgressStatus.text Alchemy._t(status)

data/app/assets/javascripts/alchemy/alchemy.growler.js.coffee

@@ -0,0 +1,27 @@
+window.Alchemy = {} if typeof (window.Alchemy) is "undefined"
+
+Alchemy.Growler =
+
+  build: (message, flash_type) ->
+    $flash_container = $("<div class=\"flash #{flash_type}\" />")
+    icon_class = (if flash_type is "notice" then "tick" else flash_type)
+    $flash_container.append "<span class=\"icon #{icon_class}\" />"
+    $flash_container.append message
+    $("#flash_notices").append $flash_container
+    $("#flash_notices").show()
+    Alchemy.Growler.fade()
+
+  fade: ->
+    $(".flash.notice, .flash.warning, .flash.warn, .flash.alert", "#flash_notices").delay(5000).hide "drop",
+      direction: "up"
+    , 400, ->
+      $(this).remove()
+
+    $(".flash.error", "#flash_notices").click ->
+      $(this).hide "drop",
+        direction: "up"
+      , 400, ->
+        $(this).remove()
+
+Alchemy.growl = (message, style = "notice") ->
+  Alchemy.Growler.build message, style