joosy 0.1.0.RC3 → 0.1.0.alpha

data/vendor/assets/javascripts/joosy/core/page.js.coffee

@@ -0,0 +1,136 @@
+#= require joosy/core/joosy
+#= require joosy/core/modules/module
+#= require joosy/core/modules/log
+#= require joosy/core/modules/events
+#= require joosy/core/modules/container
+#= require joosy/core/modules/time_manager
+#= require joosy/core/modules/widgets_manager
+#= require joosy/core/modules/filters
+
+class Joosy.Page extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+  @include Joosy.Modules.Container
+  @include Joosy.Modules.TimeManager
+  @include Joosy.Modules.WidgetsManager
+  @include Joosy.Modules.Filters
+
+  layout: false
+  previous: false
+  params: false
+  source: false
+  data: false
+
+  @fetch: (callback) -> @::__fetch = callback
+  @scroll: (element, options={}) -> 
+    @::__scrollElement = element
+    @::__scrollSpeed = options.speed || 500
+    @::__scrollMargin = options.margin || 0
+
+  @beforePageRender: (callback) -> @::__beforePageRender = callback
+  @afterPageRender:  (callback) -> @::__afterPageRender = callback
+  @onPageRender: (callback) -> @::__onPageRender = callback
+
+  @beforeLayoutRender: (callback) -> @::__beforeLayoutRender = callback
+  @afterLayoutRender: (callback) -> @::__afterLayoutRender = callback
+  @onLayoutRender: (callback) -> @::__onLayoutRender = callback
+
+  constructor: (@params, @previous) ->
+    @layout ||= ApplicationLayout
+
+    if @__runBeforeLoads(@params, @previous)
+      if @previous?.layout not instanceof @layout
+        @__renderLayout()
+      else
+        @__render()
+
+  navigate: (args...) -> Joosy.Router.navigate(args...)
+
+  __load: ->
+    @refreshElements()
+    @__delegateEvents()
+    @__setupWidgets()
+    @__runAfterLoads(@params, @previous)
+    if @__scrollElement
+      scroll = $(@__extractSelector(@__scrollElement)).offset()?.top + @__scrollMargin
+      $('html, body').animate({scrollTop: scroll}, @__scrollSpeed)
+
+  __unload: ->
+    @clearTime()
+    @__unloadWidgets()
+    @__runAfterUnloads(@params, @previous)
+
+  __render: ->
+    @layout = @previous.layout
+
+    @wait "stageClear dataReceived", =>
+      @previous?.__unload()
+
+      render = =>
+        @swapContainer @layout.content(), @view(@data)
+        @container = @layout.content()
+
+        @__load()
+        Joosy.Beautifier.go()
+
+        if @__afterPageRender?
+          @__afterPageRender @layout.content()
+
+        return @layout.content()
+
+      if @__onPageRender?
+        @__onPageRender @layout.content(), render
+      else
+        render()
+
+    if @__beforePageRender?
+      @__beforePageRender @layout.content(), =>
+        @trigger 'stageClear'
+    else
+      @trigger 'stageClear'
+
+    if @__fetch?
+      @__fetch =>
+        @trigger 'dataReceived'
+    else
+      @trigger 'dataReceived'
+
+  __renderLayout: ->
+    @layout = new @layout
+
+    @wait "stageClear dataReceived", =>
+
+      @previous?.layout?.__unload?()
+      @previous?.__unload()
+
+      render = =>
+        @swapContainer Joosy.Application.content(), @layout.view(@data)
+        @swapContainer @layout.content(), @view(@data)
+        @container = @layout.content()
+
+        @layout.__load Joosy.Application.content()
+        @__load()
+        Joosy.Beautifier.go()
+
+        if @__afterLayoutRender?
+          @__afterLayoutRender Joosy.Application.content()
+
+        return Joosy.Application.content()
+
+      if @__onLayoutRender?
+        @__onLayoutRender Joosy.Application.content(), render
+      else
+        render()
+
+
+    if @__beforeLayoutRender?
+      @__beforeLayoutRender Joosy.Application.content(), =>
+        @trigger 'stageClear'
+    else
+      @trigger 'stageClear'
+
+    if @__fetch?
+      @__fetch =>
+        @trigger 'dataReceived'
+    else
+      @trigger 'dataReceived'

data/vendor/assets/javascripts/joosy/core/resource/rest.js.coffee

@@ -0,0 +1,69 @@
+#= require ./rest_collection
+
+class Joosy.Resource.REST extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+
+  __primaryKey: 'id'
+  
+  @entity: (name) -> @__entityName = name
+  @primary: (primary) -> @::__primaryKey = primary
+  @source: (source) -> @__source = source
+  @beforeLoad: (action) -> @::__beforeLoad = action
+
+  constructor: (description) ->
+    if @constructor.__isId(description) 
+      @id = description
+    else
+      @__fillData(description)
+      @id = @e[@__primaryKey]
+
+  @entityName: -> @__entityName ?= @name.underscore()
+
+  # Returns single entity if int/string given
+  # Returns collection if no value or Object (with parameters) given
+  @find: (description, callback, options) ->
+    if @__isId(description)
+      resource = new @(description)
+      resource.fetch callback, options
+      resource
+    else
+      resources = new Joosy.Resource.RESTCollection(@, description)
+      resources.fetch callback, options
+      resources
+    
+  fetch: (callback, options) ->
+    @constructor.__ajax 'get', @constructor.__buildSource(extension: @id), options, (e) => 
+      @__fillData(e)
+      callback?(@)
+    @
+  
+  save: ->
+    
+  destroy: (callback, options) ->
+    @constructor.__ajax 'delete', @constructor.__buildSource(extension: @id), options, (e) =>
+      callback?(@)
+    @
+
+  @__isId: (something) -> Object.isNumber(something) || Object.isString(something)
+
+  @__ajax: (method, url, options={}, callback) ->
+    $.ajax url, Object.extended(
+      type: method
+      success: callback
+      cache: false
+      dataType: 'json'
+    ).merge options
+
+  @__buildSource: (options) ->
+    @__source ?= "/"+@entityName().pluralize()
+    source     = Joosy.buildUrl("#{@__source}/#{options.extension || ''}", options.params)
+
+  __fillData: (data) -> 
+    data = Object.extended(data)
+    data = @__beforeLoad(data) if @__beforeLoad?
+    
+    @e = if Object.isObject(data) && data[@constructor.entityName()] && data.keys().length == 1
+      data[@constructor.entityName()]
+    else
+      data

data/vendor/assets/javascripts/joosy/core/resource/rest_collection.js.coffee

@@ -0,0 +1,42 @@
+class Joosy.Resource.RESTCollection extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+  
+  data: []
+  pages: Object.extended()
+  
+  constructor: (@model, params={}) -> @params = Object.extended(params)
+  
+  # Clears the storage and atempts to import given JSON
+  reset: (entities) ->
+    @data = data = @modelize entities
+    @pages = Object.extended().merge 1: data
+    @
+
+  # Clears the storage and gets new data from server
+  fetch: (callback, options) ->
+    @model.__ajax 'get', @model.__buildSource(params: @params), options, (data) =>
+      @reset(data)
+      callback?(@)
+    @
+
+  # Returns the subset for requested page. Requests with &page=x if not found localy.
+  page: (number, callback=false) ->
+    if @pages[number]?
+      callback?(@pages[number])
+      return @ 
+    
+    @model.__ajax 'get', @model.__buildSource(params: @params.merge(page: number)), (data) =>
+      @pages[number] = @modelize data
+      
+      @data = []
+      @pages.keys().sort().each (x) => @data.add @pages[x]
+      
+      callback?(@pages[number])
+    @
+
+  modelize: (collection) ->
+    if collection instanceof Array
+      collection.map (x) => new @model(x)
+    else
+      []

data/vendor/assets/javascripts/joosy/core/router.js.coffee

@@ -0,0 +1,75 @@
+#= require joosy/core/joosy
+
+Joosy.Router =
+  rawRoutes: Object.extended()
+  routes: Object.extended()
+
+  map: (routes) ->
+    @rawRoutes.merge routes
+
+  setupRoutes: ->
+    @prepareRoutes @rawRoutes
+
+    @respondRoute(location.hash)
+    $(window).hashchange => @respondRoute(location.hash)
+
+  prepareRoutes: (routes, namespace='') ->
+    if !namespace && routes[404]
+      @wildcardAction = routes[404]
+      delete routes[404]
+    routes.each (path, response) =>
+      path = (namespace+path).replace(/\/{2,}/, '/')
+      if response && (typeof(response) == 'function' || response.prototype?)
+        @prepareRoute path, response
+      else
+        @prepareRoutes Object.extended(response), path
+
+  prepareRoute: (path, response) ->
+    matchPath = path.replace(/\/:([^\/]+)/g, '/([^/]+)').replace(/^\/?/, '^/?').replace(/\/?$/, '/?$')
+    @routes[matchPath] =
+      capture : (path.match(/\/:[^\/]+/g) || []).map((str) -> str.substr(2))
+      action  : response
+
+  respondRoute: (hash) ->
+    fullPath = hash.replace(/^#!?/, '')
+
+    if @currentPath != fullPath
+      @currentPath = fullPath
+      found = false
+
+      paramStr = fullPath.split('&')
+      path = paramStr.shift()
+      urlParams = @getUrlParams(paramStr)
+
+      for regex, route of @routes when @routes.hasOwnProperty(regex)
+        if vals = path.match(new RegExp(regex))
+          params = @getRouteParams(vals, route).merge urlParams
+
+          if !Joosy.Module.hasAncestor(route.action, Joosy.Page)
+            route.action.call(this, params)
+          else
+            Joosy.Application.setCurrentPage(route.action, params)
+          found = true
+          break
+
+      if !found && @wildcardAction
+        @wildcardAction(path, urlParams)
+
+  getRouteParams: (vals, route) ->
+    params = Object.extended()
+    vals.shift()
+    for param in route.capture
+      params[param] = vals.shift()
+    return params
+
+  getUrlParams: (paramStr) ->
+    params = {}
+    if paramStr
+      $.each paramStr, () ->
+        if @ != ''
+          pair = @.split '='
+          params[pair[0]] = pair[1]
+    return params
+
+  navigate: (to) ->
+    location.hash = '!'+to

data/vendor/assets/javascripts/joosy/core/widget.js.coffee

@@ -0,0 +1,35 @@
+#= require joosy/core/joosy
+#= require joosy/core/modules/module
+#= require joosy/core/modules/log
+#= require joosy/core/modules/events
+#= require joosy/core/modules/container
+#= require joosy/core/modules/filters
+
+class Joosy.Widget extends Joosy.Module
+  @include Joosy.Modules.Log
+  @include Joosy.Modules.Events
+  @include Joosy.Modules.Container
+  @include Joosy.Modules.Filters
+
+  __render: false
+
+  @render: (callback) ->
+    @::__render = callback
+
+  setInterval: (args...) ->
+    @parent.setInterval(args...)
+
+  setTimeout: (args...) ->
+    @parent.setTimeout(args...)
+
+  navigate: (args...) -> Joosy.Router.navigate(args...)
+
+  __load: (@parent, @container) ->
+    @__render?()
+    @refreshElements()
+    @__delegateEvents()
+    @__runAfterLoads()
+    return @
+
+  __unload: ->
+    @__runAfterUnloads()

data/vendor/assets/javascripts/joosy/preloader/development.js.coffee

@@ -0,0 +1,27 @@
+@Preloader =
+  receive: (url, callback) ->
+    head   = document.getElementsByTagName("head")[0]
+    script = document.createElement("script")
+    script.src = url# + (if url.match(/\?/) then '&' else '?') + "rand=" + Math.random()
+
+    done = false
+
+    proceed = ->
+      if ( !done && (!this.readyState ||
+            this.readyState == "loaded" || this.readyState == "complete") )
+
+        done = true and callback() if callback
+        script.onload = script.onreadystatechange = null
+
+    script.onload = script.onreadystatechange = proceed
+
+    head.appendChild(script)
+    return undefined
+
+  load: (libraries) ->
+    @start?.call window
+
+    if libraries.length > 0
+      @receive libraries.shift()[0], => @load(libraries)
+    else
+      @complete?.call window

data/vendor/assets/javascripts/joosy/preloader/production.js.coffee

@@ -0,0 +1,84 @@
+#= require base64
+
+window.globalEval = (src) ->
+  if window.execScript
+    window.execScript src
+  else
+    fn = ->
+      window.eval.call window,src
+    fn()
+
+@Preloader =
+  force: false
+  prefix: "cache:"
+
+  libraries: []
+  counter: 0
+
+  complete: false
+
+  ajax: (url, size, callback) ->
+    x = this.ActiveXObject
+    x = new (if x then x else XMLHttpRequest)('Microsoft.XMLHTTP')
+
+    x.open('GET', url, 1)
+    x.setRequestHeader('Content-type','application/x-www-form-urlencoded')
+
+    if @progress
+      x.onprogress = (event) =>
+        total = if size then size else event.total
+        @progress.call window, Math.round(event.loaded / total * 100 * @counter / @libraries.length), event
+
+    x.onreadystatechange = () -> callback(x) if callback? && x.readyState > 3
+    x.send()
+
+  restore: ->
+    for name, i in @libraries
+      code = window.localStorage.getItem(name)
+      window.globalEval if window.navigator.appName == "Microsoft Internet Explorer" then Base64.decode(code) else code
+    @complete?.call window, (true)
+
+  download: (libraries) ->
+    if libraries.length > 0
+      @counter += 1
+
+      lib  = libraries.shift()
+      url  = lib[0]
+      size = lib[1]
+
+      @ajax url, size, (xhr) =>
+        code = xhr.responseText
+        window.localStorage.setItem @prefix+url, (if window.navigator.appName == "Microsoft Internet Explorer" then Base64.encode(code) else code)
+        window.globalEval xhr.responseText
+        @download(libraries)
+    else
+      @clean()
+      @complete?.call window, false
+
+  load: (libraries) ->
+    @libraries = libraries.slice()
+
+    for lib, i in @libraries
+      @libraries[i] = @prefix+lib[0]
+
+    if !@force && @check()
+      @restore()
+    else
+      @start?.call window
+      @download(libraries)
+
+  check: ->
+    flag = true
+    for name, i in @libraries
+      flag &&= window.localStorage.getItem(name)?
+    flag
+
+  clean: ->
+    removed = 0
+
+    for element, i in window.localStorage
+      key = window.localStorage.key(i-removed)
+
+      if key.indexOf(@prefix) == 0 && @libraries.indexOf(key) < 0
+        window.localStorage.removeItem(key)
+        removed += 1