hyperverse 0.0.1__py3-none-any.whl

hyperdrone/_vendor/rl-tools/CMakeLists.txt

@@ -0,0 +1,205 @@
+#cmake_minimum_required(VERSION 3.14)
+#cmake_minimum_required(VERSION 3.18) # for BLAS::BLAS
+cmake_minimum_required(VERSION 3.19) # for HDF5::HDF5
+set(CMAKE_POLICY_VERSION_MINIMUM 3.5) # to prevent warnings about "Compatibility with CMake < 3.5 has been removed from CMake."
+
+project(rl_tools_core)
+
+set(CMAKE_CXX_STANDARD 17)
+
+# Everything auto-detects and auto-enables; the options below are opt-outs. Detection results
+# are reported in the configure summary at the end and exposed as plain (non-cache) variables
+# (RL_TOOLS_ENABLE_*, RL_TOOLS_BACKEND_ENABLE_*) plus compile definitions on rl_tools_full.
+option(RL_TOOLS_OFFLINE_BUILD "Use the dependencies in .dependencies without checking for updates (useful after nuking the build directory when offline)" OFF)
+option(RL_TOOLS_WARNINGS_AS_ERRORS "Treat warnings as errors" ON)
+option(RL_TOOLS_DISABLE_FAST_MATH "Disable -ffast-math (/fp:fast on MSVC)" OFF)
+
+option(RL_TOOLS_DISABLE_TARGETS "Disable building the main targets (src/)" OFF)
+option(RL_TOOLS_DISABLE_TESTS "Disable building the tests" OFF)
+option(RL_TOOLS_DISABLE_EXPERIMENTAL "Disable experimental targets" OFF)
+option(RL_TOOLS_DISABLE_TAR "Disable tar checkpoint targets/tests" OFF)
+option(RL_TOOLS_DISABLE_GIT_DIFF "Disable embedding git state into ExTrack runs" OFF)
+
+option(RL_TOOLS_DISABLE_JSON "Disable nlohmann_json" OFF)
+option(RL_TOOLS_DISABLE_HDF5 "Disable HDF5" OFF)
+option(RL_TOOLS_DISABLE_ZLIB "Disable zlib" OFF)
+option(RL_TOOLS_DISABLE_TENSORBOARD "Disable TensorBoard logging" OFF)
+option(RL_TOOLS_DISABLE_CLI11 "Disable CLI11" OFF)
+
+option(RL_TOOLS_BACKEND_DISABLE_BLAS "Disable all BLAS backends (naive fallback)" OFF)
+option(RL_TOOLS_BACKEND_DISABLE_MKL "Disable the MKL BLAS backend" OFF)
+option(RL_TOOLS_BACKEND_DISABLE_DNNL "Disable oneDNN (DNNL)" OFF)
+option(RL_TOOLS_BACKEND_DISABLE_CUDA "Disable CUDA" OFF)
+option(RL_TOOLS_BACKEND_DISABLE_CUDNN "Disable cuDNN" OFF)
+
+option(RL_TOOLS_NUMERIC_TYPES_DISABLE_BF16 "Disable bf16 numeric type support" OFF)
+option(RL_TOOLS_RL_ENVIRONMENTS_DISABLE_MUJOCO "Disable MuJoCo" OFF)
+option(RL_TOOLS_TESTS_DISABLE_EIGEN "Disable Eigen-based benchmark tests" OFF)
+
+option(RL_TOOLS_RENDERING_DISABLE_RAYTRACING "Disable raytracing" OFF)
+option(RL_TOOLS_RENDERING_RAYTRACING_DISABLE_OPTIX "Exclude OptiX from raytracing backend auto-selection" OFF)
+option(RL_TOOLS_RENDERING_RAYTRACING_DISABLE_METAL "Exclude Metal from raytracing backend auto-selection" OFF)
+option(RL_TOOLS_RENDERING_RAYTRACING_DISABLE_VULKAN "Exclude Vulkan from raytracing backend auto-selection" OFF)
+option(RL_TOOLS_RENDERING_RAYTRACING_DISABLE_WEBGPU "Exclude WebGPU from raytracing backend auto-selection" OFF)
+set(RL_TOOLS_RENDERING_RAYTRACING_BACKEND "AUTO" CACHE STRING "Raytracing backend (AUTO|OPTIX|METAL|VULKAN|WEBGPU|GENERIC); AUTO probes availability in preference order OPTIX > METAL > VULKAN > WEBGPU > GENERIC, an explicit backend is hard-required")
+set_property(CACHE RL_TOOLS_RENDERING_RAYTRACING_BACKEND PROPERTY STRINGS AUTO OPTIX METAL VULKAN WEBGPU GENERIC)
+
+include(cmake/legacy_flags.cmake)
+
+if(NOT CMAKE_BUILD_TYPE)
+    set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
+endif()
+
+add_library(rl_tools_core INTERFACE)
+add_library(RLtools::Core ALIAS rl_tools_core)
+target_compile_features(rl_tools_core INTERFACE cxx_std_17)
+target_include_directories(rl_tools_core INTERFACE ${CMAKE_CURRENT_SOURCE_DIR}/include)
+
+add_library(rl_tools_full INTERFACE)
+add_library(RLtools::RLtools ALIAS rl_tools_full)
+target_link_libraries(rl_tools_full INTERFACE rl_tools_core)
+
+# Compiler optimizations
+if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
+    if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")
+        target_compile_options(rl_tools_full INTERFACE -O3 -march=native)
+        if(NOT RL_TOOLS_DISABLE_FAST_MATH)
+            target_compile_options(rl_tools_full INTERFACE -ffast-math)
+        endif()
+    endif()
+    if(RL_TOOLS_WARNINGS_AS_ERRORS)
+        # Safe (just unused warnings)
+        target_compile_options(rl_tools_full INTERFACE $<$<COMPILE_LANGUAGE:CXX>:-Werror -Wall -Wextra>) # the $<$<COMPILE_LANGUAGE:CXX>: is required for NVCC to not complain about -Wall
+        target_compile_options(rl_tools_full INTERFACE $<$<COMPILE_LANGUAGE:CXX>:-Wno-unused-parameter -Wno-unused-local-typedefs -Wno-unused-variable -Wno-unused-but-set-variable>)
+        if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+            target_compile_options(rl_tools_full INTERFACE -Wno-unused-lambda-capture)
+        endif()
+
+        # todo (put exclusions here)
+        if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
+            include(CheckCXXCompilerFlag)
+            check_cxx_compiler_flag("-Wnan-infinity-disabled" HAS_NAN_INF_WARN)
+            if (HAS_NAN_INF_WARN)
+                target_compile_options(rl_tools_full INTERFACE $<$<COMPILE_LANGUAGE:CXX>:-Wno-error=nan-infinity-disabled>) # clang does not like some NaN handling in nlohmann_json when -ffast-math is on
+            endif()
+        endif()
+    endif()
+elseif(MSVC)
+    if(NOT CMAKE_BUILD_TYPE STREQUAL "Debug")
+        target_compile_options(rl_tools_full INTERFACE /O2)
+        if(NOT RL_TOOLS_DISABLE_FAST_MATH)
+            target_compile_options(rl_tools_full INTERFACE /fp:fast)
+        endif()
+    endif()
+    target_compile_options(rl_tools_full INTERFACE /bigobj)
+    target_compile_definitions(rl_tools_full INTERFACE _CRT_SECURE_NO_WARNINGS)
+    if(RL_TOOLS_WARNINGS_AS_ERRORS)
+        target_compile_options(rl_tools_full INTERFACE /W3 /WX)
+        target_compile_options(rl_tools_full INTERFACE
+            /wd4100  # unreferenced formal parameter
+            /wd4101  # unreferenced local variable
+            /wd4146  # unary minus on unsigned type
+            /wd4189  # local variable initialized but not referenced
+            /wd4244  # conversion, possible loss of data
+            /wd4267  # conversion from size_t, possible loss of data
+            /wd4459  # declaration hides global
+            /wd4996  # deprecated functions (getenv etc.)
+            /wd4068  # unknown pragma (e.g. #pragma GCC)
+            /wd4804  # unsafe use of type 'bool' in operation
+        )
+    endif()
+endif()
+
+
+# Configure FetchContent
+get_filename_component(CMAKE_BINARY_DIR_BASENAME ${CMAKE_BINARY_DIR} NAME)
+if(NOT DEFINED FETCHCONTENT_BASE_DIR)
+    set(_test_file "${CMAKE_CURRENT_SOURCE_DIR}/.cmake_write_test")
+    execute_process(
+        COMMAND ${CMAKE_COMMAND} -E touch "${_test_file}"
+        RESULT_VARIABLE _write_test_result
+        ERROR_QUIET
+        OUTPUT_QUIET
+    )
+    if(_write_test_result EQUAL 0)
+        file(REMOVE "${_test_file}")
+        set(_fetchcontent_base_dir_root "${CMAKE_CURRENT_SOURCE_DIR}")
+    else()
+        set(_fetchcontent_base_dir_root "${CMAKE_CURRENT_BINARY_DIR}")
+    endif()
+    set(FETCHCONTENT_BASE_DIR "${_fetchcontent_base_dir_root}/.dependencies/${CMAKE_BINARY_DIR_BASENAME}" CACHE PATH "Base dir for FetchContent downloads" FORCE)
+else()
+    set(FETCHCONTENT_BASE_DIR "${FETCHCONTENT_BASE_DIR}/${CMAKE_BINARY_DIR_BASENAME}" CACHE PATH "Base dir for FetchContent downloads")
+endif()
+if(RL_TOOLS_OFFLINE_BUILD)
+    set(FETCHCONTENT_FULLY_DISCONNECTED ON)
+endif()
+message(STATUS "RLtools dependencies: ${FETCHCONTENT_BASE_DIR}")
+include(FetchContent)
+
+# Suppress STATUS messages from FetchContent subprojects (arch details, feature
+# summaries, proto generation lists, …) while still forwarding WARNING/ERROR.
+# Requires CMake >= 3.25; silently ignored on older versions.
+macro(rl_tools_fetchcontent_makeavailable_quiet)
+    foreach(_rl_tools_fetch_name ${ARGN})
+        string(TOLOWER "${_rl_tools_fetch_name}" _rl_tools_fetch_name_lower)
+        string(TOUPPER "${_rl_tools_fetch_name}" _rl_tools_fetch_name_upper)
+        if(NOT EXISTS "${FETCHCONTENT_BASE_DIR}/${_rl_tools_fetch_name_lower}-src" AND NOT DEFINED FETCHCONTENT_SOURCE_DIR_${_rl_tools_fetch_name_upper})
+            message(STATUS "Fetching ${_rl_tools_fetch_name} (this can take a while)")
+        endif()
+    endforeach()
+    set(_rl_tools_prev_log_level ${CMAKE_MESSAGE_LOG_LEVEL})
+    set(CMAKE_MESSAGE_LOG_LEVEL ERROR)
+    # the cmake_minimum_required compatibility deprecation only respects the CACHE variable
+    if(DEFINED CACHE{CMAKE_WARN_DEPRECATED})
+        set(_rl_tools_prev_warn_deprecated "$CACHE{CMAKE_WARN_DEPRECATED}")
+    else()
+        unset(_rl_tools_prev_warn_deprecated)
+    endif()
+    set(CMAKE_WARN_DEPRECATED OFF CACHE BOOL "" FORCE)
+    FetchContent_MakeAvailable(${ARGN})
+    set(CMAKE_MESSAGE_LOG_LEVEL ${_rl_tools_prev_log_level})
+    if(DEFINED _rl_tools_prev_warn_deprecated)
+        set(CMAKE_WARN_DEPRECATED "${_rl_tools_prev_warn_deprecated}" CACHE BOOL "" FORCE)
+    else()
+        unset(CMAKE_WARN_DEPRECATED CACHE)
+    endif()
+endmacro()
+
+include(cmake/autodetect/all.cmake)
+
+include(cmake/optional/mujoco.cmake)
+include(cmake/optional/raytracing.cmake)
+
+if(NOT RL_TOOLS_DISABLE_TARGETS)
+    add_subdirectory(src)
+endif()
+
+if(NOT RL_TOOLS_DISABLE_TESTS)
+    if(RL_TOOLS_RENDERING_ENABLE_RAYTRACING AND RL_TOOLS_DISABLE_TARGETS)
+        message(FATAL_ERROR "The raytracing tests link targets from src/; combine RL_TOOLS_DISABLE_TARGETS=ON with RL_TOOLS_DISABLE_TESTS=ON or RL_TOOLS_RENDERING_DISABLE_RAYTRACING=ON")
+    endif()
+    include(cmake/optional/googletest.cmake)
+    if(RL_TOOLS_ENABLE_GTEST)
+        if(NOT RL_TOOLS_TESTS_DISABLE_EIGEN)
+            find_package(Eigen3 QUIET)
+            if(Eigen3_FOUND)
+                set(RL_TOOLS_TESTS_ENABLE_EIGEN ON)
+                set(RL_TOOLS_SUMMARY_EIGEN_REASON "system ${Eigen3_VERSION}")
+            else()
+                set(RL_TOOLS_SUMMARY_EIGEN_REASON "not found (e.g. apt install libeigen3-dev)")
+            endif()
+        endif()
+        if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/tests/data)
+            set(RL_TOOLS_TEST_DATA_PATH "${CMAKE_CURRENT_SOURCE_DIR}/tests/data" CACHE PATH "Path to test data")
+            target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_TEST_DATA_PATH=${RL_TOOLS_TEST_DATA_PATH})
+        endif()
+        include(CTest)
+        add_subdirectory(tests)
+        set(RL_TOOLS_ENABLE_TESTS ON)
+    else()
+        set(RL_TOOLS_SUMMARY_TESTS_REASON "googletest unavailable (not found and no git)")
+    endif()
+endif()
+
+include(cmake/autodetect/summary.cmake)

hyperdrone/_vendor/rl-tools/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2023 Jonas Eschmann
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

hyperdrone/_vendor/rl-tools/cmake/autodetect/all.cmake

@@ -0,0 +1,34 @@
+# tiers of optional dependencies
+# tier 0: compiler capabilities (bf16)
+# tier 1: backend (MKL, OpenBLAS, Accelerate)
+# tier 2: json, hdf5
+# tier 3: tensorboard
+# tier 4: cuda
+# tier 5: cli11
+
+# The RL_TOOLS_*_ENABLE_* variables are detection outputs (plain variables + compile
+# definitions on rl_tools_full), not inputs: forcing one from the command line used to skip
+# detection without adding the link libraries. Scrub and warn; the inputs are the
+# RL_TOOLS_*_DISABLE_* options.
+foreach(RL_TOOLS_DETECTION_OUTPUT
+        RL_TOOLS_BACKEND_ENABLE_MKL RL_TOOLS_BACKEND_ENABLE_BLAS RL_TOOLS_BACKEND_ENABLE_DNNL
+        RL_TOOLS_BACKEND_ENABLE_OPENBLAS RL_TOOLS_BACKEND_ENABLE_ACCELERATE
+        RL_TOOLS_BACKEND_ENABLE_CUDA RL_TOOLS_BACKEND_ENABLE_CUDNN
+        RL_TOOLS_ENABLE_JSON RL_TOOLS_ENABLE_HDF5 RL_TOOLS_ENABLE_ZLIB
+        RL_TOOLS_ENABLE_TENSORBOARD RL_TOOLS_ENABLE_CLI11 RL_TOOLS_ENABLE_GTEST)
+    if(DEFINED CACHE{${RL_TOOLS_DETECTION_OUTPUT}})
+        message(WARNING "${RL_TOOLS_DETECTION_OUTPUT} is a detection output, not an input - ignoring it (use the RL_TOOLS_*_DISABLE_* options to opt out)")
+        unset(${RL_TOOLS_DETECTION_OUTPUT} CACHE)
+    endif()
+endforeach()
+
+find_package(Git QUIET)
+
+include(cmake/autodetect/tier0-compiler.cmake)
+include(cmake/autodetect/tier1-blas.cmake)
+include(cmake/autodetect/tier2-json-hdf5-zlib.cmake)
+include(cmake/autodetect/tier3-tensorboard.cmake)
+include(cmake/autodetect/tier4-cuda.cmake)
+include(cmake/autodetect/tier5-cli11.cmake)
+include(cmake/autodetect/git-hash.cmake)
+include(cmake/autodetect/git-diff.cmake)

hyperdrone/_vendor/rl-tools/cmake/autodetect/git-diff.cmake

@@ -0,0 +1,100 @@
+# ==============================================================================
+# Git snapshot tracking for ExTrack
+# ==============================================================================
+
+if(RL_TOOLS_DISABLE_GIT_DIFF)
+    return()
+endif()
+
+if(NOT GIT_FOUND)
+    message(STATUS "Git not found - git snapshot tracking disabled")
+    return()
+endif()
+
+function(rl_tools_git_toplevel OUT_IS_REPO OUT_TOPLEVEL REPO_DIR)
+    execute_process(
+        COMMAND ${GIT_EXECUTABLE} rev-parse --show-toplevel
+        WORKING_DIRECTORY "${REPO_DIR}"
+        RESULT_VARIABLE GIT_TOPLEVEL_RESULT
+        OUTPUT_VARIABLE GIT_TOPLEVEL_OUTPUT
+        ERROR_QUIET
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    if(GIT_TOPLEVEL_RESULT EQUAL 0)
+        file(REAL_PATH "${GIT_TOPLEVEL_OUTPUT}" GIT_TOPLEVEL_NORMALIZED)
+        set(${OUT_IS_REPO} TRUE PARENT_SCOPE)
+        set(${OUT_TOPLEVEL} "${GIT_TOPLEVEL_NORMALIZED}" PARENT_SCOPE)
+    else()
+        set(${OUT_IS_REPO} FALSE PARENT_SCOPE)
+        set(${OUT_TOPLEVEL} "" PARENT_SCOPE)
+    endif()
+endfunction()
+
+file(REAL_PATH "${CMAKE_CURRENT_SOURCE_DIR}" RL_TOOLS_ROOT_DIR)
+file(REAL_PATH "${CMAKE_SOURCE_DIR}" CMAKE_SOURCE_DIR_NORMALIZED)
+
+if(NOT CMAKE_SOURCE_DIR_NORMALIZED STREQUAL RL_TOOLS_ROOT_DIR)
+    set(RL_TOOLS_PARENT_DIR "${CMAKE_SOURCE_DIR_NORMALIZED}")
+    set(RL_TOOLS_HAS_PARENT TRUE)
+else()
+    set(RL_TOOLS_PARENT_DIR "")
+    set(RL_TOOLS_HAS_PARENT FALSE)
+endif()
+
+rl_tools_git_toplevel(RL_TOOLS_IS_INSIDE_GIT_REPO RL_TOOLS_GIT_TOPLEVEL "${RL_TOOLS_ROOT_DIR}")
+if(RL_TOOLS_IS_INSIDE_GIT_REPO AND RL_TOOLS_GIT_TOPLEVEL STREQUAL RL_TOOLS_ROOT_DIR)
+    set(RL_TOOLS_IS_GIT_REPO TRUE)
+else()
+    set(RL_TOOLS_IS_GIT_REPO FALSE)
+endif()
+
+set(RL_TOOLS_PARENT_IS_GIT_REPO FALSE)
+if(RL_TOOLS_HAS_PARENT)
+    rl_tools_git_toplevel(RL_TOOLS_PARENT_IS_INSIDE_GIT_REPO RL_TOOLS_PARENT_GIT_TOPLEVEL "${RL_TOOLS_PARENT_DIR}")
+    if(RL_TOOLS_PARENT_IS_INSIDE_GIT_REPO AND RL_TOOLS_PARENT_GIT_TOPLEVEL STREQUAL RL_TOOLS_PARENT_DIR)
+        set(RL_TOOLS_PARENT_IS_GIT_REPO TRUE)
+    endif()
+endif()
+
+if(NOT RL_TOOLS_IS_GIT_REPO AND NOT RL_TOOLS_PARENT_IS_GIT_REPO)
+    message(STATUS "No git repositories detected - git snapshot tracking disabled")
+    return()
+endif()
+
+message(VERBOSE "Git snapshot tracking enabled:")
+message(VERBOSE "  Library: ${RL_TOOLS_ROOT_DIR} [git: ${RL_TOOLS_IS_GIT_REPO}]")
+if(RL_TOOLS_HAS_PARENT)
+    message(VERBOSE "  Project: ${RL_TOOLS_PARENT_DIR} [git: ${RL_TOOLS_PARENT_IS_GIT_REPO}]")
+endif()
+
+set(GIT_SNAPSHOT_OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/rl_tools/extrack/git_snapshot.cpp")
+set(GIT_SNAPSHOT_GENERATOR "${CMAKE_CURRENT_SOURCE_DIR}/cmake/scripts/generate-git-snapshot.cmake")
+
+set(GIT_SNAPSHOT_PARENT_ARGS "")
+if(RL_TOOLS_HAS_PARENT)
+    set(GIT_SNAPSHOT_PARENT_ARGS -DPARENT_ROOT=${RL_TOOLS_PARENT_DIR})
+endif()
+
+add_custom_target(rl_tools_git_snapshot_update
+    COMMAND ${CMAKE_COMMAND}
+        -DGIT_EXECUTABLE=${GIT_EXECUTABLE}
+        -DOUTPUT_FILE=${GIT_SNAPSHOT_OUTPUT}
+        -DRL_TOOLS_ROOT=${RL_TOOLS_ROOT_DIR}
+        -DRL_TOOLS_IS_REPO=${RL_TOOLS_IS_GIT_REPO}
+        -DPARENT_IS_REPO=${RL_TOOLS_PARENT_IS_GIT_REPO}
+        ${GIT_SNAPSHOT_PARENT_ARGS}
+        -P "${GIT_SNAPSHOT_GENERATOR}"
+    BYPRODUCTS ${GIT_SNAPSHOT_OUTPUT}
+    COMMENT "Updating git snapshot for ExTrack"
+    VERBATIM
+)
+
+set_source_files_properties(${GIT_SNAPSHOT_OUTPUT} PROPERTIES GENERATED TRUE)
+add_library(rl_tools_git_snapshot STATIC ${GIT_SNAPSHOT_OUTPUT})
+add_dependencies(rl_tools_git_snapshot rl_tools_git_snapshot_update)
+target_compile_features(rl_tools_git_snapshot PRIVATE cxx_std_11)
+target_compile_definitions(rl_tools_git_snapshot PUBLIC RL_TOOLS_EXTRACK_GIT_DIFF)
+
+if(TARGET rl_tools_full)
+    target_link_libraries(rl_tools_full INTERFACE rl_tools_git_snapshot)
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/git-hash.cmake

@@ -0,0 +1,24 @@
+find_package(Git QUIET)
+if(GIT_FOUND)
+    execute_process(
+            COMMAND ${GIT_EXECUTABLE} rev-parse HEAD
+            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+            OUTPUT_VARIABLE RL_TOOLS_COMMIT_HASH
+            OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    message(VERBOSE "Commit hash: ${RL_TOOLS_COMMIT_HASH}")
+    execute_process(
+            COMMAND ${GIT_EXECUTABLE} show -s --format=%ct HEAD
+            WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
+            OUTPUT_VARIABLE RL_TOOLS_COMMIT_TIME
+            OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    message(VERBOSE "Commit time: ${RL_TOOLS_COMMIT_TIME}")
+endif()
+if(RL_TOOLS_COMMIT_HASH)
+    target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_COMMIT_HASH_EXTERNAL=${RL_TOOLS_COMMIT_HASH})
+    target_compile_definitions(rl_tools_full INTERFACE METRA_COMMIT=${RL_TOOLS_COMMIT_HASH})
+endif()
+if(RL_TOOLS_COMMIT_TIME)
+    target_compile_definitions(rl_tools_full INTERFACE METRA_COMMIT_TIME=${RL_TOOLS_COMMIT_TIME})
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/summary.cmake

@@ -0,0 +1,64 @@
+function(rl_tools_summary_line LABEL STATE REASON)
+    string(LENGTH "${LABEL}" RL_TOOLS_SUMMARY_LABEL_LENGTH)
+    math(EXPR RL_TOOLS_SUMMARY_PADDING_LENGTH "13 - ${RL_TOOLS_SUMMARY_LABEL_LENGTH}")
+    if(RL_TOOLS_SUMMARY_PADDING_LENGTH LESS 1)
+        set(RL_TOOLS_SUMMARY_PADDING_LENGTH 1)
+    endif()
+    string(REPEAT " " ${RL_TOOLS_SUMMARY_PADDING_LENGTH} RL_TOOLS_SUMMARY_PADDING)
+    if(STATE)
+        set(RL_TOOLS_SUMMARY_STATE "ON ")
+    else()
+        set(RL_TOOLS_SUMMARY_STATE "OFF")
+    endif()
+    if(REASON STREQUAL "")
+        message(STATUS "  ${LABEL}${RL_TOOLS_SUMMARY_PADDING}${RL_TOOLS_SUMMARY_STATE}")
+    else()
+        message(STATUS "  ${LABEL}${RL_TOOLS_SUMMARY_PADDING}${RL_TOOLS_SUMMARY_STATE}  ${REASON}")
+    endif()
+endfunction()
+
+function(rl_tools_summary_feature LABEL OUTPUT_VARIABLE REASON_VARIABLE DISABLE_VARIABLE)
+    set(RL_TOOLS_SUMMARY_REASON "${${REASON_VARIABLE}}")
+    if(${DISABLE_VARIABLE})
+        set(RL_TOOLS_SUMMARY_REASON "disabled by ${DISABLE_VARIABLE}")
+    endif()
+    rl_tools_summary_line("${LABEL}" "${${OUTPUT_VARIABLE}}" "${RL_TOOLS_SUMMARY_REASON}")
+endfunction()
+
+message(STATUS "RLtools configure summary:")
+rl_tools_summary_feature("BLAS" RL_TOOLS_BACKEND_ENABLE_BLAS RL_TOOLS_SUMMARY_BLAS_REASON RL_TOOLS_BACKEND_DISABLE_BLAS)
+if(RL_TOOLS_BACKEND_ENABLE_MKL)
+    rl_tools_summary_feature("DNNL" RL_TOOLS_BACKEND_ENABLE_DNNL RL_TOOLS_SUMMARY_DNNL_REASON RL_TOOLS_BACKEND_DISABLE_DNNL)
+endif()
+rl_tools_summary_feature("CUDA" RL_TOOLS_BACKEND_ENABLE_CUDA RL_TOOLS_SUMMARY_CUDA_REASON RL_TOOLS_BACKEND_DISABLE_CUDA)
+if(RL_TOOLS_BACKEND_ENABLE_CUDA)
+    rl_tools_summary_feature("cuDNN" RL_TOOLS_BACKEND_ENABLE_CUDNN RL_TOOLS_SUMMARY_CUDNN_REASON RL_TOOLS_BACKEND_DISABLE_CUDNN)
+endif()
+rl_tools_summary_feature("JSON" RL_TOOLS_ENABLE_JSON RL_TOOLS_SUMMARY_JSON_REASON RL_TOOLS_DISABLE_JSON)
+rl_tools_summary_feature("HDF5" RL_TOOLS_ENABLE_HDF5 RL_TOOLS_SUMMARY_HDF5_REASON RL_TOOLS_DISABLE_HDF5)
+rl_tools_summary_feature("ZLIB" RL_TOOLS_ENABLE_ZLIB RL_TOOLS_SUMMARY_ZLIB_REASON RL_TOOLS_DISABLE_ZLIB)
+rl_tools_summary_feature("TensorBoard" RL_TOOLS_ENABLE_TENSORBOARD RL_TOOLS_SUMMARY_TENSORBOARD_REASON RL_TOOLS_DISABLE_TENSORBOARD)
+rl_tools_summary_feature("CLI11" RL_TOOLS_ENABLE_CLI11 RL_TOOLS_SUMMARY_CLI11_REASON RL_TOOLS_DISABLE_CLI11)
+rl_tools_summary_feature("bf16" RL_TOOLS_NUMERIC_TYPES_ENABLE_BF16 RL_TOOLS_SUMMARY_BF16_REASON RL_TOOLS_NUMERIC_TYPES_DISABLE_BF16)
+rl_tools_summary_feature("MuJoCo" RL_TOOLS_RL_ENVIRONMENTS_ENABLE_MUJOCO RL_TOOLS_SUMMARY_MUJOCO_REASON RL_TOOLS_RL_ENVIRONMENTS_DISABLE_MUJOCO)
+rl_tools_summary_feature("Raytracing" RL_TOOLS_RENDERING_ENABLE_RAYTRACING RL_TOOLS_SUMMARY_RAYTRACING_REASON RL_TOOLS_RENDERING_DISABLE_RAYTRACING)
+
+if(RL_TOOLS_DISABLE_TARGETS)
+    rl_tools_summary_line("Targets" OFF "disabled by RL_TOOLS_DISABLE_TARGETS")
+else()
+    rl_tools_summary_line("Targets" ON "")
+endif()
+rl_tools_summary_feature("Tests" RL_TOOLS_ENABLE_TESTS RL_TOOLS_SUMMARY_TESTS_REASON RL_TOOLS_DISABLE_TESTS)
+if(RL_TOOLS_ENABLE_TESTS)
+    rl_tools_summary_feature("Eigen" RL_TOOLS_TESTS_ENABLE_EIGEN RL_TOOLS_SUMMARY_EIGEN_REASON RL_TOOLS_TESTS_DISABLE_EIGEN)
+endif()
+if(RL_TOOLS_DISABLE_EXPERIMENTAL)
+    rl_tools_summary_line("Experimental" OFF "disabled by RL_TOOLS_DISABLE_EXPERIMENTAL")
+else()
+    rl_tools_summary_line("Experimental" ON "")
+endif()
+if(RL_TOOLS_DISABLE_TAR)
+    rl_tools_summary_line("Tar" OFF "disabled by RL_TOOLS_DISABLE_TAR")
+else()
+    rl_tools_summary_line("Tar" ON "")
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/tier0-compiler.cmake

@@ -0,0 +1,18 @@
+if(NOT RL_TOOLS_NUMERIC_TYPES_DISABLE_BF16)
+    include(CheckCXXSourceCompiles)
+    check_cxx_source_compiles("
+        int main(){
+            __bf16 value = static_cast<__bf16>(1.0f);
+            static_assert(sizeof(__bf16) == 2, \"bf16 size\");
+            return static_cast<int>(static_cast<float>(value));
+        }
+    " RL_TOOLS_BF16_SUPPORTED)
+    if(RL_TOOLS_BF16_SUPPORTED)
+        # CXX-only: .cu device compiles use __nv_bfloat16 through the type policy instead
+        target_compile_definitions(rl_tools_full INTERFACE $<$<COMPILE_LANGUAGE:CXX>:RL_TOOLS_NUMERIC_TYPES_ENABLE_BF16>)
+        set(RL_TOOLS_NUMERIC_TYPES_ENABLE_BF16 ON)
+        set(RL_TOOLS_SUMMARY_BF16_REASON "__bf16 supported by ${CMAKE_CXX_COMPILER_ID}")
+    else()
+        set(RL_TOOLS_SUMMARY_BF16_REASON "compiler does not support __bf16")
+    endif()
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/tier1-blas.cmake

@@ -0,0 +1,51 @@
+if(NOT RL_TOOLS_BACKEND_DISABLE_BLAS)
+    if(NOT RL_TOOLS_BACKEND_DISABLE_MKL)
+        if(NOT MKL_ROOT)
+            if(DEFINED ENV{MKL_ROOT})
+                set(MKL_ROOT $ENV{MKL_ROOT})
+            else()
+                set(MKL_ROOT /opt/intel/oneapi/mkl/latest)
+            endif()
+        endif()
+        find_package(MKL QUIET)
+    endif()
+    if(MKL_FOUND)
+        target_link_libraries(rl_tools_full INTERFACE MKL::MKL)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_MKL)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_BLAS)
+        set(RL_TOOLS_BACKEND_ENABLE_MKL ON)
+        set(RL_TOOLS_BACKEND_ENABLE_BLAS ON)
+        set(RL_TOOLS_SUMMARY_BLAS_REASON "MKL ${MKL_VERSION} (${MKL_ROOT})")
+        if(NOT RL_TOOLS_BACKEND_DISABLE_DNNL)
+            find_package(dnnl QUIET)
+            if(dnnl_FOUND)
+                target_link_libraries(rl_tools_full INTERFACE DNNL::dnnl)
+                target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_DNNL)
+                set(RL_TOOLS_BACKEND_ENABLE_DNNL ON)
+            else()
+                set(RL_TOOLS_SUMMARY_DNNL_REASON "not found")
+            endif()
+        endif()
+    else()
+        find_package(BLAS QUIET)
+        if(BLAS_FOUND)
+            message(VERBOSE "Found BLAS library ${BLAS_VENDOR} at ${BLAS_LIBRARIES}")
+            target_link_libraries(rl_tools_full INTERFACE BLAS::BLAS)
+            if(NOT APPLE)
+                target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_OPENBLAS)
+                target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_BLAS)
+                set(RL_TOOLS_BACKEND_ENABLE_OPENBLAS ON)
+                set(RL_TOOLS_BACKEND_ENABLE_BLAS ON)
+                set(RL_TOOLS_SUMMARY_BLAS_REASON "OpenBLAS")
+            else()
+                target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_ACCELERATE)
+                target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_BACKEND_ENABLE_BLAS)
+                set(RL_TOOLS_BACKEND_ENABLE_ACCELERATE ON)
+                set(RL_TOOLS_BACKEND_ENABLE_BLAS ON)
+                set(RL_TOOLS_SUMMARY_BLAS_REASON "Accelerate")
+            endif()
+        else()
+            set(RL_TOOLS_SUMMARY_BLAS_REASON "not found, naive fallback (e.g. apt install libopenblas-dev)")
+        endif()
+    endif()
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/tier2-json-hdf5-zlib.cmake

@@ -0,0 +1,81 @@
+if(NOT RL_TOOLS_DISABLE_JSON)
+    find_package(nlohmann_json QUIET)
+    if(nlohmann_json_FOUND)
+        get_target_property(nlohmann_json_INCLUDE_DIRS nlohmann_json::nlohmann_json INCLUDE_DIRECTORIES)
+        message(VERBOSE "Found existing/system nlohmann_json ${nlohmann_json_VERSION} at ${nlohmann_json_DIR}")
+        target_link_libraries(rl_tools_full INTERFACE nlohmann_json::nlohmann_json)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_JSON)
+        set(RL_TOOLS_ENABLE_JSON ON)
+        set(RL_TOOLS_SUMMARY_JSON_REASON "system ${nlohmann_json_VERSION}")
+    else()
+        if(POLICY CMP0135)
+            cmake_policy(SET CMP0135 NEW)
+        endif()
+        FetchContent_Declare(nlohmann_json
+                URL https://github.com/nlohmann/json/releases/download/v3.11.3/json.tar.xz
+                URL_HASH SHA256=d6c65aca6b1ed68e7a182f4757257b107ae403032760ed6ef121c9d55e81757d
+        )
+        rl_tools_fetchcontent_makeavailable_quiet(nlohmann_json)
+        target_include_directories(rl_tools_full INTERFACE ${nlohmann_json_SOURCE_DIR}/include)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_JSON)
+        set(RL_TOOLS_ENABLE_JSON ON)
+        set(RL_TOOLS_SUMMARY_JSON_REASON "FetchContent 3.11.3")
+    endif()
+endif()
+
+if(NOT RL_TOOLS_DISABLE_HDF5)
+    find_package(HDF5 QUIET)
+    if(HDF5_FOUND)
+        message(VERBOSE "Found existing/system HDF5 ${HDF5_VERSION} at ${HDF5_INCLUDE_DIRS}")
+        target_link_libraries(rl_tools_full INTERFACE HDF5::HDF5)
+        target_include_directories(rl_tools_full INTERFACE ${HDF5_INCLUDE_DIRS})
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_HDF5)
+        set(RL_TOOLS_ENABLE_HDF5 ON)
+        set(RL_TOOLS_SUMMARY_HDF5_REASON "system ${HDF5_VERSION}")
+    else()
+        set(RL_TOOLS_SUMMARY_HDF5_REASON "not found (e.g. apt install libhdf5-dev)")
+    endif()
+endif()
+
+
+if(NOT RL_TOOLS_DISABLE_ZLIB)
+    find_package(ZLIB QUIET)
+    if(ZLIB_FOUND)
+        message(VERBOSE "Found existing/system ZLIB ${ZLIB_VERSION} at ${ZLIB_INCLUDE_DIRS}")
+        target_link_libraries(rl_tools_full INTERFACE ZLIB::ZLIB)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_ZLIB)
+        set(RL_TOOLS_ENABLE_ZLIB ON)
+        set(RL_TOOLS_SUMMARY_ZLIB_REASON "system ${ZLIB_VERSION}")
+    elseif(GIT_FOUND)
+        set(ZLIB_BUILD_EXAMPLES OFF)
+        set(ZLIB_ENABLE_TESTS OFF)
+        set(ZLIB_COMPAT ON)
+        FetchContent_Declare(zlib
+                GIT_REPOSITORY https://github.com/zlib-ng/zlib-ng.git
+                GIT_TAG        2.2.3
+                GIT_SHALLOW    TRUE
+        )
+        rl_tools_fetchcontent_makeavailable_quiet(zlib)
+
+        # zlib-ng can expose different target names depending on options/platform.
+        # Resolve to an existing CMake target to avoid falling back to a raw -l flag.
+        if(TARGET zlibstatic)
+            set(RL_TOOLS_ZLIB_TARGET zlibstatic)
+        elseif(TARGET zlib)
+            set(RL_TOOLS_ZLIB_TARGET zlib)
+        elseif(TARGET zlib-ng)
+            set(RL_TOOLS_ZLIB_TARGET zlib-ng)
+        elseif(TARGET ZLIB::ZLIB)
+            set(RL_TOOLS_ZLIB_TARGET ZLIB::ZLIB)
+        else()
+            message(FATAL_ERROR "zlib FetchContent completed, but no expected zlib target exists (tried: zlibstatic, zlib, zlib-ng, ZLIB::ZLIB).")
+        endif()
+        message(VERBOSE "Using zlib target: ${RL_TOOLS_ZLIB_TARGET}")
+        target_link_libraries(rl_tools_full INTERFACE ${RL_TOOLS_ZLIB_TARGET})
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_ZLIB)
+        set(RL_TOOLS_ENABLE_ZLIB ON)
+        set(RL_TOOLS_SUMMARY_ZLIB_REASON "FetchContent zlib-ng")
+    else()
+        set(RL_TOOLS_SUMMARY_ZLIB_REASON "not found and no git")
+    endif()
+endif()

hyperdrone/_vendor/rl-tools/cmake/autodetect/tier3-tensorboard.cmake

@@ -0,0 +1,25 @@
+if(NOT RL_TOOLS_DISABLE_TENSORBOARD)
+    find_package(Protobuf CONFIG QUIET)
+    if(NOT Protobuf_FOUND)
+        find_package(Protobuf QUIET)
+        set(RL_TOOLS_PROTOBUF_NO_CONFIG_PACKAGE ON)
+    endif()
+    if(Protobuf_FOUND AND GIT_FOUND)
+        FetchContent_Declare(tensorboard
+                GIT_REPOSITORY https://github.com/rl-tools/tensorboard_logger.git
+                GIT_TAG   6405cc19eae874ed51ac876f4ab530205f1c0147
+        )
+        set(_RL_TOOLS_SAVED_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
+        set(BUILD_SHARED_LIBS OFF)
+        rl_tools_fetchcontent_makeavailable_quiet(tensorboard)
+        set(BUILD_SHARED_LIBS ${_RL_TOOLS_SAVED_BUILD_SHARED_LIBS})
+        target_link_libraries(rl_tools_full INTERFACE tensorboard_logger)
+        target_compile_definitions(rl_tools_full INTERFACE RL_TOOLS_ENABLE_TENSORBOARD)
+        set(RL_TOOLS_ENABLE_TENSORBOARD ON)
+        set(RL_TOOLS_SUMMARY_TENSORBOARD_REASON "FetchContent, system protobuf ${Protobuf_VERSION}")
+    elseif(NOT Protobuf_FOUND)
+        set(RL_TOOLS_SUMMARY_TENSORBOARD_REASON "protobuf not found (e.g. apt install protobuf-compiler libprotobuf-dev)")
+    else()
+        set(RL_TOOLS_SUMMARY_TENSORBOARD_REASON "no git")
+    endif()
+endif()