ela 1.1.0

data/app/js/vendor/backbone.poised/form/value.coffee

@@ -0,0 +1,33 @@
+class Backbone.Poised.Value extends Backbone.Poised.View
+  tagName: 'span'
+  className: 'poised value'
+
+  initialize: (options = {}) =>
+    throw new Error('Missing `model` option') unless options.model?
+    throw new Error('Missing `attribute` option') unless options.attribute?
+
+    @attribute = options.attribute
+    @options = _.chain(options)
+      .pick('unit', 'precision')
+      .value()
+
+    @model.on "change:#{@attribute}", @render
+
+  value: ->
+    v = @model.get(@attribute)
+    if typeof v is 'number' and isNaN(v)
+      '-'
+    else if @options.precision?
+      @model.get(@attribute).toFixed(@options.precision)
+    else
+      v
+
+  unit: ->
+    if @options.unit
+      " #{@options.unit}"
+    else
+      ''
+
+  render: =>
+    @$el.html("#{@value()}#{@unit()}")
+    this

data/app/js/vendor/backbone.poised/form/value_control.coffee

@@ -0,0 +1,15 @@
+class Backbone.Poised.ValueControl extends Backbone.Poised.BaseControl
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('model', 'attribute', 'unit', 'precision')
+      .value()
+
+  render: =>
+    super
+
+    @subviews.value = view = new Backbone.Poised.Value(@options)
+    @$info.append(view.render().el)
+
+    this

data/app/js/vendor/backbone.poised/linked_form.coffee

@@ -0,0 +1,43 @@
+Backbone.Poised ||= {}
+class Backbone.Poised.LinkedForm extends Backbone.Poised.Form
+  tagName: 'form'
+  className: 'poised'
+
+  initialize: (options = {}) ->
+    throw new Error('Missing `model1` option') unless options.model1?
+    throw new Error('Missing `model2` option') unless options.model2?
+
+    # as reference model and for validations
+    @model  = options.model1
+
+    @model1 = options.model1
+    @model2 = options.model2
+
+    @extractOptions(options)
+    @extractFields(options)
+
+  # Bind validations of both models to this view.
+  bindValidation: ->
+    Backbone.Validation.bind(this, model: @model1)
+    Backbone.Validation.bind(this, model: @model2)
+
+  # Instantiates the linked control view for the given field object.
+  # Eventually sets the default values for needed options (e.g.
+  # models, the parent view, etc.) and sets the correct validation
+  # function.
+  #
+  # @see [Backbone.Poised.Form#controlView]
+  #
+  # @returns [Backbone.Poised.LinkedControl] view The view for the control
+  controlView: (field) ->
+    field = _.defaults field,
+      model1: @model1
+      model2: @model2
+      parentView: this
+    field.validate = @model1.__proto__.validation and _.has(@model1.__proto__.validation, field.attribute)
+    switch field.type
+      when 'text' then new Backbone.Poised.LinkedStringControl(field)
+      when 'range' then new Backbone.Poised.LinkedRangeControl(field)
+      when 'number' then new Backbone.Poised.LinkedNumberControl(field)
+      when 'select' then new Backbone.Poised.LinkedSelectControl(field)
+      when 'anchor' then new Backbone.Poised.Anchor(field)

data/app/js/vendor/backbone.poised/list.coffee

@@ -0,0 +1,97 @@
+Backbone.Poised ||= {}
+class Backbone.Poised.List extends Backbone.Poised.View
+  tagName: 'ul'
+  className: 'poised'
+
+  addButtonTemplate: _.template("<li class='add button'><%= label %></li>")
+
+  extractGroupOptions: (options = {}) ->
+    @options.group = _.chain(options)
+      .pick('by', 'collapsible', 'collapsed', 'sorting')
+      .defaults
+        collapsible: false
+        collapsed: []
+      .value()
+
+  initialize: (options) ->
+    @options = _.chain(options)
+      .pick('filterAttributes', 'itemClass', 'itemLabel', 'itemTemplate', 'addible', 'addLabel', 'singleSelect')
+      .defaults
+        filterAttributes: false
+        itemClass: Backbone.Poised.List.Item
+        addible: false
+        singleSelect: false
+      .value()
+
+    @extractGroupOptions(options.group)
+
+    @collection.on 'add remove reset', @render
+
+  appendSearchfield: =>
+    @subviews.searchfield = new Backbone.Poised.List.Searchfield
+      parentView: this
+      locale: @locale
+      localePrefix: @localePrefix
+    @$el.append(@subviews.searchfield.render().el)
+
+  appendItem: (model, $el = @$el) =>
+    @subviews["item#{model.cid}"] = itemView = new @options.itemClass
+      model: model
+      parentView: this
+      itemLabel: @options.itemLabel
+      itemTemplate: @options.itemTemplate
+      filterAttributes: @options.filterAttributes
+      singleSelect: @options.singleSelect
+      locale: @locale
+      localePrefix: @localePrefix
+    $el.append(itemView.render().el)
+
+  appendAddButton: =>
+    @subviews.addButton = new Backbone.Poised.List.AddButton
+      label: (@options.addLabel or 'Add item')
+      parentView: this
+      locale: @locale
+      localePrefix: @localePrefix
+    @$el.append(@subviews.addButton.render().el)
+
+  appendGroup: (group, models) =>
+    group = group.toCamel()
+    @subviews[group] = groupView = new Backbone.Poised.List.Anchor
+      name: group
+      parentView: this
+      collapsible: $.ematch(group, @options.group.collapsible)
+      collapsed: $.ematch(group, @options.group.collapsed)
+      locale: @locale
+      localePrefix: @localePrefix
+
+    @$el.append(groupView.render().el)
+
+    $grp = $('<ul>', class: 'poised list-group')
+
+    @$el.append($grp)
+    @appendItem(model, $grp) for model in models
+
+  render: =>
+    @$el.html('')
+
+    @appendSearchfield() if @options.filterAttributes
+    @appendAddButton() if @options.addible
+
+    if @options.group.by
+      groupedModels = @collection.groupBy(@options.group.by)
+      groups = if _.isFunction(@options.group.sorting)
+        _.chain(groupedModels)
+          .keys()
+          .sort(@options.group.sorting)
+          .value()
+      else
+        @options.group.sorting or _.keys(groupedModels)
+
+      for group in groups
+        models = groupedModels[group]
+        @appendGroup(group, models) if models?
+    else
+      @collection.each (model) =>
+        @appendItem(model)
+
+    this

data/app/js/vendor/backbone.poised/list/add_button.coffee

@@ -0,0 +1,16 @@
+class Backbone.Poised.List.AddButton extends Backbone.Poised.View
+  tagName: 'li'
+  className: 'add button'
+
+  events:
+    'tap': 'add'
+
+  initialize: ({@label}) ->
+    super
+
+  add: =>
+    @trigger('add')
+
+  render: ->
+    @$el.html(@label)
+    this

data/app/js/vendor/backbone.poised/list/anchor.coffee

@@ -0,0 +1,32 @@
+Backbone.Poised.List ||= {}
+class Backbone.Poised.List.Anchor extends Backbone.Poised.View
+  tagName: 'li'
+  className: 'anchor'
+
+  events:
+    'click': 'toggleCollapse'
+
+  initialize: (options = {}) ->
+    super
+    @name = options.name or 'general'
+    @label = options.label
+
+    @collapsible = options.collapsible is true
+    @collapsed = options.collapsed isnt false if @collapsible
+
+  toggleCollapse: =>
+    @$el.toggleClass('collapsed')
+
+  render: ->
+    if @name is 'undefined'
+      defaultLocale = 'other'
+    else
+      defaultLocale = @name.toLabel()
+    @$el.html @loadLocale "listAnchors.#{@name}.label",
+      defaultValue: defaultLocale
+
+    if @collapsible
+      @$el.addClass('collapsible')
+      @toggleCollapse() if @collapsed
+
+    this

data/app/js/vendor/backbone.poised/list/item.coffee

@@ -0,0 +1,68 @@
+Backbone.Poised.List ||= {}
+class Backbone.Poised.List.Item extends Backbone.Poised.View
+  tagName: 'li'
+  className: 'item'
+
+  template: _.template('<label class="item"></label><div class="buttons"></div>')
+
+  initialize: (options = {}) ->
+    super
+
+    @template = options.itemTemplate if options.itemTemplate
+
+    @options = _.pick(options, 'itemLabel')
+    if @options.itemLabel and _.isFunction(@options.itemLabel)
+      changeTrigger = 'change'
+      @options.itemLabel(_.defaults(@labelParameters(), @model.toJSON()))
+    else if @options.itemLabel and _.isString(@options.itemLabel)
+      changeTrigger = "change:#{@options.itemLabel}"
+    else
+      changeTrigger = 'change:label change:title change:name'
+    @model.on(changeTrigger, @updateLabel)
+
+    @parentView.on 'filter', @filter
+
+  filter: (text, sharedObject) =>
+    textChars = text.split('')
+    sharedObject.fuzzyRegExp ?= new RegExp(textChars.join('.*'), 'i')
+    sharedObject.markRegExps ?= (new RegExp(textChar, 'i') for textChar in textChars)
+
+    if text.length is 0 or sharedObject.fuzzyRegExp.test(@$el.text())
+      @$el.css display: ''
+    else
+      @$el.css display: 'none'
+    @renderFilterHint(sharedObject.markRegExps)
+
+  # Querying is emacs-like, just the marking is slightly different,
+  # marking every occurence of every character in the query.
+  renderFilterHint: (markRegExps) ->
+    @$el.removeMark()
+    @$el.markRegExp(markRegExp) for markRegExp in markRegExps
+
+  eventFn: (name) =>
+    eventName = name
+    (e) ->
+      @parentView.trigger eventName, @model
+
+  # Stub: Return object to merge into the model attribute objects
+  # for the `itemLabel` function.
+  #
+  # @returns [Object] Values to merge into the model attributes
+  labelParameters: -> {}
+
+  updateLabel: =>
+    label = if @options.itemLabel and _.isFunction(@options.itemLabel)
+      @options.itemLabel(_.defaults(@labelParameters(), @model.toJSON()))
+    else if @options.itemLabel and _.isString(@options.itemLabel)
+      @model.get(@options.itemLabel)
+    else
+      @model.get('label') or @model.get('title') or @model.get('name') or 'n/A'
+    @$label.html(label)
+
+  render: =>
+    @$el.html(@template())
+    @$label = @$('label.item')
+    @updateLabel()
+    @$buttons = @$('.buttons')
+
+    this

data/app/js/vendor/backbone.poised/list/searchfield.coffee

@@ -0,0 +1,26 @@
+Backbone.Poised.List ||= {}
+class Backbone.Poised.List.Searchfield extends Backbone.Poised.View
+  tagName: 'li'
+  className: 'search-box'
+
+  template: _.template("<input type='search' placeholder='<%= placeholder %>'>")
+
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('placeholder')
+      .value()
+
+  events:
+    'input input': 'filterList'
+
+  filterList: (e) =>
+    clearTimeout @filterInputTimeout
+    @filterInputTimeout = delay 250, =>
+      @trigger('filter', $(e.target).val() or '', {})
+
+  render: =>
+    placeholder = @options.placeholder or @loadLocale('search.placeholder')
+    @$el.html @template placeholder: placeholder
+    this

data/app/js/vendor/backbone.poised/list/selectable_item.coffee

@@ -0,0 +1,65 @@
+class Backbone.Poised.List.SelectableItem extends Backbone.Poised.List.Item
+  events: _.defaults {
+    'change [type=checkbox]': 'updateModelSelection'
+    'tap': 'updateModelSelection'
+    'press': 'toggleSingleSelection'
+  }, Backbone.Poised.List.Item.prototype.events
+
+  selectedAttribute: 'selected'
+
+  hammerjs:
+    recognizers: [
+      [Hammer.Rotate, { enable: false }],
+      [Hammer.Pinch, { enable: false }, ['rotate']],
+      [Hammer.Swipe, { enable: false }],
+      [Hammer.Pan, { enable: false }, ['swipe']],
+      [Hammer.Tap, { threshold: 5 }],
+      [Hammer.Press]
+    ]
+
+  initialize: (options) ->
+    super
+    @options.singleSelect = options.singleSelect is true
+    @model.on("change:#{@selectedAttribute}", @updateCheckboxState)
+
+  updateCheckbox: =>
+    @$checkbox.attr(checked: @model.get(@selectedAttribute))
+
+  updateModelSelection: (e) =>
+    @model.set(@selectedAttribute, not @model.get(@selectedAttribute))
+    @model.collection.singleSelection = undefined
+    @model.collection.selectedBeforeSingleSelection = undefined
+
+  toggleSingleSelection: =>
+    if @options.singleSelect
+      collection = @model.collection
+      if collection.singleSelection is @model
+        collection.each (model) =>
+          previousSelection = collection.selectedBeforeSingleSelection
+          previouslySelected = previousSelection.indexOf(model) > -1
+          model.set(@selectedAttribute, previouslySelected)
+        collection.singleSelection = undefined
+      else
+        filter = {}
+        filter[@selectedAttribute] = true
+        collection.selectedBeforeSingleSelection ?= collection.where(filter)
+        collection.singleSelection = @model
+        collection.each (model) =>
+          model.set(@selectedAttribute, model is @model)
+
+  updateCheckboxState: =>
+    @$checkbox.prop('checked', @model.get(@selectedAttribute))
+
+  render: =>
+    super
+
+    @$checkbox = $ '<input>',
+      type: 'checkbox'
+      name: "model_#{@model.cid}"
+    @updateCheckboxState()
+    @$buttons.append(@$checkbox)
+    @$buttons.append $ '<label>',
+      for: "model_#{@model.cid}"
+      class: 'checkbox'
+
+    this

data/app/js/vendor/backbone.poised/patches.coffee

@@ -0,0 +1,6 @@
+Backbone.Model::match = (test, keys = null) ->
+  values = if keys? and keys isnt true then _.values(@pick.apply(this, keys)) else @values()
+  if _.isRegExp(test)
+    _.some values, (attr) -> test.test(attr)
+  else
+    _.some values, (attr) -> attr == test

data/app/js/vendor/backbone.poised/string_mixin.coffee

@@ -0,0 +1,23 @@
+String.prototype.toCamel = ->
+  str = @replace /((\-|_)[a-z])/g, ($1) -> $1[1].toUpperCase()
+  str[0].toLowerCase() + str.slice(1)
+
+String.prototype.toCapitalCamel = ->
+  str = @toCamel()
+  str[0].toUpperCase() + str.slice(1)
+
+String.prototype.toDash = ->
+  str = @replace /(_[a-z]|[A-Z])/g, ($1) -> "-" + $1.replace('_', '')
+  str = str.slice(1) if str[0] is "-"
+  str.toLowerCase()
+
+String.prototype.toUnderscore = ->
+  str = @replace /(\-[a-z]|[A-Z])/g, ($1) -> "_" + $1.replace('-', '')
+  str = str.slice(1) if str[0] is "_"
+  str.toLowerCase()
+
+String.prototype.toLabel = ->
+  str = @replace /(\-[a-z]|_[a-z]|[A-Z])/g, ($1) ->
+    " " + if $1[1] then $1[1]?.toUpperCase() else $1
+  str = str.slice(1) if str[0] is " "
+  str[0].toUpperCase() + str.slice(1)

data/app/js/vendor/backbone.poised/underscore_ext.coffee

@@ -0,0 +1,2 @@
+_.firstDefined = (args...) ->
+  _.without(args, undefined, null)[0]