three-gpu-pathtracer 0.0.13 → 0.0.14

package/src/materials/pathtracing/glsl/attenuateHit.glsl.js

@@ -0,0 +1,179 @@
+export const attenuateHitGLSL = /* glsl */`
+
+	// step through multiple surface hits and accumulate color attenuation based on transmissive surfaces
+	// returns true if a solid surface was hit
+	bool attenuateHit(
+		BVH bvh, vec3 rayOrigin, vec3 rayDirection, float rayDist,
+		int traversals, int transmissiveTraversals, bool isShadowRay,
+		Material fogMaterial,
+		out vec3 color
+	) {
+
+		vec3 ogRayOrigin = rayOrigin;
+
+		// hit results
+		uvec4 faceIndices = uvec4( 0u );
+		vec3 faceNormal = vec3( 0.0, 0.0, 1.0 );
+		vec3 barycoord = vec3( 0.0 );
+		float side = 1.0;
+		float dist = 0.0;
+		LightSampleRecord lightSampleRec;
+
+		color = vec3( 1.0 );
+
+		// TODO: we should be using sobol sampling here instead of rand but the sobol bounce and path indices need to be incremented
+		// and then reset.
+		for ( int i = 0; i < traversals; i ++ ) {
+
+			int hitType = traceScene(
+				rayOrigin, rayDirection,
+				bvh, lights, fogMaterial,
+				faceIndices, faceNormal, barycoord, side, dist,
+				lightSampleRec
+			);
+
+			if ( hitType == FOG_HIT ) {
+
+				return true;
+
+			} else if ( hitType == LIGHT_HIT ) {
+
+				float totalDist = distance( ogRayOrigin, rayOrigin + rayDirection * lightSampleRec.dist );
+				return totalDist < rayDist - max( totalDist, rayDist ) * 1e-4;
+
+			} else if ( hitType == SURFACE_HIT ) {
+
+				float totalDist = distance( ogRayOrigin, rayOrigin + rayDirection * dist );
+				if ( totalDist > rayDist ) {
+
+					return false;
+
+				}
+
+				// TODO: attenuate the contribution based on the PDF of the resulting ray including refraction values
+				// Should be able to work using the material BSDF functions which will take into account specularity, etc.
+				// TODO: should we account for emissive surfaces here?
+
+				uint materialIndex = uTexelFetch1D( materialIndexAttribute, faceIndices.x ).r;
+				Material material = readMaterialInfo( materials, materialIndex );
+
+				// adjust the ray to the new surface
+				bool isEntering = side == 1.0;
+				rayOrigin = stepRayOrigin( rayOrigin, rayDirection, - faceNormal, dist );
+
+				#if FEATURE_FOG
+
+				if ( material.fogVolume ) {
+
+					fogMaterial = material;
+					fogMaterial.fogVolume = side == 1.0;
+					i -= sign( transmissiveTraversals );
+					transmissiveTraversals --;
+					continue;
+
+				}
+
+				#endif
+
+				if ( ! material.castShadow && isShadowRay ) {
+
+					continue;
+
+				}
+
+				vec2 uv = textureSampleBarycoord( attributesArray, ATTR_UV, barycoord, faceIndices.xyz ).xy;
+				vec4 vertexColor = textureSampleBarycoord( attributesArray, ATTR_COLOR, barycoord, faceIndices.xyz );
+
+				// albedo
+				vec4 albedo = vec4( material.color, material.opacity );
+				if ( material.map != - 1 ) {
+
+					vec3 uvPrime = material.mapTransform * vec3( uv, 1 );
+					albedo *= texture2D( textures, vec3( uvPrime.xy, material.map ) );
+
+				}
+
+				if ( material.vertexColors ) {
+
+					albedo *= vertexColor;
+
+				}
+
+				// alphaMap
+				if ( material.alphaMap != - 1 ) {
+
+					albedo.a *= texture2D( textures, vec3( uv, material.alphaMap ) ).x;
+
+				}
+
+				// transmission
+				float transmission = material.transmission;
+				if ( material.transmissionMap != - 1 ) {
+
+					vec3 uvPrime = material.transmissionMapTransform * vec3( uv, 1 );
+					transmission *= texture2D( textures, vec3( uvPrime.xy, material.transmissionMap ) ).r;
+
+				}
+
+				// metalness
+				float metalness = material.metalness;
+				if ( material.metalnessMap != - 1 ) {
+
+					vec3 uvPrime = material.metalnessMapTransform * vec3( uv, 1 );
+					metalness *= texture2D( textures, vec3( uvPrime.xy, material.metalnessMap ) ).b;
+
+				}
+
+				float alphaTest = material.alphaTest;
+				bool useAlphaTest = alphaTest != 0.0;
+				float transmissionFactor = ( 1.0 - metalness ) * transmission;
+				if (
+					transmissionFactor < rand() && ! (
+						// material sidedness
+						material.side != 0.0 && side == material.side
+
+						// alpha test
+						|| useAlphaTest && albedo.a < alphaTest
+
+						// opacity
+						|| material.transparent && ! useAlphaTest && albedo.a < rand()
+					)
+				) {
+
+					return true;
+
+				}
+
+				if ( side == 1.0 && isEntering ) {
+
+					// only attenuate by surface color on the way in
+					color *= mix( vec3( 1.0 ), albedo.rgb, transmissionFactor );
+
+				} else if ( side == - 1.0 ) {
+
+					// attenuate by medium once we hit the opposite side of the model
+					color *= transmissionAttenuation( dist, material.attenuationColor, material.attenuationDistance );
+
+				}
+
+				bool isTransmissiveRay = dot( rayDirection, faceNormal * side ) < 0.0;
+				if ( ( isTransmissiveRay || isEntering ) && transmissiveTraversals > 0 ) {
+
+					i -= sign( transmissiveTraversals );
+					transmissiveTraversals --;
+
+				}
+
+			} else {
+
+				return false;
+
+			}
+
+		}
+
+		return true;
+
+	}
+
+`;

package/src/materials/pathtracing/glsl/cameraUtils.glsl.js

@@ -0,0 +1,81 @@
+export const cameraUtilsGLSL = /* glsl */`
+
+	vec3 ndcToRayOrigin( vec2 coord ) {
+
+		vec4 rayOrigin4 = cameraWorldMatrix * invProjectionMatrix * vec4( coord, - 1.0, 1.0 );
+		return rayOrigin4.xyz / rayOrigin4.w;
+	}
+
+	void getCameraRay( out vec3 rayDirection, out vec3 rayOrigin ) {
+
+		vec2 ssd = vec2( 1.0 ) / resolution;
+
+		// Jitter the camera ray by finding a uv coordinate at a random sample
+		// around this pixel's UV coordinate for AA
+		vec2 ruv = sobol2( 0 );
+		vec2 jitteredUv = vUv + vec2( tentFilter( ruv.x ) * ssd.x, tentFilter( ruv.y ) * ssd.y );
+
+		#if CAMERA_TYPE == 2
+
+			// Equirectangular projection
+			vec4 rayDirection4 = vec4( equirectUvToDirection( jitteredUv ), 0.0 );
+			vec4 rayOrigin4 = vec4( 0.0, 0.0, 0.0, 1.0 );
+
+			rayDirection4 = cameraWorldMatrix * rayDirection4;
+			rayOrigin4 = cameraWorldMatrix * rayOrigin4;
+
+			rayDirection = normalize( rayDirection4.xyz );
+			rayOrigin = rayOrigin4.xyz / rayOrigin4.w;
+
+		#else
+
+			// get [- 1, 1] normalized device coordinates
+			vec2 ndc = 2.0 * jitteredUv - vec2( 1.0 );
+			rayOrigin = ndcToRayOrigin( ndc );
+
+			#if CAMERA_TYPE == 1
+
+				// Orthographic projection
+				rayDirection = ( cameraWorldMatrix * vec4( 0.0, 0.0, - 1.0, 0.0 ) ).xyz;
+				rayDirection = normalize( rayDirection );
+
+			#else
+
+				// Perspective projection
+				rayDirection = normalize( mat3(cameraWorldMatrix) * ( invProjectionMatrix * vec4( ndc, 0.0, 1.0 ) ).xyz );
+
+			#endif
+
+		#endif
+
+		#if FEATURE_DOF
+		{
+
+			// depth of field
+			vec3 focalPoint = rayOrigin + normalize( rayDirection ) * physicalCamera.focusDistance;
+
+			// get the aperture sample
+			// if blades === 0 then we assume a circle
+			vec3 shapeUVW= sobol3( 1 );
+			int blades = physicalCamera.apertureBlades;
+			float anamorphicRatio = physicalCamera.anamorphicRatio;
+			vec2 apertureSample = blades == 0 ? sampleCircle( shapeUVW.xy ) : sampleRegularPolygon( blades, shapeUVW );
+			apertureSample *= physicalCamera.bokehSize * 0.5 * 1e-3;
+
+			// rotate the aperture shape
+			apertureSample =
+				rotateVector( apertureSample, physicalCamera.apertureRotation ) *
+				saturate( vec2( anamorphicRatio, 1.0 / anamorphicRatio ) );
+
+			// create the new ray
+			rayOrigin += ( cameraWorldMatrix * vec4( apertureSample, 0.0, 0.0 ) ).xyz;
+			rayDirection = focalPoint - rayOrigin;
+
+		}
+		#endif
+
+		rayDirection = normalize( rayDirection );
+
+	}
+
+`;

package/src/materials/pathtracing/glsl/getSurfaceRecord.glsl.js

@@ -0,0 +1,317 @@
+
+export const getSurfaceRecordGLSL = /* glsl */`
+
+	#define SKIP_SURFACE 0
+	#define HIT_SURFACE 1
+	int getSurfaceRecord(
+		Material material, sampler2DArray attributesArray,
+		float side, vec3 barycoord, uvec4 faceIndices, vec3 faceNormal, float accumulatedRoughness,
+
+		out SurfaceRecord surf
+	) {
+
+		if ( material.fogVolume ) {
+
+			vec3 normal = vec3( 0, 0, 1 );
+
+			SurfaceRecord fogSurface;
+			fogSurface.volumeParticle = true;
+			fogSurface.color = material.color;
+			fogSurface.emission = material.emissiveIntensity * material.emissive;
+			fogSurface.normal = normal;
+			fogSurface.faceNormal = normal;
+			fogSurface.clearcoatNormal = normal;
+
+			surf = fogSurface;
+			return HIT_SURFACE;
+
+		}
+
+		// uv coord for textures
+		vec2 uv = textureSampleBarycoord( attributesArray, ATTR_UV, barycoord, faceIndices.xyz ).xy;
+		vec4 vertexColor = textureSampleBarycoord( attributesArray, ATTR_COLOR, barycoord, faceIndices.xyz );
+
+		// albedo
+		vec4 albedo = vec4( material.color, material.opacity );
+		if ( material.map != - 1 ) {
+
+			vec3 uvPrime = material.mapTransform * vec3( uv, 1 );
+			albedo *= texture2D( textures, vec3( uvPrime.xy, material.map ) );
+		}
+
+		if ( material.vertexColors ) {
+
+			albedo *= vertexColor;
+
+		}
+
+		// alphaMap
+		if ( material.alphaMap != - 1 ) {
+
+			albedo.a *= texture2D( textures, vec3( uv, material.alphaMap ) ).x;
+
+		}
+
+		// possibly skip this sample if it's transparent, alpha test is enabled, or we hit the wrong material side
+		// and it's single sided.
+		// - alpha test is disabled when it === 0
+		// - the material sidedness test is complicated because we want light to pass through the back side but still
+		// be able to see the front side. This boolean checks if the side we hit is the front side on the first ray
+		// and we're rendering the other then we skip it. Do the opposite on subsequent bounces to get incoming light.
+		float alphaTest = material.alphaTest;
+		bool useAlphaTest = alphaTest != 0.0;
+		if (
+			// material sidedness
+			material.side != 0.0 && side != material.side
+
+			// alpha test
+			|| useAlphaTest && albedo.a < alphaTest
+
+			// opacity
+			|| material.transparent && ! useAlphaTest && albedo.a < sobol( 3 )
+		) {
+
+			return SKIP_SURFACE;
+
+		}
+
+		// fetch the interpolated smooth normal
+		vec3 normal = normalize( textureSampleBarycoord(
+			attributesArray,
+			ATTR_NORMAL,
+			barycoord,
+			faceIndices.xyz
+		).xyz );
+
+		// roughness
+		float roughness = material.roughness;
+		if ( material.roughnessMap != - 1 ) {
+
+			vec3 uvPrime = material.roughnessMapTransform * vec3( uv, 1 );
+			roughness *= texture2D( textures, vec3( uvPrime.xy, material.roughnessMap ) ).g;
+
+		}
+
+		// metalness
+		float metalness = material.metalness;
+		if ( material.metalnessMap != - 1 ) {
+
+			vec3 uvPrime = material.metalnessMapTransform * vec3( uv, 1 );
+			metalness *= texture2D( textures, vec3( uvPrime.xy, material.metalnessMap ) ).b;
+
+		}
+
+		// emission
+		vec3 emission = material.emissiveIntensity * material.emissive;
+		if ( material.emissiveMap != - 1 ) {
+
+			vec3 uvPrime = material.emissiveMapTransform * vec3( uv, 1 );
+			emission *= texture2D( textures, vec3( uvPrime.xy, material.emissiveMap ) ).xyz;
+
+		}
+
+		// transmission
+		float transmission = material.transmission;
+		if ( material.transmissionMap != - 1 ) {
+
+			vec3 uvPrime = material.transmissionMapTransform * vec3( uv, 1 );
+			transmission *= texture2D( textures, vec3( uvPrime.xy, material.transmissionMap ) ).r;
+
+		}
+
+		// normal
+		if ( material.flatShading ) {
+
+			// if we're rendering a flat shaded object then use the face normals - the face normal
+			// is provided based on the side the ray hits the mesh so flip it to align with the
+			// interpolated vertex normals.
+			normal = faceNormal * side;
+
+		}
+
+		vec3 baseNormal = normal;
+		if ( material.normalMap != - 1 ) {
+
+			vec4 tangentSample = textureSampleBarycoord(
+				attributesArray,
+				ATTR_TANGENT,
+				barycoord,
+				faceIndices.xyz
+			);
+
+			// some provided tangents can be malformed (0, 0, 0) causing the normal to be degenerate
+			// resulting in NaNs and slow path tracing.
+			if ( length( tangentSample.xyz ) > 0.0 ) {
+
+				vec3 tangent = normalize( tangentSample.xyz );
+				vec3 bitangent = normalize( cross( normal, tangent ) * tangentSample.w );
+				mat3 vTBN = mat3( tangent, bitangent, normal );
+
+				vec3 uvPrime = material.normalMapTransform * vec3( uv, 1 );
+				vec3 texNormal = texture2D( textures, vec3( uvPrime.xy, material.normalMap ) ).xyz * 2.0 - 1.0;
+				texNormal.xy *= material.normalScale;
+				normal = vTBN * texNormal;
+
+			}
+
+		}
+
+		normal *= side;
+
+		// clearcoat
+		float clearcoat = material.clearcoat;
+		if ( material.clearcoatMap != - 1 ) {
+
+			vec3 uvPrime = material.clearcoatMapTransform * vec3( uv, 1 );
+			clearcoat *= texture2D( textures, vec3( uvPrime.xy, material.clearcoatMap ) ).r;
+
+		}
+
+		// clearcoatRoughness
+		float clearcoatRoughness = material.clearcoatRoughness;
+		if ( material.clearcoatRoughnessMap != - 1 ) {
+
+			vec3 uvPrime = material.clearcoatRoughnessMapTransform * vec3( uv, 1 );
+			clearcoatRoughness *= texture2D( textures, vec3( uvPrime.xy, material.clearcoatRoughnessMap ) ).g;
+
+		}
+
+		// clearcoatNormal
+		vec3 clearcoatNormal = baseNormal;
+		if ( material.clearcoatNormalMap != - 1 ) {
+
+			vec4 tangentSample = textureSampleBarycoord(
+				attributesArray,
+				ATTR_TANGENT,
+				barycoord,
+				faceIndices.xyz
+			);
+
+			// some provided tangents can be malformed (0, 0, 0) causing the normal to be degenerate
+			// resulting in NaNs and slow path tracing.
+			if ( length( tangentSample.xyz ) > 0.0 ) {
+
+				vec3 tangent = normalize( tangentSample.xyz );
+				vec3 bitangent = normalize( cross( clearcoatNormal, tangent ) * tangentSample.w );
+				mat3 vTBN = mat3( tangent, bitangent, clearcoatNormal );
+
+				vec3 uvPrime = material.clearcoatNormalMapTransform * vec3( uv, 1 );
+				vec3 texNormal = texture2D( textures, vec3( uvPrime.xy, material.clearcoatNormalMap ) ).xyz * 2.0 - 1.0;
+				texNormal.xy *= material.clearcoatNormalScale;
+				clearcoatNormal = vTBN * texNormal;
+
+			}
+
+		}
+
+		clearcoatNormal *= side;
+
+		// sheenColor
+		vec3 sheenColor = material.sheenColor;
+		if ( material.sheenColorMap != - 1 ) {
+
+			vec3 uvPrime = material.sheenColorMapTransform * vec3( uv, 1 );
+			sheenColor *= texture2D( textures, vec3( uvPrime.xy, material.sheenColorMap ) ).rgb;
+
+		}
+
+		// sheenRoughness
+		float sheenRoughness = material.sheenRoughness;
+		if ( material.sheenRoughnessMap != - 1 ) {
+
+			vec3 uvPrime = material.sheenRoughnessMapTransform * vec3( uv, 1 );
+			sheenRoughness *= texture2D( textures, vec3( uvPrime.xy, material.sheenRoughnessMap ) ).a;
+
+		}
+
+		// iridescence
+		float iridescence = material.iridescence;
+		if ( material.iridescenceMap != - 1 ) {
+
+			vec3 uvPrime = material.iridescenceMapTransform * vec3( uv, 1 );
+			iridescence *= texture2D( textures, vec3( uvPrime.xy, material.iridescenceMap ) ).r;
+
+		}
+
+		// iridescence thickness
+		float iridescenceThickness = material.iridescenceThicknessMaximum;
+		if ( material.iridescenceThicknessMap != - 1 ) {
+
+			vec3 uvPrime = material.iridescenceThicknessMapTransform * vec3( uv, 1 );
+			float iridescenceThicknessSampled = texture2D( textures, vec3( uvPrime.xy, material.iridescenceThicknessMap ) ).g;
+			iridescenceThickness = mix( material.iridescenceThicknessMinimum, material.iridescenceThicknessMaximum, iridescenceThicknessSampled );
+
+		}
+
+		iridescence = iridescenceThickness == 0.0 ? 0.0 : iridescence;
+
+		// specular color
+		vec3 specularColor = material.specularColor;
+		if ( material.specularColorMap != - 1 ) {
+
+			vec3 uvPrime = material.specularColorMapTransform * vec3( uv, 1 );
+			specularColor *= texture2D( textures, vec3( uvPrime.xy, material.specularColorMap ) ).rgb;
+
+		}
+
+		// specular intensity
+		float specularIntensity = material.specularIntensity;
+		if ( material.specularIntensityMap != - 1 ) {
+
+			vec3 uvPrime = material.specularIntensityMapTransform * vec3( uv, 1 );
+			specularIntensity *= texture2D( textures, vec3( uvPrime.xy, material.specularIntensityMap ) ).a;
+
+		}
+
+		surf.volumeParticle = false;
+
+		surf.faceNormal = faceNormal;
+		surf.normal = normal;
+
+		surf.metalness = metalness;
+		surf.color = albedo.rgb;
+		surf.emission = emission;
+
+		surf.ior = material.ior;
+		surf.transmission = transmission;
+		surf.thinFilm = material.thinFilm;
+		surf.attenuationColor = material.attenuationColor;
+		surf.attenuationDistance = material.attenuationDistance;
+
+		surf.clearcoatNormal = clearcoatNormal;
+		surf.clearcoat = clearcoat;
+
+		surf.sheen = material.sheen;
+		surf.sheenColor = sheenColor;
+
+		surf.iridescence = iridescence;
+		surf.iridescenceIor = material.iridescenceIor;
+		surf.iridescenceThickness = iridescenceThickness;
+
+		surf.specularColor = specularColor;
+		surf.specularIntensity = specularIntensity;
+
+		// apply perceptual roughness factor from gltf. sheen perceptual roughness is
+		// applied by its brdf function
+		// https://registry.khronos.org/glTF/specs/2.0/glTF-2.0.html#microfacet-surfaces
+		surf.roughness = roughness * roughness;
+		surf.clearcoatRoughness = clearcoatRoughness * clearcoatRoughness;
+		surf.sheenRoughness = sheenRoughness;
+
+		// frontFace is used to determine transmissive properties and PDF. If no transmission is used
+		// then we can just always assume this is a front face.
+		surf.frontFace = side == 1.0 || transmission == 0.0;
+		surf.eta = material.thinFilm || surf.frontFace ? 1.0 / material.ior : material.ior;
+		surf.f0 = iorRatioToF0( surf.eta );
+
+		// Compute the filtered roughness value to use during specular reflection computations.
+		// The accumulated roughness value is scaled by a user setting and a "magic value" of 5.0.
+		// If we're exiting something transmissive then scale the factor down significantly so we can retain
+		// sharp internal reflections
+		surf.filteredRoughness = applyFilteredGlossy( surf.roughness, accumulatedRoughness );
+		surf.filteredClearcoatRoughness = applyFilteredGlossy( surf.clearcoatRoughness, accumulatedRoughness );
+
+		return HIT_SURFACE;
+
+	}
+`;

package/src/materials/pathtracing/glsl/traceScene.glsl.js

@@ -0,0 +1,54 @@
+export const traceSceneGLSL = /* glsl */`
+
+	#define NO_HIT 0
+	#define SURFACE_HIT 1
+	#define LIGHT_HIT 2
+	#define FOG_HIT 3
+
+	int traceScene(
+
+		vec3 rayOrigin, vec3 rayDirection,
+		BVH bvh, LightsInfo lights, Material fogMaterial,
+		out uvec4 faceIndices, out vec3 faceNormal, out vec3 barycoord, out float side, out float dist,
+		out LightSampleRecord lightSampleRec
+
+	) {
+
+		bool hit = bvhIntersectFirstHit( bvh, rayOrigin, rayDirection, faceIndices, faceNormal, barycoord, side, dist );
+		bool lightHit = lightsClosestHit( lights.tex, lights.count, rayOrigin, rayDirection, lightSampleRec );
+
+		#if FEATURE_FOG
+
+		if ( fogMaterial.fogVolume ) {
+
+			float particleDist = intersectFogVolume( fogMaterial, sobol( 1 ) );
+			if ( particleDist + 1e-4 < dist && ( particleDist + 1e-4 < lightSampleRec.dist || ! lightHit ) ) {
+
+				side = 1.0;
+				faceNormal = normalize( - rayDirection );
+				dist = particleDist;
+				return FOG_HIT;
+
+			}
+
+		}
+
+		#endif
+
+		if ( lightHit && ( lightSampleRec.dist < dist || ! hit ) ) {
+
+			return LIGHT_HIT;
+
+		}
+
+		if ( hit ) {
+
+			return SURFACE_HIT;
+
+		}
+
+		return NO_HIT;
+
+	}
+
+`;