lc_alchemy_cms 3.2.0

data/app/assets/javascripts/alchemy/alchemy.list_filter.js.coffee

@@ -0,0 +1,49 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# The Alchemy list filter
+#
+# The list items must have a name attribute.
+#
+# It hides all list items that don't match the term from filter input field.
+#
+class Alchemy.ListFilterHandler
+
+  # Pass a input field with a data-alchemy-list-filter attribute to this constructor
+  constructor: (filter) ->
+    @filter_field = $(filter)
+    @items = $(@filter_field.data('alchemy-list-filter'))
+    @clear = @filter_field.siblings('.js_filter_field_clear')
+    @_observe()
+
+  _observe: ->
+    @filter_field.on 'keyup', (e) =>
+      @clear.show()
+      @_filter @filter_field.val()
+    @clear.click (e) =>
+      e.preventDefault()
+      @_clear()
+    @filter_field.focus ->
+      key.setScope('list_filter')
+    key 'esc', 'list_filter', =>
+      @_clear()
+      @filter_field.blur()
+
+  _filter: (term) ->
+    @clear.hide() if term == ''
+    @items.map ->
+      item = $(this)
+      # indexOf is much faster then match()
+      if item.attr('name').toLowerCase().indexOf(term.toLowerCase()) != -1
+        item.show()
+      else
+        item.hide()
+
+  _clear: ->
+    @filter_field.val ''
+    @_filter ''
+
+# Initializes an Alchemy.ListFilterHandler on all input fields with a data-alchemy-list-filter attribute.
+#
+Alchemy.ListFilter = (scope) ->
+  $('[data-alchemy-list-filter]', scope).map ->
+    new Alchemy.ListFilterHandler(this)

data/app/assets/javascripts/alchemy/alchemy.page_sorter.js

@@ -0,0 +1,48 @@
+if (typeof(Alchemy) === 'undefined') {
+  var Alchemy = {};
+}
+
+(function($) {
+
+  var PageSorter = {};
+  $.extend(Alchemy, PageSorter);
+
+  Alchemy.PageSorter = {
+
+    init: function() {
+      var $sortables = $('ul#sitemap').find('ul.level_1_children');
+      $sortables.nestedSortable({
+        disableNesting: 'no-nest',
+        forcePlaceholderSize: true,
+        handle: '.handle',
+        items: 'li',
+        listType: 'ul',
+        opacity: 0.5,
+        placeholder: 'placeholder',
+        tabSize: 16,
+        tolerance: 'pointer',
+        toleranceElement: '> div'
+      });
+      $('#save_page_order').click(function(e) {
+        var params = {
+          set: JSON.stringify($sortables.nestedSortable('toHierarchy'))
+        };
+        $.post(Alchemy.routes.order_admin_pages_path, params);
+        return false;
+      });
+      $('#sort_panel .button').click(Alchemy.pleaseWaitOverlay);
+      Alchemy.PageSorter.disableButton();
+    },
+
+    disableButton: function() {
+      var $buttonLink = $('#page_sorting_button a');
+      $buttonLink.removeAttr('onclick');
+      $('#page_sorting_button').addClass('active');
+      $buttonLink.css({
+        cursor: 'default'
+      });
+    }
+
+  }
+
+})(jQuery);

data/app/assets/javascripts/alchemy/alchemy.preview.js.coffee

@@ -0,0 +1,106 @@
+#= require alchemy/alchemy.jquery_loader
+#= require alchemy/alchemy.browser
+#= require alchemy/alchemy.i18n
+
+window.Alchemy = {} if typeof(Alchemy) is 'undefined'
+
+Alchemy.initAlchemyPreviewMode = ($) ->
+
+  # Setting jQueryUIs global animation duration
+  $.fx.speeds._default = 400
+
+  # The Alchemy JavaScript Object contains all Functions
+  $.extend Alchemy,
+    ElementSelector:
+
+      # defaults
+      scrollOffset: 20
+
+      styles:
+        reset:
+          outline: ""
+          "outline-offset": ""
+          "-moz-outline-radius": ""
+
+        default_hover:
+          outline: "3px solid #F0B437"
+          "outline-offset": "4px"
+          cursor: "pointer"
+
+        webkit_hover:
+          outline: "4px auto #F0B437"
+
+        moz_hover:
+          "-moz-outline-radius": "3px"
+
+        default_selected:
+          outline: "3px solid #90B9D0"
+          "outline-offset": "4px"
+
+        webkit_selected:
+          outline: "4px auto #90B9D0"
+
+        moz_selected:
+          "-moz-outline-radius": "3px"
+
+      init: ->
+        $elements = $("[data-alchemy-element]")
+        @$previewElements = $elements
+        $elements.mouseover (e) =>
+          $el = $(e.delegateTarget)
+          $el.attr("title", Alchemy._t('click_to_edit'))
+          $el.css(@getStyle("hover")) unless $el.hasClass("selected")
+        $elements.mouseout (e) =>
+          $el = $(e.delegateTarget)
+          $el.removeAttr("title")
+          $el.css(@getStyle("reset")) unless $el.hasClass("selected")
+        $elements.on "Alchemy.SelectElement", (e) =>
+          @selectElement(e)
+        $elements.click (e) =>
+          @clickElement(e)
+
+      selectElement: (e) ->
+        $el = $(e.delegateTarget)
+        $elements = @$previewElements
+        offset = @scrollOffset
+        el_offset = $el.offset()
+        e.preventDefault()
+        $elements.removeClass("selected").css(@getStyle("reset"))
+        $el.addClass("selected").css(@getStyle("selected"))
+        $("html, body").animate
+          scrollTop: el_offset.top - offset
+          scrollLeft: el_offset.left - offset
+        , 400
+        return
+
+      clickElement: (e) ->
+        $el = $(e.delegateTarget)
+        parent$ = window.parent.jQuery
+        target_id = $el.data("alchemy-element")
+        $element_editor = parent$("#element_area .element_editor").closest("[id=\"element_" + target_id + "\"]")
+        elementsWindow = window.parent.Alchemy.ElementsWindow
+        e.preventDefault()
+        $element_editor.trigger("Alchemy.SelectElementEditor", target_id)
+        if elementsWindow.hidden
+          elementsWindow.show()
+        $el.trigger("Alchemy.SelectElement")
+        return
+
+      getStyle: (state) ->
+        if state == "reset"
+          @styles["reset"]
+        else
+          default_state_style = @styles["default_#{state}"]
+          browser = "webkit" if Alchemy.Browser.isWebKit
+          browser = "moz" if Alchemy.Browser.isFirefox
+          if browser
+            $.extend(default_state_style, @styles["#{browser}_#{state}"])
+          else
+            default_state_style
+
+  Alchemy.ElementSelector.init()
+
+if typeof(jQuery) is 'undefined'
+  Alchemy.loadjQuery(Alchemy.initAlchemyPreviewMode)
+else
+  Alchemy.initAlchemyPreviewMode(jQuery)

data/app/assets/javascripts/alchemy/alchemy.preview_window.js.coffee

@@ -0,0 +1,58 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+Alchemy.PreviewWindow =
+
+  init: (url) ->
+    $iframe = $("<iframe name=\"alchemy_preview_window\" src=\"#{url}\" id=\"alchemy_preview_window\" frameborder=\"0\"/>")
+    $reload = $('#reload_preview_button')
+    @_showSpinner()
+    $iframe.load =>
+      @_hideSpinner()
+    $('body').append($iframe)
+    @currentWindow = $iframe
+    @_bindReloadButton()
+    @resize()
+
+  resize: ->
+    $window = $(window)
+    if Alchemy.ElementsWindow.hidden
+      width = $window.width() - 64
+    else
+      width = $window.width() - 466
+    height = $window.height() - 73
+    width = 240 if width < 240
+    @currentWidth = width
+    @currentWindow.css
+      width: width
+      height: height
+
+  refresh: (callback) ->
+    $iframe = $('#alchemy_preview_window')
+    @_showSpinner()
+    # We need to be sure that no load event is binded on the preview frame.
+    $iframe.off('load')
+    $iframe.load (e) =>
+      @_hideSpinner()
+      if callback
+        callback.call(e, $iframe)
+    $iframe.attr 'src', $iframe.attr('src')
+    true
+
+  _showSpinner: ->
+    @reload = $('#reload_preview_button')
+    @spinner = Alchemy.Spinner.small()
+    @reload.html @spinner.spin().el
+
+  _hideSpinner: ->
+    @spinner.stop()
+    @reload.html('<span class="icon reload"></span>')
+
+  _bindReloadButton: ->
+    $reload = $('#reload_preview_button')
+    key 'alt+r', =>
+      @refresh()
+    $reload.click =>
+      @refresh()
+
+Alchemy.reloadPreview = ->
+  Alchemy.PreviewWindow.refresh()

data/app/assets/javascripts/alchemy/alchemy.sitemap.js.coffee

@@ -0,0 +1,50 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# The admin sitemap Alchemy module
+Alchemy.Sitemap =
+
+  # Storing some objects.
+  init: ->
+    @search_field = $("#search_field")
+    @filter_field_clear = $('.js_filter_field_clear')
+    @display = $('#page_filter_result')
+    @items = $(".sitemap_page", '#sitemap')
+    @_observe()
+
+  # Filters the sitemap
+  filter: (term) ->
+    results = []
+    self = Alchemy.Sitemap
+    self.items.map ->
+      item = $(this)
+      if term != '' && item.attr('name').toLowerCase().indexOf(term) != -1
+        item.addClass('highlight')
+        item.removeClass('no-match')
+        results.push item
+      else
+        item.addClass('no-match')
+        item.removeClass('highlight')
+    self.filter_field_clear.show()
+    length = results.length
+    if length == 1
+      self.display.show().text("1 #{Alchemy._t('page_found')}")
+      $.scrollTo(results[0], {duration: 400, offset: -80})
+    else if length > 1
+      self.display.show().text("#{length} #{Alchemy._t('pages_found')}")
+    else
+      self.items.removeClass('no-match highlight')
+      self.display.hide()
+      $.scrollTo('0', 400)
+      self.filter_field_clear.hide()
+
+  # Adds onkey up observer to search field
+  _observe: ->
+    filter = @filter
+    @search_field.on 'keyup', ->
+      term = $(this).val()
+      filter(term.toLowerCase())
+    @search_field.on 'focus', ->
+      key.setScope('search')
+    @filter_field_clear.click =>
+      @search_field.val('')
+      filter('')

data/app/assets/javascripts/alchemy/alchemy.spinner.js.coffee

@@ -0,0 +1,49 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+Alchemy.Spinner =
+
+  DEFAULTS:
+    lines: 5
+    corners: 1
+    rotate: 54
+    trail: 75
+    speed: 1.25
+    hwaccel: true
+
+  tiny: (opts) ->
+    defaults = $.extend({}, Alchemy.Spinner.DEFAULTS,
+      length: 2
+      width: 1
+      radius: 1
+    )
+    new Spinner($.extend(defaults, opts))
+
+  small: (opts) ->
+    defaults = $.extend({}, Alchemy.Spinner.DEFAULTS,
+      length: 2
+      width: 2
+      radius: 2
+    )
+    new Spinner($.extend(defaults, opts))
+
+  medium: (opts) ->
+    defaults = $.extend({}, Alchemy.Spinner.DEFAULTS,
+      length: 4
+      width: 4
+      radius: 4
+    )
+    new Spinner($.extend(defaults, opts))
+
+  large: (opts) ->
+    defaults = $.extend({}, Alchemy.Spinner.DEFAULTS,
+      length: 8
+      width: 10
+      radius: 8
+    )
+    new Spinner($.extend(defaults, opts))
+
+  watch: (scope) ->
+    $('a.spinner', scope).click ->
+      spinner = Alchemy.Spinner.tiny()
+      spinner.spin(this)
+      $(this).css('background': 'none').off('click')

data/app/assets/javascripts/alchemy/alchemy.string_extension.js.coffee

@@ -0,0 +1,11 @@
+String::beginsWith = (t, i) ->
+  if i is false
+    t is @substring(0, t.length)
+  else
+    t.toLowerCase() is @substring(0, t.length).toLowerCase()
+
+String::endsWith = (t, i) ->
+  if i is false
+    t is @substring(@length - t.length)
+  else
+    t.toLowerCase() is @substring(@length - t.length).toLowerCase()

data/app/assets/javascripts/alchemy/alchemy.tinymce.js.coffee

@@ -0,0 +1,66 @@
+# Alchemy Tinymce wrapper
+#
+$.extend Alchemy.Tinymce,
+
+  # Returns default config for a tinymce editor.
+  #
+  getDefaultConfig: (id) ->
+    config = @defaults
+    config.language = Alchemy.locale
+    config.selector = "textarea#tinymce_#{id}"
+    config.init_instance_callback = @initInstanceCallback
+    return config
+
+  # Returns configuration for given custom tinymce editor selector.
+  #
+  # It uses the +.getDefaultConfig+ and merges the custom parts.
+  #
+  getCustomConfig: (id, selector) ->
+    editor_config = @customConfigs[selector]
+    if editor_config
+      $.extend({}, @getDefaultConfig(id), editor_config)
+
+  # Initializes all TinyMCE editors with given ids
+  #
+  # @param ids [Array]
+  #   - Editor ids that should be initialized.
+  #
+  init: (ids) ->
+    for id in ids
+      @initEditor(id)
+
+  # Initializes one specific TinyMCE editor
+  #
+  # @param id [Number]
+  #   - Editor id that should be initialized.
+  #
+  initEditor: (id) ->
+    textarea = $("textarea#tinymce_#{id}")
+    return if textarea.length == 0
+    if selector = textarea[0].classList[1]
+      config = @getCustomConfig(id, selector)
+    else
+      config = @getDefaultConfig(id)
+    if config
+      spinner = Alchemy.Spinner.small()
+      textarea.parents('.tinymce_container').prepend spinner.spin().el
+      tinymce.init(config)
+    else
+      Alchemy.debug('No tinymce configuration found for', id)
+
+  # Gets called after an editor instance gets intialized
+  #
+  initInstanceCallback: (inst) ->
+    $this = $("##{inst.id}")
+    parent = $this.parents('.element_editor')
+    parent.find('.spinner').remove()
+    inst.on 'change', (e) ->
+      Alchemy.setElementDirty(parent)
+
+  # Removes the TinyMCE editor from given dom ids.
+  #
+  remove: (ids) ->
+    for id in ids
+      editor = tinymce.get("tinymce_#{id}")
+      if editor
+        editor.remove()

data/app/assets/javascripts/alchemy/alchemy.translations.js.coffee

@@ -0,0 +1,132 @@
+window.Alchemy = {} if typeof(window.Alchemy) is 'undefined'
+
+# Holds translations for javascripts
+#
+Alchemy.translations =
+
+  # German
+  de:
+    allowed_chars: 'von %{count} Zeichen'
+    cancel: 'Abbrechen'
+    cancelled: 'Abgebrochen'
+    click_to_edit: 'Klicken zum Bearbeiten'
+    complete: 'Abgeschlossen'
+    element_dirty_notice: 'Dieses Element hat nicht gespeicherte Änderungen. Möchten Sie es wirklich einklappen?'
+    help: 'Hilfe'
+    ok: 'Ok'
+    page_dirty_notice: 'Sie haben ungesicherte Änderungen auf der Seite. Diese gehen verloren, wenn Sie fortfahren.'
+    page_found: 'Seite gefunden'
+    pages_found: 'Seiten gefunden'
+    url_validation_failed: 'Die URL hat kein gültiges Format.'
+    warning: 'Achtung!'
+    'File is too large': 'Datei ist zu groß.'
+    'File is too small': 'Datei ist zu klein.'
+    'File type not allowed': 'Dateityp nicht erlaubt.'
+    'Maximum number of files exceeded': 'Maximale Anzahl gleichzeitig erlaubter Datei-Uploads erreicht.'
+    'Uploaded bytes exceed file size': 'Maximale Größe der erlaubten Dateigröße erreicht.'
+
+  # English
+  en:
+    allowed_chars: 'of %{count} chars'
+    cancel: 'Cancel'
+    cancelled: 'Cancelled'
+    click_to_edit: 'click to edit'
+    complete: 'Complete'
+    element_dirty_notice: 'This element has unsaved changes. Do you really want to fold it?'
+    help: 'Help'
+    ok: 'Ok'
+    page_dirty_notice: 'You have unsaved changes on this page. They will be lost if you continue.'
+    page_found: 'Page found'
+    pages_found: 'Pages found'
+    url_validation_failed: 'The url has no valid format.'
+    warning: 'Warning!'
+    'File is too large': 'File is too large'
+    'File is too small': 'File is too small'
+    'File type not allowed': 'File type not allowed'
+    'Maximum number of files exceeded': 'Maximum number of files exceeded.'
+    'Uploaded bytes exceed file size': 'Uploaded bytes exceed file size'
+
+  # Dutch
+  nl:
+    allowed_chars: 'of %{count} chars'
+    cancel: 'Annuleren'
+    cancelled: 'Afgebroken'
+    click_to_edit: 'klik om aan te passen'
+    complete: 'Klaar'
+    element_dirty_notice: 'Dit element bevat niet opgeslagen wijzigingen. Wilt u dit echt inklappen?'
+    help: 'Hulp'
+    ok: 'Ok'
+    page_found: 'Page found'
+    pages_found: 'Pages found'
+    page_dirty_notice: 'Er zijn wijzigingen op deze pagina aangebracht. Deze gaan verloren als u doorgaat.'
+    url_validation_failed: 'De url heeft geen geldig formaat.'
+    warning: 'Waarschuwing!'
+    'File is too large': 'File is too large'
+    'File is too small': 'File is too small'
+    'File type not allowed': 'File type not allowed'
+    'Maximum number of files exceeded': 'Uploadlimiet bereikt.'
+    'Uploaded bytes exceed file size': 'Uploaded bytes exceed file size'
+
+
+  # French
+  fr:
+    allowed_chars: 'von %{count} signes'
+    cancel: 'abandonner'
+    cancelled: 'annulé'
+    click_to_edit: 'Cliquez pour modifier'
+    complete: 'terminé'
+    element_dirty_notice: 'Cet élément a des modifications non enregistrées. Souhaitez-vous vraiment plier?'
+    help: 'Aide'
+    ok: 'Ok'
+    page_dirty_notice: 'Vous avez des modifications non enregistrées sur la page. Ce sera perdue si vous continuez.'
+    page_found: 'page trouvée'
+    pages_found: 'pages trouvées'
+    url_validation_failed: "L'URL n'est pas correctement formatée."
+    warning: 'Attention!'
+    'File is too large': 'Le fichier est trop grand.'
+    'File is too small': 'Le fichier est trop petit.'
+    'File type not allowed': 'Type de document non autorisé.'
+    'Maximum number of files exceeded': 'Le nombre maximum de fichiers est atteint.'
+    'Uploaded bytes exceed file size': 'Taille de fichier maximale autorisée atteint.'
+
+  # Russian
+  ru:
+    allowed_chars: '%{count} знаков'
+    cancel: 'Отмена'
+    cancelled: 'Отменено'
+    click_to_edit: 'нажмите, чтобы редактировать'
+    complete: 'Завершено'
+    element_dirty_notice: 'Для этого элемента есть несохраненные изменения. Вы действительно хотите их сбросить?'
+    help: 'Помощь'
+    ok: 'Ок'
+    page_dirty_notice: 'На странице есть несохраненные изменения. Если вы продолжите, то они пропадут.'
+    page_found: 'Страница найдена'
+    pages_found: 'Страницы найдены'
+    url_validation_failed: 'Адрес (URL) имеет неверный формат.'
+    warning: 'Внимание!'
+    'File is too large': 'Файл слишком большой'
+    'File is too small': 'Файл слишком маленький'
+    'File type not allowed': 'Этот тип файла не разрешен'
+    'Maximum number of files exceeded': 'Исчерпано максимальное количество файлов.'
+    'Uploaded bytes exceed file size': 'Превышен максимальный размер файла'
+
+  # Spanish
+  es:
+    allowed_chars: 'de %{count} caracteres'
+    cancel: 'Cancelar'
+    cancelled: 'Cancelado'
+    click_to_edit: 'Pulsar para editar'
+    complete: 'Completado'
+    element_dirty_notice: 'Este elemento tiene cambios sin guardar. ¿Realmente quieres plegarlo?'
+    help: 'Ayuda'
+    ok: 'Aceptar'
+    page_dirty_notice: 'Tienes cambios sin guardar en esta página. Si continúas se perderán.'
+    page_found: 'Página encontrada'
+    pages_found: 'Páginas encontradas'
+    url_validation_failed: 'La url no tiene un formato válido.'
+    warning: '¡Atención!'
+    'File is too large': 'El archivo es demasiado grande'
+    'File is too small': 'El archivo es demasiado pequeño'
+    'File type not allowed': 'El tipo de archivo no está permitido'
+    'Maximum number of files exceeded': 'Número máximo de archivos excedido.'
+    'Uploaded bytes exceed file size': 'Los bytes subidos exceden el tamaño del archivo'