joosy 0.1.0.RC3 → 0.1.0.alpha

data/app/assets/javascripts/joosy/core/form.js.coffee

@@ -1,304 +0,0 @@
-#= require joosy/core/joosy
-#= require joosy/core/modules/module
-#= require joosy/core/modules/log
-#= require joosy/core/modules/events
-#= require joosy/core/modules/container
-
-#
-# AJAXifies form including file uploads and stuff. Built on top of jQuery.Form.
-#
-# Joosy.Form automatically cares of form validation hihglights. It can
-# read common server error responses and add .field_with_errors class to proper 
-# field.
-#
-# If you don't have resource associated with form (#fill), it will try to find fields
-# by exact keywords from response. Otherwise it will search for resource_name[field].
-#
-# @example Joosy.Form usage
-#   form = new Joosy.Form, -> (response)
-#     console.log "Saved and got some: #{response}"
-#   
-#   form.progress = (percent) -> console.log "Uploaded by #{percent}%"
-#   form.fill @resource
-#
-class Joosy.Form extends Joosy.Module
-  @include Joosy.Modules.Log
-  @include Joosy.Modules.Events
-  @include Joosy.Modules.Container
-
-  #
-  # Marks the CSS class to use to mark invalidated fields
-  #
-  invalidationClass: 'field_with_errors'
-  
-  #
-  # List of mappings for fields of invalidated data which comes from server
-  #
-  # If you have something like {foo: 'bar', bar: 'baz'} coming from server
-  # substitutions = {foo: 'foo_id'} will change it to {foo_id: 'bar', bar: 'baz'}
-  #
-  substitutions: {}
-
-  #
-  # List of elements for internal usage
-  #
-  elements:
-    'fields': 'input,select,textarea'
-
-  #
-  # Makes one AJAX request with form data without binding
-  #
-  # @see #constructor
-  #
-  # @param [Element] form       Instance of HTML form element
-  # @param [Hash] opts          Options
-  #
-  @submit: (form, opts={}) ->
-    form = new @(form, opts)
-    form.container.submit()
-    form.unbind()
-    null
-
-  #
-  # During initialization replaces your basic form submit with AJAX request
-  #
-  # @note If method of form differs from POST or GET it will simulate it
-  # by adding hidden _method input. In this cases the method itself will be
-  # set to POST.
-  #
-  # @note For browsers having no support of HTML5 Forms it may do an iframe requests
-  # to handle file uploading.
-  #
-  # @param [jQuery] form        Form element instance
-  # @param [Hash] opts          Options
-  #
-  # @option opts [Function] before        `(XHR) -> Bollean` to trigger right before submit.
-  #   By default will run form invalidation cleanup. This behavior can be canceled
-  #   by returning false from your own before callback. Both of callbacks will run if
-  #   you return true.
-  #
-  # @option opts [Function] success       `(Object) -> null` triggers on 200 HTTP code from server. 
-  #   Pases in the parsed JSON.
-  #
-  # @option opts [Function] progress      `(Float) -> null` runs periodically while form is uploading
-  #
-  # @option opts [Function] error         `(Object) -> Boolean` triggers if server responded with anything but 200.
-  #   By default will run form invalidation routine. This behavior can be canceled
-  #   by returning false from your own error callback. Both of callbacks will run if
-  #   you return true.
-  #
-  constructor: (form, opts={}) ->
-    if Object.isFunction opts
-      @success = opts
-    else
-      Object.each opts, (key, value) =>
-        @[key] = value
-
-    @container = $(form)
-    @refreshElements()
-    @__delegateEvents()
-
-    method = @container.get(0).getAttribute('method')?.toLowerCase()
-    if method && !['get', 'post'].has method
-      @__markMethod method
-      @container.attr 'method', 'POST'
-
-    @container.ajaxForm
-      dataType: 'json'
-      beforeSend: =>
-        @__before arguments...
-      success: =>
-        @__success arguments...
-      error: =>
-        @__error arguments...
-      xhr: =>
-        xhr = $.ajaxSettings.xhr()
-        if xhr.upload? && @progress
-          xhr.upload.onprogress = (event) =>
-            if event.lengthComputable
-              @progress (event.position / event.total * 100).round 2
-        xhr
-
-  #
-  # Resets form submit behavior to default
-  #
-  unbind: ->
-    @container.unbind('submit').find('input:submit,input:image,button:submit').unbind('click');
-
-  #
-  # Links current form with given resource and sets values of form inputs from with it.
-  # Form will use give resource while doing invalidation routine.
-  #
-  # @param [Resource] resource      Resource to fill fields with
-  # @param [Function] decorator     Decoration callback
-  #
-  fill: (resource, decorator) ->
-    @__resource = resource
-    
-    if decorator?
-      e = decorator resource.e
-    else
-      e = resource.e
-    Object.each e, (key, val) =>
-      key = resource.__entityName + "[#{key}]"
-      input = @fields.filter("[name='#{key.underscore()}']:not(:file),[name='#{key.camelize(false)}']:not(:file)")
-      unless input.is ':checkbox'
-        input.val val
-      else
-        if val
-          input.attr 'checked', 'checked'
-        else
-          input.removeAttr 'checked'
-
-    @container.attr 'action', resource.constructor.__buildSource(extension: resource.id)
-    @__markMethod() if resource.id
-    @container.attr 'method', 'POST'
-
-  #
-  # Submit the HTML Form
-  #
-  submit: ->
-    @container.submit()
-  
-  #
-  # Serializes form into query string.
-  #
-  # @param [Boolean] skipMethod         Determines if we should skip magical _method field
-  #
-  # @return [String]
-  #
-  serialize: (skipMethod=true) ->
-    data = @container.serialize()
-    data = data.replace /\&?\_method\=put/i, '' if skipMethod
-    
-    data
-
-  #
-  # Inner success callback.
-  #
-  __success: (response, status, xhr) ->
-    if xhr
-      @success? response
-    else if response.status == 200
-      @success response.json
-    else
-      @__error response.json
-
-  #
-  # Inner before callback.
-  # By default will clean invalidation.
-  #
-  __before: (xhr, settings) ->
-    if !@before? || @before(arguments...) is true
-      @fields.removeClass @invalidationClass
-
-  #
-  # Inner error callback.
-  # By default will trigger basic invalidation.
-  #
-  __error: (data) ->
-    errors = if data.responseText
-      try
-        data = jQuery.parseJSON(data.responseText)
-      catch error
-        {}
-    else
-      data
-
-    if !@error? || @error(errors) is true
-      errors = @__stringifyErrors(errors)
-      
-      Object.each errors, (field, notifications) =>
-        input = @__findField(field).addClass @invalidationClass
-        @notification? input, notifications
-  
-  #
-  # Finds field by field name.
-  # This is not inlined since we want to override
-  # or monkeypatch it from time to time
-  #
-  # @param [String] field         Name of field to find
-  #
-  __findField: (field) ->
-    @fields.filter("[name='#{field}']")
-
-  #
-  # Simulates REST methods by adding hidden _method input with real method
-  # while setting POST as the transport method
-  #
-  # @param [String] method      Real method to simulate
-  #
-  __markMethod: (method='PUT') ->
-    method = $('<input/>',
-      type: 'hidden'
-      name: '_method'
-      value: method
-    )
-    @container.append method
-    
-  #
-  # Prepares server response for default error handler
-  # Turns all possible response notations into form notation (foo[bar])
-  # Every direct field of incoming data will be decorated by @substitutions
-  #
-  # @example Flat validation result
-  #   { field1: ['error'] }             # input
-  #   { field1: ['error'] }             # if form was not associated with Resource by {#fill}
-  #   { "fluffy[field1]": ['error']}    # if form was associated with Resource (named fluffy)
-  #
-  # @example Complex validation result
-  #   { foo: { bar: { baz: ['error'] } } }    # input
-  #   { "foo[bar][bar]": ['error'] }          # output
-  #
-  # @param [Object] errors        Data to prepare
-  #
-  # @return [Hash<String, Array>]          Flat hash with field names in keys and arrays 
-  #   of errors in values
-  #
-  __stringifyErrors: (errors) ->
-    result = {}
-    
-    Object.each errors, (field, notifications) =>
-      if @substitutions[field]?
-        field = @substitutions[field]
-
-      if Object.isObject notifications
-        Object.each @__foldInlineEntities(notifications), (key, value) ->
-          result[field+key] = value
-      else
-        if field.indexOf(".") != -1
-          splited = field.split '.'
-          field   = splited.shift()
-          field   = @__resource.__entityName + "[#{field}]" if @__resource
-          field  += "[#{f}]" for f in splited
-      
-        else if @__resource
-          field = @__resource.__entityName + "[#{field}]"
-
-        result[field] = notifications
-
-    result
-
-  #
-  # Flattens complex inline structures into form notation
-  #
-  # @example Basic flattening
-  #   data  = foo: { bar: { baz: [] } }
-  #   inner = @__foldInlineEntities(data.foo, 'foo')
-  #   
-  #   inner # { "foo[bar][baz]": [] }
-  #
-  # @param [Object] hash      Structure to fold
-  # @param [String] scope     Prefix for resulting scopes
-  # @param [Object] result    Context of result for recursion
-  #
-  # @return [Hash]
-  #
-  __foldInlineEntities: (hash, scope="", result={}) ->
-    Object.each hash, (key, value) =>
-      if Object.isObject(value)
-        @__foldInlineEntities(value, "#{scope}[#{key}]", result)
-      else
-        result["#{scope}[#{key}]"] = value
-
-    result

data/app/assets/javascripts/joosy/core/helpers/view.js.coffee

@@ -1,30 +0,0 @@
-#= require joosy/core/joosy
-
-#
-# Rendering and string representation helpers
-#
-Joosy.helpers 'Application', ->
-  
-  #
-  # Converts \n into <br/> in your text
-  #
-  # @param [String] text      Text to convert
-  #
-  @nl2br = (text) ->
-    text.toString().replace /\n/g, '<br/>'
-
-  #
-  # Wraps the inline block into given template
-  # Request template will receive the inline block as @yield parameter
-  # 
-  # Example
-  #   -# foo/baz template
-  #   != @renderWrapped 'foo/bar', ->
-  #     %b This string will be passed to 'foo/bar'
-  #
-  #   -# foo/bar template
-  #   %h1 I'm the wrapper here!
-  #     != @yield
-  #
-  @renderWrapped = (template, lambda) ->
-    @render template, Joosy.Module.merge(this, yield: lambda())

data/app/assets/javascripts/joosy/core/joosy.js.coffee

@@ -1,129 +0,0 @@
-#
-# All the tiny core stuff
-#
-# @module
-#
-@Joosy =
-  #
-  # Core modules container
-  #
-  Modules: {}
-  
-  #
-  # Resources container
-  #
-  Resource: {}
-  
-  #
-  # Templaters container
-  #
-  Templaters: {}
-
-  #
-  # If enabled Joosy will log to console a lot of 'in progress' stuff
-  #
-  debug: false
-
-  #
-  # Registeres anything inside specified namespace (objects chain starting from `window`)
-  #
-  # @example Basic usage
-  #   Joosy.namespace 'foobar', ->
-  #     class @RealThing
-  # 
-  #   foo = new foobar.RealThing
-  #
-  # @param [String] name            Namespace keyword
-  # @param [Boolean] generator      Namespace content
-  #
-  namespace: (name, generator=false) ->
-    name  = name.split '.'
-    space = window
-    for part in name
-      space = space[part] ?= {}
-
-    if generator
-      generator = generator.apply space
-    for key, klass of space
-      if space.hasOwnProperty(key) &&
-         Joosy.Module.hasAncestor klass, Joosy.Module
-        klass.__namespace__ = name
-
-  #
-  # Registeres given methods as a helpers inside a given set
-  #
-  # @param [String] name            Helpers set keyword
-  # @param [Boolean] generator      Helpers content
-  #
-  helpers: (name, generator) ->
-    Joosy.namespace "Joosy.Helpers.#{name}", generator
-
-  #
-  # Scary `hello world`
-  #
-  test: ->
-    text = "Hi :). I'm Joosy. And everything is just fine!"
-
-    if console
-      console.log text
-    else
-      alert text
-
-  #
-  # Generates UUID
-  #
-  uuid: ->
-    'xxxxxxxx-xxxx-4xxx-yxxx-xxxxxxxxxxxx'.replace /[xy]/g, (c) ->
-      r = Math.random() * 16 | 0
-      v = if c is 'x' then r else r & 3 | 8
-      v.toString 16
-    .toUpperCase()
-
-  #
-  # Preloads sets of images then runs callback
-  #
-  # @param [Array<String>] images             Images paths
-  # @param [Function] callback                Action to run when every picture was loaded (or triggered an error)
-  #
-  preloadImages: (images, callback) ->
-    unless Object.isArray(images)
-      images = [images]
-    if images.length == 0
-      callback()
-
-    ticks   = images.length
-    result  = []
-    checker = ->
-      if (ticks -= 1) == 0
-        callback?()
-
-    for p in images
-      result.push $('<img/>').load(checker).error(checker).attr('src', p)
-
-    result
-
-  #
-  # Basic URI builder. Joins base path with params hash
-  #
-  # @param [String] url         Base url
-  # @param [Hash] params        Parameters to join
-  #
-  # @example Basic usage
-  #   Joosy.buildUrl 'http://joosy.ws/#!/test', {foo: 'bar'}    # http://joosy.ws/?foo=bar#!/test
-  #
-  buildUrl: (url, params) ->
-    paramsString = []
-
-    Object.each params, (key, value) ->
-      paramsString.push "#{key}=#{value}"
-
-    hash = url.match(/(\#.*)?$/)[0]
-    url  = url.replace /\#.*$/, ''
-    if !paramsString.isEmpty() && !url.has(/\?/)
-      url  = url + "?"
-
-    paramsString = paramsString.join '&'
-    if !paramsString.isBlank() && url.last() != '?'
-      paramsString = '&' + paramsString
-
-    url + paramsString + hash

data/app/assets/javascripts/joosy/core/layout.js.coffee

@@ -1,162 +0,0 @@
-#= require joosy/core/joosy
-#= require joosy/core/modules/module
-#= require joosy/core/modules/log
-#= require joosy/core/modules/events
-#= require joosy/core/modules/container
-#= require joosy/core/modules/renderer
-#= require joosy/core/modules/time_manager
-#= require joosy/core/modules/widgets_manager
-#= require joosy/core/modules/filters
-
-#
-# Base class for all of your Joosy Layouts.
-# @see http://guides.joosy.ws/guides/layouts-pages-and-routing.html
-#
-# @example Sample application layout
-#   class @ApplicationLayout extends Joosy.Layout
-#     @view 'application'
-#
-class Joosy.Layout extends Joosy.Module
-  @include Joosy.Modules.Log
-  @include Joosy.Modules.Events
-  @include Joosy.Modules.Container
-  @include Joosy.Modules.Renderer
-  @include Joosy.Modules.TimeManager
-  @include Joosy.Modules.WidgetsManager
-  @include Joosy.Modules.Filters
-
-  @view 'default'
-
-  #
-  # Sets the method which will controll the painting preparation proccess.
-  #
-  # This method will be called right ater previous layout {Joosy.Layout.erase} and in parallel with
-  #   layout data fetching so you can use it to initiate preloader.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @example Sample before painter
-  #   @beforePaint (complete) ->
-  #     if !@data # checks if parallel fetching finished
-  #       $('preloader').slideDown -> complete()
-  # 
-  #
-  @beforePaint: (callback) ->
-    @::__beforePaint = callback
-    
-  #
-  # Sets the method which will controll the painting proccess.
-  #
-  # This method will be called after fetching, erasing and beforePaint is complete.
-  # It should be used to setup appearance effects of layout.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @example Sample painter
-  #   @paint (complete) ->
-  #     @container.fadeIn -> complete()
-  #
-  @paint: (callback) ->
-    @::__paint = callback
-
-  #
-  # Sets the method which will controll the erasing proccess.
-  #
-  # Use this method to setup hiding effect.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @note This method will be caled _before_ unload routines so in theory you can
-  #   access layout data from that. Think twice if you are doing it right though.
-  #
-  # @example Sample eraser
-  #   @erase (complete) ->
-  #     @container.fadeOut -> complete()
-  #
-  @erase: (callback) ->
-    @::__erase = callback
-  
-  #
-  # Sets the method which will controll the data fetching proccess.
-  #
-  # @note Given method will be called with `complete` function as parameter. As soon as your
-  #   preparations are done you should call that function.
-  #
-  # @note You are strongly encouraged to NOT fetch anything with Layout!
-  #   Use {Joosy.Page.fetch}
-  #
-  # @example Basic usage
-  #   @fetch (complete) ->
-  #     $.get '/rumbas', (@data) => complete()
-  #
-  @fetch: (callback) ->
-    @::__fetch = callback
-
-  #
-  # Defaults to `false` to ease beforePaint state check.
-  #
-  data: false
-  
-  #
-  # @param [Hash] params              List of route params
-  #
-  constructor: (@params) ->
-
-  #
-  # @see Joosy.Router#navigate
-  #
-  navigate: (args...) ->
-    Joosy.Router.navigate(args...)
-
-  #
-  # This is required by {Joosy.Modules.Renderer}
-  # Sets the base template dir to app_name/templates/layouts
-  #
-  __renderSection: ->
-    'layouts'
-
-  #
-  # Layout bootstrap proccess.
-  #
-  #   * {Joosy.Modules.Container#refreshElements}
-  #   * {Joosy.Modules.Container#__delegateEvents}
-  #   * {Joosy.Modules.WidgetsManager#__setupWidgets}
-  #   * {Joosy.Modules.Filters#__runAfterLoads}
-  #
-  __load: (@container) ->
-    @refreshElements()
-    @__delegateEvents()
-    @__setupWidgets()
-    @__runAfterLoads()
-
-  #
-  # Layout destruction proccess.
-  #
-  #   * {Joosy.Modules.TimeManager#__clearTime}
-  #   * {Joosy.Modules.WidgetsManager#__unloadWidgets}
-  #   * {Joosy.Modules.Renderer#__removeMetamorphs}
-  #   * {Joosy.Modules.Filters#__runAfterUnloads}
-  #
-  __unload: ->
-    @__clearTime()
-    @__unloadWidgets()
-    @__removeMetamorphs()
-    @__runAfterUnloads()
-
-  #
-  # @todo Rename this shit already. We are not going to release having function that marks
-  #   element with UUID called `yield`.
-  #
-  yield: ->
-    @uuid = Joosy.uuid()
-
-  #
-  # Gets layout element.
-  #
-  # @return [jQuery]
-  #
-  content: ->
-    $("##{@uuid}")