PySide6-Examples 6.7.0__cp39-abi3-win_amd64.whl

PySide6/examples/location/mapviewer/MapViewer/map/MapSliders.qml

@@ -0,0 +1,282 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Controls
+
+Row {
+    id: containerRow
+
+    property var mapSource
+    property real fontSize : 14
+    property color labelBackground : "transparent"
+    property int edge: Qt.RightEdge
+    property alias expanded: sliderToggler.checked
+
+    function rightEdge() {
+        return (containerRow.edge === Qt.RightEdge);
+    }
+
+    layoutDirection: rightEdge() ? Qt.LeftToRight : Qt.RightToLeft
+    anchors.top: parent.top
+    anchors.bottom: parent.bottom
+    anchors.right: rightEdge() ? parent.right : undefined
+    anchors.left: rightEdge() ? undefined : parent.left
+
+    AbstractButton {
+        id: sliderToggler
+        width: 32
+        height: 96
+        checkable: true
+        checked: true
+        anchors.verticalCenter: parent.verticalCenter
+
+        transform:  Scale {
+                        origin.x: rightEdge() ? 0 : sliderToggler.width / 2
+                        xScale: rightEdge() ? 1 : -1
+                    }
+
+        background: Rectangle {
+            color: "transparent"
+        }
+
+
+        property real shear: 0.333
+        property real buttonOpacity: 0.5
+        property real mirror : rightEdge() ? 1.0 : -1.0
+
+        Rectangle {
+            width: 16
+            height: 48
+            color: "seagreen"
+            antialiasing: true
+            opacity: sliderToggler.buttonOpacity
+            anchors.top: parent.top
+            anchors.left: sliderToggler.checked ?  parent.left : parent.horizontalCenter
+            transform: Matrix4x4 {
+                property real d : sliderToggler.checked ? 1.0 : -1.0
+                matrix:    Qt.matrix4x4(1.0,  d * sliderToggler.shear,    0.0,    0.0,
+                                        0.0,    1.0,    0.0,    0.0,
+                                        0.0,    0.0,    1.0,    0.0,
+                                        0.0,    0.0,    0.0,    1.0)
+            }
+        }
+
+        Rectangle {
+            width: 16
+            height: 48
+            color: "seagreen"
+            antialiasing: true
+            opacity: sliderToggler.buttonOpacity
+            anchors.top: parent.verticalCenter
+            anchors.right: sliderToggler.checked ?  parent.right : parent.horizontalCenter
+            transform: Matrix4x4 {
+                property real d : sliderToggler.checked ? -1.0 : 1.0
+                matrix:    Qt.matrix4x4(1.0,  d * sliderToggler.shear,    0.0,    0.0,
+                                        0.0,    1.0,    0.0,    0.0,
+                                        0.0,    0.0,    1.0,    0.0,
+                                        0.0,    0.0,    0.0,    1.0)
+            }
+        }
+    }
+
+    Rectangle {
+        id: sliderContainer
+        height: parent.height
+        width: sliderRow.width + 10
+        visible: sliderToggler.checked
+        color: Qt.rgba( 0, 191 / 255.0, 255 / 255.0, 0.07)
+
+        property var labelBorderColor: "transparent"
+        property var slidersHeight : sliderContainer.height
+                                     - rowSliderValues.height
+                                     - rowSliderLabels.height
+                                     - sliderColumn.spacing * 2
+                                     - sliderColumn.topPadding
+                                     - sliderColumn.bottomPadding
+
+        Column {
+            id: sliderColumn
+            spacing: 10
+            topPadding: 16
+            bottomPadding: 48
+            anchors.centerIn: parent
+
+            // the sliders value labels
+            Row {
+                id: rowSliderValues
+                spacing: sliderRow.spacing
+                width: sliderRow.width
+                height: 32
+                property real entryWidth: zoomSlider.width
+
+                Rectangle{
+                    color: labelBackground
+                    height: parent.height
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelZoomValue
+                        text: zoomSlider.value.toFixed(3)
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+                Rectangle{
+                    color: labelBackground
+                    height: parent.height
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelBearingValue
+                        text: bearingSlider.value.toFixed(2)
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+                Rectangle{
+                    color: labelBackground
+                    height: parent.height
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelTiltValue
+                        text: tiltSlider.value.toFixed(2)
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+                Rectangle{
+                    color: labelBackground
+                    height: parent.height
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelFovValue
+                        text: fovSlider.value.toFixed(2)
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+            } // rowSliderValues
+
+            // The sliders row
+            Row {
+                id: sliderRow
+                height: sliderContainer.slidersHeight
+
+                Slider {
+                    id: zoomSlider
+                    height: parent.height
+                    orientation : Qt.Vertical
+                    from : containerRow.mapSource.minimumZoomLevel
+                    to : containerRow.mapSource.maximumZoomLevel
+                    value : containerRow.mapSource.zoomLevel
+                    onValueChanged: {
+                            containerRow.mapSource.zoomLevel = value
+                    }
+                }
+                Slider {
+                    id: bearingSlider
+                    height: parent.height
+                    from: 0
+                    to: 360
+                    orientation : Qt.Vertical
+                    value: containerRow.mapSource.bearing
+                    onValueChanged: {
+                        containerRow.mapSource.bearing = value;
+                    }
+                }
+                Slider {
+                    id: tiltSlider
+                    height: parent.height
+                    orientation : Qt.Vertical
+                    from: containerRow.mapSource.minimumTilt;
+                    to: containerRow.mapSource.maximumTilt
+                    value: containerRow.mapSource.tilt
+                    onValueChanged: {
+                        containerRow.mapSource.tilt = value;
+                    }
+                }
+                Slider {
+                    id: fovSlider
+                    height: parent.height
+                    orientation : Qt.Vertical
+                    from: containerRow.mapSource.minimumFieldOfView
+                    to: containerRow.mapSource.maximumFieldOfView
+                    value: containerRow.mapSource.fieldOfView
+                    onValueChanged: {
+                        containerRow.mapSource.fieldOfView = value;
+                    }
+                }
+            } // Row sliders
+
+            // The labels row
+            Row {
+                id: rowSliderLabels
+                spacing: sliderRow.spacing
+                width: sliderRow.width
+                property real entryWidth: zoomSlider.width
+                property real entryHeight: 64
+
+                Rectangle{
+                    color: labelBackground
+                    height: parent.entryHeight
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelZoom
+                        text: "Zoom"
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+
+                Rectangle{
+                    color: labelBackground
+                    height: parent.entryHeight
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelBearing
+                        text: "Bearing"
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+                Rectangle{
+                    color: labelBackground
+                    height: parent.entryHeight
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelTilt
+                        text: "Tilt"
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+                Rectangle{
+                    color: labelBackground
+                    height: parent.entryHeight
+                    width: parent.entryWidth
+                    border.color: sliderContainer.labelBorderColor
+                    Label {
+                        id: labelFov
+                        text: "FoV"
+                        font.pixelSize: fontSize
+                        rotation: -90
+                        anchors.centerIn: parent
+                    }
+                }
+            } // rowSliderLabels
+        } // Column
+    } // sliderContainer
+} // containerRow

PySide6/examples/location/mapviewer/MapViewer/map/Marker.qml

@@ -0,0 +1,64 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtLocation
+
+//! [mqi-top]
+MapQuickItem {
+    id: marker
+//! [mqi-top]
+
+//! [mqi-anchor]
+    anchorPoint.x: image.width/4
+    anchorPoint.y: image.height
+
+    HoverHandler {
+        id: hoverHandler
+    }
+    TapHandler {
+        id: tapHandler
+        acceptedButtons: Qt.RightButton
+        gesturePolicy: TapHandler.WithinBounds
+        onTapped: {
+            mapview.currentMarker = -1
+            for (var i = 0; i< mapview.markers.length; i++){
+                if (marker == mapview.markers[i]){
+                    mapview.currentMarker = i
+                    break
+                }
+            }
+            mapview.showMarkerMenu(marker.coordinate)
+        }
+    }
+    DragHandler {
+        id: dragHandler
+        grabPermissions: PointerHandler.CanTakeOverFromItems | PointerHandler.CanTakeOverFromHandlersOfDifferentType
+    }
+
+    sourceItem: Image {
+        id: image
+//! [mqi-anchor]
+        source: "../resources/marker.png"
+        opacity: hoverHandler.hovered ? 0.6 : 1.0
+
+        Text{
+            id: number
+            y: image.height/10
+            width: image.width
+            color: "white"
+            font.bold: true
+            font.pixelSize: 14
+            horizontalAlignment: Text.AlignHCenter
+            Component.onCompleted: {
+                text = mapview.markerCounter
+            }
+        }
+
+//! [mqi-closeimage]
+    }
+//! [mqi-closeimage]
+
+//! [mqi-close]
+}
+//! [mqi-close]

PySide6/examples/location/mapviewer/MapViewer/map/MiniMap.qml

@@ -0,0 +1,78 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtPositioning
+import QtLocation
+
+Rectangle{
+
+    function clamp(num, min, max)
+    {
+      return num < min ? min : num > max ? max : num;
+    }
+
+    function minimumScaleFactor()
+    {
+        var hscalefactor = (400.0 / Math.max(Math.min(mapview.width, 1000), 400)) * 0.5
+        var vscalefactor = (400.0 / Math.max(Math.min(mapview.height, 1000), 400)) * 0.5
+        return Math.min(hscalefactor,vscalefactor)
+    }
+
+    function avgScaleFactor()
+    {
+        var hscalefactor = (400.0 / Math.max(Math.min(mapview.width, 1000), 400)) * 0.5
+        var vscalefactor = (400.0 / Math.max(Math.min(mapview.height, 1000), 400)) * 0.5
+        return (hscalefactor+vscalefactor) * 0.5
+    }
+
+    id: miniMapRect
+    width: Math.floor(mapview.width * avgScaleFactor()) + 2
+    height: Math.floor(mapview.height * avgScaleFactor()) + 2
+    anchors.right: (parent) ? parent.right : undefined
+    anchors.rightMargin: 10
+    anchors.top: (parent) ? parent.top : undefined
+    anchors.topMargin: 10
+    color: "#242424"
+    Map {
+        id: miniMap
+        anchors.top: parent.top
+        anchors.topMargin: 1
+        anchors.left: parent.left
+        anchors.leftMargin: 1
+        width: Math.floor(mapview.width * avgScaleFactor())
+        height: Math.floor(mapview.height * avgScaleFactor())
+        zoomLevel: clamp(mapview.map.zoomLevel - 4.5, 1.0, 5.0) //(map.zoomLevel > minimumZoomLevel + 3) ? minimumZoomLevel + 3 : 1.5
+        center: mapview.map.center
+        plugin: mapview.map.plugin
+        copyrightsVisible: false
+        property double mapZoomLevel : mapview.map.zoomLevel
+
+        // cannot use property bindings on map.visibleRegion in MapRectangle because it's non-NOTIFYable
+        onCenterChanged: miniMapRectangle.updateCoordinates()
+        onMapZoomLevelChanged: miniMapRectangle.updateCoordinates()
+        onWidthChanged: miniMapRectangle.updateCoordinates()
+        onHeightChanged: miniMapRectangle.updateCoordinates()
+
+        MapRectangle {
+            id: miniMapRectangle
+            color: "#44ff0000"
+            border.width: 1
+            border.color: "red"
+            autoFadeIn: false
+
+            function getMapVisibleRegion()
+            {
+                return mapview.map.visibleRegion.boundingGeoRectangle()
+            }
+
+            function updateCoordinates()
+            {
+                topLeft.latitude =  getMapVisibleRegion().topLeft.latitude
+                topLeft.longitude=  getMapVisibleRegion().topLeft.longitude
+                bottomRight.latitude =  getMapVisibleRegion().bottomRight.latitude
+                bottomRight.longitude=  getMapVisibleRegion().bottomRight.longitude
+            }
+        }
+    }
+}

PySide6/examples/location/mapviewer/MapViewer/menus/ItemPopupMenu.qml

@@ -0,0 +1,19 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Controls
+
+Menu {
+    property variant type
+    signal itemClicked(string item)
+
+    MenuItem {
+        text: qsTr("Info")
+        onTriggered: itemClicked("show" + type + "Info")
+    }
+    MenuItem {
+        text: qsTr("Delete")
+        onTriggered: itemClicked("delete" + type)
+    }
+}

PySide6/examples/location/mapviewer/MapViewer/menus/MainMenu.qml

@@ -0,0 +1,122 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Controls
+import QtLocation
+
+MenuBar {
+    id: menuBar
+    property variant providerMenu: providerMenu
+    property variant mapTypeMenu: mapTypeMenu
+    property variant toolsMenu: toolsMenu
+    property variant plugin
+    property alias isFollowMe: toolsMenu.isFollowMe
+    property alias isMiniMap: toolsMenu.isMiniMap
+
+    signal selectProvider(string providerName)
+    signal selectMapType(variant mapType)
+    signal selectTool(string tool);
+    signal toggleMapState(string state)
+
+    function clearMenu(menu)
+    {
+        while (menu.count)
+            menu.removeItem(menu.itemAt(0))
+    }
+
+    Menu {
+        id: providerMenu
+        title: qsTr("Provider")
+
+        function createMenu(plugins)
+        {
+            clearMenu(providerMenu)
+            for (var i = 0; i < plugins.length; i++) {
+                createProviderMenuItem(plugins[i]);
+            }
+        }
+
+        function createProviderMenuItem(provider)
+        {
+            var action = Qt.createQmlObject('import QtQuick.Controls; Action{ text: "' + provider + '"; checkable: true; onTriggered: function(){selectProvider("' + provider + '")} }', providerMenu)
+            addAction(action)
+        }
+    }
+
+    Menu {
+        id: mapTypeMenu
+        title: qsTr("MapType")
+
+        Component {
+            id: mapTypeMenuActionComponent
+            Action {
+
+            }
+        }
+        function createMenu(map)
+        {
+            clearMenu(mapTypeMenu)
+            for (var i = 0; i<map.supportedMapTypes.length; i++) {
+                createMapTypeMenuItem(map.supportedMapTypes[i], map.activeMapType === map.supportedMapTypes[i]);
+            }
+        }
+
+        function createMapTypeMenuItem(mapType, checked)
+        {
+            var action = mapTypeMenuActionComponent.createObject(mapTypeMenu, { text: mapType.name, checkable: true, checked: checked })
+            action.triggered.connect(function(){selectMapType(mapType)})
+            addAction(action)
+        }
+    }
+
+    Menu {
+        id: toolsMenu
+        property bool isFollowMe: false;
+        property bool isMiniMap: false;
+        property variant plugin: menuBar.plugin
+
+        title: qsTr("Tools")
+
+        Action {
+            text: qsTr("Reverse geocode")
+            enabled: plugin ? plugin.supportsGeocoding(Plugin.ReverseGeocodingFeature) : false
+            onTriggered: selectTool("RevGeocode")
+        }
+        MenuItem {
+            text: qsTr("Geocode")
+            enabled: plugin ? plugin.supportsGeocoding() : false
+            onTriggered: selectTool("Geocode")
+        }
+        MenuItem {
+            text: qsTr("Route with coordinates")
+            enabled: plugin ? plugin.supportsRouting() : false
+            onTriggered: selectTool("CoordinateRoute")
+        }
+        MenuItem {
+            text: qsTr("Route with address")
+            enabled: plugin ? plugin.supportsRouting() : false
+            onTriggered: selectTool("AddressRoute")
+        }
+        MenuItem {
+            text: isMiniMap ? qsTr("Hide minimap") : qsTr("Minimap")
+            onTriggered: toggleMapState("MiniMap")
+        }
+        MenuItem {
+            text: isFollowMe ? qsTr("Stop following") : qsTr("Follow me")
+            onTriggered: toggleMapState("FollowMe")
+        }
+        MenuItem {
+            text: qsTr("Language")
+            onTriggered: selectTool("Language")
+        }
+        MenuItem {
+            text: qsTr("Prefetch Map Data")
+            onTriggered: selectTool("Prefetch")
+        }
+        MenuItem {
+            text: qsTr("Clear Map Data")
+            onTriggered: selectTool("Clear")
+        }
+    }
+}

PySide6/examples/location/mapviewer/MapViewer/menus/MapPopupMenu.qml

@@ -0,0 +1,30 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Controls
+
+Menu {
+    property variant coordinate
+    property int markersCount
+    property int mapItemsCount
+    signal itemClicked(string item)
+
+    MenuItem {
+        text: qsTr("Add Marker")
+        onTriggered: itemClicked("addMarker")
+    }
+    MenuItem {
+        text: qsTr("Get coordinate")
+        onTriggered: itemClicked("getCoordinate")
+    }
+    MenuItem {
+        text: qsTr("Fit Viewport To Markers")
+        onTriggered: itemClicked("fitViewport")
+    }
+    MenuItem {
+        text: qsTr("Delete all markers")
+        enabled: markersCount > 0
+        onTriggered: itemClicked("deleteMarkers")
+    }
+}

PySide6/examples/location/mapviewer/MapViewer/menus/MarkerPopupMenu.qml

@@ -0,0 +1,38 @@
+// Copyright (C) 2023 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Controls
+
+Menu {
+    property int currentMarker
+    property int markersCount
+    signal itemClicked(string item)
+
+    MenuItem {
+        text: qsTr("Delete")
+        onTriggered: itemClicked("deleteMarker")
+    }
+    MenuItem {
+        text: qsTr("Coordinates")
+        onTriggered: itemClicked("getMarkerCoordinate")
+    }
+    MenuItem {
+        text: qsTr("Move to")
+        onTriggered: itemClicked("moveMarkerTo")
+    }
+    MenuItem {
+        text: currentMarker < markersCount-2 ? qsTr("Route to next markers")
+                                             : qsTr("Route to next marker")
+        enabled: currentMarker <= markersCount - 2
+        onTriggered: currentMarker < markersCount-2 ? itemClicked("routeToNextPoints")
+                                                    : itemClicked("routeToNextPoint")
+    }
+    MenuItem {
+        text: currentMarker < markersCount-2 ? qsTr("Distance to next markers")
+                                             : qsTr("Distance to next marker")
+        enabled: currentMarker <= markersCount - 2
+        onTriggered: currentMarker < markersCount-2 ? itemClicked("distanceToNextPoints")
+                                                    : itemClicked("distanceToNextPoint")
+    }
+}

PySide6/examples/location/mapviewer/MapViewer/qmldir

@@ -0,0 +1,27 @@
+module MapViewer
+typeinfo mapviewer.qmltypes
+Main 1.0 Main.qml
+Helper 1.0 helper.js
+MapComponent 1.0 map/MapComponent.qml
+MapSliders 1.0 map/MapSliders.qml
+Marker 1.0 map/Marker.qml
+MiniMap 1.0 map/MiniMap.qml
+ItemPopupMenu 1.0 menus/ItemPopupMenu.qml
+MainMenu 1.0 menus/MainMenu.qml
+MapPopupMenu 1.0 menus/MapPopupMenu.qml
+MarkerPopupMenu 1.0 menus/MarkerPopupMenu.qml
+Geocode 1.0 forms/Geocode.qml
+GeocodeForm 1.0 forms/GeocodeForm.ui.qml
+Message 1.0 forms/Message.qml
+MessageForm 1.0 forms/MessageForm.ui.qml
+ReverseGeocode 1.0 forms/ReverseGeocode.qml
+ReverseGeocodeForm 1.0 forms/ReverseGeocodeForm.ui.qml
+RouteCoordinate 1.0 forms/RouteCoordinate.qml
+Locale 1.0 forms/Locale.qml
+LocaleForm 1.0 forms/LocaleForm.ui.qml
+RouteAddress 1.0 forms/RouteAddress.qml
+RouteAddressForm 1.0 forms/RouteAddressForm.ui.qml
+RouteCoordinateForm 1.0 forms/RouteCoordinateForm.ui.qml
+RouteList 1.0 forms/RouteList.qml
+RouteListDelegate 1.0 forms/RouteListDelegate.qml
+RouteListHeader 1.0 forms/RouteListHeader.qml

PySide6/examples/location/mapviewer/doc/mapviewer.rst

@@ -0,0 +1,14 @@
+Map Viewer Example
+==================
+
+.. tags:: Android
+
+The Map Viewer example shows how to display and interact with a map,
+search for an address, and find driving directions.
+
+This is a large example covering many basic uses of maps, positioning, and
+navigation services in Qt Location.
+
+.. image:: mapviewer.webp
+   :width: 400
+   :alt: Map Viewer Screenshot