PySide6-Examples 6.7.0__cp39-abi3-win_amd64.whl

PySide6/examples/quick/scenegraph/scenegraph_customgeometry/main.py

@@ -0,0 +1,152 @@
+# Copyright (C) 2022 The Qt Company Ltd.
+# SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+"""PySide6 port of the Qt Quick customgeometry example from Qt v6.x"""
+
+import sys
+from pathlib import Path
+
+from PySide6.QtQuick import (QQuickView, QQuickItem, QSGNode, QSGGeometryNode,
+                             QSGGeometry, QSGFlatColorMaterial)
+from PySide6.QtQml import QmlElement
+from PySide6.QtGui import QGuiApplication, QColor
+from PySide6.QtCore import (QPointF, QUrl, Property, Signal, Slot)
+
+# To be used on the @QmlElement decorator
+# (QML_IMPORT_MINOR_VERSION is optional)
+QML_IMPORT_NAME = "CustomGeometry"
+QML_IMPORT_MAJOR_VERSION = 1
+
+
+@QmlElement
+class BezierCurve(QQuickItem):
+    p1Changed = Signal()
+    p2Changed = Signal()
+    p3Changed = Signal()
+    p4Changed = Signal()
+    segmentCountChanged = Signal()
+
+    def __init__(self, parent=None):
+        super().__init__(parent)
+
+        self._p1 = QPointF(0, 0)
+        self._p2 = QPointF(1, 0)
+        self._p3 = QPointF(0, 1)
+        self._p4 = QPointF(1, 1)
+        self._segmentCount = 32
+
+        self._node = None
+        self._geometry = None
+        self.setFlag(QQuickItem.Flags.ItemHasContents, True)
+
+    def p1(self):
+        return self._p1
+
+    def p2(self):
+        return self._p2
+
+    def p3(self):
+        return self._p3
+
+    def p4(self):
+        return self._p4
+
+    def segmentCount(self):
+        return self._segmentCount
+
+    @Slot(QPointF)
+    def setP1(self, p):
+        if p != self._p1:
+            self._p1 = p
+            self.p1Changed.emit()
+            self.update()
+
+    @Slot(QPointF)
+    def setP2(self, p):
+        if p != self._p2:
+            self._p2 = p
+            self.p2Changed.emit()
+            self.update()
+
+    @Slot(QPointF)
+    def setP3(self, p):
+        if p != self._p3:
+            self._p3 = p
+            self.p3Changed.emit()
+            self.update()
+
+    @Slot(QPointF)
+    def setP4(self, p):
+        if p != self._p4:
+            self._p4 = p
+            self.p4Changed.emit()
+            self.update()
+
+    @Slot(int)
+    def setSegmentCount(self, p):
+        if p != self._segmentCount:
+            self._segmentCount = p
+            self.segmentCountChanged.emit()
+            self.update()
+
+    def updatePaintNode(self, oldNode, updatePaintNodeData):
+        self._node = oldNode
+        if not self._node:
+            self._default_attributes = QSGGeometry.defaultAttributes_Point2D()
+            self._geometry = QSGGeometry(self._default_attributes, self._segmentCount)
+            self._geometry.setLineWidth(2)
+            self._geometry.setDrawingMode(QSGGeometry.DrawingMode.DrawLineStrip)
+
+            self._node = QSGGeometryNode()
+            self._node.setGeometry(self._geometry)
+            self._node.setFlag(QSGNode.Flags.OwnsGeometry)
+            self._material = QSGFlatColorMaterial()
+            self._material.setColor(QColor(255, 0, 0))
+            self._node.setMaterial(self._material)
+            self._node.setFlag(QSGNode.Flags.OwnsMaterial)
+        else:
+            self._geometry = self._node.geometry()
+            self._geometry.allocate(self._segmentCount)
+
+        item_size = self.size()
+        item_width = float(item_size.width())
+        item_height = float(item_size.height())
+        vertices = self._geometry.vertexDataAsPoint2D()
+        for i in range(self._segmentCount):
+            t = float(i) / float(self._segmentCount - 1)
+            inv_t = 1 - t
+            pos = ((inv_t * inv_t * inv_t * self._p1)
+                   + (3 * inv_t * inv_t * t * self._p2)
+                   + (3 * inv_t * t * t * self._p3)
+                   + (t * t * t * self._p4))
+            vertices[i].set(pos.x() * item_width, pos.y() * item_height)
+
+        self._geometry.setVertexDataAsPoint2D(vertices)
+
+        self._node.markDirty(QSGNode.DirtyGeometry)
+        return self._node
+
+    p1 = Property(QPointF, p1, setP1, notify=p1Changed)
+    p2 = Property(QPointF, p2, setP2, notify=p2Changed)
+    p3 = Property(QPointF, p3, setP3, notify=p3Changed)
+    p4 = Property(QPointF, p4, setP4, notify=p4Changed)
+
+    segmentCount = Property(int, segmentCount, setSegmentCount,
+                            notify=segmentCountChanged)
+
+
+if __name__ == "__main__":
+    app = QGuiApplication([])
+    view = QQuickView()
+    format = view.format()
+    format.setSamples(16)
+    view.setFormat(format)
+
+    qml_file = Path(__file__).parent / "main.qml"
+    view.setSource(QUrl.fromLocalFile(qml_file))
+    if not view.rootObject():
+        sys.exit(-1)
+    view.show()
+    ex = app.exec()
+    del view
+    sys.exit(ex)

PySide6/examples/quick/scenegraph/scenegraph_customgeometry/main.qml

@@ -0,0 +1,34 @@
+// Copyright (C) 2022 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import CustomGeometry
+
+Item {
+    width: 300
+    height: 200
+
+    BezierCurve {
+        id: line
+        anchors.fill: parent
+        anchors.margins: 20
+        property real t
+        SequentialAnimation on t {
+            NumberAnimation { to: 1; duration: 2000; easing.type: Easing.InOutQuad }
+            NumberAnimation { to: 0; duration: 2000; easing.type: Easing.InOutQuad }
+            loops: Animation.Infinite
+        }
+
+        p2: Qt.point(t, 1 - t)
+        p3: Qt.point(1 - t, t)
+    }
+
+    Text {
+        anchors.bottom: line.bottom
+        x: 20
+        width: parent.width - 40
+        wrapMode: Text.WordWrap
+
+        text: "This curve is a custom scene graph item, implemented using GL_LINE_STRIP"
+    }
+}

PySide6/examples/quick/scenegraph/scenegraph_customgeometry/scenegraph_customgeometry.pyproject

@@ -0,0 +1,3 @@
+{
+    "files": ["main.py","main.qml"]
+}

PySide6/examples/quick/shared/Button.qml

@@ -0,0 +1,50 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+import QtQuick.Window 2.1
+
+Item {
+    id: container
+
+    property alias text: buttonLabel.text
+    property alias label: buttonLabel
+    signal clicked
+    property alias containsMouse: hoverHandler.hovered
+    property alias pressed: tapHandler.pressed
+    implicitHeight: Math.max(Screen.pixelDensity * 7, buttonLabel.implicitHeight * 1.2)
+    implicitWidth: Math.max(Screen.pixelDensity * 11, buttonLabel.implicitWidth * 1.3)
+    height: implicitHeight
+    width: implicitWidth
+
+    SystemPalette { id: palette }
+
+    Rectangle {
+        id: frame
+        anchors.fill: parent
+        color: palette.button
+        gradient: Gradient {
+            GradientStop { position: 0.0; color: tapHandler.pressed ? Qt.darker(palette.button, 1.3) : palette.button }
+            GradientStop { position: 1.0; color: Qt.darker(palette.button, 1.3) }
+        }
+        antialiasing: true
+        radius: height / 6
+        border.color: Qt.darker(palette.button, 1.5)
+        border.width: 1
+    }
+
+    TapHandler {
+        id: tapHandler
+        onTapped: container.clicked();
+    }
+    HoverHandler {
+        id: hoverHandler
+    }
+
+    Text {
+        id: buttonLabel
+        text: container.text
+        color: palette.buttonText
+        anchors.centerIn: parent
+    }
+}

PySide6/examples/quick/shared/CheckBox.qml

@@ -0,0 +1,59 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+
+Item {
+    id: root
+    implicitHeight: frame.height
+    implicitWidth: row.implicitWidth
+    width: implicitWidth
+    height: implicitHeight
+    property alias text: label.text
+    property bool checked
+    property alias pressed: tapHandler.pressed
+    property alias row: row
+    signal clicked
+
+    SystemPalette { id: palette }
+
+    Row {
+        id: row
+        anchors.verticalCenter: parent.verticalCenter
+        spacing: 6
+        Rectangle {
+            id: frame
+            gradient: Gradient {
+                GradientStop { position: 0.0; color: tapHandler.pressed ? Qt.darker(palette.button, 1.3) : palette.button }
+                GradientStop { position: 1.0; color: Qt.darker(palette.button, 1.3) }
+            }
+            height: label.implicitHeight * 1.5
+            width: height
+            anchors.margins: 1
+            radius: 3
+            antialiasing: true
+            border.color: Qt.darker(palette.button, 1.5)
+            Image {
+                id: theX
+                source: "images/checkmark.png"
+                anchors.fill: frame
+                anchors.margins: frame.width / 5
+                fillMode: Image.PreserveAspectFit
+                smooth: true
+                visible: root.checked
+            }
+        }
+        Text {
+            id: label
+            color: palette.text
+            anchors.verticalCenter: frame.verticalCenter
+        }
+    }
+    TapHandler {
+        id: tapHandler
+        onTapped: {
+            parent.checked = !parent.checked
+            parent.clicked()
+        }
+    }
+}

PySide6/examples/quick/shared/FlickrRssModel.qml

@@ -0,0 +1,45 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+
+ListModel {
+    id: flickrImages
+    property string tags : ""
+    readonly property string queryUrl : "http://api.flickr.com/services/feeds/photos_public.gne?"
+
+    function encodeParams(x) {
+        return encodeURIComponent(x.replace(" ",","));
+    }
+    function fetchImages(format) {
+        var requestURL = queryUrl + (tags ? "tags="+encodeParams(tags)+"&" : "") + "format=" + format + "&nojsoncallback=1";
+        var xhr = new XMLHttpRequest;
+        xhr.onreadystatechange = function() {
+            if (xhr.readyState === XMLHttpRequest.DONE) {
+
+                if (xhr.status !== 200) {
+                    console.log("Failed to get images from flickr. status code: " + xhr.status);
+                    return;
+                }
+
+                var jsonText = xhr.responseText;
+                var objArray = JSON.parse(jsonText.replace(/\'/g,"'"))
+                if (objArray.errors !== undefined)
+                    console.log("Error fetching tweets: " + objArray.errors[0].message)
+                else {
+                    for (var key in objArray.items) {
+                        var rssItem = objArray.items[key];
+                        var jsonObject = "{ \"title\": \"" + rssItem.title +"\",\"media\": \"" + rssItem.media.m + "\", \"thumbnail\": \"" + rssItem.media.m.replace(/\_m\.jpg/,"_s.jpg") +"\"}"
+                        flickrImages.append(JSON.parse(jsonObject));
+                    }
+                }
+            }
+        }
+        xhr.open("GET", requestURL, true);
+        xhr.send();
+    }
+    Component.onCompleted: {
+        fetchImages("json");
+    }
+}
+

PySide6/examples/quick/shared/Images.qml

@@ -0,0 +1,14 @@
+// Copyright (C) 2021 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+pragma Singleton
+import QtQml
+
+QtObject {
+    readonly property url back:         Qt.resolvedUrl("images/back.png")
+    readonly property url checkmark:    Qt.resolvedUrl("images/checkmark.png")
+    readonly property url next:         Qt.resolvedUrl("images/next.png")
+    readonly property url qtLogo:       Qt.resolvedUrl("images/qt-logo.png")
+    readonly property url sliderHandle: Qt.resolvedUrl("images/slider_handle.png")
+    readonly property url tab:          Qt.resolvedUrl("images/tab.png")
+}

PySide6/examples/quick/shared/Label.qml

@@ -0,0 +1,9 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQuick
+
+Text {
+    SystemPalette { id: palette }
+    color: palette.text
+}

PySide6/examples/quick/shared/LauncherList.qml

@@ -0,0 +1,205 @@
+// Copyright (C) 2017 Crimson AS <info@crimson.no>
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+import QtQml
+import QtQml.Models 2.12
+import QtQuick
+
+Rectangle {
+    id: root
+    property int activePageCount: 0
+
+    //model is a list of {"name":"somename", "url":"file:///some/url/mainfile.qml"}
+    //function used to add to model A) to enforce scheme B) to allow Qt.resolveUrl in url assignments
+
+    color: "#eee"
+    function addExample(name, desc, url) {
+        myModel.append({"name":name, "description":desc, "url":url})
+    }
+    function showExample(url) {
+        pageComponent.createObject(pageContainer, { exampleUrl: url }).show()
+    }
+
+    // The container rectangle here is used to give a nice "feel" when
+    // transitioning into an example.
+    Rectangle {
+        anchors.fill: parent
+        color: "black"
+
+        ListView {
+            id: launcherList
+            clip: true
+            delegate: SimpleLauncherDelegate{
+                required property url url
+                onClicked: root.showExample(url)
+            }
+            model: ListModel {id:myModel}
+            anchors.fill: parent
+            enabled: opacity == 1.0
+        }
+    }
+
+    Item {
+        id: pageContainer
+        anchors.fill: parent
+    }
+
+    Component {
+        id: pageComponent
+        Rectangle {
+            id: page
+            clip: true
+            property url exampleUrl
+            width: parent.width
+            height: parent.height - bar.height
+            color: "white"
+            TapHandler {
+                //Eats mouse events
+            }
+            Loader{
+                focus: true
+                source: parent.exampleUrl
+                anchors.fill: parent
+            }
+
+            function show() {
+                showAnim.start()
+            }
+
+            function exit() {
+                exitAnim.start()
+            }
+
+            ParallelAnimation {
+                id: showAnim
+                ScriptAction {
+                    script: root.activePageCount++
+                }
+                NumberAnimation {
+                    target: launcherList
+                    property: "opacity"
+                    from: 1.0
+                    to: 0.0
+                    duration: 500
+                }
+                NumberAnimation {
+                    target: launcherList
+                    property: "scale"
+                    from: 1.0
+                    to: 0.0
+                    duration: 500
+                }
+                NumberAnimation {
+                    target: page
+                    property: "x"
+                    from: -page.width
+                    to: 0
+                    duration: 300
+                }
+            }
+            SequentialAnimation {
+                id: exitAnim
+
+                ScriptAction {
+                    script: root.activePageCount--
+                }
+
+                ParallelAnimation {
+                    NumberAnimation {
+                        target: launcherList
+                        property: "opacity"
+                        from: 0.0
+                        to: 1.0
+                        duration: 300
+                    }
+                    NumberAnimation {
+                        target: launcherList
+                        property: "scale"
+                        from: 0.0
+                        to: 1.0
+                        duration: 300
+                    }
+                    NumberAnimation {
+                        target: page
+                        property: "x"
+                        from: 0
+                        to: -page.width
+                        duration: 300
+                    }
+                }
+
+                ScriptAction {
+                    script: page.destroy()
+                }
+            }
+        }
+    }
+    Rectangle {
+        id: bar
+        visible: height > 0
+        anchors.bottom: parent.bottom
+        width: parent.width
+        height: root.activePageCount > 0 ? 40 : 0
+
+        Behavior on height {
+            NumberAnimation {
+                duration: 300
+            }
+        }
+
+        Rectangle {
+            height: 1
+            color: "#ccc"
+            anchors.top: parent.top
+            anchors.left: parent.left
+            anchors.right: parent.right
+        }
+
+        Rectangle {
+            height: 1
+            color: "#fff"
+            anchors.top: parent.top
+            anchors.topMargin: 1
+            anchors.left: parent.left
+            anchors.right: parent.right
+        }
+
+        gradient: Gradient {
+            GradientStop { position: 0 ; color: "#eee" }
+            GradientStop { position: 1 ; color: "#ccc" }
+        }
+
+        Image {
+            id: back
+            source: "images/back.png"
+            anchors.verticalCenter: parent.verticalCenter
+            anchors.verticalCenterOffset: 2
+            anchors.left: parent.left
+            anchors.leftMargin: 16
+
+            TapHandler {
+                id: tapHandler
+                enabled: root.activePageCount > 0
+                onTapped: {
+                    pageContainer.children[pageContainer.children.length - 1].exit()
+                }
+            }
+            Rectangle {
+                anchors.centerIn: back
+                width: 38
+                height: 31
+                anchors.verticalCenterOffset: -1
+                opacity: tapHandler.pressed ? 1 : 0
+                Behavior on opacity { NumberAnimation{ duration: 100 }}
+                gradient: Gradient {
+                    GradientStop { position: 0 ; color: "#22000000" }
+                    GradientStop { position: 0.2 ; color: "#11000000" }
+                }
+                border.color: "darkgray"
+                antialiasing: true
+                radius: 4
+            }
+        }
+    }
+}

PySide6/examples/quick/shared/README

@@ -0,0 +1,11 @@
+These files are shared between multiple examples as a set of common and
+reusuable components. While they do demonstrate the building of reusable
+components in QML, they are not official examples themselves.
+Consequently they do not have entries in the Qt documentation, and are
+documented only through the code comments within the files. Developers
+new to QML are strongly encouraged to go through the official examples
+before delving into this directory.
+
+For most application use, see the Qt Quick Components project to find
+ready-made Components you can use in your own projects. Qt Quick
+examples do not use them only to avoid external dependencies.

PySide6/examples/quick/shared/SimpleLauncherDelegate.qml

@@ -0,0 +1,96 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+import QtQuick
+
+Rectangle {
+    id: container
+    required property string name
+    required property string description
+
+    property Item exampleItem
+    width: ListView.view.width
+    height: button.implicitHeight + 22
+
+    signal clicked()
+
+    gradient: Gradient {
+        GradientStop {
+            position: 0
+            Behavior on color {ColorAnimation { duration: 100 }}
+            color: tapHandler.pressed ? "#e0e0e0" : "#fff"
+        }
+        GradientStop {
+            position: 1
+            Behavior on color {ColorAnimation { duration: 100 }}
+            color: tapHandler.pressed ? "#e0e0e0" : button.containsMouse ? "#f5f5f5" : "#eee"
+        }
+    }
+
+    Image {
+        id: image
+        opacity: 0.7
+        Behavior on opacity {NumberAnimation {duration: 100}}
+        source: "images/next.png"
+        anchors.verticalCenter: parent.verticalCenter
+        anchors.right: parent.right
+        anchors.rightMargin: 16
+    }
+
+    Item {
+        id: button
+        anchors.top: parent.top
+        anchors.left: parent.left
+        anchors.bottom: parent.bottom
+        anchors.right:image.left
+        implicitHeight: col.height
+        height: implicitHeight
+        width: buttonLabel.width + 20
+        property alias containsMouse: hoverHandler.hovered
+
+        TapHandler {
+            id: tapHandler
+            onTapped: container.clicked()
+        }
+        HoverHandler {
+            id: hoverHandler
+        }
+
+        Column {
+            spacing: 2
+            id: col
+            anchors.verticalCenter: parent.verticalCenter
+            width: parent.width
+            Text {
+                id: buttonLabel
+                anchors.left: parent.left
+                anchors.leftMargin: 10
+                anchors.right: parent.right
+                anchors.rightMargin: 10
+                text: container.name
+                color: "black"
+                font.pixelSize: 22
+                wrapMode: Text.WrapAtWordBoundaryOrAnywhere
+                styleColor: "white"
+                style: Text.Raised
+
+            }
+            Text {
+                id: buttonLabel2
+                anchors.left: parent.left
+                anchors.leftMargin: 10
+                text: container.description
+                wrapMode: Text.WrapAtWordBoundaryOrAnywhere
+                color: "#666"
+                font.pixelSize: 12
+            }
+        }
+    }
+
+    Rectangle {
+        height: 1
+        color: "#ccc"
+        anchors.bottom: parent.bottom
+        anchors.left: parent.left
+        anchors.right: parent.right
+    }
+}