joosy 0.1.0.RC3 → 0.1.0.alpha

data/app/assets/javascripts/joosy/core/modules/container.js.coffee

@@ -1,104 +0,0 @@
-#
-# DOM container handling, DOM elements and DOM events bindings
-#
-# @note Requires implementor to contain DOM node at @container propert
-#
-# @module
-#
-Joosy.Modules.Container =
-  events: false
-  elements: false
-
-  eventSplitter: /^(\S+)\s*(.*)$/
-
-  $: (selector) ->
-    $(selector, @container)
-
-  #
-  # Rebinds selectors defined in 'elements' hash to object properties
-  #
-  # @example Sample elements
-  #   elements:
-  #     foo: '.foo'
-  #     bar: '.bar'
-  #
-  refreshElements: ->
-    @__collectElements().each (key, value) =>
-      # TODO: Check for possible collisions?
-      @[key] = @$(value)
-
-  #
-  # Fills container with given data removing all events
-  #
-  # @param [jQuery] container       jQuery entity of container to update
-  # @param [String] data            HTML to inject
-  #
-  swapContainer: (container, data) ->
-    container.unbind().off()
-    container.html data
-    container
-
-  #
-  # Gathers 'elements' from current and super classes
-  #
-  __collectElements: ->
-    elements = Object.extended @elements || {}
-
-    klass = this
-    while klass = klass.constructor.__super__
-      Joosy.Module.merge elements, klass.elements, false
-
-    elements
-
-  #
-  # Gathers 'events' from current and super classes
-  #
-  __collectEvents: ->
-    events = Object.extended @events || {}
-
-    klass = this
-    while klass = klass.constructor.__super__
-      Joosy.Module.merge events, klass.events, false
-
-    events
-
-  #
-  # Converts '$...' notation to selector from 'elements'
-  #
-  # @param [String] selector            Selector to convert
-  #
-  __extractSelector: (selector) ->
-    if r = selector.match /\$([A-z]+)/
-      selector = @__collectElements()[r[1]]
-
-    selector
-
-  #
-  # Bings events defined in 'events' to container
-  #
-  # @example Sample events
-  #   events:
-  #     'click': -> # this will raise on container click
-  #     'click .foo': -> # this will raise on .foo click
-  #     'click $foo': -> #this will search for selector of foo element
-  #
-  __delegateEvents: ->
-    module = this
-    events = @__collectEvents()
-
-    events.each (key, method) =>
-      unless Object.isFunction method
-        method = @[method]
-      callback = (event) ->
-        method.call module, this, event
-
-      match      = key.match @eventSplitter
-      eventName  = match[1]
-      selector   = @__extractSelector match[2]
-
-      if selector == ""
-        @container.bind eventName, callback
-        Joosy.Modules.Log.debugAs @, "#{eventName} binded on container"
-      else
-        @container.on eventName, selector, callback
-        Joosy.Modules.Log.debugAs @, "#{eventName} binded on #{selector}"

data/app/assets/javascripts/joosy/core/modules/events.js.coffee

@@ -1,123 +0,0 @@
-#
-# Basic events implementation
-#
-# @module
-#
-Joosy.Modules.Events =
-
-  #
-  # Waits for the list of given events to happen at least once. Then runs callback.
-  #
-  # @param [String] events              List of events to wait for separated by space
-  # @param [Function] callback          Action to run when all events were triggered at least once
-  #
-  wait: (events, callback) ->
-    events = events.split /\s+/ if Object.isString events
-
-    @__oneShotEvents ||= []
-    @__oneShotEvents.push [events, callback]
-
-  #
-  # Binds action to run each time any of given even was triggered
-  #
-  # @param [String] events              List of events separated by space
-  # @param [Function] callback          Action to run on trigger
-  #
-  bind: (events, callback) ->
-    events = events.split /\s+/
-
-    @__boundEvents ||= []
-    @__boundEvents.push [events, callback]
-
-  #
-  # Unbinds action from runing on trigger
-  #
-  # @param [Function] target            Action to unbind
-  #
-  unbind: (target) ->
-    for [events, callback], index in @__boundEvents
-      if callback == target
-        @__boundEvents.splice index, 1
-        return
-
-  #
-  # Triggers event for {bind} and {wait}
-  #
-  # @param [String]           Name of event to trigger
-  #
-  trigger: (event) ->
-    Joosy.Modules.Log.debugAs @, "Event #{event} triggered"
-    if @__oneShotEvents
-      for [events, callback], index in @__oneShotEvents
-        position = events.indexOf event
-        if position >= 0
-          events.splice position, 1
-
-        if events.length == 0
-          @__oneShotEvents.splice index, 1
-
-          callback()
-
-    if @__boundEvents
-      for [events, callback] in @__boundEvents
-        if events.has event
-          callback()
-  
-  #
-  # Runs set of callbacks finializing with result callback
-  #
-  # @example Basic usage
-  #   Joosy.Events.synchronize (context) ->
-  #     contet.do (done) -> done()
-  #     contet.do (done) -> done()
-  #     content.after ->
-  #       console.log 'Success!'
-  #
-  # @param [Function] block           Configuration block (see example)
-  #
-  synchronize: (block) ->
-    context = new Joosy.Modules.Events.SynchronizationContext(this)
-    block.call(this, context)
-    
-    @wait context.expectations, => context.after.call(this)
-
-    context.actions.each (data) =>
-      data[0].call this, =>
-        @trigger data[1]
-        
-#
-# Internal representation of {Joosy.Modules.Events#synchronize} context
-#
-# @see Joosy.Modules.Events#synchronize
-#
-class Joosy.Modules.Events.SynchronizationContext
-  @uid = 0
-
-  constructor: (@parent) ->
-    @expectations = []
-    @actions = []
-
-  #
-  # Internal simple counter to separate given synchronization actions
-  #
-  uid: ->
-    @constructor.uid += 1
-
-  #
-  # Registeres another async function that should be synchronized
-  #
-  # @param [Function] action        `(Function) -> null` to call.
-  #   Should call given function to mark itself complete.
-  #
-  do: (action) ->
-    event = "synchro-#{@uid()}"
-    @expectations.push event
-    @actions.push [action, event]
-
-  #
-  # Registers finalizer: the action that will be called when all do-functions 
-  #   marked themselves as complete.
-  #
-  # @param [Function] after       Function to call.
-  #
-  after: (@after) ->

data/app/assets/javascripts/joosy/core/modules/filters.js.coffee

@@ -1,67 +0,0 @@
-#
-# Filters registration routines
-#
-# @module
-#
-Joosy.Modules.Filters =
-
-  #
-  # Defines static registration routines
-  #
-  # @example Set of methods
-  #   class Test
-  #     @beforeLoad -> # supposed to run before load and control loading queue
-  #     @afterLoad -> # supposed to run after load to finalize loading
-  #     @afterUnload -> # supposed to run after unload to collect garbage
-  #
-  included: ->
-    @beforeLoad = (callback) ->
-      unless @::hasOwnProperty '__beforeLoads'
-        @::__beforeLoads = [].concat @.__super__.__beforeLoads || []
-      @::__beforeLoads.push callback
-
-    @afterLoad = (callback) ->
-      unless @::hasOwnProperty '__afterLoads'
-        @::__afterLoads = [].concat @.__super__.__afterLoads || []
-      @::__afterLoads.push callback
-
-    @afterUnload = (callback) ->
-      unless @::hasOwnProperty '__afterUnloads'
-        @::__afterUnloads = [].concat @.__super__.__afterUnloads || []
-      @::__afterUnloads.push callback
-
-  #
-  # Runs filters registered as beforeLoad
-  #
-  __runBeforeLoads: (opts...) ->
-    unless @__beforeLoads?.length > 0
-      return true
-
-    flag = true
-
-    for filter in @__beforeLoads
-      unless Object.isFunction filter
-        filter = @[filter]
-      flag = flag && filter.apply @, opts
-
-    return flag
-
-    #
-    # Runs filters registered as afterLoad
-    #
-  __runAfterLoads: (opts...) ->
-    if @__afterLoads?.length > 0
-      for filter in @__afterLoads
-        unless Object.isFunction filter
-          filter = @[filter]
-        filter.apply @, opts
-
-  #
-  # Runs filters registered as afterUnload
-  #
-  __runAfterUnloads: (opts...) ->
-    if @__afterUnloads?.length > 0
-      for filter in @__afterUnloads
-        unless Object.isFunction filter
-          filter = @[filter]
-        filter.apply @, opts

data/app/assets/javascripts/joosy/core/modules/log.js.coffee

@@ -1,36 +0,0 @@
-#
-# Wrappers for console.log
-#
-# @module
-#
-Joosy.Modules.Log =
-  
-  #
-  # Checks if console is available and proxies given arguments directly to `console.log`
-  #
-  log: (args...) ->
-    return unless console?
-
-    if console.log.apply?
-      args.unshift "Joosy>"
-      console.log args...
-    else
-      console.log args.first()
-
-  #
-  # Runs `log` if debug is active
-  #
-  debug: (args...) ->
-    return unless Joosy.debug
-    @log args...
-
-  #
-  # Logs given message wrapping it with description of given object (class name)
-  #
-  # @param [Object] context           The class required to be described in log message
-  # @param [String] string            Message to log
-  #
-  debugAs: (context, string, args...) ->
-    return unless Joosy.debug
-    context = Joosy.Module.__className(context) || 'unknown context'
-    @debug "#{context}> #{string}", args...

data/app/assets/javascripts/joosy/core/modules/module.js.coffee

@@ -1,105 +0,0 @@
-moduleKeywords = ['included', 'extended']
-
-#
-# Base Joosy class extending Coffee class with module-like injections 
-#   and other tiny stuff.
-#
-class Joosy.Module
-  #
-  # Sets the default namespace for all Joosy descendants.
-  # This is used in {Joosy.namespace} magic.
-  #
-  @__namespace__: []
-
-  #
-  # Gets Object/Class class name.
-  #
-  # @note Never use this to make some magical auto-suggestions!!!
-  #   Remember: minifcation will rename your classes. Therefore it
-  #   is only intended for development debugging purposes.
-  #
-  # @note Go @jashkenas Go! Give us https://github.com/jashkenas/coffee-script/issues/2052.
-  #   Please go vote for this feature if you are reading this. It will
-  #   give us ability to eleminate a lot of boilerplate for you.
-  #
-  # @return [String]
-  #
-  @__className: (klass) ->
-    unless Object.isFunction(klass)
-      klass = klass.constructor
-
-    if klass.name?
-      klass.name
-    else
-      klass.toString().replace /^function ([a-zA-Z]+)\([\s\S]+/, '$1'
-
-  #
-  # Determines if class A has class B in its ancestors.
-  #
-  # @param [Class] what       Class to check againt
-  # @param [Class] klass      Possible ancestor to search for
-  #
-  # @return [Boolean]
-  #
-  @hasAncestor: (what, klass) ->
-    unless what? && klass?
-      return false
-
-    [what, klass] = [what.prototype, klass.prototype]
-
-    while what
-      if what == klass
-        return true
-      what = what.constructor?.__super__
-
-    false
-    
-  #
-  # Simple and fast shallow merge implementation.
-  #
-  # This is here due to: https://github.com/andrewplummer/Sugar/issues/100.
-  # This bug was closed and we got some performance but this implementation is
-  # still like 10x fater for basic tasks.
-  #
-  # @param [Object] destination       Object to extend
-  # @param [Object] source            Source of new properties
-  # @param [Boolean] unsafe           Determines if we should rewrite destination properties
-  #
-  # @return [Object]                  The new and mighty destination Object
-  #
-  @merge: (destination, source, unsafe=true) ->
-    for key, value of source
-      if source.hasOwnProperty(key)
-        if unsafe || !destination.hasOwnProperty(key)
-          destination[key] = value
-    destination
-
-  #
-  # Mixes given object as dynamic methods
-  #
-  # @param [Object] object          Module object
-  #
-  @include: (object) ->
-    unless object
-      throw new Error 'include(object) requires obj'
-
-    Object.each object, (key, value) =>
-      if key not in moduleKeywords
-        this::[key] = value
-
-    object.included?.apply this
-    null
-
-  #
-  # Mixes given object as static methods
-  #
-  # @param [Object] object          Module object
-  #
-  @extend: (object) ->
-    unless object
-      throw new Error 'extend(object) requires object'
-
-    @merge this, object
-
-    object.extended?.apply this
-    null

data/app/assets/javascripts/joosy/core/modules/renderer.js.coffee

@@ -1,195 +0,0 @@
-#= require_tree ../templaters
-#= require metamorph
-
-#
-# Core DOM rendering mechanics
-#
-# @module
-# @todo           Describe this scary thing o_O
-#
-Joosy.Modules.Renderer =
-
-  #
-  # Default behavior for non-set renderer (empty template?)
-  #
-  __renderer: ->
-    throw new Error "#{Joosy.Module.__className @constructor} does not have an attached template"
-
-  __helpers: null
-
-  #
-  # Defines class-level helpers: @view and @helpers
-  #
-  # View (@view): Sets the curent template by specifying its name or lambda
-  # Helpers (@helpers): Lists set of helpers' namespaces to include
-  #
-  included: ->
-    @view = (template, options={}) ->
-      if Object.isFunction template
-        @::__renderer = template
-      else
-        @::__renderer = (locals={}) ->
-          if options.dynamic
-            @renderDynamic template, locals
-          else
-            @render template, locals
-
-    @helpers = (helpers...) ->
-      @::__helpers ||= []
-      helpers.map (helper) =>
-        module = Joosy.Helpers[helper]
-        unless module
-          throw new Error "Cannot find helper module #{helper}"
-
-        @::__helpers.push module
-
-      @::__helpers = @::__helpers.unique()
-
-  __instantiateHelpers: ->
-    unless @__helpersInstance
-      @__helpersInstance = Object.extended Joosy.Helpers.Application
-        
-      @__helpersInstance.widget = (element, widget) =>
-        @widgets ||= {}
-        
-        uuid    = Joosy.uuid()
-        element = document.createElement element
-        temp    = document.createElement 'div'
-        
-        element.id = uuid
-        @widgets['#'+uuid] = widget
-
-        temp.appendChild element
-        temp.innerHTML
-
-      if @__helpers
-        for helper in @__helpers
-          Joosy.Module.merge @__helpersInstance, helper
-
-    @__helpersInstance
-
-  # If we do not have __proto__ available...
-  __proxifyHelpers: (locals) ->
-    if locals.hasOwnProperty '__proto__'
-      locals.__proto__ = @__instantiateHelpers()
-      locals
-    else
-      unless @__helpersProxyInstance
-        @__helpersProxyInstance = (locals) ->
-          Joosy.Module.merge this, locals
-
-        @__helpersProxyInstance.prototype = @__instantiateHelpers()
-
-      new @__helpersProxyInstance locals
-
-  render: (template, locals={}, parentStackPointer=false) ->
-    @__render false, template, locals, parentStackPointer
-    
-  renderDynamic: (template, locals={}, parentStackPointer=false) ->
-    @__render true, template, locals, parentStackPointer
-
-  __render: (dynamic, template, locals={}, parentStackPointer=false) ->
-    stack = @__renderingStackChildFor parentStackPointer
-    
-    stack.template = template
-    stack.locals   = locals
-    
-    isResource   = Joosy.Module.hasAncestor locals.constructor, Joosy.Resource.Generic
-    isCollection = Joosy.Module.hasAncestor locals.constructor, Joosy.Resource.Collection
-    
-    if Object.isString template
-      if @__renderSection?
-        template = Joosy.Application.templater.resolveTemplate @__renderSection(), template, this
-
-      template = Joosy.Application.templater.buildView template
-    else if !Object.isFunction template
-      throw new Error "#{Joosy.Module.__className @}> template (maybe @view) does not look like a string or lambda"
-    
-    if !Object.isObject(locals) && !isResource && !isCollection
-      throw new Error "#{Joosy.Module.__className @}> locals (maybe @data?) not in: dumb hash, Resource, Collection"
-      
-    renderers =
-      render: (template, locals={}) =>
-        @render template, locals, stack
-      renderDynamic: (template, locals={}) =>
-        @renderDynamic template, locals, stack
-        
-    context = =>
-      data = {}
-
-      if isResource
-        Joosy.Module.merge data, stack.locals.e
-      else
-        Joosy.Module.merge data, stack.locals
-
-      Joosy.Module.merge data, @__instantiateHelpers(), false
-      Joosy.Module.merge data, renderers
-      data
-    
-    if dynamic
-      morph  = Metamorph template(context())
-      update = =>
-        for child in stack.children
-          @__removeMetamorphs child
-        stack.children = []
-        morph.html template(context())
-        @refreshElements?()
-
-      # This is here to break stack tree and save from 
-      # repeating DOM handling
-      update = update.debounce 0
-
-      if isCollection
-        for resource in locals.data
-          resource.bind 'changed', update
-          stack.metamorphBindings.push [resource, update]
-      if isResource || isCollection
-        locals.bind 'changed', update
-        stack.metamorphBindings.push [locals, update]
-      else
-        for key, object of locals
-          if locals.hasOwnProperty key
-            if object?.bind? && object?.unbind?
-              object.bind 'changed', update
-              stack.metamorphBindings.push [object, update]
-
-      morph.outerHTML()
-    else
-      template context()
-
-  __renderingStackElement: (parent=null) ->
-    metamorphBindings: []
-    locals: null
-    template: null
-    children: []
-    parent: parent
-
-  __renderingStackChildFor: (parentPointer) ->
-    if !@__renderingStack
-      @__renderingStack = []
-    
-    if !parentPointer
-      element = @__renderingStackElement()
-      @__renderingStack.push element
-      element
-    else
-      element = @__renderingStackElement parentPointer
-      parentPointer.children.push element
-      element
-
-  __removeMetamorphs: (stackPointer=false) ->
-    remove = (stackPointer) =>
-      if stackPointer?.children
-        for child in stackPointer.children
-          @__removeMetamorphs child
-  
-      if stackPointer?.metamorphBindings
-        for [object, callback] in stackPointer.metamorphBindings
-          object.unbind callback
-        stackPointer.metamorphBindings = []
-    
-    unless stackPointer
-      @__renderingStack?.each (stackPointer) ->
-        remove stackPointer
-    else
-      remove stackPointer

data/app/assets/javascripts/joosy/core/modules/time_manager.js.coffee

@@ -1,46 +0,0 @@
-#
-# Comfortable and clever wrappers for timeouts management
-#
-# @module
-#
-Joosy.Modules.TimeManager =
-  
-  #
-  # Registeres timeout for current object
-  #
-  # @param [Integer] timeout          Miliseconds to wait
-  # @param [Function] action          Action to run on timeout
-  #
-  setTimeout: (timeout, action) ->
-    @__timeouts ||= []
-
-    timer = window.setTimeout (=> action()), timeout
-    @__timeouts.push timer
-
-    timer
-
-  #
-  # Registeres interval for current object
-  #
-  # @param [Integer] delay            Miliseconds between runs
-  # @param [Function] action          Action to run
-  #
-  setInterval: (delay, action) ->
-    @__intervals ||= []
-
-    timer = window.setInterval (=> action()), delay
-    @__intervals.push timer
-
-    timer
-
-  #
-  # Drops all registered timeouts and intervals for this object
-  #
-  __clearTime: ->
-    if @__intervals
-      for entry in @__intervals
-        window.clearInterval entry
-
-    if @__timeouts
-      for entry in @__timeouts
-        window.clearTimeout entry