joosy 0.1.0.RC3 → 0.1.0.alpha

data/app/assets/javascripts/joosy/core/resource/generic.js.coffee

@@ -1,254 +0,0 @@
-#
-# Basic data wrapper with triggering and entity name binding
-#
-# @example Basic usage
-#   class R extends Joosy.Resource.Generic
-#     @entity 'r'
-#   
-#     @beforeLoad (data) ->
-#       data.real = true
-#   
-#   r = R.create {r: {foo: {bar: 'baz'}}}
-#   
-#   r('foo')                  # {baz: 'baz'}
-#   r('real')                 # true
-#   r('foo.bar')              # baz
-#   r('foo.bar', 'fluffy')    # triggers 'changed'
-#
-class Joosy.Resource.Generic extends Joosy.Module
-  @include Joosy.Modules.Log
-  @include Joosy.Modules.Events
-
-  #
-  # Sets the data source description (which is NOT required)
-  # @note This has no use in Generic but is required in any descendant
-  # 
-  # @param [mixed] Source can be any type including lambda.
-  #   If lambda is given resource will not expect direct {Joosy.Resource.Generic.create} calls
-  #   You'll have to prepare descendant with {Joosy.Resource.Generic.at} first.
-  #
-  # @example Simple case
-  #   Class Y extends Joosy.Resource.Generic
-  #     @source 'fluffies'
-  #   
-  #   r = Y.create {}
-  #
-  # @example Case with lambda
-  #   class R extends Joosy.Resource.Generic
-  #     @source -> (path) "/"+path
-  #   
-  #   r = R.create {}                 # will raise exception
-  #   r = R.at('foo/bar').create {}   # will work as expected
-  #
-  @source: (source) -> @__source = source
-  
-  #
-  # Creates the proxy of current resource with proper {Joosy.Resource.Generic.source} value
-  #
-  # @note Should be used together with lambda source (see {Joosy.Resource.Generic.source} for example)
-  #
-  @at: ->
-    if !Object.isFunction @__source
-      throw new Error "#{Joosy.Module.__className @}> should be created directly (without `at')"
-
-    #
-    # Class inheritance used to create proxy
-    #
-    # @private
-    #
-    class clone extends this
-    clone.__source = @__source arguments...
-    clone
-
-  #
-  # Sets the entity text name:
-  #   required to do some magic like skipping the root node.
-  #
-  # @param [String] name    Singular name of resource
-  #
-  @entity: (name) -> @::__entityName = name
-  
-  #
-  # Sets the collection to use
-  #
-  # @note By default will try to seek for `EntityNamesCollection`.
-  #   Will fallback to {Joosy.Resource.Collection}
-  #
-  # @param [Class] klass       Class to assign as collection
-  #
-  @collection: (klass) -> @::__collection = -> klass
-  
-  #
-  # Implements {Joosy.Resource.Generic.collection} default behavior.
-  #
-  __collection: ->
-    named = @__entityName.camelize().pluralize() + 'Collection'
-    if window[named] then window[named] else Joosy.Resource.Collection
-  
-  #
-  # Allows to modify data before it gets stored.
-  # You can define several beforeLoad filters that will be chained.
-  #
-  # @param [Function] action    `(Object) -> Object` to call
-  #
-  @beforeLoad: (action) ->
-    unless @::hasOwnProperty '__beforeLoads'
-      @::__beforeLoads = [].concat @.__super__.__beforeLoads || []
-    @::__beforeLoads.push action
-
-  #
-  # Dynamically creates collection of inline resources.
-  #
-  # Inline resources share the instance with direct data and therefore can be used
-  #   to handle inline changes with triggers and all that resources stuff
-  #
-  # @example Basic usage
-  #   class Zombie extends Joosy.Resource.Generic
-  #     @entity 'zombie'
-  #   class Puppy extends Joosy.Resource.Generic
-  #     @entity 'puppy'
-  #     @map 'zombies'
-  #   
-  #   p = Puppy.create {zombies: [{foo: 'bar'}]}
-  #   
-  #   p('zombies')            # Direct access: [{foo: 'bar'}]
-  #   p.zombies               # Wrapped Collection of Zombie instances
-  #   p.zombies.at(0)('foo')  # bar
-  #
-  # @param [String] name    Pluralized name of property to define
-  # @param [Class] klass    Resource class to instantiate
-  #
-  @map: (name, klass=false) ->
-    unless klass
-      klass = window[name.singularize().camelize()]
-      
-    if !klass
-      throw new Error "#{Joosy.Module.__className @}> class can not be detected for '#{name}' mapping"
-
-    @beforeLoad (data) ->
-      @[name] = new (klass::__collection()) klass
-      if Object.isArray data[name]
-        @[name].reset data[name]
-      data
-
-  #
-  # Wraps instance of resource inside shim-function allowing to track
-  # data changes. See class example
-  #
-  # @return [Joosy.Resource.Generic]
-  #
-  @create: ->    
-    shim = ->
-      shim.__call.apply shim, arguments
-
-    if shim.__proto__
-      shim.__proto__ = @prototype
-    else
-      for key, value of @prototype
-        shim[key] = value
-        
-    shim.constructor = @
-    
-    @apply shim, arguments
-
-    shim
-
-  #
-  # Should NOT be called directly, use {::create} instead
-  #
-  # @private
-  # @param [Object] data      Data to store
-  #
-  constructor: (data) ->
-    @__fillData data, false
-    
-  #
-  # Set the resource data manually
-  #
-  # @param [Object] data      Data to store
-  #
-  # @return [Joosy.Resource.Generic]      Returns self
-  #
-  reset: (data) ->
-    @__fillData data
-    return this
-  
-  #
-  # Getter for wrapped data
-  #
-  # @param [String] path    Attribute name to get. Can contain dots to get inline Objects values
-  # @return [mixed]
-  #
-  get: (path) ->
-    target = @__callTarget path
-    target[0][target[1]]
-
-  #
-  # Setter for wrapped data, triggers `changed` event.
-  #
-  # @param [String] path    Attribute name to set. Can contain dots to get inline Objects values
-  # @param [mixed] value    Value to set
-  #
-  set: (path, value) ->
-    target = @__callTarget path
-    target[0][target[1]] = value
-    @trigger 'changed'
-    null
-
-  #
-  # Locates the actual instance of attribute path `foo.bar` from get/set
-  #
-  # @param [String] path    Path to the attribute (`foo.bar`)
-  # @return [Array]         Instance of object containing last step of path and keyword for required field
-  #
-  __callTarget: (path) ->
-    if path.has(/\./) && !@e[path]?
-      path    = path.split '.'
-      keyword = path.pop()
-      target  = @e
-      
-      for part in path
-        target[part] ||= {}
-        target = target[part]
-
-      [target, keyword]
-    else
-      [@e, path]
-
-  #
-  # Wrapper for {Joosy.Resource.Generic.create} magic
-  #
-  __call: (path, value) ->
-    if arguments.length > 1
-      @set path, value
-    else
-      @get path
-
-  #
-  # Defines how exactly prepared data should be saved
-  #
-  # @param [Object] data    Raw data to store
-  #
-  __fillData: (data, notify=true) ->
-    @e = @__prepareData data
-    
-    if notify
-      @trigger 'changed'
-
-    null
-
-  #
-  # Prepares raw data: cuts the root node if it exists, runs before filters
-  #
-  # @param [Hash] data    Raw data to prepare
-  # @return [Hash]
-  #
-  __prepareData: (data) ->    
-    if Object.isObject(data) && Object.keys(data).length == 1 && @__entityName
-      name = @__entityName.camelize(false)
-      data = data[name] if data[name]
-
-    if @__beforeLoads?
-      data = bl.call(this, data) for bl in @__beforeLoads
-      
-    data

data/app/assets/javascripts/joosy/core/resource/rest.js.coffee

@@ -1,197 +0,0 @@
-#= require ./rest_collection
-
-#
-# Resource with the HTTP REST as the backend.
-#
-# @example Basic usage
-#   class Rocket extends Joosy.Resource.REST
-#     @entity 'rocket'
-#   
-#   r = Rocket.find {speed: 'fast'}   # queries /rockets/?speed=fast to get RESTCollection
-#   r = Rocket.find 1                 # queries /rockets/1 to get Rocket instance
-#   
-#   class Engine extends Joosy.Resource.REST
-#     @entity 'engine'
-#     @source -> 
-#       (rocket) "/rockets/#{rocket 'id'}/engines"
-#   
-#   e = Engine.at(r).find {oil: true} # queries /rockets/1/engies?oil=true
-#
-class Joosy.Resource.REST extends Joosy.Resource.Generic
-
-  #
-  # Default primary key field 'id'
-  #
-  __primaryKey: 'id'
-  
-  #
-  # Implements `@collection` default behavior.
-  # Changes the default fallback to Joosy.Resource.RESTCollection.
-  #
-  __collection: ->
-    named = @__entityName.camelize().pluralize() + 'Collection'
-    if window[named] then window[named] else Joosy.Resource.RESTCollection
-
-  #
-  # Sets the field containing primary key.
-  #
-  # @note It has no direct use inside the REST resource itself and can be omited.
-  #   But it usually should not since we have plans on adding some kind of Identity Map to Joosy.
-  #
-  # @param [String] primary     Name of the field
-  #
-  @primary: (primary) -> @::__primaryKey = primary
-
-  #
-  # Should NOT be called directly, use {Joosy.Resource.Generic.create} instead
-  #
-  # @param [Integer, String, Object] description    ID of entity or full data to store
-  #
-  constructor: (description={}) ->
-    if @constructor.__isId description
-      @id = description
-    else
-      super description
-      @id = @e[@__primaryKey]
-
-  #
-  # Queries for REST data and creates resources instances.
-  #
-  # Returns single entity if integer or string given.
-  # Returns collection if no value or Object (with parameters) given.
-  #
-  # If first parameter is a Function it's considered as a result callback,
-  #   in this case parameters will be considered equal to `{ }`
-  #
-  # @example Different find
-  #   class Rocket extends Joosy.Resource.REST
-  #     @entity 'rocket'
-  #   
-  #   Rocket.find 1
-  #   Rocket.find {type: 'nuclear'}, (data) -> data
-  #   Rocket.find (data) -> data
-  #   Rocket.find 1, 
-  #     success: (data) -> data)
-  #     cache: true
-  #
-  # @param [Integer, String, Object] description    ID of entity or full data to store
-  # @param [Hash, Function] options                 AJAX options.
-  #   Will be considered as a success callback if function is given.
-  #
-  # @return [Joosy.Resource.REST, Joosy.Resource.RESTCollection]
-  #
-  @find: (description, options) ->
-    if Object.isFunction options
-      options = {success: options}
-    
-    if @__isId description
-      resource = @create description
-      resource.fetch options
-      resource
-    else
-      if !options? && Object.isFunction description
-        options = {success: description}
-        description = undefined
-      resources = new (@::__collection()) this, description
-      resources.fetch options
-      resources
-
-  #
-  # Queries the resource url and reloads the data from server
-  #
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  # @return [Joosy.Resource.REST]
-  #
-  fetch: (options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-
-    @constructor.__ajax 'get', @constructor.__buildSource(extension: @id), options, (e) =>
-      @__fillData e, false
-      callback? this
-      @trigger 'changed'
-    this
-
-  save: ->
-
-  #
-  # Destroys the resource by DELETE query
-  #
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  # @return [Joosy.Resource.REST]
-  #
-  destroy: (options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-    
-    @constructor.__ajax 'delete', @constructor.__buildSource(extension: @id), options, (e) =>
-      callback? this
-    this
-    
-  #
-  # Requests the REST member URL with POST or any method given in options.type.
-  #
-  # @param [String] ending              Member url (like 'foo' or 'foo/bar')
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  #
-  request: (ending, options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-      
-    if options.method || options.type
-      type = options.method || options.type
-    else
-      type = 'post'
-    
-    @constructor.__ajax type, @constructor.__buildSource(extension: "#{@id}/#{ending}"), options, callback
-
-  #
-  # Checks if given description can be considered as ID
-  #
-  # @param [Integer, String, Object] something      Value to test
-  # @return [Boolean]
-  #
-  @__isId: (something) ->
-    Object.isNumber(something) || Object.isString(something)
-
-  #
-  # jQuery AJAX wrapper.
-  #
-  # @param [String] method      HTTP Method (GET/POST/PUT/DELETE)
-  # @param [String] url         URL to query
-  # @param [Hash] options       AJAX options to pass with request
-  # @param [Function] callback  XHR callback
-  #
-  @__ajax: (method, url, options={}, callback) ->
-    $.ajax url, Joosy.Module.merge options,
-      type: method
-      success: callback
-      cache: false
-      dataType: 'json'
-
-  #
-  # Builds URL for current resource location.
-  #
-  # @param [Hash] options     Handling options
-  #
-  # @option options [String] extension      String to add to resource base url
-  # @option options [Hash] params           GET-params to add to resulting url
-  #
-  @__buildSource: (options={}) ->
-    unless @hasOwnProperty '__source'
-      @__source = "/" + @::__entityName.pluralize()
-      
-    source = if Object.isFunction(@__source) then @__source() else @__source
-    source = Joosy.buildUrl "#{source}/#{options.extension || ''}", options.params

data/app/assets/javascripts/joosy/core/resource/rest_collection.js.coffee

@@ -1,125 +0,0 @@
-#
-# Collection of Resources with REST-fetching capabilities.
-#
-# @note Generally you should not use RESTCollection directly. It will be
-#   automatically created by Joosy.Resource.REST#find.
-#
-# @example Basic samples
-#   class R extends Joosy.Resource.REST
-#     @entity 'r'
-#   
-#   collection = new Joosy.Resource.RESTCollection(R, {color: 'green'})
-#   
-#   collection.fetch()
-#   collection.page 2
-#   
-#   collection.params = {color: 'red', sort: 'date'}
-#   collection.fetch()
-#
-class Joosy.Resource.RESTCollection extends Joosy.Resource.Collection
-  @include Joosy.Modules.Log
-  @include Joosy.Modules.Events
-
-  #
-  # Hash containing the cache for pages of raw data.
-  # Keys are pages numbers, values are stored AJAX response.
-  #
-  pages: Object.extended()
-
-  #
-  # @param [Class] model      Resource class this collection will handle
-  # @param [Hash] params      Additional parameters that will be added to all REST requests.
-  #
-  constructor: (model, params={}) ->
-    super model
-    @params = Object.extended params
-
-  #
-  # Clears the storage and attempts to import given array
-  #
-  # @param [Array, Hash] entities     Array of entities to import.
-  #   If hash was given will seek for moodel name camelized and pluralized.
-  # @param [Boolean] notify           Indicates whether to trigger 'changed' event
-  #
-  # @return [Joosy.Resource.RESTCollection]   Returns self.
-  #
-  reset: (entities, notify=true) ->
-    super entities, false
-    if notify
-      @trigger 'changed'
-    this
-
-  #
-  # Clears the storage and gets new data from server.
-  #
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  #
-  # @return [Joosy.Resource.RESTCollection]   Returns self.
-  #
-  fetch: (options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-    
-    @__fetch @params, options, (data) =>
-      @reset data, false
-      callback? this
-      @trigger 'changed'
-    this
-
-  #
-  # Returns the subset for requested page: requests with &page=x.
-  #
-  # @param [Integer] number             Index of page
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  #
-  # @return [Joosy.Resource.RESTCollection]   Returns self.
-  #
-  page: (number, options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-    
-    @__fetch Joosy.Module.merge({page: number}, @params), options, (data) =>
-      @reset data, false
-      callback? @data
-      @trigger 'changed'
-    this
-    
-  #
-  # Requests the REST collection URL with POST or any method given in options.type.
-  #
-  # @param [String] ending              Collection url (like 'foo' or 'foo/bar')
-  # @param [Hash, Function] options     AJAX options.
-  #   Will be considered as a success callback if function is given.
-  #
-  request: (ending, options) ->
-    if Object.isFunction options
-      callback = options
-    else
-      callback = options?.success
-      delete options?.success
-      
-    if options.method || options.type
-      type = options.method || options.type
-    else
-      type = 'post'
-    
-    @model.__ajax type, @model.__buildSource(extension: ending), options, callback
-    
-  #
-  # Internal AJAX request implementation.
-  #
-  # @param [Hash] urlOptions      GET-params for request
-  # @param [Hash] ajaxOptions     AJAX options to pass with request
-  # @param [Function] callback
-  #
-  __fetch: (urlOptions, ajaxOptions, callback) ->
-    @model.__ajax 'get', @model.__buildSource(params: @params.merge(urlOptions)), ajaxOptions, (data) ->
-      callback(data)