PySide6-Examples 6.7.0__cp39-abi3-win_amd64.whl

PySide6/examples/scriptableapplication/CMakeLists.txt

@@ -0,0 +1,228 @@
+# Copyright (C) 2023 The Qt Company Ltd.
+# SPDX-License-Identifier: BSD-3-Clause
+
+cmake_minimum_required(VERSION 3.18)
+cmake_policy(VERSION 3.18)
+
+# Enable policy to run automoc on generated files.
+if(POLICY CMP0071)
+  cmake_policy(SET CMP0071 NEW)
+endif()
+
+project(scriptableapplication)
+
+# Set CPP standard to C++17 minimum.
+set(CMAKE_CXX_STANDARD 17)
+
+# Find required Qt packages.
+find_package(Qt6 COMPONENTS Core Gui Widgets)
+
+# Use provided python interpreter if given.
+if(NOT python_interpreter)
+    if(WIN32 AND "${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
+        find_program(python_interpreter "python_d")
+        if(NOT python_interpreter)
+            message(FATAL_ERROR
+                "A debug Python interpreter could not be found, which is a requirement when "
+                "building this example in a debug configuration. Make sure python_d.exe is in "
+                "PATH.")
+        endif()
+    else()
+        find_program(python_interpreter "python")
+        if(NOT python_interpreter)
+            message(FATAL_ERROR
+                "No Python interpreter could be found. Make sure python is in PATH.")
+        endif()
+    endif()
+endif()
+message(STATUS "Using python interpreter: ${python_interpreter}")
+
+# Macro to get various pyside / python include / link flags.
+macro(pyside_config option output_var)
+    if(${ARGC} GREATER 2)
+        set(is_list ${ARGV2})
+    else()
+        set(is_list "")
+    endif()
+
+    execute_process(
+      COMMAND ${python_interpreter} "${CMAKE_SOURCE_DIR}/../utils/pyside_config.py"
+              ${option}
+      OUTPUT_VARIABLE ${output_var}
+      OUTPUT_STRIP_TRAILING_WHITESPACE)
+
+    if ("${${output_var}}" STREQUAL "")
+        message(FATAL_ERROR "Error: Calling pyside_config.py ${option} returned no output.")
+    endif()
+    if(is_list)
+        string (REPLACE " " ";" ${output_var} "${${output_var}}")
+    endif()
+endmacro()
+
+# Query for the shiboken6-generator path, PySide6 path, Python path, include paths and linker flags.
+pyside_config(--shiboken-module-path SHIBOKEN_MODULE_PATH)
+pyside_config(--shiboken-generator-path SHIBOKEN_GENERATOR_PATH)
+pyside_config(--pyside-path PYSIDE_PATH)
+
+pyside_config(--python-include-path PYTHON_INCLUDE_DIR)
+pyside_config(--shiboken-generator-include-path SHIBOKEN_GENERATOR_INCLUDE_DIR 1)
+pyside_config(--pyside-include-path PYSIDE_INCLUDE_DIR 1)
+
+pyside_config(--python-link-flags-cmake PYTHON_LINKING_DATA 0)
+pyside_config(--shiboken-module-shared-libraries-cmake SHIBOKEN_MODULE_SHARED_LIBRARIES 0)
+pyside_config(--pyside-shared-libraries-cmake PYSIDE_SHARED_LIBRARIES 0)
+
+set(SHIBOKEN_PATH "${SHIBOKEN_GENERATOR_PATH}/shiboken6${CMAKE_EXECUTABLE_SUFFIX}")
+
+if(NOT EXISTS ${SHIBOKEN_PATH})
+    message(FATAL_ERROR "Shiboken executable not found at path: ${SHIBOKEN_PATH}")
+endif()
+
+
+# Get all relevant Qt include dirs, to pass them on to shiboken.
+get_property(QT_WIDGETS_INCLUDE_DIRS TARGET Qt6::Widgets PROPERTY INTERFACE_INCLUDE_DIRECTORIES)
+set(INCLUDES "")
+foreach(INCLUDE_DIR ${QT_WIDGETS_INCLUDE_DIRS})
+    list(APPEND INCLUDES "-I${INCLUDE_DIR}")
+endforeach()
+
+# On macOS, check if Qt is a framework build. This affects how include paths should be handled.
+get_target_property(QtCore_is_framework Qt6::Core FRAMEWORK)
+if (QtCore_is_framework)
+    get_target_property(qt_core_library_location Qt6::Core LOCATION)
+    # PYSIDE-623: We move up until the directory contains all the frameworks.
+    #             This is "lib" in ".../lib/QtCore.framework/Versions/A/QtCore".
+    get_filename_component(lib_dir "${qt_core_library_location}/../../../.." ABSOLUTE)
+    list(APPEND INCLUDES "--framework-include-paths=${lib_dir}")
+endif()
+
+# Set up the options to pass to shiboken.
+set(WRAPPED_HEADER ${CMAKE_SOURCE_DIR}/wrappedclasses.h)
+set(TYPESYSTEM_FILE ${CMAKE_SOURCE_DIR}/scriptableapplication.xml)
+
+set(SHIBOKEN_OPTIONS --generator-set=shiboken --enable-parent-ctor-heuristic
+    --enable-pyside-extensions --enable-return-value-heuristic --use-isnull-as-nb-bool
+    --avoid-protected-hack
+    ${INCLUDES}
+    -I${CMAKE_SOURCE_DIR}
+    -T${CMAKE_SOURCE_DIR}
+    -T${PYSIDE_PATH}/typesystems
+    --output-directory=${CMAKE_CURRENT_BINARY_DIR}
+    )
+
+# Specify which sources will be generated by shiboken, and their dependencies.
+set(GENERATED_SOURCES
+    ${CMAKE_CURRENT_BINARY_DIR}/AppLib/applib_module_wrapper.cpp
+    ${CMAKE_CURRENT_BINARY_DIR}/AppLib/mainwindow_wrapper.cpp)
+
+set(GENERATED_SOURCES_DEPENDENCIES
+    ${WRAPPED_HEADER}
+    ${TYPESYSTEM_FILE}
+    )
+
+# Add custom target to run shiboken.
+add_custom_command(OUTPUT ${GENERATED_SOURCES}
+                    COMMAND ${SHIBOKEN_PATH}
+                    ${SHIBOKEN_OPTIONS} ${WRAPPED_HEADER} ${TYPESYSTEM_FILE}
+                    DEPENDS ${GENERATED_SOURCES_DEPENDENCIES}
+                    WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+                    COMMENT "Running generator for ${TYPESYSTEM_FILE}.")
+
+# Set the CPP files.
+set(SOURCES
+    mainwindow.cpp
+    pythonutils.cpp
+    ${GENERATED_SOURCES}
+    )
+
+# We need to include the headers for the module bindings that we use.
+set(PYSIDE_ADDITIONAL_INCLUDES "")
+foreach(INCLUDE_DIR ${PYSIDE_INCLUDE_DIR})
+    list(APPEND PYSIDE_ADDITIONAL_INCLUDES "${INCLUDE_DIR}/QtCore")
+    list(APPEND PYSIDE_ADDITIONAL_INCLUDES "${INCLUDE_DIR}/QtGui")
+    list(APPEND PYSIDE_ADDITIONAL_INCLUDES "${INCLUDE_DIR}/QtWidgets")
+endforeach()
+
+# =============================================================================================
+# !!! (The section below is deployment related, so in a real world application you will want to
+# take care of this properly with some custom script or tool).
+# =============================================================================================
+# Enable rpaths so that the example can be executed from the build dir.
+set(CMAKE_SKIP_BUILD_RPATH FALSE)
+set(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
+set(CMAKE_INSTALL_RPATH ${PYSIDE_PATH} ${SHIBOKEN_MODULE_PATH})
+set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
+# =============================================================================================
+# !!! End of dubious section.
+# =============================================================================================
+
+# Declare executable so we can enable automoc.
+add_executable(${PROJECT_NAME} main.cpp)
+
+# Enable automoc.
+set_property(TARGET ${PROJECT_NAME} PROPERTY AUTOMOC 1)
+
+# Add the rest of the sources.
+target_sources(${PROJECT_NAME} PUBLIC ${SOURCES})
+
+# Apply relevant include and link flags.
+target_include_directories(${PROJECT_NAME} PRIVATE ${PYTHON_INCLUDE_DIR})
+target_include_directories(${PROJECT_NAME} PRIVATE ${SHIBOKEN_GENERATOR_INCLUDE_DIR})
+target_include_directories(${PROJECT_NAME} PRIVATE ${PYSIDE_INCLUDE_DIR})
+target_include_directories(${PROJECT_NAME} PRIVATE ${PYSIDE_ADDITIONAL_INCLUDES})
+target_include_directories(${PROJECT_NAME} PRIVATE ${CMAKE_SOURCE_DIR})
+
+target_link_libraries(${PROJECT_NAME} PRIVATE Qt6::Widgets)
+target_link_libraries(${PROJECT_NAME} PRIVATE ${SHIBOKEN_MODULE_SHARED_LIBRARIES})
+target_link_libraries(${PROJECT_NAME} PRIVATE ${PYSIDE_SHARED_LIBRARIES})
+
+# Find and link to the python library.
+list(GET PYTHON_LINKING_DATA 0 PYTHON_LIBDIR)
+list(GET PYTHON_LINKING_DATA 1 PYTHON_LIB)
+find_library(PYTHON_LINK_FLAGS ${PYTHON_LIB} PATHS ${PYTHON_LIBDIR} HINTS ${PYTHON_LIBDIR})
+target_link_libraries(${PROJECT_NAME} PRIVATE ${PYTHON_LINK_FLAGS})
+
+# Same as CONFIG += no_keywords to avoid syntax errors in object.h due to the usage of the word Slot
+target_compile_definitions(${PROJECT_NAME} PRIVATE QT_NO_KEYWORDS)
+
+if(WIN32)
+    # =============================================================================================
+    # !!! (The section below is deployment related, so in a real world application you will want to
+    # take care of this properly (this is simply to eliminate errors that users usually encounter.
+    # =============================================================================================
+    # Circumvent some "#pragma comment(lib)"s in "include/pyconfig.h" which might force to link
+    # against a wrong python shared library.
+
+    set(PYTHON_VERSIONS_LIST 3 36 37 38 39)
+    set(PYTHON_ADDITIONAL_LINK_FLAGS "")
+    foreach(VER ${PYTHON_VERSIONS_LIST})
+        set(PYTHON_ADDITIONAL_LINK_FLAGS
+            "${PYTHON_ADDITIONAL_LINK_FLAGS} /NODEFAULTLIB:\"python${VER}_d.lib\"")
+        set(PYTHON_ADDITIONAL_LINK_FLAGS
+            "${PYTHON_ADDITIONAL_LINK_FLAGS} /NODEFAULTLIB:\"python${VER}.lib\"")
+    endforeach()
+
+    set_target_properties(${PROJECT_NAME} PROPERTIES LINK_FLAGS "${PYTHON_ADDITIONAL_LINK_FLAGS}")
+
+    # Add custom target to hard link PySide6 shared libraries (just like in qmake example), so you
+    # don't have to set PATH manually to point to the PySide6 package.
+    set(shared_libraries ${SHIBOKEN_MODULE_SHARED_LIBRARIES} ${PYSIDE_SHARED_LIBRARIES})
+    foreach(LIBRARY_PATH ${shared_libraries})
+        string(REGEX REPLACE ".lib$" ".dll" LIBRARY_PATH ${LIBRARY_PATH})
+        get_filename_component(BASE_NAME ${LIBRARY_PATH} NAME)
+        file(TO_NATIVE_PATH ${LIBRARY_PATH} SOURCE_PATH)
+        file(TO_NATIVE_PATH "${CMAKE_CURRENT_BINARY_DIR}/${BASE_NAME}" DEST_PATH)
+        add_custom_command(OUTPUT "${BASE_NAME}"
+                            COMMAND mklink /H "${DEST_PATH}" "${SOURCE_PATH}"
+                            DEPENDS ${LIBRARY_PATH}
+                            WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}
+                            COMMENT "Creating hardlink to PySide6 shared library ${BASE_NAME}")
+
+        # Fake target that depends on the previous one, but has special ALL keyword, which means
+        # it will always be executed.
+        add_custom_target("fake_${BASE_NAME}" ALL DEPENDS ${BASE_NAME})
+    endforeach()
+    # =============================================================================================
+    # !!! End of dubious section.
+    # =============================================================================================
+endif()

PySide6/examples/scriptableapplication/doc/scriptableapplication.pyproject

@@ -0,0 +1,9 @@
+{
+    "files": ["../main.cpp",
+              "../mainwindow.cpp",
+              "../mainwindow.h",
+              "../pythonutils.cpp",
+              "../pythonutils.h",
+              "../wrappedclasses.h",
+              "../CMakeLists.txt"]
+}

PySide6/examples/scriptableapplication/doc/scriptableapplication.rst

@@ -0,0 +1,195 @@
+Scriptable Application Example
+==============================
+
+This example demonstrates how to make a Qt C++ application scriptable.
+
+It has a class ``MainWindow`` (files ``mainwindow.cpp,h``)
+that inherits from ``QMainWindow``, for which bindings are generated
+using Shiboken.
+
+The header ``wrappedclasses.h`` is passed to Shiboken which generates
+class wrappers and headers in a sub directory called ``AppLib/``
+which are linked to the application.
+
+The files ``pythonutils.cpp,h`` contain some code which binds the
+instance of ``MainWindow`` to a variable called ``mainWindow`` in
+the global Python namespace (``__main___``).
+It is then possible to run Python script snippets like:
+
+.. code-block:: python
+
+    mainWindow.testFunction1()
+
+which trigger the underlying C++ function.
+
+Building the project
+********************
+
+This example can be built using ``CMake`` or ``QMake``,
+but there are common requirements that you need to take into
+consideration:
+
+* Make sure that a --standalone PySide package (bundled with Qt libraries)
+  is installed into the current active Python environment
+  (system or virtualenv)
+* qmake has to be in your PATH:
+
+  * so that CMake find_package(Qt6 COMPONENTS Core) works (used for include
+    headers),
+  * used for building the application with qmake instead of CMake
+
+* use the same Qt version for building the example application, as was used
+  for building PySide, this is to ensure binary compatibility between the
+  newly generated bindings libraries, the PySide libraries and the
+  Qt libraries.
+
+For Windows you will also need:
+* a Visual Studio environment to be active in your terminal
+
+* Correct visual studio architecture chosen (32 vs 64 bit)
+
+* Make sure that your Qt + Python + PySide package + app build configuration
+  is the same (all Release, which is more likely, or all Debug).
+
+* Make sure that your Qt + Python + PySide package + app are built with a
+  compatible version of MSVC, to avoid mixing of C++ runtime libraries.
+
+Both build options will use the ``pyside_config.py`` file to configure the project
+using the current PySide/Shiboken installation (for qmake via ``pyside.pri``,
+and for CMake via the project ``CMakeLists.txt``).
+
+
+Using CMake
++++++++++++
+
+To build this example with CMake you will need a recent version of CMake (3.16+).
+
+You can build this example by executing the following commands
+(slightly adapted to your file system layout) in a terminal:
+
+macOS/Linux:
+
+.. code-block:: bash
+
+    cd ~/pyside-setup/examples/scriptableapplication
+
+On Windows:
+
+.. code-block:: bash
+
+    cd C:\pyside-setup\examples\scriptableapplication
+
+
+.. code-block:: bash
+
+    mkdir build
+    cd build
+    cmake -S.. -B. -G Ninja -DCMAKE_BUILD_TYPE=Release
+    ninja
+    ./scriptableapplication
+
+Using QMake
++++++++++++
+
+The file ``scriptableapplication.pro`` is the project file associated
+to the example when using qmake.
+
+You can build this example by executing:
+
+.. code-block:: bash
+
+    mkdir build
+    cd build
+    qmake ..
+    make # or nmake / jom for Windows
+
+
+Windows troubleshooting
+***********************
+
+Using ``qmake`` should work out of the box, there was a known issue
+with directories and white spaces that is solved by using the
+"~1" character, so the path will change from:
+``c:\Program Files\Python39\libs``
+to
+``c:\Progra~1\Python39\libs``
+this will avoid the issues when the Makefiles are generated.
+
+It is possible when using ``CMake`` to pick up the wrong compiler
+for a different architecture, but it can be addressed explicitly
+by setting the ``CC`` environment variable:
+
+.. code-block:: bash
+
+    set CC=cl
+
+passing the compiler on the command line:
+
+.. code-block:: bash
+
+    cmake -S.. -B. -DCMAKE_C_COMPILER=cl.exe -DCMAKE_CXX_COMPILER=cl.exe
+
+or using the -G option:
+
+.. code-block:: bash
+
+    cmake -S.. -B. -G "Visual Studio 14 Win64" -DCMAKE_BUILD_TYPE=Release
+
+
+If the ``-G "Visual Studio 14 Win64"`` option is used, a ``sln`` file
+will be generated, and can be used with ``MSBuild``
+instead of ``ninja``.
+
+.. code-block:: bash
+
+    MSBuild scriptableapplication.sln "/p:Configuration=Release"
+
+Note that using the "Ninja" generator is preferred to
+the MSBuild one, because in the latter case the executable is placed
+into a directory other than the one that contains the dependency
+dlls (shiboken, pyside). This leads to execution problems if the
+application is started within the Release subdirectory and not the
+one containing the dependencies.
+
+Virtualenv Support
+******************
+
+If the application is started from a terminal with an activated python
+virtual environment, that environment's packages will be used for the
+python module import process.
+In this case, make sure that the application was built while the
+`virtualenv` was active, so that the build system picks up the correct
+python shared library and PySide package.
+
+Linux Shared Libraries Notes
+****************************
+
+For this example's purpose, we link against the absolute paths of the
+shared libraries (``libshiboken`` and ``libpyside``) because the
+installation of the modules is being done via wheels, and there is
+no clean solution to include symbolic links in the package
+(so that regular -lshiboken works).
+
+Windows Notes
+*************
+
+The build config of the application (Debug or Release) should match
+the PySide6 build config, otherwise the application will not properly
+work.
+
+In practice this means the only supported configurations are:
+
+#. release config build of the application +
+   PySide ``setup.py`` without ``--debug`` flag + ``python.exe`` for the
+   PySide build process + ``python39.dll`` for the linked in shared
+   library + release build of Qt.
+#. debug config build of the application +
+   PySide ``setup.py`` *with* ``--debug`` flag + ``python_d.exe`` for the
+   PySide build process + ``python39_d.dll`` for the linked in shared
+   library + debug build of Qt.
+
+This is necessary because all the shared libraries in question have to
+link to the same C++ runtime library (``msvcrt.dll`` or ``msvcrtd.dll``).
+To make the example as self-contained as possible, the shared libraries
+in use (``pyside6.dll``, ``shiboken6.dll``) are hard-linked into the build
+folder of the application.

PySide6/examples/scriptableapplication/main.cpp

@@ -0,0 +1,17 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+#include "mainwindow.h"
+
+#include <QApplication>
+#include <QScreen>
+
+int main(int argc, char *argv[])
+{
+    QApplication a(argc, argv);
+    MainWindow mainWindow;
+    const QRect availableGeometry =  mainWindow.screen()->availableGeometry();
+    mainWindow.resize(availableGeometry.width() / 2, availableGeometry.height() / 2);
+    mainWindow.show();
+    return a.exec();
+}

PySide6/examples/scriptableapplication/mainwindow.cpp

@@ -0,0 +1,107 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+#include "mainwindow.h"
+#include "pythonutils.h"
+
+#include <QtWidgets/QApplication>
+#include <QtWidgets/QMenu>
+#include <QtWidgets/QMenuBar>
+#include <QtWidgets/QPlainTextEdit>
+#include <QtWidgets/QStatusBar>
+#include <QtWidgets/QToolBar>
+#include <QtWidgets/QVBoxLayout>
+
+#include <QtGui/QAction>
+#include <QtGui/QFontDatabase>
+#include <QtGui/QIcon>
+
+#include <QtCore/QDebug>
+#include <QtCore/QTextStream>
+
+using namespace Qt::StringLiterals;
+
+static const auto defaultScript = R"(import AppLib
+print("Hello, world")
+mainWindow.testFunction1()
+)"_L1;
+
+MainWindow::MainWindow()
+    : m_scriptEdit(new QPlainTextEdit(defaultScript, this))
+{
+    setWindowTitle(tr("Scriptable Application"));
+
+    auto  *fileMenu = menuBar()->addMenu(tr("&File"));
+    const QIcon runIcon = QIcon::fromTheme("system-run"_L1);
+    auto *runAction = fileMenu->addAction(runIcon, tr("&Run..."),
+                                          this, &MainWindow::slotRunScript);
+    runAction->setShortcut(Qt::CTRL | Qt::Key_R);
+    auto *diagnosticAction = fileMenu->addAction(tr("&Print Diagnostics"),
+                                                 this, &MainWindow::slotPrintDiagnostics);
+    diagnosticAction->setShortcut(Qt::CTRL | Qt::Key_D);
+    fileMenu->addAction(tr("&Invoke testFunction1()"),
+                        this, &MainWindow::testFunction1);
+    const QIcon quitIcon = QIcon::fromTheme(QIcon::ThemeIcon::ApplicationExit);
+    auto *quitAction = fileMenu->addAction(quitIcon, tr("&Quit"),
+                                           qApp, &QCoreApplication::quit);
+    quitAction->setShortcut(Qt::CTRL | Qt::Key_Q);
+
+    auto *editMenu = menuBar()->addMenu(tr("&Edit"));
+    const QIcon clearIcon = QIcon::fromTheme(QIcon::ThemeIcon::EditClear);
+    auto *clearAction = editMenu->addAction(clearIcon, tr("&Clear"),
+                                            m_scriptEdit, &QPlainTextEdit::clear);
+
+    auto *helpMenu = menuBar()->addMenu(tr("&Help"));
+    const QIcon aboutIcon = QIcon::fromTheme(QIcon::ThemeIcon::HelpAbout);
+    auto *aboutAction = helpMenu->addAction(aboutIcon, tr("&About Qt"),
+                                            qApp, &QApplication::aboutQt);
+
+    auto *toolBar = new QToolBar;
+    addToolBar(toolBar);
+    toolBar->addAction(quitAction);
+    toolBar->addSeparator();
+    toolBar->addAction(clearAction);
+    toolBar->addSeparator();
+    toolBar->addAction(runAction);
+    toolBar->addSeparator();
+    toolBar->addAction(aboutAction);
+
+    m_scriptEdit->setFont(QFontDatabase::systemFont(QFontDatabase::FixedFont));
+    setCentralWidget(m_scriptEdit);
+
+    if (!PythonUtils::bindAppObject("__main__"_L1, "mainWindow"_L1,
+                                    PythonUtils::MainWindowType, this)) {
+       statusBar()->showMessage(tr("Error loading the application module"));
+    }
+}
+
+void MainWindow::slotRunScript()
+{
+    const QString text = m_scriptEdit->toPlainText().trimmed();
+    if (!text.isEmpty())
+        runScript(text);
+}
+
+void MainWindow::slotPrintDiagnostics()
+{
+    const QString script = R"P(import sys
+print('Path=', sys.path)
+print('Executable=', sys.executable)
+)P"_L1;
+    runScript(script);
+}
+
+void MainWindow::runScript(const QString &script)
+{
+    if (!::PythonUtils::runScript(script))
+        statusBar()->showMessage(tr("Error running script"));
+}
+
+void MainWindow::testFunction1()
+{
+    static int n = 1;
+    QString message;
+    QTextStream(&message) << __FUNCTION__ << " called #" << n++;
+    qDebug().noquote() << message;
+    statusBar()->showMessage(message);
+}

PySide6/examples/scriptableapplication/mainwindow.h

@@ -0,0 +1,31 @@
+// Copyright (C) 2017 The Qt Company Ltd.
+// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR BSD-3-Clause
+
+#ifndef MAINWINDOW_H
+#define MAINWINDOW_H
+
+#include <QtWidgets/QMainWindow>
+
+QT_FORWARD_DECLARE_CLASS(QPlainTextEdit)
+
+class MainWindow : public QMainWindow
+{
+    Q_OBJECT
+public:
+    MainWindow();
+
+    void testFunction1();
+
+    static constexpr auto TEST = QLatin1StringView("test");
+
+private Q_SLOTS:
+    void slotRunScript();
+    void slotPrintDiagnostics();
+
+private:
+    void runScript(const QString &);
+
+    QPlainTextEdit *m_scriptEdit;
+};
+
+#endif // MAINWINDOW_H

PySide6/examples/scriptableapplication/pyside.pri

@@ -0,0 +1,52 @@
+PYSIDE_CONFIG = $$PWD/../utils/pyside_config.py
+
+# Use provided python interpreter if given.
+isEmpty(python_interpreter) {
+    python_interpreter = python
+}
+message(Using python interpreter: $$python_interpreter)
+
+SHIBOKEN_GENERATOR = $$system($$python_interpreter $$PYSIDE_CONFIG --shiboken-generator-path)
+isEmpty(SHIBOKEN_GENERATOR): error(Unable to locate the shiboken-generator package location)
+
+SHIBOKEN_MODULE = $$system($$python_interpreter $$PYSIDE_CONFIG --shiboken-module-path)
+isEmpty(SHIBOKEN_MODULE): error(Unable to locate the shiboken package location)
+
+PYSIDE = $$system($$python_interpreter $$PYSIDE_CONFIG --pyside-path)
+isEmpty(PYSIDE): error(Unable to locate the PySide package location)
+
+PYTHON_INCLUDE = $$system($$python_interpreter $$PYSIDE_CONFIG --python-include-path)
+isEmpty(PYTHON_INCLUDE): error(Unable to locate the Python include headers directory)
+
+PYTHON_LFLAGS = $$system($$python_interpreter $$PYSIDE_CONFIG --python-link-flags-qmake)
+isEmpty(PYTHON_LFLAGS): error(Unable to locate the Python library for linking)
+
+SHIBOKEN_INCLUDE = $$system($$python_interpreter $$PYSIDE_CONFIG --shiboken-generator-include-path)
+isEmpty(SHIBOKEN_INCLUDE): error(Unable to locate the shiboken include headers directory)
+
+PYSIDE_INCLUDE = $$system($$python_interpreter $$PYSIDE_CONFIG --pyside-include-path)
+isEmpty(PYSIDE_INCLUDE): error(Unable to locate PySide include headers directory)
+
+SHIBOKEN_LFLAGS = $$system($$python_interpreter $$PYSIDE_CONFIG --shiboken-module-qmake-lflags)
+isEmpty(SHIBOKEN_LFLAGS): error(Unable to locate the shiboken libraries for linking)
+
+PYSIDE_LFLAGS = $$system($$python_interpreter $$PYSIDE_CONFIG --pyside-qmake-lflags)
+isEmpty(PYSIDE_LFLAGS): error(Unable to locate the PySide libraries for linking)
+
+SHIBOKEN_SHARED_LIBRARIES = $$system($$python_interpreter $$PYSIDE_CONFIG --shiboken-module-shared-libraries-qmake)
+isEmpty(SHIBOKEN_SHARED_LIBRARIES): error(Unable to locate the used shiboken module shared libraries)
+
+PYSIDE_SHARED_LIBRARIES = $$system($$python_interpreter $$PYSIDE_CONFIG --pyside-shared-libraries-qmake)
+isEmpty(PYSIDE_SHARED_LIBRARIES): error(Unable to locate the used PySide shared libraries)
+
+INCLUDEPATH += "$$PYTHON_INCLUDE" $$PYSIDE_INCLUDE $$SHIBOKEN_INCLUDE
+LIBS += $$PYTHON_LFLAGS $$PYSIDE_LFLAGS $$SHIBOKEN_LFLAGS
+!build_pass:message(INCLUDEPATH is $$INCLUDEPATH)
+!build_pass:message(LIBS are $$LIBS)
+
+!build_pass:message(Using $$PYSIDE)
+
+!win32 {
+    !build_pass:message(RPATH will include $$PYSIDE and $$SHIBOKEN_MODULE)
+    QMAKE_RPATHDIR += $$PYSIDE $$SHIBOKEN_MODULE
+}