RinUI 0.0.9__py3-none-any.whl

RinUI/windows/CtrlBtn.qml

@@ -0,0 +1,119 @@
+import QtQuick 2.12
+import QtQuick.Controls 2.3
+import QtQuick.Window 2.3
+import "../themes"
+import "../components"
+
+
+Base {
+    id: root
+    interactive: true  // 是否可以交互
+    property int mode: 0  //0:max 1:min 2:close
+    property alias icon: icon.icon
+
+    // tooltip
+    ToolTip {
+        parent: parent
+        delay: 500
+        visible: mouseArea.containsMouse
+        text: mode === 0 ? qsTr("Maximize") : mode === 1 ? qsTr("Minimize") : mode === 2 ? qsTr("Close") : qsTr("Unknown")
+    }
+
+    //关闭 最大化 最小化按钮
+    function toggleControl(mode) {
+        if (mode === 0) {
+            if (window.visibility === Window.Maximized) {
+                window.showNormal();
+            } else {
+                window.showMaximized();
+            }
+        } else if (mode===1) {
+            window.showMinimized();
+        } else if (mode===2) {
+            window.close();
+        }
+    }
+
+    width: 48
+    height: parent.height
+
+
+    // 背景 / Background
+    Rectangle {
+        id: background
+        anchors.fill: parent
+        color: mode === 2 ? Theme.currentTheme.colors.captionCloseColor : Theme.currentTheme.colors.subtleSecondaryColor
+        opacity: 0
+
+        Behavior on opacity { NumberAnimation { duration: 100; easing.type: Easing.InOutQuad } }
+    }
+
+
+    // 按钮图标
+    IconWidget {
+        id: icon
+        icon: mode === 0 ?
+                window.visibility === Window.Maximized ?
+                    "ic_fluent_square_multiple_20_regular" :
+                    "ic_fluent_square_20_regular" :
+            mode === 1 ?
+                "ic_fluent_subtract_20_regular" :
+            mode === 2 ?
+                "ic_fluent_dismiss_20_regular"
+            :
+                "ic_fluent_circle_20_regular"  // unknown style
+        size: mode === 0 ? 14 : 16
+        anchors.centerIn: parent
+    }
+
+    // 鼠标区域 / MouseArea
+    MouseArea {
+        id: mouseArea
+        anchors.fill: parent
+        enabled: enabled
+        hoverEnabled: true
+        onClicked: {
+            toggleControl(mode)
+        }
+    }
+
+    states: [
+        State {
+        name: "disabledCtrl"
+            when: !enabled
+            PropertyChanges {  // 禁用时禁止改变属性
+                target: icon;
+                opacity: 0.3614
+            }
+            PropertyChanges {  // 禁用时禁止改变属性
+                target: root;
+            }
+        },
+        State {
+            name: "pressedCtrl"
+            when: mouseArea.pressed
+            PropertyChanges {
+                target: background;
+                opacity: 0.8
+            }
+            PropertyChanges {
+                target: icon;
+                opacity: 0.6063
+                color: root.mode === 2 ? Theme.currentTheme.colors.captionCloseTextColor : textColor
+            }
+        },
+        State {
+            name: "hoveredCtrl"
+            when: mouseArea.containsMouse
+            PropertyChanges {
+                target: background;
+                opacity: 1
+            }
+            PropertyChanges {
+                target: icon;
+                opacity: root.mode === 2 ? 1 : 0.6063
+                color: root.mode === 2 ? Theme.currentTheme.colors.captionCloseTextColor : textColor
+            }
+        }
+    ]
+}

RinUI/windows/FluentPage.qml

@@ -0,0 +1,92 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import Qt5Compat.GraphicalEffects  // 图形库
+import "../themes"
+import "../components"
+import "../windows"
+
+// 内容层 / Content Area
+Page {
+    id: fluentPage
+    default property alias content: container.data
+    property alias contentHeader: headerContainer.data
+    property alias customHeader: headerRow.data
+    property alias extraHeaderItems: extraHeaderRow.data
+    property int radius: Theme.currentTheme.appearance.windowRadius
+    property int wrapperWidth: 1000
+    horizontalPadding: 56
+    // StackView.onRemoved: destroy()
+    spacing: 0
+    property alias contentSpacing: container.spacing
+
+
+    // 头部 / Header //
+    header: Item {
+        height: fluentPage.title !== "" ? 36 + 44 : 0
+
+        RowLayout {
+            id: headerRow
+            width: Math.min(fluentPage.width - fluentPage.horizontalPadding * 2, fluentPage.wrapperWidth)  // 限制最大宽度
+            anchors.horizontalCenter: parent.horizontalCenter
+            height: parent.height
+
+            Text {
+                // anchors.left: parent.left
+                // anchors.bottom: parent.bottom
+                Layout.alignment: Qt.AlignLeft | Qt.AlignBottom
+                typography: Typography.Title
+                text: fluentPage.title
+                visible: fluentPage.title !== ""  // 标题
+            }
+
+            Row {
+                id: extraHeaderRow
+                spacing: 4
+                Layout.alignment: Qt.AlignRight | Qt.AlignBottom
+            }
+        }
+    }
+
+
+    background: Item {}
+
+    Flickable {
+        anchors.fill: parent
+        clip: true
+        ScrollBar.vertical: ScrollBar {}
+        contentHeight: container.height + 18 + headerContainer.height
+
+        Row {
+            id: headerContainer
+            width: fluentPage.width
+        }
+
+        ColumnLayout {
+            id: container
+            anchors.top: headerContainer.bottom
+            anchors.topMargin: 18
+            anchors.horizontalCenter: parent.horizontalCenter
+            width: Math.min(fluentPage.width - fluentPage.horizontalPadding * 2, fluentPage.wrapperWidth)  // 24 + 24 的边距
+            spacing: 14
+        }
+    }
+
+    layer.enabled: true
+    layer.effect: OpacityMask{
+        maskSource: Rectangle{
+            width: fluentPage.width
+            height: fluentPage.height
+            radius: fluentPage.radius
+
+            Rectangle {
+                anchors.right: parent.right
+                anchors.top: parent.top
+                width: parent.width - Theme.currentTheme.appearance.windowRadius
+                height: Theme.currentTheme.appearance.windowRadius
+            }
+        }
+    }
+
+    // anchors.fill: parent
+}

RinUI/windows/FluentWindow.qml

@@ -0,0 +1,32 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import "../themes"
+import "../components"
+import "../windows"
+
+FluentWindowBase {
+    id: window
+    // visible: true
+    title: qsTr("Fluent Window")
+    width: 900
+    height: 600
+    minimumWidth: 400
+    minimumHeight: 300
+    titleEnabled: false
+    titleBarHeight: Theme.currentTheme.appearance.windowTitleBarHeight
+
+    property alias navigationItems: navigationView.navigationItems  // 导航栏item
+    property alias defaultPage: navigationView.defaultPage  // 默认索引项
+    property alias appLayerEnabled: navigationView.appLayerEnabled  // 应用层背景
+    default property alias content: freeContainter.data
+
+    NavigationView {
+        id: navigationView
+        window: window
+    }
+    Item {
+        id: freeContainter
+        anchors.fill: parent
+    }
+}

RinUI/windows/FluentWindowBase.qml

@@ -0,0 +1,157 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import "../themes"
+import "../windows"
+import "../components"
+
+ApplicationWindow {
+    id: baseWindow
+    // visible: true
+    title: qsTr("Fluent Window Base")
+    width: 800
+    height: 600
+    minimumWidth: 400
+    minimumHeight: 300
+    property int hwnd: 0
+
+    flags: frameless ? Qt.FramelessWindowHint | Qt.Window | Qt.WindowMinimizeButtonHint | Qt.WindowMaximizeButtonHint | Qt.WindowCloseButtonHint :
+        Qt.Window
+    color: frameless ? "transparent" : Theme.currentTheme.colors.backgroundColor
+
+    // 自定义属性
+    property var icon: "../assets/img/default_app_icon.png"  // 图标
+    property alias titleEnabled: titleBar.titleEnabled
+    property int titleBarHeight: Theme.currentTheme.appearance.dialogTitleBarHeight
+    property bool frameless: true  // 是否无边框
+
+
+    // 直接添加子项
+    property alias framelessMenuBar: menuBarArea.children  // 无边框模式时菜单栏
+    default property alias content: contentArea.children
+    property alias floatLayer: floatLayer
+
+    // 最大化样式
+    onVisibilityChanged: {
+        if (baseWindow.visibility === Window.Maximized) {
+            background.radius = 0
+            background.border.width = 0
+        } else {
+            background.radius = Theme.currentTheme.appearance.windowRadius
+            background.border.width = 1
+        }
+    }
+
+    FloatLayer {
+        id: floatLayer
+        anchors.topMargin: titleBarHeight
+        z: 998
+    }
+
+    // 布局
+    ColumnLayout {
+        anchors.fill: parent
+        // anchors.topMargin: Utils.windowDragArea
+        anchors.bottomMargin: Utils.windowDragArea
+        anchors.leftMargin: Utils.windowDragArea
+        anchors.rightMargin: Utils.windowDragArea
+        spacing: 0
+
+        // 顶部边距
+        Item {
+            Layout.preferredHeight: frameless ? titleBar.height : 0
+            Layout.fillWidth: true
+        }
+
+        // menubar
+        Item {
+            id: menuBarArea
+            Layout.fillWidth: true
+        }
+
+        // 主体内容区域
+        Item {
+            id: contentArea
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+        }
+    }
+
+    // 标题栏
+    TitleBar {
+        id: titleBar
+        window: baseWindow
+        icon: baseWindow.icon
+        title: baseWindow.title
+        Layout.fillWidth: true
+        height: baseWindow.titleBarHeight
+        visible: frameless
+    }
+
+
+    // 背景样式
+    background: Rectangle {
+        id: background
+        anchors.fill: parent
+        color: Utils.backdropEnabled ? "transparent" : Theme.currentTheme.colors.backgroundColor
+        border.color: Theme.currentTheme.colors.windowBorderColor
+        layer.enabled: true  // 启用透明渲染
+        border.width: 1
+        radius: Theme.currentTheme.appearance.windowRadius
+        z: -1
+        clip: true
+        visible: frameless
+
+        // Shadow {}
+
+        Behavior on color {
+            ColorAnimation {
+                duration: Utils.backdropEnabled ? 0 : 150
+            }
+        }
+    }
+
+    Behavior on color {
+        ColorAnimation {
+            duration: Utils.appearanceSpeed
+        }
+    }
+
+
+    //改变鼠标形状
+    MouseArea {
+        anchors.fill: parent
+        hoverEnabled: baseWindow.visibility !== Window.Maximized
+        z: -1
+        cursorShape: {
+            if (!baseWindow.frameless) {
+                return
+            }
+            const p = Qt.point(mouseX, mouseY)
+            const b = Utils.windowDragArea
+            if (p.x < b && p.y < b) return Qt.SizeFDiagCursor
+            if (p.x >= width - b && p.y >= height - b) return Qt.SizeFDiagCursor
+            if (p.x >= width - b && p.y < b) return Qt.SizeBDiagCursor
+            if (p.x < b && p.y >= height - b) return Qt.SizeBDiagCursor
+            if (p.x < b || p.x >= width - b) return Qt.SizeHorCursor
+            if (p.y < b || p.y >= height - b) return Qt.SizeVerCursor
+        }
+        acceptedButtons: Qt.NoButton
+    }
+
+    DragHandler {
+        id: resizeHandler
+        grabPermissions: TapHandler.TakeOverForbidden
+        target: null
+        onActiveChanged: if (active && baseWindow.visibility !== Window.Maximized) {
+            const p = resizeHandler.centroid.position
+            const b = Utils.windowDragArea + 10
+            let e = 0;
+            if (p.x < b) e |= Qt.LeftEdge
+            if (p.x >= width - b) e |= Qt.RightEdge
+            if (p.y < b) e |= Qt.TopEdge
+            if (p.y >= height - b) e |= Qt.BottomEdge
+            baseWindow.startSystemResize(e)
+        }
+    }
+}

RinUI/windows/TitleBar.qml

@@ -0,0 +1,132 @@
+import QtQuick 2.12
+import QtQuick.Controls 2.3
+import QtQuick.Window 2.3
+import "../themes"
+import "../components"
+import "../windows"
+
+Item {
+    id: root
+    property int titleBarHeight: Theme.currentTheme.appearance.dialogTitleBarHeight
+    property alias title: titleLabel.text
+    property alias icon: iconLabel.source
+    property alias backgroundColor: rectBk.color
+
+    // 自定义属性
+    property bool titleEnabled: true
+    property alias iconEnabled: iconLabel.visible
+    property bool minimizeEnabled: true
+    property bool maximizeEnabled: true
+    property bool closeEnabled: true
+
+    property alias minimizeVisible: minimizeBtn.visible
+    property alias maximizeVisible: maximizeBtn.visible
+    property alias closeVisible: closeBtn.visible
+
+
+    height: titleBarHeight
+    anchors.top: parent.top
+    anchors.left: parent.left
+    anchors.right: parent.right
+    clip: true
+    z: 999
+
+    implicitWidth: 200
+
+    property var window: null
+    function toggleMaximized() {
+        if (window.visibility === Window.Maximized) {
+            window.showNormal();
+        } else {
+            window.showMaximized();
+        }
+    }
+
+    Rectangle{
+        id:rectBk
+        anchors.fill: parent
+        color: "transparent"
+
+        MouseArea {
+            anchors.fill: parent
+            anchors.leftMargin: 48
+            anchors.margins: Utils.windowDragArea
+            propagateComposedEvents: true
+            acceptedButtons: Qt.LeftButton
+            property point clickPos: "0,0"
+
+            onPressed: {
+                clickPos = Qt.point(mouseX, mouseY)
+                Theme.sendDragWindowEvent(window)
+            }
+            onDoubleClicked: toggleMaximized()
+            onPositionChanged: (mouse) => {
+                if (window.isMaximized || window.isFullScreen || window.visibility === Window.Maximized) {
+                    return
+                }
+
+                if ((Qt.platform.os !== "windows" || Qt.platform.os !== "winrt") && Theme.isThemeMgrInitialized()) {
+                    return  // 在win环境使用原生方法拖拽
+                }
+
+                //鼠标偏移量
+                let delta = Qt.point(mouse.x-clickPos.x, mouse.y-clickPos.y)
+
+                window.setX(window.x+delta.x)
+                window.setY(window.y+delta.y)
+            }
+        }
+    }
+
+    // 窗口按钮 / Window Controls
+    Row{
+        anchors.right: parent.right
+        anchors.top: parent.top
+        anchors.bottom: parent.bottom
+        spacing: 0
+        CtrlBtn {
+            id: minimizeBtn
+            mode: 1
+            enabled: root.minimizeEnabled
+        }
+        CtrlBtn {
+            id: maximizeBtn
+            mode: 0
+            enabled: root.maximizeEnabled
+
+        }
+        CtrlBtn {
+            id: closeBtn
+            mode: 2
+            enabled: root.closeEnabled
+        }
+    }
+
+    // 窗口标题 / Window Title
+    Row {
+        id: titleRow
+        anchors.left: parent.left
+        anchors.top: parent.top
+        anchors.bottom: parent.bottom
+        anchors.leftMargin: 16
+        spacing: 16
+        visible: root.titleEnabled
+
+        //图标
+        IconWidget {
+            id: iconLabel
+            size: 16
+            anchors.verticalCenter: parent.verticalCenter
+            visible: icon || source
+        }
+
+        //标题
+        Text {
+            id: titleLabel
+            anchors.verticalCenter:  parent.verticalCenter
+
+            typography: Typography.Caption
+            text: qsTr("Fluent TitleBar")
+        }
+    }
+}

RinUI/windows/qmldir

@@ -0,0 +1,8 @@
+module RinUI.windows
+
+FluentWindowBase 1.0 FluentWindowBase.qml
+FluentWindow 1.0 FluentWindow.qml
+TitleBar 1.0 TitleBar.qml
+FluentPage 1.0 FluentPage.qml
+CtrlBtn 1.0 CtrlBtn.qml
+ErrorPage 1.0 ErrorPage.qml

RinUI/windows/window/ApplicationWindow.qml

@@ -0,0 +1,9 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import "../../windows"
+
+FluentWindowBase {
+    id: baseWindow
+    frameless: false
+    default property alias content: baseWindow.data
+}

RinUI/windows/window/Window.qml

@@ -0,0 +1,112 @@
+import QtQuick 2.15
+import QtQuick.Controls 2.15
+import QtQuick.Layouts 2.15
+import "../../windows"
+import "../../themes"
+
+Window {
+    id: baseWindow
+    flags: frameless ? Qt.FramelessWindowHint | Qt.Window | Qt.WindowMinimizeButtonHint | Qt.WindowMaximizeButtonHint | Qt.WindowCloseButtonHint
+        : Qt.Window
+
+    color: frameless ? "transparent" : Theme.currentTheme.colors.backgroundColor
+    property bool frameless: false
+    default property alias content: baseWindow.data
+    property int titleBarHeight: Theme.currentTheme.appearance.dialogTitleBarHeight
+
+    // 布局
+    ColumnLayout {
+        anchors.fill: parent
+        anchors.bottomMargin: Utils.windowDragArea
+        anchors.leftMargin: Utils.windowDragArea
+        anchors.rightMargin: Utils.windowDragArea
+        spacing: 0
+
+        // 顶部边距
+        Item {
+            Layout.preferredHeight: titleBar.height
+            Layout.fillWidth: true
+            visible: frameless
+        }
+
+        // 主体内容区域
+        Item {
+            id: contentArea
+            Layout.fillWidth: true
+            Layout.fillHeight: true
+        }
+    }
+
+    // 标题栏
+    TitleBar {
+        id: titleBar
+        window: baseWindow
+        icon: baseWindow.icon
+        title: baseWindow.title
+        Layout.fillWidth: true
+        height: baseWindow.titleBarHeight
+        visible: frameless
+    }
+
+    Rectangle {
+        id: background
+        anchors.fill: parent
+        color: Utils.backdropEnabled ? "transparent" : Theme.currentTheme.colors.backgroundColor
+        border.color: Theme.currentTheme.colors.windowBorderColor
+        z: -1
+        clip: true
+        visible: frameless
+
+        // Shadow {}
+
+        Behavior on color {
+            ColorAnimation {
+                duration: Utils.backdropEnabled ? 0 : 150
+            }
+        }
+    }
+
+    Behavior on color {
+        ColorAnimation {
+            duration: Utils.appearanceSpeed
+        }
+    }
+
+    //改变鼠标形状
+    MouseArea {
+        anchors.fill: parent
+        hoverEnabled: baseWindow.visibility !== Window.Maximized
+        z: -1
+        cursorShape: {
+            if (!frameless) {
+                return
+            }
+            const p = Qt.point(mouseX, mouseY)
+            const b = Utils.windowDragArea
+            if (p.x < b && p.y < b) return Qt.SizeFDiagCursor
+            if (p.x >= width - b && p.y >= height - b) return Qt.SizeFDiagCursor
+            if (p.x >= width - b && p.y < b) return Qt.SizeBDiagCursor
+            if (p.x < b && p.y >= height - b) return Qt.SizeBDiagCursor
+            if (p.x < b || p.x >= width - b) return Qt.SizeHorCursor
+            if (p.y < b || p.y >= height - b) return Qt.SizeVerCursor
+        }
+        acceptedButtons: Qt.NoButton
+    }
+
+    DragHandler {
+        id: resizeHandler
+        enabled: false
+        grabPermissions: TapHandler.TakeOverForbidden
+        target: null
+        onActiveChanged: if (active && baseWindow.visibility !== Window.Maximized) {
+            const p = resizeHandler.centroid.position
+            const b = Utils.windowDragArea + 10
+            let e = 0;
+            if (p.x < b) e |= Qt.LeftEdge
+            if (p.x >= width - b) e |= Qt.RightEdge
+            if (p.y < b) e |= Qt.TopEdge
+            if (p.y >= height - b) e |= Qt.BottomEdge
+            baseWindow.startSystemResize(e)
+        }
+    }
+}

rinui-0.0.9.data/data/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2025 RinLit
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.