ela 1.1.0

data/app/js/vendor/backbone.poised/form/linked_select_control.coffee

@@ -0,0 +1,18 @@
+class Backbone.Poised.LinkedSelectControl extends Backbone.Poised.LinkedControl
+  initialize: (options = {}) =>
+    super
+
+    @options = _.chain(options)
+      .pick('attribute', 'placeholder', 'options', 'multiselect', 'locale', 'localePrefix')
+      .defaults(parentView: this)
+      .value()
+
+  render: =>
+    super
+
+    @subviews.spinner1 = new Backbone.Poised.Selectbox(_.defaults(model: @model1, @options))
+    @$control1.append(@subviews.spinner1.render().el)
+    @subviews.spinner2 = new Backbone.Poised.Selectbox(_.defaults(model: @model2, @options))
+    @$control2.append(@subviews.spinner2.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/linked_string_control.coffee

@@ -0,0 +1,27 @@
+class Backbone.Poised.LinkedStringControl extends Backbone.Poised.LinkedControl
+  initialize: (options = {}) =>
+    super
+
+    @options = _.chain(options)
+      .pick('attribute', 'rows', 'placeholder')
+      .defaults
+        type: 'text'
+        placeholder: null
+        rows: 1
+      .value()
+
+  render: =>
+    super
+
+    if @options.rows > 1
+      @subviews.textarea1 = new Backbone.Poised.Textarea(_.defaults(model: @model1, @options))
+      @$control1.append(@subviews.textarea1.render().el)
+      @subviews.textarea2 = new Backbone.Poised.Textarea(_.defaults(model: @model2, @options))
+      @$control2.append(@subviews.textarea2.render().el)
+    else
+      @subviews.textfield1 = new Backbone.Poised.Textfield(_.defaults(model: @model1, @options))
+      @$control1.append(@subviews.textfield1.render().el)
+      @subviews.textfield2 = new Backbone.Poised.Textfield(_.defaults(model: @model2, @options))
+      @$control2.append(@subviews.textfield2.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/number_control.coffee

@@ -0,0 +1,25 @@
+class Backbone.Poised.NumberControl extends Backbone.Poised.BaseControl
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('model', 'clearOnFocus', 'stepSize', 'precision', 'range', 'attribute', 'unit', 'minValue', 'maxValue')
+      .defaults
+        clearOnFocus: true
+        type: 'number'
+        minValue: _.firstDefined(options.minValue, options.range?[0])
+        maxValue: _.firstDefined(options.maxValue, options.range?[1])
+        parentView: this
+      .value()
+
+    if @options.stepSize? and not @options.precision?
+      @options.precision = _.find([0..3], (i) =>
+        @options.stepSize * Math.pow(10, i) >= 1)
+
+  render: =>
+    super
+
+    @subviews.spinner = new Backbone.Poised.Textfield(@options)
+    @$info.append(@subviews.spinner.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/range_control.coffee

@@ -0,0 +1,48 @@
+class Backbone.Poised.RangeControl extends Backbone.Poised.BaseControl
+  initialize: (options) =>
+    super
+
+    @options = _.chain(@options)
+      .pick('model', 'renderSpinner', 'clearOnFocus', 'stepSize', 'precision', 'range', 'attribute', 'unit', 'sliderMinValue', 'sliderMaxValue', 'spinnerMinValue', 'spinnerMaxValue')
+      .defaults
+        renderSpinner: true
+        clearOnFocus: true
+        type: 'number'
+      .value()
+
+    if @options.stepSize? and not @options.precision?
+      @options.precision = _.find([0..3], (i) =>
+        @options.stepSize * Math.pow(10, i) >= 1)
+
+    # A spinner field is a textfield of type number.
+    if @options.renderSpinner
+      @spinnerOptions = _.chain(@options)
+        .pick('model', 'attribute', 'type', 'clearOnFocus', 'unit', 'precision', 'stepSize')
+        .defaults
+          minValue: _.firstDefined(@options.spinnerMinValue, @options.range?[0], @options.range?.spinner?[0])
+          maxValue: _.firstDefined(@options.spinnerMaxValue, @options.range?[1], @options.range?.spinner?[1])
+          parentView: this
+        .value()
+
+    @sliderOptions = _.chain(@options)
+      .pick('model', 'attribute', 'stepSize')
+      .defaults
+        minValue: _.firstDefined(@options.sliderMinValue, @options.range?[0], @options.range?.slider?[0])
+        maxValue: _.firstDefined(@options.sliderMaxValue, @options.range?[1], @options.range?.slider?[1])
+        parentView: this
+      .value()
+
+  render: =>
+    super
+
+    if @options.renderSpinner
+      @subviews.spinner = new Backbone.Poised.Textfield(@spinnerOptions)
+      @$info.append(@subviews.spinner.render().el)
+    else
+      @subviews.value = new Backbone.Poised.Value(@options)
+      @$info.append(@subviews.value.render().el)
+
+    @subviews.slider = new Backbone.Poised.Slider(@sliderOptions)
+    @$el.append(@subviews.slider.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/select_control.coffee

@@ -0,0 +1,16 @@
+class Backbone.Poised.SelectControl extends Backbone.Poised.BaseControl
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('model', 'attribute', 'placeholder', 'options', 'multiselect', 'locale', 'localePrefix')
+      .defaults(parentView: this)
+      .value()
+
+  render: =>
+    super
+
+    @subviews.selectbox = new Backbone.Poised.Selectbox(@options)
+    @$info.append(@subviews.selectbox.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/selectbox.coffee

@@ -0,0 +1,78 @@
+class Backbone.Poised.Selectbox extends Backbone.Poised.View
+  className: 'poised selectbox'
+
+  events:
+    'change select': 'changeAttributeValue'
+
+  initialize: (options = {}) =>
+    throw new Error('Missing `model` option') unless options.model?
+    throw new Error('Missing `attribute` option') unless options.attribute?
+
+    @attribute = options.attribute
+
+    @options = _.chain(options)
+      .pick('placeholder', 'options', 'multiselect', 'validate')
+      .defaults
+        options: []
+        multiselect: false
+        validate: true
+      .value()
+    unless @options.placeholder?
+      @options.placeholder = not @options.multiselect and not @model.get(@attribute)?
+    @options.placeholder = 'Please select ...' if @options.placeholder is true
+
+    @model.on("change:#{@attribute}", @updateSelectedOption)
+
+  changeAttributeValue: =>
+    if @options.multiselect
+      options = for option in @$select.find('option:selected')
+        $(option).data('value')
+    else
+      options = @$select.find('option:selected').data('value')
+    @model.set(@attribute, options)
+
+  updateSelectedOption: (model, value) =>
+    selectedValues = _.compact(_.flatten(
+      [value or @model.get(@attribute)]
+    ))
+    for option, idx in @$select.find('option')
+      $option = $(option)
+      if @options.placeholder and _.isEmpty(selectedValues)
+        isSelected = idx is 0
+      else
+        isSelected = _.contains(selectedValues, $option.data('value'))
+      $option.attr(selected: isSelected)
+
+  render: =>
+    @$select = $ '<select />',
+      class: 'poised'
+      name: @attribute
+      multiple: @options.multiselect
+
+    if @options.placeholder
+      @$select.append $ '<option>',
+        text: @loadLocale(
+          "formFields.#{@attribute}.options.placeholder"
+          "formFields.selectPlaceholder"
+          "generic.selectPlaceholder"
+          defaultValue: @options.placeholder
+        )
+        disabled: true
+
+    if _.isFunction(@options.options)
+      options = @options.options.apply(@model)
+    else
+      options = @options.options
+    if _.isArray(options)
+      options = _.object(options, options)
+    for label, option of options
+      @$select.append $ '<option>',
+        data:
+          value: option
+        text: @loadLocale "formFields.#{@attribute}.options.#{label}",
+          defaultValue: label
+
+    @$el.html(@$select)
+
+    @updateSelectedOption()
+    this

data/app/js/vendor/backbone.poised/form/slider.coffee

@@ -0,0 +1,109 @@
+window.poisedCurrentSlider = null
+
+class Backbone.Poised.Slider extends Backbone.Poised.View
+  template: _.template('<div class="bar"></div><div class="handle"></div>')
+
+  className: 'poised slider'
+
+  startValue: 0
+  range: 100
+
+  events:
+    'tap': 'handleTap'
+    'panstart': 'handlePanStart'
+    'press': 'handlePress'
+    'pan': 'handlePan'
+    'panend': 'handlePanEnd'
+    'pressup': 'handlePanEnd'
+
+  hammerjs:
+    recognizers: [
+      [Hammer.Rotate, { enable: false }],
+      [Hammer.Pinch, { enable: false }, ['rotate']],
+      [Hammer.Swipe, { enable: false }],
+      [Hammer.Pan, { direction: Hammer.DIRECTION_HORIZONTAL, threshold: 1 }, ['swipe']],
+      [Hammer.Tap, { threshold: 5 }],
+      [Hammer.Press]
+    ]
+
+  initialize: (options = {}) =>
+    throw new Error('Missing `model` option') unless options.model?
+    throw new Error('Missing `attribute` option') unless options.attribute?
+
+    @attribute = options.attribute
+
+    options = _.chain(options)
+      .pick('maxValue', 'minValue', 'stepSize')
+      .defaults
+        minValue: 0
+        maxValue: 100
+        stepSize: 1
+      .value()
+
+    @range = options.maxValue if options.maxValue?
+
+    if options.minValue?
+      @startValue = options.minValue
+      @range -= options.minValue
+
+    @stepSize = options.stepSize
+
+    @model.on "change:#{@attribute}", @updateHandlePosition
+
+  # TODO: Save previously focused element and resore focus after
+  # slider action finished.
+  clearFocus: ->
+    $('input').blur()
+
+  handleTap: (e) ->
+    touchPosition = e.gesture.center.x - @$bar.offset().left
+    @model.set @attribute, @calculateAttributeValue(touchPosition)
+    @trigger('tapChange', this)
+
+  isPanning: false
+
+  startLiveChange: =>
+    @isPanning = true
+    @clearFocus()
+    @trigger('liveChangeStart', this)
+
+  handlePanStart: (e) =>
+    if Math.abs(e.gesture.deltaX) > Math.abs(e.gesture.deltaY) and not @isPanning
+      @startLiveChange()
+
+  handlePress: (e) =>
+    @startLiveChange()
+    @handlePan(e)
+
+  handlePan: (e) =>
+    if @isPanning
+      touchPosition = e.gesture.center.x - @$el.offset().left
+      @model.set @attribute, @calculateAttributeValue(touchPosition)
+      @trigger('liveChange', this)
+
+  handlePanEnd: (e) =>
+    if @isPanning
+      @trigger('liveChangeEnd', this)
+      @isPanning = false
+
+  calculateAttributeValue: (position) ->
+    barWidth = @$bar.width()
+    position = Math.max(position, 0)
+    position = Math.min(position, barWidth)
+    @startValue + Math.round((@range * position / barWidth) / @stepSize) * @stepSize
+
+  calculateHandlePosition: (val) ->
+    val = Math.max(val, @startValue)
+    val = Math.min(val, @startValue+@range)
+    (val - @startValue)/ @range * 100
+
+  updateHandlePosition: (model, value) =>
+    position = @calculateHandlePosition(value)
+    @$handle.css 'left', "#{position.toFixed(2)}%"
+
+  render: =>
+    @$el.html @template()
+    @$handle = @$el.find('.handle')
+    @$bar    = @$el.find('.bar')
+    @updateHandlePosition(@model, @model.get(@attribute))
+    this

data/app/js/vendor/backbone.poised/form/string_control.coffee

@@ -0,0 +1,23 @@
+class Backbone.Poised.StringControl extends Backbone.Poised.BaseControl
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('model', 'attribute', 'rows', 'placeholder')
+      .defaults
+        type: 'text'
+        placeholder: null
+        rows: 1
+      .value()
+
+  render: =>
+    super
+
+    if @options.rows > 1
+      @subviews.textarea = new Backbone.Poised.Textarea(@options)
+      @$el.append(@subviews.textarea.render().el)
+    else
+      @subviews.textfield = new Backbone.Poised.Textfield(@options)
+      @$info.append(@subviews.textfield.render().el)
+
+    this

data/app/js/vendor/backbone.poised/form/submit_control.coffee

@@ -0,0 +1,39 @@
+class Backbone.Poised.SubmitControl extends Backbone.Poised.View
+  tagName: 'ul'
+  className: 'poised button-group'
+
+  events:
+    'tap input.submit': 'submitTapped'
+    'tap input.cancel': 'cancelTapped'
+    'tap input.reset': 'resetTapped'
+
+  initialize: (options = {}) ->
+    super
+
+    @options = _.chain(options)
+      .pick('cancelable', 'resetable')
+      .defaults
+        cancelable: false
+        resetable: false
+      .value()
+
+  submitTapped: (e) =>
+    @trigger('submit')
+    e.preventDefault()
+
+  cancelTapped: (e) =>
+    @trigger('cancel')
+    e.preventDefault()
+
+  resetTapped: (e) =>
+    @trigger('reset')
+    e.preventDefault()
+
+  render: =>
+    @$el.html()
+    @$el.append('<li><input class="poised button primary submit" type="submit" value="Save"></li>')
+    if @options.cancelable
+      @$el.append('<li><input class="poised button secondary cancel" type="submit" value="Cancel"></li>')
+    if @options.resetable
+      @$el.append('<li><input class="poised button secondary reset" type="submit" value="Reset"></li>')
+    this

data/app/js/vendor/backbone.poised/form/textarea.coffee

@@ -0,0 +1,36 @@
+class Backbone.Poised.Textarea extends Backbone.Poised.View
+  tagName: 'span'
+  className: 'poised textarea'
+
+  events:
+    'input textarea': 'updateAttributeValue'
+
+  initialize: (options = {}) =>
+    throw new Error('Missing `model` option') unless options.model?
+    throw new Error('Missing `attribute` option') unless options.attribute?
+
+    @options = _.chain(options)
+      .pick('rows', 'placeholder')
+      .defaults
+        rows: 3
+        placeholder: null
+      .value()
+
+    @attribute = options.attribute
+
+    @model.on "change:#{@attribute}", @render
+
+  updateAttributeValue: =>
+    @model.set(@attribute, @$textarea.val())
+
+  updateTextareaValue: (model, value) =>
+    val = value or @model.get(@attribute)
+    @$textarea.val(val)
+
+  render: =>
+    @$textarea = $ '<textarea>', @options
+    @$el.html(@$textarea)
+
+    @updateTextareaValue()
+
+    this

data/app/js/vendor/backbone.poised/form/textfield.coffee

@@ -0,0 +1,86 @@
+class Backbone.Poised.Textfield extends Backbone.View
+  className: 'poised textfield'
+
+  events:
+    'focusin input': 'clearInputValue'
+    'focusout input': 'readInput'
+
+  initialize: (options = {}) =>
+    throw new Error('Missing `model` option') unless options.model?
+    throw new Error('Missing `attribute` option') unless options.attribute?
+
+    @attribute = options.attribute
+
+    @options = _.chain(options)
+      .pick('type', 'placeholder', 'autofocus', 'clearOnFocus', 'stepSize', 'precision', 'minValue', 'maxValue', 'unit', 'validate')
+      .defaults
+        type: 'text'
+        autofocus: false
+        clearOnFocus: false
+        minValue: null
+        maxValue: null
+        validate: true
+      .value()
+
+    if @options.stepSize? and not @options.precision?
+      @options.precision = _.find([0..3], (i) =>
+        @options.stepSize * Math.pow(10, i) >= 1)
+
+    if _.isArray(options.range)
+      [@options.minValue, @options.maxValue] = options.range
+
+    @model.on "change:#{@attribute}", @setValue
+
+  limit: (val) ->
+    val = Math.max(val, @options.minValue) if @options.minValue?
+    val = Math.min(val, @options.maxValue) if @options.maxValue?
+    val
+
+  _updateValue: (value = @model.get(@attribute)) =>
+    if @options.type is 'number'
+      if typeof value is 'string'
+        if value.match(/^[+\-]?\d+(\.\d+)?$/i)?
+          value = @limit(parseFloat(value))
+        else
+          value = @model.get(@attribute)
+
+      if @options.precision
+        valueString = value.toFixed(@options.precision)
+
+    @model.set(@attribute, value)
+    @$input.val(valueString or value)
+
+    if @model.validate? and @options.validate
+      @model.validate(@attribute)
+
+  setValue: (_, value) =>
+    return if @$input.is(':focus')
+    @_updateValue(value)
+
+  readInput: =>
+    @_updateValue(@$input.val())
+
+  clearInputValue: =>
+    @$input.val('') if @options.clearOnFocus
+
+  render: =>
+    @$el.empty()
+
+    inputAttributes =
+      class: 'poised'
+      name: @attribute
+      type: @options.type
+      placeholder: @options.placeholder
+      autofocus: @options.autofocus
+
+    if @options.type is 'number'
+      inputAttributes.min  = @options.minValue
+      inputAttributes.max  = @options.maxValue
+      inputAttributes.step = @options.stepSize or 'any'
+
+    @$input = $('<input />', inputAttributes).appendTo(@$el)
+
+    @$el.append($('<abbr/>', text: @options.unit)) if @options.unit
+
+    @_updateValue()
+    this