vispy 0.15.0__cp312-cp312-macosx_10_13_x86_64.whl

vispy/glsl/arrows/curved.glsl

@@ -0,0 +1,63 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "arrows/util.glsl"
+
+
+/* ---------------------------------------------------------
+
+   Computes the signed distance to an curved arrow
+
+   Parameters:
+   -----------
+
+   texcoord : Point to compute distance to
+   body :     Total length of the arrow (pixels, body+head)
+   head :     Length of the head (pixels)
+   height :   Height of the head (pixel)
+   linewidth: Stroke line width (in pixels)
+   antialias: Stroke antialiased area (in pixels)
+
+   Return:
+   -------
+   Signed distance to the arrow
+
+   --------------------------------------------------------- */
+
+float arrow_curved(vec2 texcoord,
+                   float body, float head,
+                   float linewidth, float antialias)
+{
+    float w = linewidth/2.0 + antialias;
+    vec2 start = -vec2(body/2.0, 0.0);
+    vec2 end   = +vec2(body/2.0, 0.0);
+    float height = 0.5;
+
+    vec2 p1 = end - head*vec2(+1.0,+height);
+    vec2 p2 = end - head*vec2(+1.0,-height);
+    vec2 p3 = end;
+
+    // Head : 3 circles
+    vec2 c1  = circle_from_2_points(p1, p3, 1.25*body).zw;
+    float d1 = length(texcoord - c1) - 1.25*body;
+    vec2 c2  = circle_from_2_points(p2, p3, 1.25*body).xy;
+    float d2 = length(texcoord - c2) - 1.25*body;
+    vec2 c3  = circle_from_2_points(p1, p2, max(body-head, 1.0*body)).xy;
+    float d3 = length(texcoord - c3) - max(body-head, 1.0*body);
+
+    // Body : 1 segment
+    float d4 = segment_distance(texcoord, start, end - vec2(linewidth,0.0));
+
+    // Outside (because of circles)
+    if( texcoord.y > +(2.0*head + antialias) )
+         return 1000.0;
+    if( texcoord.y < -(2.0*head + antialias) )
+         return 1000.0;
+    if( texcoord.x < -(body/2.0 + antialias) )
+         return 1000.0;
+    if( texcoord.x > c1.x ) //(body + antialias) )
+         return 1000.0;
+
+    return min( d4, -min(d3,min(d1,d2)));
+}

vispy/glsl/arrows/stealth.glsl

@@ -0,0 +1,50 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "arrows/util.glsl"
+
+
+/* ---------------------------------------------------------
+
+   Computes the signed distance to an stealth arrow
+
+   Parameters:
+   -----------
+
+   texcoord : Point to compute distance to
+   body :     Total length of the arrow (pixels, body+head)
+   head :     Length of the head (pixels)
+   height :   Height of the head (pixel)
+   linewidth: Stroke line width (in pixels)
+   antialias: Stroke antialiased area (in pixels)
+
+   Return:
+   -------
+   Signed distance to the arrow
+
+   --------------------------------------------------------- */
+
+float arrow_stealth(vec2 texcoord,
+                    float body, float head,
+                    float linewidth, float antialias)
+{
+    float w = linewidth/2.0 + antialias;
+    vec2 start = -vec2(body/2.0, 0.0);
+    vec2 end   = +vec2(body/2.0, 0.0);
+    float height = 0.5;
+
+    // Head : 4 lines
+    float d1 = line_distance(texcoord, end-head*vec2(+1.0,-height),
+                                       end);
+    float d2 = line_distance(texcoord, end-head*vec2(+1.0,-height),
+                                       end-vec2(3.0*head/4.0,0.0));
+    float d3 = line_distance(texcoord, end-head*vec2(+1.0,+height), end);
+    float d4 = line_distance(texcoord, end-head*vec2(+1.0,+0.5),
+                                       end-vec2(3.0*head/4.0,0.0));
+
+    // Body : 1 segment
+    float d5 = segment_distance(texcoord, start, end - vec2(linewidth,0.0));
+
+    return min(d5, max( max(-d1, d3), - max(-d2,d4)));
+}

vispy/glsl/arrows/triangle-30.glsl

@@ -0,0 +1,12 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "arrows/util.glsl"
+
+float arrow_triangle_30(vec2 texcoord,
+                        float body, float head,
+                        float linewidth, float antialias)
+{
+    return arrow_triangle(texcoord, body, head, 0.25, linewidth, antialias);
+}

vispy/glsl/arrows/triangle-60.glsl

@@ -0,0 +1,12 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "arrows/util.glsl"
+
+float arrow_triangle_60(vec2 texcoord,
+                        float body, float head,
+                        float linewidth, float antialias)
+{
+    return arrow_triangle(texcoord, body, head, 0.5, linewidth, antialias);
+}

vispy/glsl/arrows/triangle-90.glsl

@@ -0,0 +1,12 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "arrows/util.glsl"
+
+float arrow_triangle_90(vec2 texcoord,
+                        float body, float head,
+                        float linewidth, float antialias)
+{
+    return arrow_triangle(texcoord, body, head, 1.0, linewidth, antialias);
+}

vispy/glsl/arrows/util.glsl

@@ -0,0 +1,98 @@
+// ----------------------------------------------------------------------------
+// Copyright (c) 2014, Nicolas P. Rougier. All Rights Reserved.
+// Distributed under the (new) BSD License.
+// ----------------------------------------------------------------------------
+#include "math/signed-line-distance.glsl"
+#include "math/point-to-line-distance.glsl"
+#include "math/signed-segment-distance.glsl"
+#include "math/circle-through-2-points.glsl"
+#include "math/point-to-line-projection.glsl"
+
+
+/* ---------------------------------------------------------
+
+   Computes the signed distance to a triangle arrow
+
+   Parameters:
+   -----------
+
+   texcoord : Point to compute distance to
+   body :     Total length of the arrow (pixels, body+head)
+   head :     Length of the head (pixels)
+   height :   Height of the head (pixel)
+   linewidth: Stroke line width (in pixels)
+   antialias: Stroke antialiased area (in pixels)
+
+   Return:
+   -------
+   Signed distance to the arrow
+
+   --------------------------------------------------------- */
+
+float arrow_triangle(vec2 texcoord,
+                     float body, float head, float height,
+                     float linewidth, float antialias)
+{
+    float w = linewidth/2.0 + antialias;
+    vec2 start = -vec2(body/2.0, 0.0);
+    vec2 end   = +vec2(body/2.0, 0.0);
+
+    // Head : 3 lines
+    float d1 = line_distance(texcoord, end, end - head*vec2(+1.0,-height));
+    float d2 = line_distance(texcoord, end - head*vec2(+1.0,+height), end);
+    float d3 = texcoord.x - end.x + head;
+
+    // Body : 1 segment
+    float d4 = segment_distance(texcoord, start, end - vec2(linewidth,0.0));
+
+    float d = min(max(max(d1, d2), -d3), d4);
+    return d;
+}
+
+
+/* ---------------------------------------------------------
+
+   Computes the signed distance to an angle arrow
+
+   Parameters:
+   -----------
+
+   texcoord : Point to compute distance to
+   body :     Total length of the arrow (pixels, body+head)
+   head :     Length of the head (pixels)
+   height :   Height of the head (pixel)
+   linewidth: Stroke line width (in pixels)
+   antialias: Stroke antialiased area (in pixels)
+
+   Return:
+   -------
+   Signed distance to the arrow
+
+   --------------------------------------------------------- */
+float arrow_angle(vec2 texcoord,
+                  float body, float head, float height,
+                  float linewidth, float antialias)
+{
+    float d;
+    float w = linewidth/2.0 + antialias;
+    vec2 start = -vec2(body/2.0, 0.0);
+    vec2 end   = +vec2(body/2.0, 0.0);
+
+    // Arrow tip (beyond segment end)
+    if( texcoord.x > body/2.0) {
+        // Head : 2 segments
+        float d1 = line_distance(texcoord, end, end - head*vec2(+1.0,-height));
+        float d2 = line_distance(texcoord, end - head*vec2(+1.0,+height), end);
+        // Body : 1 segment
+        float d3 = end.x - texcoord.x;
+        d = max(max(d1,d2), d3);
+    } else {
+        // Head : 2 segments
+        float d1 = segment_distance(texcoord, end - head*vec2(+1.0,-height), end);
+        float d2 = segment_distance(texcoord, end - head*vec2(+1.0,+height), end);
+        // Body : 1 segment
+        float d3 = segment_distance(texcoord, start, end - vec2(linewidth,0.0));
+        d = min(min(d1,d2), d3);
+    }
+    return d;
+}