lc_alchemy_cms 3.2.0

data/app/assets/javascripts/alchemy/alchemy.gui.js.coffee

@@ -0,0 +1,22 @@
+window.Alchemy = {} if window.Alchemy == undefined
+
+# Alchemy GUI initializers
+Alchemy.GUI =
+
+  # Initializes all Alchemy GUI elements in given scope
+  init: (scope) ->
+    Alchemy.SelectBox(scope)
+    Alchemy.Datepicker(scope)
+    Alchemy.Buttons.observe(scope)
+    Alchemy.watchForDialogs(scope)
+    Alchemy.Hotkeys(scope)
+    Alchemy.ListFilter(scope)
+    Alchemy.Spinner.watch(scope)
+    Alchemy.Autocomplete.tags(scope)
+    $('[data-alchemy-char-counter]', scope).each ->
+      new Alchemy.CharCounter(this)
+
+  initElement: ($el) ->
+    Alchemy.ElementDirtyObserver($el)
+    Alchemy.GUI.init($el)
+    Alchemy.ImageLoader($el)

data/app/assets/javascripts/alchemy/alchemy.hotkeys.js.coffee

@@ -0,0 +1,49 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# Handles Alchemy hotkeys
+#
+Alchemy.bindedHotkeys = []
+
+Alchemy.Hotkeys = (scope) ->
+
+  # Unbind all previously registered hotkeys.
+  unless scope
+    $(document).off('keypress')
+    for hotkey in Alchemy.bindedHotkeys
+      key.unbind(hotkey)
+
+  # Binds keyboard shortcuts to search fields.
+  $search_fields = $('#search_field, #search_input_field', scope)
+  $search_fields_clear = $('.search_field_clear, .js_filter_field_clear', scope)
+
+  key 'alt+f', ->
+    key.setScope('search')
+    $search_fields.focus()
+    false
+  Alchemy.bindedHotkeys.push('alt+f')
+
+  key 'esc', 'search', ->
+    $search_fields_clear.click()
+    $search_fields.blur()
+  Alchemy.bindedHotkeys.push('esc')
+
+  unless scope
+    $(document).on 'keypress', (e) ->
+      if !$(e.target).is('input, textarea') && String.fromCharCode(e.which) == '?'
+        Alchemy.openDialog '/admin/help',
+          title: Alchemy._t('help')
+          size: '400x492'
+        false
+      else
+        true
+
+  # Binds click events to hotkeys.
+  #
+  # Simply add a data-alchemy-hotkey attribute to your link.
+  # If a hotkey is triggered by user, the click event of the element gets triggerd.
+  #
+  $('[data-alchemy-hotkey]', scope).each ->
+    $this = $(this)
+    hotkey = $this.data('alchemy-hotkey')
+    key hotkey, -> $this.click()
+    Alchemy.bindedHotkeys.push(hotkey)

data/app/assets/javascripts/alchemy/alchemy.html5.js

@@ -0,0 +1,22 @@
+// Testing for HTML5 features
+if (typeof(Alchemy) === 'undefined') {
+  var Alchemy = {};
+}
+
+Alchemy.HTML5 = {};
+
+Alchemy.HTML5.hasUploadSupport = function() {
+  return typeof(window.FileReader) !== 'undefined' && supportFileAPI() && supportAjaxUploadProgressEvents();
+
+  function supportFileAPI() {
+    var fi = document.createElement('INPUT');
+    fi.type = 'file';
+    return 'files' in fi;
+  }
+
+  function supportAjaxUploadProgressEvents() {
+    var xhr = new XMLHttpRequest();
+    return !!(xhr && ('upload' in xhr) && ('onprogress' in xhr.upload));
+  }
+
+};

data/app/assets/javascripts/alchemy/alchemy.i18n.js.coffee

@@ -0,0 +1,26 @@
+#= require alchemy/alchemy.translations
+
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+Alchemy.I18n =
+
+  # Translates given string
+  #
+  translate: (key, replacement) ->
+    if !Alchemy.locale?
+      throw 'Alchemy.locale is not set! Please set Alchemy.locale to a locale string in order to translate something.'
+    translations = Alchemy.translations[Alchemy.locale]
+    if translations
+      translation = translations[key] || key
+      if replacement
+        translation.replace(/%\{.+\}/, replacement)
+      else
+        translation
+    else
+      Alchemy.debug "Translations for locale #{Alchemy.locale} not found!"
+      key
+
+# Global utility method for translating a given string
+#
+Alchemy._t = (key, replacement) ->
+  Alchemy.I18n.translate(key, replacement)

data/app/assets/javascripts/alchemy/alchemy.image_cropper.js.coffee

@@ -0,0 +1,44 @@
+window.Alchemy = {} if typeof (window.Alchemy) is "undefined"
+
+Alchemy.ImageCropper =
+
+  initialized: false
+
+  init: (box, min_size, default_box, ratio, true_size) ->
+    crop_from_field = $("#essence_picture_crop_from")
+    crop_size_field = $("#essence_picture_crop_size")
+    options =
+      onSelect: (coords) ->
+        crop_from_field.val coords.x + "x" + coords.y
+        crop_size_field.val coords.w + "x" + coords.h
+      setSelect: box
+      aspectRatio: (if ratio then ratio else `undefined`)
+      minSize: (if min_size then min_size else `undefined`)
+      boxWidth: 800
+      boxHeight: 600
+      trueSize: true_size
+    Alchemy.ImageCropper.box = box
+    Alchemy.ImageCropper.default_box = default_box
+    Alchemy.ImageCropper.crop_from_field = crop_from_field
+    Alchemy.ImageCropper.crop_size_field = crop_size_field
+    unless Alchemy.ImageCropper.initialized
+      Alchemy.ImageCropper.api = $.Jcrop("#imageToCrop", options)
+      Alchemy.ImageCropper.initialized = true
+    dialog = Alchemy.currentDialog()
+    if dialog?
+      dialog.options.closed = ->
+        Alchemy.ImageCropper.destroy()
+
+  undo: ->
+    Alchemy.ImageCropper.api.setSelect Alchemy.ImageCropper.box
+
+  reset: ->
+    Alchemy.ImageCropper.api.setSelect Alchemy.ImageCropper.default_box
+    Alchemy.ImageCropper.crop_from_field.val ""
+    Alchemy.ImageCropper.crop_size_field.val ""
+
+  destroy: ->
+    if Alchemy.ImageCropper.api
+      Alchemy.ImageCropper.api.destroy()
+    Alchemy.ImageCropper.initialized = false
+    true

data/app/assets/javascripts/alchemy/alchemy.initializer.js.coffee

@@ -0,0 +1,63 @@
+# Initialize all onload scripts at once.
+#
+# Called at jQuery ready event and Turbolinks page change event.
+#
+Alchemy.Initializer = ->
+
+  # We obviously have javascript enabled.
+  $('html').removeClass('no-js')
+
+  # Initialize the GUI.
+  Alchemy.GUI.init()
+
+  # Fade all growl notifications.
+  if $('#flash_notices').length > 0
+    Alchemy.Growler.fade()
+
+  # Add observer for please wait overlay.
+  $('a.please_wait, #main_navi a.main_navi_entry, div.button_with_label form :submit, #sub_navigation .subnavi_tab a, .pagination a')
+    .not('*[data-alchemy-confirm], #subnav_additions .subnavi_tab button')
+    .click ->
+      unless Alchemy.isPageDirty()
+        Alchemy.pleaseWaitOverlay()
+
+  # Hack for enabling tab focus for <a>'s styled as button.
+  $('a.button').attr({tabindex: 0})
+
+  # Locale select handler
+  $('select#change_locale').on 'change', (e) ->
+    url = window.location.pathname
+    delimiter = if url.match(/\?/) then '&' else '?'
+    window.location.href = "#{url}#{delimiter}locale=#{$(this).val()}"
+
+  # Site select handler
+  $('select#change_site').on 'change', (e) ->
+    url = window.location.pathname
+    delimiter = if url.match(/\?/) then '&' else '?'
+    window.location.href = "#{url}#{delimiter}site_id=#{$(this).val()}"
+
+  # Submit forms of selects with `data-autosubmit="true"`
+  $('select[data-auto-submit="true"]').on 'change', (e) ->
+    Alchemy.pleaseWaitOverlay()
+    $(this.form).submit()
+
+  # Attaches the image loader on all images
+  Alchemy.ImageLoader('#main_content')
+
+  # Override the filter of keymaster.js so we can blur the fields on esc key.
+  key.filter = (event) ->
+    tagName = (event.target || event.srcElement).tagName
+    key.isPressed('esc') || !(tagName == 'INPUT' || tagName == 'SELECT' || tagName == 'TEXTAREA')
+
+  # Sticky table headers
+  $('table.list').floatThead
+    useAbsolutePositioning: false,
+    scrollingTop: 122,
+    zIndex: 1
+
+# Enabling the Turbolinks Progress Bar
+Turbolinks.enableProgressBar()
+
+# Turbolinks DOM Ready
+$(document).on 'page:change', ->
+  Alchemy.Initializer()

data/app/assets/javascripts/alchemy/alchemy.jquery_loader.js

@@ -0,0 +1,42 @@
+if (typeof(Alchemy) === 'undefined') {
+  var Alchemy = {};
+}
+
+// Load jQuery on demand. Use this if jQuery is not present.
+// Found on http://css-tricks.com/snippets/jquery/load-jquery-only-if-not-present/
+Alchemy.loadjQuery = function(callback) {
+
+  var thisPageUsingOtherJSLibrary = false;
+
+  if (typeof($) === 'function') {
+    thisPageUsingOtherJSLibrary = true;
+  }
+
+  function getScript(url, success) {
+    var script = document.createElement('script');
+    var head = document.getElementsByTagName('head')[0],
+      done = false;
+    script.src = url;
+    // Attach handlers for all browsers
+    script.onload = script.onreadystatechange = function() {
+      if (!done && (!this.readyState || this.readyState === 'loaded' || this.readyState === 'complete')) {
+        done = true;
+        // callback function provided as param
+        success();
+        script.onload = script.onreadystatechange = null;
+        head.removeChild(script);
+      };
+    };
+    head.appendChild(script);
+  }
+
+  getScript('//code.jquery.com/jquery.min.js', function() {
+    if (typeof(jQuery) !== 'undefined') {
+      if (thisPageUsingOtherJSLibrary) {
+        jQuery.noConflict();
+      }
+      callback(jQuery);
+    }
+  });
+
+}

data/app/assets/javascripts/alchemy/alchemy.js

@@ -0,0 +1,52 @@
+// Alchemy CMS Sprockets Manifest
+// ------------------------------
+//= require jquery2
+//= require jquery_ujs
+//= require turbolinks
+//= require jquery-ui/datepicker
+//= require jquery-ui/draggable
+//= require jquery-ui/effect-drop
+//= require jquery-ui/effect-fade
+//= require jquery-ui/sortable
+//= require jquery-ui/tabs
+//= require tinymce/tinymce.min
+//= require_tree ../../../../vendor/assets/javascripts/jquery_plugins/
+//= require spin.min
+//= require keymaster
+//= require requestAnimationFrame
+//= require select2
+//= require select2_locale_de
+//= require select2_locale_es
+//= require select2_locale_fr
+//= require select2_locale_nl
+//= require select2_locale_ru
+//= require alchemy/alchemy.base
+//= require alchemy/alchemy.autocomplete
+//= require alchemy/alchemy.browser
+//= require alchemy/alchemy.buttons
+//= require alchemy/alchemy.dialog
+//= require alchemy/alchemy.char_counter
+//= require alchemy/alchemy.confirm_dialog
+//= require alchemy/alchemy.datepicker
+//= require alchemy/alchemy.dirty
+//= require alchemy/alchemy.dragndrop
+//= require alchemy/alchemy.element_editors
+//= require alchemy/alchemy.elements_window
+//= require alchemy/alchemy.growler
+//= require alchemy/alchemy.gui
+//= require alchemy/alchemy.hotkeys
+//= require alchemy/alchemy.i18n
+//= require alchemy/alchemy.image_cropper
+//= require alchemy/alchemy.string_extension
+//= require alchemy/alchemy.link_dialog
+//= require alchemy/alchemy.list_filter
+//= require alchemy/alchemy.initializer
+//= require alchemy/alchemy.page_sorter
+//= require alchemy/alchemy.uploader
+//= require alchemy/alchemy.preview_window
+//= require alchemy/alchemy.sitemap
+//= require alchemy/alchemy.spinner
+//= require alchemy/alchemy.tinymce
+//= require alchemy/alchemy.translations
+//= require alchemy/alchemy.windows
+//= require alchemy/alchemy.custom

data/app/assets/javascripts/alchemy/alchemy.link_dialog.js.coffee

@@ -0,0 +1,250 @@
+# Represents the link Dialog that appears, if a user clicks the link buttons
+# in TinyMCE or on an Essence that has links enabled (e.g. EssencePicture)
+#
+class window.Alchemy.LinkDialog extends Alchemy.Dialog
+
+  constructor: (@link_object) ->
+    @url = Alchemy.routes.link_admin_pages_path
+    @$link_object = $(@link_object)
+    @options =
+      size: '600x320'
+      title: 'Link'
+    super(@url, @options)
+
+  # Called from Dialog class after the url was loaded
+  replace: (data) ->
+    # let Dialog class handle the content replacement
+    super(data)
+    # attach events we handle
+    @attachEvents()
+    # Store some jQuery objects for further reference
+    @$page_anchor = $('#page_anchor', @dialog_body)
+    @$internal_urlname = $('#internal_urlname', @dialog_body)
+    @$internal_anchor = $('#internal_anchor', @dialog_body)
+    @$external_url = $('#external_url', @dialog_body)
+    @$public_filename = $('#public_filename', @dialog_body)
+    @$overlay_tabs = $('#overlay_tabs', @dialog_body)
+    @$page_container = $('#page_selector_container')
+    @initInternalAnchors()
+    # if we edit an existing link
+    if @link_object
+      # we select the correct tab
+      @selectTab()
+
+  # Attaches click events to several buttons in the link dialog.
+  attachEvents: ->
+    # The select page and show elements links.
+    $('a.sitemap_pagename_link, a.show_elements_to_link', @dialog_body).click (e) =>
+      $this = $(e.target)
+      page_id = $this.data('page-id')
+      url = $this.data('url')
+      # Select page in page tree
+      @selectPage(page_id)
+      # if the show elements link was clicked
+      if $this.hasClass('show_elements_to_link')
+        # we open the elements select for that page
+        @showElementsSelect($this.attr('href'), url)
+      else
+        # store url
+        @$internal_urlname.val('/' + url)
+      false
+    # The ok buttons
+    $('.create-link.button', @dialog_body).click (e) =>
+      @link_type = $(e.target).data('link-type')
+      switch @link_type
+        # get stored url for link type
+        when 'external'
+          url = @$external_url.val()
+        when 'file'
+          url = @$public_filename.val()
+        else
+          url = $("##{@link_type}_urlname").val()
+      # Create the link
+      @createLink
+        url: url
+        title: $("##{@link_type}_link_title").val()
+        target: $("##{@link_type}_link_target").val()
+      false
+
+  # Sets the page selected and scrolls it in the viewport.
+  selectPage: (page_id) ->
+    # deselect any selected page from page tree
+    @deselectPage()
+    # reset the internal anchor select
+    @$internal_anchor.select2('val', '')
+    $('#sitemap_sitename_' + page_id).addClass('selected_page')
+    @$page_container.scrollTo("#sitemap_sitename_#{page_id}", {duration: 400, offset: -10})
+
+  deselectPage: ->
+    $('#sitemap .selected_page', @dialog_body).removeClass('selected_page')
+
+  # Creates a link if no validation errors are present.
+  # Otherwise shows an error notice.
+  createLink: (options) ->
+    if @link_type == 'external'
+      if @validateURLFormat(options.url)
+        @setLink(options.url, options.title, options.target)
+      else
+        return @showValidationError()
+    else
+      @setLink(options.url, options.title, options.target)
+    @close()
+
+  # Sets the link either in TinyMCE or on an Essence.
+  setLink: (url, title, target) ->
+    Alchemy.setElementDirty(@$link_object.parents('.element_editor'))
+    if @link_object.editor
+      @setTinyMCELink(url, title, target)
+    else
+      @setEssenceLink(url, title, target)
+
+  # Sets a link in TinyMCE editor.
+  setTinyMCELink: (url, title, target) ->
+    editor = @link_object.editor
+    editor.execCommand 'mceInsertLink', false,
+      'href': url
+      'class': @link_type
+      'title': title
+      'data-link-target': target
+      'target': if target == 'blank' then '_blank' else null
+    editor.selection.collapse()
+    true
+
+  # Sets a link on an Essence (e.g. EssencePicture).
+  setEssenceLink: (url, title, target) ->
+    content_id = @$link_object.data('content-id')
+    $("#contents_#{content_id}_link").val(url).change()
+    $("#contents_#{content_id}_link_title").val(title)
+    $("#contents_#{content_id}_link_class_name").val(@link_type)
+    $("#contents_#{content_id}_link_target").val(target)
+    @$link_object.addClass('linked')
+    @$link_object.next().addClass('linked').removeClass('disabled')
+
+  # Selects the correct tab for link type and fills all fields.
+  selectTab: ->
+    # Creating an temporary anchor node if we are linking an EssencePicture or EssenceText.
+    if (@link_object.nodeType)
+      $link = @createTempLink()
+    # Restoring the bookmarked selection inside the TinyMCE of an EssenceRichtext.
+    else if (@link_object.node.nodeName == 'A')
+      $link = $(@link_object.node)
+      @link_object.selection.moveToBookmark(@link_object.bookmark)
+    else
+      return false
+    # Populate title and target fields.
+    $('.link_title', @dialog_body).val $link.attr('title')
+    $('.link_target', @dialog_body).select2('val', $link.attr('data-link-target'))
+    # Checking of what kind the link is (internal, external or file).
+    if $link.hasClass('external')
+      # Handles an external link.
+      tab = $('#overlay_tab_external_link')
+      @$external_url.val($link.attr('href'))
+    else if $link.hasClass('file')
+      # Handles a file link.
+      tab = $('#overlay_tab_file_link')
+      @$public_filename.select2('val', $link[0].pathname + $link[0].search)
+    else
+      # Handles an internal link.
+      tab = $('#overlay_tab_internal_link')
+      @selectInternalLinkTab($link)
+    # activate the tab jquery ui 1.10 style o.O
+    @$overlay_tabs.tabs('option', 'active', $('#overlay_tabs > div').index(tab))
+
+  # Handles actions for internal link tab.
+  selectInternalLinkTab: ($link) ->
+    url = $link.attr('href').split('#')
+    urlname = url[0]
+    anchor = url[1]
+    if anchor
+      # store the anchor
+      @$page_anchor.val("##{anchor}")
+      # and update the url field
+      @$internal_urlname.val("#{urlname}##{anchor}")
+      # if we linked an internal anchor
+      if @$internal_urlname.val().match(/^#/)
+        # we select the correct value from anchors select
+        value = @$internal_urlname.val()
+        @$internal_anchor.select2 'val', value.replace(/^#/, '')
+    else
+      @$internal_urlname.val(urlname)
+    $sitemap_line = $('.sitemap_sitename').closest('[name="'+urlname+'"]')
+    if ($sitemap_line.length > 0)
+      # Select the line where the link was detected in.
+      $sitemap_line.addClass('selected_page')
+      @$page_container.scrollTo($sitemap_line.parents('li'), {duration: 400, offset: -10})
+
+  # Opens a new Dialog that shows the elements from given page_id in a selectbox.
+  # The value is stored as anchor and the url gets updated so it includes the anchor link
+  showElementsSelect: (show_elements_url, urlname) ->
+    dialog = new Alchemy.Dialog show_elements_url,
+      size: '400x165'
+      ready: =>
+        $element_select = $('.elements_from_page_selector')
+        # check if the urlname is the same as stored,
+        current_urlname = @$internal_urlname.val().split('#')[0]
+        if "/#{urlname}" == current_urlname
+          # then we can select the current anchor in the selectbox
+          $element_select.select2 'val', @$page_anchor.val()
+        $element_select.change =>
+          @$page_anchor.val $element_select.select2('val')
+        $('button', dialog.dialog_body).click =>
+          @$internal_urlname.val("/#{urlname}#{@$page_anchor.val()}")
+          dialog.close()
+          false
+        return
+    dialog.open()
+    return
+
+  # Creates a temporay $('a') object that holds all values on it.
+  createTempLink: ->
+    @$tmp_link = $('<a/>')
+    content_id = @$link_object.data('content-id')
+    @$tmp_link.attr 'href', $("#contents_#{content_id}_link").val()
+    @$tmp_link.attr 'title', $("#contents_#{content_id}_link_title").val()
+    @$tmp_link.attr 'data-link-target', $("#contents_#{content_id}_link_target").val()
+    @$tmp_link.attr 'target', if $("#contents_#{content_id}_link_target").val() == 'blank' then '_blank' else null
+    @$tmp_link.addClass $("#contents_#{content_id}_link_class_name").val()
+    @$tmp_link
+
+  # Validates url for beginning with an protocol.
+  validateURLFormat: (url) ->
+    if url.match(Alchemy.link_url_regexp)
+      true
+    else
+      false
+
+  # Shows validation errors
+  showValidationError: ->
+    $('#errors ul', @dialog_body).html("<li>#{Alchemy._t('url_validation_failed')}</li>")
+    $('#errors', @dialog_body).show()
+
+  # Populates the internal anchors select
+  initInternalAnchors: ->
+    frame = document.getElementById('alchemy_preview_window')
+    elements = frame.contentDocument.getElementsByTagName('*')
+    if elements.length > 0
+      for element in elements
+        if element.id
+          @$internal_anchor.append("<option value='#{element.id}'>##{element.id}</option>")
+    else
+      @$internal_anchor.html("<option>#{Alchemy._t('No anchors found')}</option>")
+    @$internal_anchor.change (e) =>
+      # deselect any selected page from page tree
+      @deselectPage()
+      # store the internal anchor as urlname
+      $("#internal_urlname").val("##{e.target.value}")
+
+  # Public class methods
+
+  # Removes link from Essence.
+  @removeLink = (link, content_id) ->
+    $link = $(link)
+    $("#contents_#{content_id}_link").val('').change()
+    $("#contents_#{content_id}_link_title").val('')
+    $("#contents_#{content_id}_link_class_name").val('')
+    $("#contents_#{content_id}_link_target").val('')
+    if $link.hasClass('linked')
+      Alchemy.setElementDirty $(link).parents('.element_editor')
+      $link.removeClass('linked').addClass('disabled')
+    $('#edit_link_' + content_id).removeClass('linked')
+    false