lc_alchemy_cms 3.2.0

data/app/assets/javascripts/alchemy/alchemy.browser.js.coffee

@@ -0,0 +1,22 @@
+window.Alchemy = {} if typeof(Alchemy) is "undefined"
+
+Alchemy.Browser =
+  isiPhone: navigator.userAgent.match(/iPhone/i) isnt null
+  isiPad: navigator.userAgent.match(/iPad/i) isnt null
+  isiPod: navigator.userAgent.match(/iPod/i) isnt null
+  isiOS: navigator.userAgent.match(/iPad|iPhone|iPod/i) isnt null
+  isFirefox: navigator.userAgent.match(/Firefox/i) isnt null
+  isChrome: navigator.userAgent.match(/Chrome/i) isnt null
+  isSafari: navigator.userAgent.match(/AppleWebKit/) and not navigator.userAgent.match(/Chrome/)
+  isIE: navigator.userAgent.match(/MSIE/i) isnt null
+  getVersion: (browser) ->
+    if Alchemy.Browser["is" + browser]
+      parseInt(navigator.userAgent.match(new RegExp(browser + ".[0-9]+", "i"))[0].replace(new RegExp(browser + "."), ""), 10)
+    else
+      null
+
+Alchemy.Browser.ChromeVersion = Alchemy.Browser.getVersion("Chrome")
+Alchemy.Browser.FirefoxVersion = Alchemy.Browser.getVersion("Firefox")
+Alchemy.Browser.SafariVersion = Alchemy.Browser.getVersion("Safari")
+Alchemy.Browser.IEVersion = Alchemy.Browser.getVersion("MSIE")
+Alchemy.Browser.isWebKit = Alchemy.Browser.isChrome || Alchemy.Browser.isSafari

data/app/assets/javascripts/alchemy/alchemy.buttons.js.coffee

@@ -0,0 +1,32 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+Alchemy.Buttons =
+
+  observe: (scope) ->
+    $('form', scope).not('.button_with_label form').on 'submit', (event) ->
+      $btn = $(this).find(':submit')
+      if $btn.attr('disabled') == 'disabled'
+        event.preventDefault()
+        event.stopPropagation()
+        false
+      else
+        Alchemy.Buttons.disable($btn)
+
+  disable: (button) ->
+    $button = $(button)
+    spinner = Alchemy.Spinner.small()
+    $button.data('content', $button.html())
+    $button.attr('disabled', true)
+    $button.addClass('disabled')
+    $button.css
+      width: $button.outerWidth()
+    $button.empty()
+    spinner.spin($button[0])
+    return true
+
+  enable: (scope) ->
+    $button = $('form :submit:disabled', scope)
+    $button.removeClass('disabled')
+    $button.removeAttr('disabled')
+    $button.html($button.data('content'))
+    return true

data/app/assets/javascripts/alchemy/alchemy.char_counter.js.coffee

@@ -0,0 +1,19 @@
+class window.Alchemy.CharCounter
+
+  constructor: (field) ->
+    @$field = $(field)
+    @max_chars = @$field.data('alchemy-char-counter')
+    @text = Alchemy._t('allowed_chars', @max_chars)
+    @$display = $('<small class="alchemy-char-counter"/>')
+    @$field.after(@$display)
+    countChars.call(this)
+    @$field.keyup =>
+      countChars.call(this)
+      true
+
+  countChars = ->
+    char_length = @$field.val().length
+    @$display.removeClass('too-long')
+    @$display.text("#{char_length} #{@text}")
+    if char_length > @max_chars
+      @$display.addClass('too-long')

data/app/assets/javascripts/alchemy/alchemy.confirm_dialog.js.coffee

@@ -0,0 +1,85 @@
+class window.Alchemy.ConfirmDialog extends Alchemy.Dialog
+
+  DEFAULTS:
+    header_height: 36
+    size: '300x100'
+    padding: true
+    modal: true
+    title: 'Please confirm'
+    ok_label: 'Yes'
+    cancel_label: 'No'
+    on_ok: ->
+
+  constructor: (@message, @options = {}) ->
+    super('', @options)
+
+  load: ->
+    @dialog_title.text @options.title
+    @dialog_body.html "<p>#{@message}</p>"
+    @dialog_body.append @build_buttons()
+    @bind_buttons()
+
+  build_buttons: ->
+    $btn_container = $('<div class="alchemy-dialog-buttons" />')
+    @cancel_button = $("<button class=\"cancel\">#{@options.cancel_label}</button>")
+    @ok_button = $("<button class=\"confirm\">#{@options.ok_label}</button>")
+    $btn_container.append(@cancel_button)
+    $btn_container.append(@ok_button)
+    $btn_container
+
+  bind_buttons: ->
+    @cancel_button.focus()
+    @cancel_button.click =>
+      @close()
+      Alchemy.Buttons.enable()
+      false
+    @ok_button.click =>
+      @close()
+      @options.on_ok()
+      false
+
+# Opens a confirm dialog
+#
+# Arguments:
+#
+# message - The message that will be displayed to the user (String)
+#
+# Options:
+#
+#   title: ''         - The title of the overlay window (String)
+#   cancel_label: ''   - The label of the cancel button (String)
+#   ok_label: ''       - The label of the ok button (String)
+#   on_ok: null  - The function to invoke on confirmation (Function)
+#
+window.Alchemy.openConfirmDialog = (message, options = {}) ->
+  dialog = new Alchemy.ConfirmDialog(message, options)
+  dialog.open()
+
+# Opens a confirm to delete dialog
+#
+# Arguments:
+#
+#   url  - The url to the server delete action. Uses DELETE as HTTP method. (String)
+#   opts - An options object (Object)
+#
+# Options:
+#
+#   title: ''        - The title of the confirmation window (String)
+#   message: ''      - The message that will be displayed to the user (String)
+#   ok_label: ''      - The label for the ok button (String)
+#   cancel_label: ''  - The label for the cancel button (String)
+#
+window.Alchemy.confirmToDeleteDialog = (url, opts) ->
+  options =
+    on_ok: ->
+      Alchemy.pleaseWaitOverlay()
+      $.ajax
+        url: url
+        type: "DELETE"
+        error: (xhr, status, error) ->
+          type = if xhr.status == 403 then 'warning' else 'error'
+          Alchemy.pleaseWaitOverlay(false)
+          Alchemy.growl(xhr.responseText || error, type)
+
+  $.extend(options, opts)
+  Alchemy.openConfirmDialog options.message, options

data/app/assets/javascripts/alchemy/alchemy.custom.js

@@ -0,0 +1 @@
+// You can overwrite this file in your app or engine to customize javascript available in Alchemy's backend.

data/app/assets/javascripts/alchemy/alchemy.datepicker.js.coffee

@@ -0,0 +1,31 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+$.extend Alchemy,
+
+  Datepicker: (scope) ->
+    browserHasDatepicker = Alchemy.isiOS
+    datepicker_options =
+      dateFormat: "yy-mm-dd"
+      changeMonth: true
+      changeYear: true
+      showWeek: true
+      showButtonPanel: true
+      showOtherMonths: true
+      onSelect: ->
+        Alchemy.setElementDirty $(this).parents("div.element_editor")
+
+    if Alchemy.locale is "de"
+      $.extend datepicker_options,
+        dateFormat: "dd.mm.yy"
+        dayNames: ["Sonntag", "Montag", "Dienstag", "Mittwoch", "Donnerstag", "Freitag", "Samstag"]
+        dayNamesMin: ["So", "Mo", "Di", "Mi", "Do", "Fr", "Sa"]
+        monthNames: ["Januar", "Februar", "März", "April", "Mai", "Juni", "Juli", "August", "September", "Oktober", "November", "Dezember"]
+        monthNamesShort: ["Jan", "Feb", "Mär", "Apr", "Mai", "Jun", "Jul", "Aug", "Sep", "Okt", "Nov", "Dez"]
+        closeText: "Ok"
+        currentText: "Heute"
+        weekHeader: "KW"
+        nextText: "nächster"
+        prevText: "vorheriger"
+
+    # Initializes the jQueryUI datepicker and disables the browsers default Datepicker unless the browser is iOS.
+    $('input[type="date"], input.date', scope).datepicker(datepicker_options).prop "type", "text" unless browserHasDatepicker

data/app/assets/javascripts/alchemy/alchemy.dialog.js.coffee

@@ -0,0 +1,266 @@
+# Dialog windows
+#
+class window.Alchemy.Dialog
+
+  DEFAULTS:
+    header_height: 36
+    size: '400x300'
+    padding: true
+    title: ''
+    modal: true
+    overflow: 'visible'
+    ready: ->
+    closed: ->
+
+  # Arguments:
+  #  - url: The url to load the content from via ajax
+  #  - options: A object holding options
+  #    - size: The maximum size of the Dialog
+  #    - title: The title of the Dialog
+  constructor: (@url, @options = {}) ->
+    @options = $.extend({}, @DEFAULTS, @options)
+    @$document = $(document)
+    @$window = $(window)
+    @$body = $('body')
+    size = @options.size.split('x')
+    @width = parseInt(size[0], 10)
+    @height = parseInt(size[1], 10)
+    @build()
+
+  # Opens the Dialog and loads the content via ajax.
+  open: ->
+    @dialog.trigger 'Alchemy.DialogOpen'
+    @bind_close_events()
+    window.requestAnimationFrame =>
+      @dialog_container.addClass('open')
+      @overlay.addClass('open') if @overlay?
+    @dialog.draggable
+      iframeFix: true
+      handle: '.alchemy-dialog-title'
+      containment: 'parent'
+    @$body.addClass('prevent-scrolling')
+    Alchemy.currentDialogs.push(this)
+    @load()
+    true
+
+  # Closes the Dialog and removes it from the DOM
+  close: ->
+    @$document.off 'keydown'
+    @dialog_container.removeClass('open')
+    @overlay.removeClass('open') if @overlay?
+    @$document.on 'webkitTransitionEnd transitionend oTransitionEnd', =>
+      @$document.off 'webkitTransitionEnd transitionend oTransitionEnd'
+      @dialog_container.remove()
+      @overlay.remove() if @overlay?
+      @$body.removeClass('prevent-scrolling')
+      Alchemy.currentDialogs.pop(this)
+      if @options.closed?
+        @options.closed()
+    true
+
+  # Loads the content via ajax and replaces the Dialog body with server response.
+  load: ->
+    @show_spinner()
+    $.get @url, (data) =>
+      @replace(data)
+    .fail (xhr) =>
+      @show_error(xhr)
+    true
+
+  # Reloads the Dialog content
+  reload: ->
+    @dialog_body.empty()
+    @load()
+
+  # Replaces the dialog body with given content and initializes it.
+  replace: (data) ->
+    @remove_spinner()
+    @dialog_body.hide()
+    @dialog_body.html(data)
+    @init()
+    if @options.ready?
+      @options.ready(@dialog_body)
+    @dialog_body.show('fade', 200)
+    true
+
+  # Adds a spinner into Dialog body
+  show_spinner: ->
+    @spinner = Alchemy.Spinner.medium()
+    @spinner.spin(@dialog_body[0])
+
+  # Removes the spinner from Dialog body
+  remove_spinner: ->
+    @spinner.stop()
+
+  # Initializes the Dialog body
+  init: ->
+    Alchemy.GUI.init(@dialog_body)
+    $('#overlay_tabs', @dialog_body).tabs()
+    @watch_remote_forms()
+
+  # Watches ajax requests inside of dialog body and replaces the content accordingly
+  watch_remote_forms: ->
+    form = $('[data-remote="true"]', @dialog_body)
+    form.bind "ajax:complete", (e, xhr, status) =>
+      content_type = xhr.getResponseHeader('Content-Type')
+      Alchemy.Buttons.enable(@dialog_body)
+      if status == 'success'
+        if content_type.match(/javascript/)
+          return
+        else
+          @dialog_body.html(xhr.responseText)
+          @init()
+      else
+        @show_error(xhr, status)
+
+  # Displays an error message
+  show_error: (xhr, status_message) ->
+    error_type = "warning"
+    switch xhr.status
+      when 0
+        error_header = "The server does not respond."
+        error_body = "Please check server and try again."
+      when 403
+        error_header = "You are not authorized!"
+        error_body = "Please close this window."
+      else
+        error_type = "error"
+        if status_message
+          error_header = status_message
+          console.error eval(xhr.responseText)
+        else
+          error_header = "#{xhr.statusText} (#{xhr.status})"
+        error_body = "Please check log and try again."
+    $errorDiv = $("<div class=\"message #{error_type}\" />")
+    $errorDiv.append "<span class=\"icon #{error_type}\" />"
+    $errorDiv.append "<h1>#{error_header}</h1>"
+    $errorDiv.append "<p>#{error_body}</p>"
+    @dialog_body.html $errorDiv
+
+  # Binds close events on:
+  # - Close button
+  # - Overlay (if the Dialog is a modal)
+  # - ESC Key
+  bind_close_events: ->
+    @close_button.click =>
+      @close()
+      false
+    @dialog_container.addClass('closable').click (e) =>
+      return true if e.target != @dialog_container.get(0)
+      @close()
+      false
+    @$document.keydown (e) =>
+      if e.which == 27
+        @close()
+        false
+      else
+        true
+
+  # Builds the html structure of the Dialog
+  build: ->
+    @dialog_container = $('<div class="alchemy-dialog-container" />')
+    @dialog = $('<div class="alchemy-dialog" />')
+    @dialog_body = $('<div class="alchemy-dialog-body" />')
+    @dialog_header = $('<div class="alchemy-dialog-header" />')
+    @dialog_title = $('<div class="alchemy-dialog-title" />')
+    @close_button = $('<a class="alchemy-dialog-close"><span class="icon close small"></span></a>')
+    @dialog_title.text(@options.title)
+    @dialog_header.append(@dialog_title)
+    @dialog_header.append(@close_button)
+    @dialog.append(@dialog_header)
+    @dialog.append(@dialog_body)
+    @dialog_container.append(@dialog)
+    @dialog.addClass('modal') if @options.modal
+    @dialog_body.addClass('padded') if @options.padding
+    if @options.modal
+      @overlay = $('<div class="alchemy-dialog-overlay" />')
+      @$body.append(@overlay)
+    @$body.append(@dialog_container)
+    @resize()
+    @dialog
+
+  # Sets the correct size of the dialog
+  # It normalizes the given size, so that it never acceeds the window size.
+  resize: ->
+    padding = 16
+    $doc_width = @$window.width()
+    $doc_height = @$window.height()
+    if @options.size == 'fullscreen'
+      [@width, @height] = [$doc_width, $doc_height]
+    if @width >= $doc_width
+      @width = $doc_width - padding
+    if @height >= $doc_height
+      @height = $doc_height - padding - @DEFAULTS.header_height
+    @dialog.css
+      'width': @width
+      'min-height': @height
+      overflow: @options.overflow
+    if @options.overflow == 'hidden'
+      @dialog_body.css
+        height: @height
+        overflow: 'auto'
+    else
+      @dialog_body.css
+        'min-height': @height
+        overflow: 'visible'
+    return
+
+# Collection of all current dialog instances
+window.Alchemy.currentDialogs = []
+
+# Gets the last dialog instantiated, which is the current one.
+window.Alchemy.currentDialog = ->
+  length = Alchemy.currentDialogs.length
+  return if length == 0
+  Alchemy.currentDialogs[length - 1]
+
+# Utility function to close the current Dialog
+#
+# You can pass a callback function, that gets triggered after the Dialog gets closed.
+#
+window.Alchemy.closeCurrentDialog = (callback) ->
+  dialog = Alchemy.currentDialog()
+  if dialog?
+    dialog.options.closed = callback
+    dialog.close()
+
+# Utility function to open a new Dialog
+window.Alchemy.openDialog = (url, options) ->
+  if !url
+    throw('No url given! Please provide an url.')
+  dialog = new Alchemy.Dialog(url, options)
+  dialog.open()
+
+# Watches elements for Alchemy Dialogs
+#
+# Links having a data-alchemy-dialog or data-alchemy-confirm-delete
+# and input/buttons having a data-alchemy-confirm attribute get watched.
+#
+# You can pass a scope so that only elements inside this scope are queried.
+#
+# The href attribute of the link is the url for the overlay window.
+#
+# See Alchemy.Dialog for further options you can add to the data attribute
+#
+window.Alchemy.watchForDialogs = (scope) ->
+  $('a[data-alchemy-dialog]', scope).click (e) ->
+    $this = $(this)
+    url = $this.attr('href')
+    options = $this.data('alchemy-dialog')
+    Alchemy.openDialog(url, options)
+    false
+  $('a[data-alchemy-confirm-delete]', scope).click (event) ->
+    $this = $(this)
+    options = $this.data('alchemy-confirm-delete')
+    Alchemy.confirmToDeleteDialog($this.attr('href'), options)
+    false
+  $('input[data-alchemy-confirm], button[data-alchemy-confirm]', scope).click (event) ->
+    options = $(this).data('alchemy-confirm')
+    Alchemy.openConfirmDialog options.message, $.extend options,
+      ok_label: options.ok_label
+      cancel_label: options.cancel_label
+      on_ok: =>
+        Alchemy.pleaseWaitOverlay()
+        @form.submit()
+        return
+    false