RinUI 0.0.9__py3-none-any.whl

RinUI/components/Navigation/NavigationSubItem.qml

@@ -0,0 +1,103 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import "../../themes"
+import "../../components"
+
+
+ItemDelegate {
+    id: root
+    property var itemData
+    property int parentIndex: -1
+    property var currentPage
+    highlighted: String(navigationBar.currentPage) === String(itemData.page)
+
+    height: 40
+
+    focusPolicy: collapsed ? Qt.NoFocus : Qt.StrongFocus  // to get keyboard focus
+
+    // accessibility
+    FocusIndicator {
+        control: parent
+        anchors.margins: 2
+    }
+
+    width: parent ? parent.width : 200
+
+    background: Rectangle {
+        id: itemBg
+        anchors.fill: parent
+        anchors.topMargin: 2
+        anchors.bottomMargin: 2
+        clip: true
+        radius: Theme.currentTheme.appearance.buttonRadius / 2
+        color: pressed
+            ? Theme.currentTheme.colors.subtleTertiaryColor
+            : (root.highlighted || root.hovered)
+                ? Theme.currentTheme.colors.subtleSecondaryColor
+                : Theme.currentTheme.colors.subtleColor
+
+        Row {
+            id: left
+            spacing: 16
+            anchors.left: parent.left
+            anchors.verticalCenter: parent.verticalCenter
+            anchors.leftMargin: 11 + 34
+            anchors.topMargin: 6
+            anchors.bottomMargin: 8
+
+            IconWidget {
+                id: icon
+                anchors.verticalCenter: parent.verticalCenter
+                size: itemData.icon || itemData.source ? 19 : 0
+                icon: itemData.icon || ""
+                source: itemData.source || ""
+            }
+
+            Text {
+                id: text
+                anchors.verticalCenter: parent.verticalCenter
+                typography: Typography.Body
+                text: itemData.title
+                clip: true
+                opacity: navigationBar.collapsed ? 0 : 1
+                wrapMode: Text.NoWrap
+                horizontalAlignment: Text.AlignLeft
+
+                Behavior on x {
+                    NumberAnimation {
+                        duration: Utils.appearanceSpeed
+                        easing.type: Easing.InOutQuint
+                    }
+                }
+
+                Behavior on opacity {
+                    NumberAnimation {
+                        duration: Utils.appearanceSpeed
+                    }
+                }
+            }
+        }
+
+        Indicator {
+            id: indicator
+            y: root.height / 2 - indicator.height / 2 -2
+            currentItemHeight: root.height
+            visible: highlighted ? 1 : 0
+            width: 3
+        }
+
+        Behavior on color {
+            ColorAnimation {
+                duration: Utils.appearanceSpeed
+                easing.type: Easing.InOutQuart
+            }
+        }
+    }
+
+    onClicked: {
+        if (itemData.page && currentPage && !root.highlighted && !collapsed) {
+            // 记录上一次的索引
+            navigationView.safePush(itemData.page)
+        }
+    }
+}

RinUI/components/Navigation/NavigationView.qml

@@ -0,0 +1,210 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import "../../themes"
+import "../../components"
+import "../../windows"
+
+
+RowLayout {
+    // 外观 / Appearance //
+    property bool appLayerEnabled: true  // 应用层背景
+    property alias navExpandWidth: navigationBar.expandWidth  // 导航栏宽度
+    property alias navMinimumExpandWidth: navigationBar.minimumExpandWidth  // 导航栏保持展开时窗口的最小宽度
+
+    property alias navigationItems: navigationBar.navigationItems  // 导航栏item
+    property string defaultPage: ""  // 默认索引项
+    property var lastPages: []  // 上个页面索引
+    property int pushEnterFromY: height
+    property var window: parent  // 窗口对象
+
+    id: navigationView
+    anchors.fill: parent
+
+    Connections {
+        target: window
+        function onWidthChanged() {
+            navigationBar.collapsed = navigationBar.isNotOverMinimumWidth()  // 判断窗口是否小于最小宽度
+        }
+    }
+
+    NavigationBar {
+        id: navigationBar
+        windowTitle: window.title
+        windowIcon: window.icon
+        windowWidth: window.width
+        stackView: stackView
+        z: 999
+        Layout.fillHeight: true
+    }
+
+    // 主体内容区域
+    Item {
+        Layout.fillWidth: true
+        Layout.fillHeight: true
+        // clip: true
+
+        Rectangle {
+            id: appLayer
+            width: parent.width + Utils.windowDragArea + radius
+            height: parent.height + Utils.windowDragArea + radius
+            color: Theme.currentTheme.colors.layerColor
+            border.color: Theme.currentTheme.colors.cardBorderColor
+            border.width: 1
+            opacity: window.appLayerEnabled
+            radius: Theme.currentTheme.appearance.windowRadius
+        }
+
+
+        StackView {
+            id: stackView
+            anchors.fill: parent
+            anchors.leftMargin: 1
+            anchors.topMargin: 1
+
+
+            // 切换动画 / Page Transition //
+            pushEnter : Transition {
+                PropertyAnimation {
+                    property: "opacity"
+                    from: 0
+                    to: 1
+                    duration: Utils.animationSpeed
+                    easing.type: Easing.InOutQuad
+                }
+
+                PropertyAnimation {
+                    property: "y"
+                    from: pushEnterFromY
+                    to: 0
+                    duration: Utils.animationSpeedMiddle
+                    easing.type: Easing.OutQuint
+                }
+            }
+
+            pushExit : Transition {
+                PropertyAnimation {
+                    property: "opacity"
+                    from: 1
+                    to: 0
+                    duration: Utils.animationSpeed
+                    easing.type: Easing.InOutQuad
+                }
+            }
+
+            popExit : Transition {
+                PropertyAnimation {
+                    property: "opacity"
+                    from: 1
+                    to: 0
+                    duration: Utils.animationSpeed
+                    easing.type: Easing.InOutQuad
+                }
+
+                PropertyAnimation {
+                    property: "y"
+                    from: 0
+                    to: pushEnterFromY
+                    duration: Utils.animationSpeedMiddle
+                    easing.type: Easing.InOutQuint
+                }
+            }
+
+            popEnter : Transition {
+                SequentialAnimation {
+                    PauseAnimation {  // 延时 200ms
+                        duration: Utils.animationSpeed
+                    }
+                    PropertyAnimation {
+                        property: "opacity"
+                        from: 0
+                        to: 1
+                        duration: Utils.appearanceSpeed
+                        easing.type: Easing.InOutQuad
+                    }
+                }
+            }
+
+            initialItem: Item {}
+
+        }
+
+        // 导航切换逻辑
+        // Connections {
+        //     target: navigationBar
+        //     function onCurrentIndexChanged() {
+        //         let index = navigationBar.currentIndex
+        //         let page = navigationItems[index].page
+        //         console.log("Pushing Page:", page, "Index:", index)
+        //         if (stackView.depth === 0 || stackView.currentItem.objectName !== page) {
+        //             checkPage(page)
+        //         }
+        //     }
+        // }
+
+
+        Component.onCompleted: {
+            if (navigationItems.length > 0) {
+                if (defaultPage !== "") {
+                    safePush(defaultPage, false)
+                } else {
+                    safePush(navigationItems[0].page, false)  // 推送默认页面
+                }  // 推送页面
+            }
+        }
+    }
+
+    function safePop() {
+        console.log("Popping Page; Depth:", stackView.depth)
+        if (navigationBar.lastPages.length > 1) {
+            navigationBar.currentPage = navigationBar.lastPages.pop()  // Retrieve and remove the last page
+            navigationBar.lastPages = navigationBar.lastPages  // refresh
+            stackView.pop()
+        } else {
+            console.log("Can't pop: only root page left")
+        }
+    }
+
+    function safePush(page, reload) {
+        // 无效检测
+        if (!(typeof page === "object" || typeof page === "string" || page instanceof Component)) {
+            console.error("Invalid page:", page)
+            return
+        }
+
+        // 重复检测
+        if (navigationBar.currentPage === page && !reload) {
+            console.log("Page already loaded:", page)
+            return
+        }
+
+        navigationBar.lastPages.push(navigationBar.currentPage)  // 记录当前页面
+        navigationBar.lastPages = navigationBar.lastPages  // refresh
+        navigationBar.currentPage = page.toString()
+
+        if (page instanceof Component) {
+            // let obj = page.createObject(stackView)
+            stackView.push(page)
+
+        } else if (typeof page === "object" || typeof page === "string" ) {
+            let component = Qt.createComponent(page)  // 页面转控件
+
+            if (component.status === Component.Ready) {
+                console.log("Depth:", stackView.depth)
+                stackView.push(component)
+
+            } else if (component.status === Component.Error) {
+                console.error("Failed to load:", page, component.errorString())
+                stackView.push("ErrorPage.qml", {
+                    errorMessage: component.errorString(),  // 传参
+                    page: page,
+                })
+            }
+        }
+    }
+
+    function findPageByKey(key) {
+        const item = menuItems.find(i => i.key === key);
+        return item ? item.page : null;
+    }
+}

RinUI/components/Navigation/SelectorBar.qml

@@ -0,0 +1,58 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import "../../components"
+import "../../themes"
+
+
+RowLayout {
+    id: root
+    property var model: []
+    property int currentIndex: -1
+    property bool enabled: true
+    // 自动检测模型类型
+    readonly property string modelType: {
+        if (!model) return "null";
+        if (Array.isArray(model) && typeof model[0] === "object") return "array-with-role";
+        if (Array.isArray(model)) return "array";
+        if (model instanceof ListModel) return "listmodel";
+        if (typeof model === "object" && "count" in model) return "listmodel-like";
+        return "unknown";
+    }
+
+    implicitHeight: 40
+    spacing: 0
+
+    Repeater {
+        model: root.model
+        delegate: Button {
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+            Layout.preferredHeight: 40
+            flat: true
+
+            background: Item {}
+
+            text: {
+                switch (root.modelType) {
+                    case "array": return modelData;
+                    case "array-with-role": return modelData["text"] || modelData || "";
+                    case "listmodel":
+                    case "listmodel-like":
+                        return model["text"] || modelData || "";
+                    default: return "";
+                }
+            }
+            icon.name: root.modelType === "array-with-role" ? modelData["icon"] : ""
+            icon.source: root.modelType === "array-with-role" ? modelData["source"] : ""
+
+            onClicked: root.currentIndex = index
+            enabled: root.enabled
+
+            Indicator {
+                orientation: Qt.Horizontal
+                visible: index === root.currentIndex
+            }
+        }
+    }
+}

RinUI/components/ScrollBar.qml

@@ -0,0 +1,163 @@
+import QtQuick 2.15
+import QtQuick.Templates 2.15  // 从Templates导入ScrollBar，否则qt6强制用原生样式……byd我看了大半天
+import "../themes"
+import "../components"
+
+ScrollBar {
+    id: scrollBar
+
+    property int minimumWidth: Theme.currentTheme.appearance.scrollBarMinWidth
+    property int expandWidth: Theme.currentTheme.appearance.scrollBarWidth
+
+    // 宽高
+    implicitWidth: horizontal ? parent.width
+        : (implicitContentWidth + leftPadding + rightPadding)
+    implicitHeight: vertical ? parent.height
+        : (implicitContentHeight + topPadding + bottomPadding)
+
+    // 锚点 //
+    anchors.verticalCenter: vertical ? parent.verticalCenter : undefined
+    anchors.horizontalCenter: horizontal ? parent.horizontalCenter : undefined
+    anchors.right: vertical ? parent.right : undefined
+    anchors.bottom: horizontal ? parent.bottom : undefined
+
+    verticalPadding : vertical ? 15 : 3
+    horizontalPadding : horizontal ? 15 : 3
+    enabled: size < 1.0
+
+
+    // 内容 / Content //
+    contentItem: Item {
+        id: item
+        // collapsed / 收缩状态 //
+        property bool collapsed: (
+            scrollBar.policy === ScrollBar.AlwaysOn || (scrollBar.active)
+        )  // 当滚动条处于AlwaysOn状态或处于激活状态且尺寸小于1.0时，则为收缩状态
+
+        // 最小尺寸 / Minimum Size //
+        implicitWidth: scrollBar.interactive ? scrollBar.expandWidth : scrollBar.minimumWidth
+        implicitHeight: scrollBar.interactive ? scrollBar.expandWidth : scrollBar.minimumWidth
+
+        Rectangle{
+            id: bar
+            width:  vertical ? scrollBar.minimumWidth : parent.width
+            height: horizontal ? scrollBar.minimumWidth : parent.height
+            color: Theme.currentTheme.colors.controlStrongColor
+            anchors{
+                right: vertical ? parent.right : undefined
+                bottom: horizontal ? parent.bottom : undefined
+            }
+            radius: 9999
+            visible: scrollBar.size < 1.0
+
+            Behavior on color {
+                ColorAnimation {
+                    duration: Utils.appearanceSpeed
+                    easing.type: Easing.OutCubic
+                }
+            }
+        }
+
+        states: [
+            State{
+                name: "collapsed"
+                when: contentItem.collapsed
+                PropertyChanges {
+                    target: bar
+                    width:  vertical ? scrollBar.expandWidth : parent.width
+                    height: horizontal ? scrollBar.expandWidth : parent.height
+                }
+            },
+            State{
+                name: "minimum"
+                when: !contentItem.collapsed
+                PropertyChanges {
+                    target: bar
+                    width:  vertical ? scrollBar.minimumWidth : parent.width
+                    height: horizontal ? scrollBar.minimumWidth : parent.height
+                }
+            }
+        ]
+        transitions:[
+            Transition {
+                to: "minimum"
+                SequentialAnimation {
+                    PauseAnimation { duration: 450 }  // 等待时长
+                    NumberAnimation {
+                        target: bar
+                        properties: vertical ? "width"  : "height"
+                        duration: 167
+                        easing.type: Easing.OutCubic
+                    }
+                }
+            },
+            Transition {
+                to: "collapsed"
+                SequentialAnimation {
+                    PauseAnimation { duration: 150 }
+                    NumberAnimation {
+                        target: bar
+                        properties: vertical ? "width"  : "height"
+                        duration: 167
+                        easing.type: Easing.OutCubic
+                    }
+                }
+            }
+        ]
+    }
+    // 背景 / Background //
+    background: Rectangle{
+        id: background
+        radius: 5
+        color: Theme.currentTheme.colors.backgroundAcrylicColor
+        opacity: 0
+        visible: scrollBar.size < 1.0
+
+        states: [
+            State{
+                name: "show"
+                when: contentItem.collapsed
+                PropertyChanges {
+                    target: background
+                    opacity: 1
+                }
+            },
+            State{
+                name: "hide"
+                when: !contentItem.collapsed
+                PropertyChanges {
+                    target: background
+                    opacity: 0
+                }
+            }
+        ]
+
+        // 动画
+        transitions:[
+            Transition {
+                to: "hide"
+                SequentialAnimation {
+                    PauseAnimation { duration: 450 }  // 等待时长
+                    NumberAnimation {
+                        target: background
+                        properties: "opacity"
+                        duration: 167
+                        easing.type: Easing.OutCubic
+                    }
+                }
+            },
+            Transition {
+                to: "show"
+                SequentialAnimation {
+                    PauseAnimation { duration: 150 }
+                    NumberAnimation {
+                        target: background
+                        properties: "opacity"
+                        duration: 167
+                        easing.type: Easing.OutCubic
+                    }
+                }
+            }
+        ]
+    }
+}

RinUI/components/ScrollView.qml

@@ -0,0 +1,13 @@
+import QtQuick 2.15
+import QtQuick.Templates 2.15
+import "../themes"
+import "../components"
+
+ScrollView {
+    ScrollBar.vertical: ScrollBar {
+        policy: ScrollBar.AsNeeded
+    }
+    ScrollBar.horizontal: ScrollBar {
+        policy: ScrollBar.AsNeeded
+    }
+}

RinUI/components/Shadow.qml

@@ -0,0 +1,48 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import Qt5Compat.GraphicalEffects
+import "../themes"
+
+DropShadow {
+    property string style: "cardRest" // shadow style
+
+    anchors.fill: source
+    horizontalOffset: 0
+    verticalOffset: Theme.currentTheme.shadows[style].offsetY
+    radius: Theme.currentTheme.shadows[style].blur
+    color: Theme.currentTheme.shadows[style].color
+    samples: 1 + radius * 2
+    // source: sourceItem
+    cached: true
+}
+
+// Repeater {
+//     id: shadowRepeater
+//     property string style: "cardRest"
+//     property int blurRadius: Theme.currentTheme.shadows[style].blur
+//     property int offsetY: Theme.currentTheme.shadows[style].offsetY
+//     property real intensity: 1.5          // 阴影强度系数
+//     property real spreadRatio: 1        // 阴影扩散系数
+//     property real controlRadius: 8         // 控制半径
+//     readonly property color shadowColor: Theme.currentTheme.shadows[style].color
+//
+//     model: Math.max(blurRadius, 16) // 保证最小8层渲染
+//
+//     Rectangle {
+//         anchors {
+//             fill: parent
+//             margins: -index * spreadRatio  // 非线性扩散
+//             topMargin: -index * spreadRatio + (offsetY) // 动态偏移分配
+//         }
+//
+//         color: "transparent"
+//         radius: controlRadius + (index * spreadRatio) // 优化半径增长曲线
+//         border.width: 1
+//         border.color: shadowColor
+//
+//         // 非线性透明度衰减
+//         opacity: (0.011 * (count - index + 1)) * shadowRepeater.opacity
+//
+//         z: -1
+//     }
+// }

RinUI/components/StatusAndInfo/InfoBadge.qml

@@ -0,0 +1,78 @@
+import QtQuick 2.15
+import QtQuick.Controls.Basic 2.15
+import QtQuick.Layouts 2.15
+import "../../themes"
+import "../../components"
+
+
+Rectangle {
+    id: root
+    property int count: -1
+    property string text: {
+        if (root.count < 0)
+            return ""
+        else if (root.count > maxCount)
+            return maxCount + "+"
+        else
+            return count.toString()
+    }
+    property int maxCount: 99
+    property string icon: {
+        switch (severity) {
+            case Severity.Info: return "ic_fluent_text_asterisk_20_filled";
+            case Severity.Success: return "ic_fluent_checkmark_20_filled";
+            case Severity.Warning: return "!";
+            case Severity.Error: return "ic_fluent_dismiss_20_filled";
+            default: return "";
+        }
+    }
+    property bool dot: false
+    property int severity: Severity.Info
+
+    property bool solid: true
+    property color primaryColor: {
+        switch (severity) {
+            case Severity.Info: return Theme.currentTheme.colors.systemAttentionColor;
+            case Severity.Success: return Theme.currentTheme.colors.systemSuccessColor;
+            case Severity.Warning: return Theme.currentTheme.colors.systemCautionColor;
+            case Severity.Error: return Theme.currentTheme.colors.systemCriticalColor;
+            default: return Theme.currentTheme.colors.systemNeutralColor;
+        }
+    }
+
+    width: dot ? 4 : Math.max(contents.width + 6, 16) + !solid * 2
+    height: dot ? 4 : 16 + !solid * 2
+    radius: height / 2
+
+    RowLayout {
+        id: contents
+        anchors.centerIn: parent
+        spacing: 4
+        visible: !root.dot
+
+        IconWidget {
+            icon: root.icon
+            size: 10
+            color: solid ? Theme.currentTheme.colors.textOnAccentColor : primaryColor
+            visible: !root.text
+        }
+
+        Text {
+            typography: Typography.Caption
+            text: root.text
+            color: solid ? Theme.currentTheme.colors.textOnAccentColor : primaryColor
+            visible: root.text
+        }
+    }
+
+    color: solid ? primaryColor : "transparent"
+    border.width: Theme.currentTheme.appearance.borderWidth
+    border.color: solid ? "transparent" : primaryColor
+
+    Behavior on color {
+        ColorAnimation {
+            duration: Utils.appearanceSpeed
+            easing.type: Easing.OutQuint
+        }
+    }
+}