RinUI 0.0.9__py3-none-any.whl

RinUI/components/BasicInput/Slider.qml

@@ -0,0 +1,212 @@
+import QtQuick 2.15
+import QtQuick.Controls.Basic 2.15
+import "../../themes"
+import "../../components"
+
+// thanks JerryQAQ
+
+Slider {
+    id: root
+    // 尺寸属性
+    property real handleSize: Theme.currentTheme.appearance.sliderHandleSize  // 手柄基础尺寸
+    property real borderWidth: 3   // 边框宽度
+    property int ticksPadding: 4  // 刻度线间距
+    property real trackHeight: 4
+    property bool showTooltip: true
+    property bool tickmarks: false
+    property real tickFrequency: 0  // 刻度线频率
+    property color primaryColor: Theme.currentTheme.colors.primaryColor
+
+    // accessibility
+    FocusIndicator {
+        control: parent
+    }
+
+    // auto enable snap
+    snapMode: Slider.SnapAlways
+
+    // 自适应高度和宽度
+    implicitHeight: orientation === Qt.Horizontal ? 32 : 150
+    implicitWidth: orientation === Qt.Horizontal ? 150 : 32
+
+
+    // Background / 背景 //
+    background: Rectangle {
+        anchors.centerIn: parent
+        width: root.orientation === Qt.Horizontal ? parent.width - handle.width : trackHeight
+        height: root.orientation === Qt.Horizontal ? trackHeight : parent.height - handle.width
+        radius: 99
+        color: Theme.currentTheme.colors.controlStrongColor
+
+        Behavior on color {
+            ColorAnimation {
+                duration: Utils.appearanceSpeed
+                easing.type: Easing.OutQuart
+            }
+        }
+
+        // 进度条
+        Rectangle {
+            width: root.orientation === Qt.Horizontal ? root.visualPosition * parent.width : trackHeight
+            height: root.orientation === Qt.Horizontal ? trackHeight : (1 - root.visualPosition) * parent.height
+            anchors.bottom: root.orientation === Qt.Vertical ? parent.bottom : undefined
+            radius: 99
+            color: Theme.currentTheme.colors.primaryColor
+
+            Behavior on width {
+                NumberAnimation {
+                    duration: Utils.animationSpeedFaster
+                    easing.type: Easing.OutCubic
+                }
+            }
+            Behavior on color {
+                ColorAnimation {
+                    duration: Utils.appearanceSpeed
+                    easing.type: Easing.OutQuart
+                }
+            }
+            Behavior on height {
+                NumberAnimation {
+                    duration: Utils.animationSpeedFaster
+                    easing.type: Easing.OutCubic
+                }
+            }
+        }
+
+        // 刻度线 / Repeater //
+         Repeater {
+             model: (to - from) / (tickFrequency !== 0 ? tickFrequency : stepSize)
+
+             delegate: Column {
+                x: root.orientation === Qt.Horizontal ?
+                    index * parent.width / (to - from) * (tickFrequency !== 0 ? tickFrequency : stepSize) - width / 2
+                    : ticksPadding + trackHeight
+                y: root.orientation === Qt.Vertical ?
+                    index * parent.height / (to - from) * (tickFrequency !== 0 ? tickFrequency : stepSize) - height / 2
+                    : ticksPadding + trackHeight
+                spacing: 2
+                Rectangle {
+                    anchors.horizontalCenter: parent.horizontalCenter
+                    width: root.orientation === Qt.Horizontal ? 1 : 4
+                    height: root.orientation === Qt.Horizontal ? 4 : 1
+                    color: Theme.currentTheme.colors.controlStrongColor
+
+                    visible: root.tickmarks && index !== 0 && index !== ((to - from) / stepSize)
+                }
+             }
+        }
+    }
+
+
+    // 手柄 / Handle //
+    handle: Item {
+        id: handle
+        property bool hovered: false
+        width: handleSize + 2
+        height: handleSize + 2
+
+        // 动态调整手柄位置：根据 orientation 切换 x/y 轴逻辑
+        x: root.orientation === Qt.Horizontal
+           ? root.visualPosition * (parent.width - width)  // 横向：x 受 visualPosition 控制
+           : (parent.width - width) / 2  // 竖向
+        y: root.orientation === Qt.Vertical
+           ? (root.visualPosition) * (parent.height - height)  // 竖向：y 受 visualPosition 控制
+           : (parent.height - height) / 2  // 横向
+
+
+        ToolTip {
+            text: root.value.toString()
+            visible: root.showTooltip ? (handle.hovered || root.pressed)  : false
+            delay: 50
+        }
+
+        // MouseArea
+        MouseArea {
+            anchors.fill: parent
+            hoverEnabled: true
+            acceptedButtons: Qt.NoButton
+            onEntered: handle.hovered = true
+            onExited: handle.hovered = false
+        }
+
+        // border
+        Rectangle {
+            anchors.fill: parent
+            radius: width / 2
+            color: Theme.currentTheme.colors.controlQuaternaryColor
+        }
+
+        // border middle(?)
+        Rectangle {
+            anchors.centerIn: parent
+            width: handleSize
+            height: handleSize
+            radius: width / 2
+            color: Theme.currentTheme.colors.controlSolidColor
+
+            Behavior on color {
+                ColorAnimation {
+                    duration: Utils.appearanceSpeed
+                    easing.type: Easing.OutQuart
+                }
+            }
+        }
+
+        // dot 主题色圆点
+        Rectangle {
+            id: dot
+            anchors.centerIn: parent
+            // 取偶数
+            width: Math.round(handleSize * 0.55) & ~1
+            height: Math.round(handleSize * 0.55) & ~1
+            radius: width / 2
+
+            // 悬停
+            scale: root.pressed ? 0.83 :
+                handle.hovered ? 1.16 : 1.0
+            color: root.pressed ? Qt.alpha(Theme.currentTheme.colors.primaryColor, 0.8) :
+                handle.hovered ? Qt.alpha(Theme.currentTheme.colors.primaryColor, 0.9) : Theme.currentTheme.colors.primaryColor
+
+            // 动画
+            Behavior on color {
+                ColorAnimation {
+                    duration: Utils.appearanceSpeed
+                    easing.type: Easing.OutCubic
+                }
+            }
+            Behavior on scale {
+                NumberAnimation {
+                    duration: Utils.animationSpeed
+                    easing.type: Easing.OutBack
+                }
+            }
+        }
+
+        Behavior on x {
+            NumberAnimation {
+                duration: Utils.animationSpeedFaster
+                easing.type: Easing.OutCubic
+            }
+        }
+        Behavior on y {
+            NumberAnimation {
+                duration: Utils.animationSpeedFaster
+                easing.type: Easing.OutCubic
+            }
+        }
+    }
+
+
+    // 状态管理
+    states: [
+        State {
+            name: "disabled"
+            when: !root.enabled
+            PropertyChanges {
+                target: handle
+                color: Theme.currentTheme.colors.textDisabled
+                opacity: 0.6
+            }
+        }
+    ]
+}

RinUI/components/BasicInput/Switch.qml

@@ -0,0 +1,102 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import "../../themes"
+import "../../components"
+
+
+Switch {
+    id: root
+
+    // width: 40
+    implicitHeight: 20
+
+    property color backgroundColor: Theme.currentTheme.colors.controlSecondaryColor
+    property color primaryColor: Theme.currentTheme.colors.primaryColor
+    property string checkedText: qsTr("On")
+    property string uncheckedText: qsTr("Off")
+
+    // accessibility
+    FocusIndicator {
+        control: parent
+        // radius: 999
+    }
+
+    // 背景 / Background
+    background: Rectangle {
+        id: background
+        width: 40
+        height: 20
+        radius: height / 2
+        color: checked ? primaryColor :
+            hovered ? Theme.currentTheme.colors.controlTertiaryColor : backgroundColor
+
+        // 边框 / Border
+        border.color: checked ? "transparent" : Theme.currentTheme.colors.controlBorderStrongColor
+        border.width: Theme.currentTheme.appearance.borderWidth
+
+        Behavior on color { ColorAnimation { duration: Utils.animationSpeed; easing.type: Easing.OutQuart } }
+    }
+
+    // 指示器 / Indicator //
+    indicator: Rectangle {
+        id: indicator
+        width: pressed && enabled ? background.height - 3:
+            hovered  && enabled ? background.height - 3 * 2 : background.height - 4 * 2
+        height: (hovered || pressed) && enabled ? background.height - 3 * 2 : background.height - 4 * 2
+
+        anchors.verticalCenter: background.verticalCenter
+        radius: height / 2
+        color: checked ? Theme.currentTheme.colors.textOnAccentColor : Theme.currentTheme.colors.controlBorderStrongColor
+
+        Behavior on color { ColorAnimation { duration: Utils.animationSpeed; easing.type: Easing.OutQuart } }
+
+        Behavior on x { NumberAnimation { duration: Utils.animationSpeed; easing.type: Easing.OutQuint } }
+        Behavior on height { NumberAnimation { duration: Utils.animationSpeed; easing.type: Easing.OutQuint } }
+
+        x: (hovered || pressed) && enabled
+            ? visualPosition * (background.width - 3 - width) + (checked ? 0 : 3)
+            : visualPosition * (background.width - 8 - width) + 4
+    }
+
+    contentItem: Row {
+        anchors.fill: parent
+        spacing: 12
+        Rectangle { width: 40; height: 20; color: "transparent" }  // 占位符
+
+        Text {
+            text: (root.text === '') ? root.checked ? checkedText : uncheckedText : root.text
+        }
+    }
+
+    // 状态变化
+    states: [
+        State {
+            name: "disabledSwitch"
+            when: !root.enabled
+            PropertyChanges {
+                target: root
+                opacity: 0.2169
+                primaryColor: Theme.currentTheme.colors.disabledColor
+            }
+        },
+        State {
+            name: "pressedSwitch"
+            when: pressed
+            PropertyChanges {
+                target: background
+                opacity: 0.8
+            }
+        },
+        State {
+            name: "hoveredSwitch"
+            when: hovered
+            PropertyChanges {
+                target: background
+                opacity: 0.9
+            }
+        }
+    ]
+
+    // 动画
+    Behavior on opacity { NumberAnimation { duration: Utils.appearanceSpeed; easing.type: Easing.OutQuart } }
+}

RinUI/components/BasicInput/ToggleButton.qml

@@ -0,0 +1,11 @@
+import QtQuick 2.15
+import QtQuick.Controls.Basic 2.15
+import QtQuick.Layouts 2.15
+import "../../themes"
+import "../../components"
+
+Button {
+    id: root
+    highlighted: checked
+    checkable: true
+}

RinUI/components/BasicInput/ToolButton.qml

@@ -0,0 +1,31 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import "../../components"
+
+Button {
+    id: toolBtn
+    // flat: true
+    property alias size: iconWidget.size
+    property alias color: iconWidget.color
+    // width: height * 1
+
+    contentItem: Item {
+        width: parent.width
+        height: parent.height
+        Text {
+            anchors.centerIn: parent
+            id: btnText
+            text: toolBtn.text
+        }
+        IconWidget {
+            id: iconWidget
+            width: parent.width
+            height: parent.height
+            size: 20
+            icon: toolBtn.icon.name ? toolBtn.icon.name : toolBtn.text
+            color: icon.color ? icon.color : highlighted ? flat ?
+                enabled ? Theme.currentTheme.colors.textAccentColor : Theme.currentTheme.colors.textColor :
+                Theme.currentTheme.colors.textOnAccentColor : Theme.currentTheme.colors.textColor
+        }
+    }
+}

RinUI/components/ContextMenu.qml

@@ -0,0 +1,184 @@
+import QtQuick 2.15
+import QtQuick.Controls.Basic 2.15
+import "../themes"
+import "../components"
+
+
+Popup {
+    id: contextMenu
+
+    // 选中信号 / Signal //
+    signal itemSelected(int index)
+
+    property alias model: listView.model
+    property alias currentIndex: listView.currentIndex
+    property int maxHeight: 300  // 最大高度
+    property string textRole: ""
+    property bool keyboardNavigation: false
+
+    implicitWidth: 100
+    implicitHeight: Math.min(listView.contentHeight + 6, maxHeight)
+    y: (parent.height - contextMenu.height) / 2
+    height: implicitHeight  // 保持隐式绑定
+    closePolicy: Popup.CloseOnPressOutside
+    focus: true
+
+    // 内容 / ListView //
+    contentItem: ListView {
+        id: listView
+        clip: true
+        focus: true
+        spacing: 0
+        anchors.fill: parent  // 清除边距
+        anchors.topMargin: 2
+        anchors.bottomMargin: 2
+
+        // 垂直滚动条 / Vertical ScrollBar //
+        ScrollBar.vertical: ScrollBar {
+            id: scrollBar
+            policy: ScrollBar.AsNeeded
+        }
+        model: control.popup.visible ? control.delegateModel : null
+
+        // 选择器 / Selection //
+        delegate: ItemDelegate {
+            id: delegate
+            width: listView.width
+            height: text.implicitHeight + 20  // 自适应
+            highlighted: ListView.isCurrentItem  // 当前项高亮
+            focusPolicy: Qt.StrongFocus
+
+            background: Rectangle {
+                id: itemBg
+                anchors.fill: parent
+                anchors.leftMargin: 5
+                anchors.rightMargin: 5
+                anchors.topMargin: 3
+                radius: Theme.currentTheme.appearance.buttonRadius
+                color: pressed
+                    ? Theme.currentTheme.colors.subtleTertiaryColor
+                    : (highlighted || hovered)
+                        ? Theme.currentTheme.colors.subtleSecondaryColor
+                        : Theme.currentTheme.colors.subtleColor
+
+                Text {
+                    id: text
+                    anchors.fill: parent
+                    anchors.leftMargin: 11
+                    anchors.rightMargin: 11
+                    anchors.topMargin: 6
+                    anchors.bottomMargin: 8
+                    verticalAlignment: Text.AlignVCenter
+
+                    typography: Typography.Body
+                    wrapMode: Text.Wrap
+                    text: model[contextMenu.parent.textRole]
+                }
+
+                // 选择指示器
+                Indicator {
+                    currentItemHeight: itemBg.height
+                    visible: highlighted
+                }
+
+                // accessibility
+                FocusIndicator {
+                    control: parent
+                    visible: highlighted && keyboardNavigation
+                }
+
+                Behavior on color { ColorAnimation { duration: Utils.appearanceSpeed; easing.type:Easing.InOutQuart } }
+            }
+
+            Keys.onUpPressed: {
+                contextMenu.keyboardNavigation = true
+                listView.decrementCurrentIndex()
+            }
+
+            Keys.onDownPressed: {
+                contextMenu.keyboardNavigation = true
+                listView.incrementCurrentIndex()
+            }
+
+            onClicked: {
+                listView.currentIndex = index
+                contextMenu.itemSelected(index)
+                contextMenu.close()
+            }
+        }
+    }
+
+    // 背景 / Background //
+    background: Rectangle {
+        id: background
+        anchors.fill: parent
+        radius: Theme.currentTheme.appearance.windowRadius
+        color: Theme.currentTheme.colors.backgroundAcrylicColor
+        border.color: Theme.currentTheme.colors.controlBorderColor
+
+        // 阴影 / Shadow //
+        layer.enabled: true
+        layer.effect: Shadow {
+            id: shadow
+            style: "flyout"
+            source: background
+        }
+    }
+
+    // 按钮 / Button //
+
+
+    Behavior on y { NumberAnimation { duration: Utils.animationSpeed; easing.type:Easing.InOutQuart } }
+
+    enter: Transition {
+        ParallelAnimation {
+            NumberAnimation {
+                target: contextMenu
+                property: "opacity"
+                from: 0
+                to: 1
+                duration: 70
+                easing.type: Easing.InOutQuart
+            }
+            // NumberAnimation {
+            //     target: shadow
+            //     property: "opacity"
+            //     from: 0
+            //     to: 1
+            //     duration: 600
+            //     easing.type: Easing.InOutCubic
+            // }
+            NumberAnimation {
+                target: scrollBar
+                property: "opacity"
+                from: 0
+                to: 1
+                duration: 1000
+                easing.type: Easing.InOutCubic
+            }
+            NumberAnimation {
+                target: contextMenu
+                property: "height"
+                from: 46
+                to: contextMenu.implicitHeight
+                duration: Utils.animationSpeedMiddle
+                easing.type: Easing.OutQuint
+                onRunningChanged: {
+                    scrollBar.visible = true;
+                }
+            }
+        }
+    }
+    exit: Transition {
+        ParallelAnimation {
+            NumberAnimation {
+                target: contextMenu
+                property: "opacity"
+                from: 1
+                to: 0
+                duration: 150
+                easing.type: Easing.InOutQuart
+            }
+        }
+    }
+}