node-liblzma 1.0.4 → 1.1.4

package/deps/xz/m4/tuklib_cpucores.m4

@@ -1,148 +0,0 @@
-#
-# SYNOPSIS
-#
-#   TUKLIB_CPUCORES
-#
-# DESCRIPTION
-#
-#   Check how to find out the number of available CPU cores in the system.
-#   This information is used by tuklib_cpucores.c.
-#
-#   Supported methods:
-#     - GetSystemInfo(): Windows (including Cygwin)
-#     - sysctl(): BSDs, OS/2
-#     - sysconf(): GNU/Linux, Solaris, Tru64, IRIX, AIX, QNX, Cygwin (but
-#       GetSystemInfo() is used on Cygwin)
-#     - pstat_getdynamic(): HP-UX
-#
-# COPYING
-#
-#   Author: Lasse Collin
-#
-#   This file has been put into the public domain.
-#   You can do whatever you want with this file.
-#
-
-AC_DEFUN_ONCE([TUKLIB_CPUCORES], [
-AC_REQUIRE([TUKLIB_COMMON])
-
-# sys/param.h might be needed by sys/sysctl.h.
-AC_CHECK_HEADERS([sys/param.h])
-
-AC_CACHE_CHECK([how to detect the number of available CPU cores],
-	[tuklib_cv_cpucores_method], [
-
-# Maybe checking $host_os would be enough but this matches what
-# tuklib_cpucores.c does.
-#
-# NOTE: IRIX has a compiler that doesn't error out with #error, so use
-# a non-compilable text instead of #error to generate an error.
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#if defined(_WIN32) || defined(__CYGWIN__)
-int main(void) { return 0; }
-#else
-compile error
-#endif
-]])], [tuklib_cv_cpucores_method=special], [
-
-# FreeBSD has both cpuset and sysctl. Look for cpuset first because
-# it's a better approach.
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/param.h>
-#include <sys/cpuset.h>
-
-int
-main(void)
-{
-	cpuset_t set;
-	cpuset_getaffinity(CPU_LEVEL_WHICH, CPU_WHICH_PID, -1,
-			sizeof(set), &set);
-	return 0;
-}
-]])], [tuklib_cv_cpucores_method=cpuset], [
-
-# On OS/2, both sysconf() and sysctl() pass the tests in this file,
-# but only sysctl() works. On QNX it's the opposite: only sysconf() works
-# (although it assumes that _POSIX_SOURCE, _XOPEN_SOURCE, and _POSIX_C_SOURCE
-# are undefined or alternatively _QNX_SOURCE is defined).
-#
-# We test sysctl() first and intentionally break the sysctl() test on QNX
-# so that sysctl() is never used on QNX.
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#ifdef __QNX__
-compile error
-#endif
-#include <sys/types.h>
-#ifdef HAVE_SYS_PARAM_H
-#	include <sys/param.h>
-#endif
-#include <sys/sysctl.h>
-int
-main(void)
-{
-	int name[2] = { CTL_HW, HW_NCPU };
-	int cpus;
-	size_t cpus_size = sizeof(cpus);
-	sysctl(name, 2, &cpus, &cpus_size, NULL, 0);
-	return 0;
-}
-]])], [tuklib_cv_cpucores_method=sysctl], [
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <unistd.h>
-int
-main(void)
-{
-	long i;
-#ifdef _SC_NPROCESSORS_ONLN
-	/* Many systems using sysconf() */
-	i = sysconf(_SC_NPROCESSORS_ONLN);
-#else
-	/* IRIX */
-	i = sysconf(_SC_NPROC_ONLN);
-#endif
-	return 0;
-}
-]])], [tuklib_cv_cpucores_method=sysconf], [
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/param.h>
-#include <sys/pstat.h>
-
-int
-main(void)
-{
-	struct pst_dynamic pst;
-	pstat_getdynamic(&pst, sizeof(pst), 1, 0);
-	(void)pst.psd_proc_cnt;
-	return 0;
-}
-]])], [tuklib_cv_cpucores_method=pstat_getdynamic], [
-
-	tuklib_cv_cpucores_method=unknown
-])])])])])])
-
-case $tuklib_cv_cpucores_method in
-	cpuset)
-		AC_DEFINE([TUKLIB_CPUCORES_CPUSET], [1],
-			[Define to 1 if the number of available CPU cores
-			can be detected with cpuset(2).])
-		;;
-	sysctl)
-		AC_DEFINE([TUKLIB_CPUCORES_SYSCTL], [1],
-			[Define to 1 if the number of available CPU cores
-			can be detected with sysctl().])
-		;;
-	sysconf)
-		AC_DEFINE([TUKLIB_CPUCORES_SYSCONF], [1],
-			[Define to 1 if the number of available CPU cores
-			can be detected with sysconf(_SC_NPROCESSORS_ONLN)
-			or sysconf(_SC_NPROC_ONLN).])
-		;;
-	pstat_getdynamic)
-		AC_DEFINE([TUKLIB_CPUCORES_PSTAT_GETDYNAMIC], [1],
-			[Define to 1 if the number of available CPU cores
-			can be detected with pstat_getdynamic().])
-		;;
-esac
-])dnl

package/deps/xz/m4/tuklib_integer.m4

@@ -1,74 +0,0 @@
-#
-# SYNOPSIS
-#
-#   TUKLIB_INTEGER
-#
-# DESCRIPTION
-#
-#   Checks for tuklib_integer.h:
-#     - Endianness
-#     - Does operating system provide byte swapping macros
-#     - Does the hardware support fast unaligned access to 16-bit
-#       and 32-bit integers
-#
-# COPYING
-#
-#   Author: Lasse Collin
-#
-#   This file has been put into the public domain.
-#   You can do whatever you want with this file.
-#
-
-AC_DEFUN_ONCE([TUKLIB_INTEGER], [
-AC_REQUIRE([TUKLIB_COMMON])
-AC_REQUIRE([AC_C_BIGENDIAN])
-AC_CHECK_HEADERS([byteswap.h sys/endian.h sys/byteorder.h], [break])
-
-# Even if we have byteswap.h, we may lack the specific macros/functions.
-if test x$ac_cv_header_byteswap_h = xyes ; then
-	m4_foreach([FUNC], [bswap_16,bswap_32,bswap_64], [
-		AC_MSG_CHECKING([if FUNC is available])
-		AC_LINK_IFELSE([AC_LANG_SOURCE([
-#include <byteswap.h>
-int
-main(void)
-{
-	FUNC[](42);
-	return 0;
-}
-		])], [
-			AC_DEFINE(HAVE_[]m4_toupper(FUNC), [1],
-					[Define to 1 if] FUNC [is available.])
-			AC_MSG_RESULT([yes])
-		], [AC_MSG_RESULT([no])])
-
-	])dnl
-fi
-
-AC_MSG_CHECKING([if unaligned memory access should be used])
-AC_ARG_ENABLE([unaligned-access], AS_HELP_STRING([--enable-unaligned-access],
-		[Enable if the system supports *fast* unaligned memory access
-		with 16-bit and 32-bit integers. By default, this is enabled
-		only on x86, x86_64, and big endian PowerPC.]),
-	[], [enable_unaligned_access=auto])
-if test "x$enable_unaligned_access" = xauto ; then
-	# TODO: There may be other architectures, on which unaligned access
-	# is OK.
-	case $host_cpu in
-		i?86|x86_64|powerpc|powerpc64)
-			enable_unaligned_access=yes
-			;;
-		*)
-			enable_unaligned_access=no
-			;;
-	esac
-fi
-if test "x$enable_unaligned_access" = xyes ; then
-	AC_DEFINE([TUKLIB_FAST_UNALIGNED_ACCESS], [1], [Define to 1 if
-		the system supports fast unaligned access to 16-bit and
-		32-bit integers.])
-	AC_MSG_RESULT([yes])
-else
-	AC_MSG_RESULT([no])
-fi
-])dnl

package/deps/xz/m4/tuklib_mbstr.m4

@@ -1,30 +0,0 @@
-#
-# SYNOPSIS
-#
-#   TUKLIB_MBSTR
-#
-# DESCRIPTION
-#
-#   Check if multibyte and wide character functionality is available
-#   for use by tuklib_mbstr_* functions. If not enough multibyte string
-#   support is available in the C library, the functions keep working
-#   with the assumption that all strings are a in single-byte character
-#   set without combining characters, e.g. US-ASCII or ISO-8859-*.
-#
-#   This .m4 file and tuklib_mbstr.h are common to all tuklib_mbstr_*
-#   functions, but each function is put into a separate .c file so
-#   that it is possible to pick only what is strictly needed.
-#
-# COPYING
-#
-#   Author: Lasse Collin
-#
-#   This file has been put into the public domain.
-#   You can do whatever you want with this file.
-#
-
-AC_DEFUN_ONCE([TUKLIB_MBSTR], [
-AC_REQUIRE([TUKLIB_COMMON])
-AC_FUNC_MBRTOWC
-AC_CHECK_FUNCS([wcwidth])
-])dnl

package/deps/xz/m4/tuklib_physmem.m4

@@ -1,212 +0,0 @@
-#
-# SYNOPSIS
-#
-#   TUKLIB_PHYSMEM
-#
-# DESCRIPTION
-#
-#   Check how to get the amount of physical memory.
-#   This information is used in tuklib_physmem.c.
-#
-#   Supported methods:
-#
-#     - Windows (including Cygwin), OS/2, DJGPP (DOS), OpenVMS, AROS,
-#       and QNX have operating-system specific functions.
-#
-#     - AIX has _system_configuration.physmem.
-#
-#     - sysconf() works on GNU/Linux and Solaris, and possibly on
-#       some BSDs.
-#
-#     - BSDs use sysctl().
-#
-#     - Tru64 uses getsysinfo().
-#
-#     - HP-UX uses pstat_getstatic().
-#
-#     - IRIX has setinvent_r(), getinvent_r(), and endinvent_r().
-#
-#     - sysinfo() works on Linux/dietlibc and probably on other Linux
-#       systems whose libc may lack sysconf().
-#
-# COPYING
-#
-#   Author: Lasse Collin
-#
-#   This file has been put into the public domain.
-#   You can do whatever you want with this file.
-#
-
-AC_DEFUN_ONCE([TUKLIB_PHYSMEM], [
-AC_REQUIRE([TUKLIB_COMMON])
-
-# sys/param.h might be needed by sys/sysctl.h.
-AC_CHECK_HEADERS([sys/param.h])
-
-AC_CACHE_CHECK([how to detect the amount of physical memory],
-	[tuklib_cv_physmem_method], [
-
-# Maybe checking $host_os would be enough but this matches what
-# tuklib_physmem.c does.
-#
-# NOTE: IRIX has a compiler that doesn't error out with #error, so use
-# a non-compilable text instead of #error to generate an error.
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#if defined(_WIN32) || defined(__CYGWIN__) || defined(__OS2__) \
-		|| defined(__DJGPP__) || defined(__VMS) \
-		|| defined(AMIGA) || defined(__AROS__) || defined(__QNX__)
-int main(void) { return 0; }
-#else
-compile error
-#endif
-]])], [tuklib_cv_physmem_method=special], [
-
-# Look for AIX-specific solution before sysconf(), because the test
-# for sysconf() will pass on AIX but won't actually work
-# (sysconf(_SC_PHYS_PAGES) compiles but always returns -1 on AIX).
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/systemcfg.h>
-
-int
-main(void)
-{
-	(void)_system_configuration.physmem;
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=aix], [
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <unistd.h>
-int
-main(void)
-{
-	long i;
-	i = sysconf(_SC_PAGESIZE);
-	i = sysconf(_SC_PHYS_PAGES);
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=sysconf], [
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/types.h>
-#ifdef HAVE_SYS_PARAM_H
-#	include <sys/param.h>
-#endif
-#include <sys/sysctl.h>
-int
-main(void)
-{
-	int name[2] = { CTL_HW, HW_PHYSMEM };
-	unsigned long mem;
-	size_t mem_ptr_size = sizeof(mem);
-	sysctl(name, 2, &mem, &mem_ptr_size, NULL, 0);
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=sysctl], [
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/sysinfo.h>
-#include <machine/hal_sysinfo.h>
-
-int
-main(void)
-{
-	int memkb;
-	int start = 0;
-	getsysinfo(GSI_PHYSMEM, (caddr_t)&memkb, sizeof(memkb), &start);
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=getsysinfo],[
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/param.h>
-#include <sys/pstat.h>
-
-int
-main(void)
-{
-	struct pst_static pst;
-	pstat_getstatic(&pst, sizeof(pst), 1, 0);
-	(void)pst.physical_memory;
-	(void)pst.page_size;
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=pstat_getstatic],[
-
-AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <invent.h>
-int
-main(void)
-{
-	inv_state_t *st = NULL;
-	setinvent_r(&st);
-	getinvent_r(st);
-	endinvent_r(st);
-	return 0;
-}
-]])], [tuklib_cv_physmem_method=getinvent_r], [
-
-# This version of sysinfo() is Linux-specific. Some non-Linux systems have
-# different sysinfo() so we must check $host_os.
-case $host_os in
-	linux*)
-		AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
-#include <sys/sysinfo.h>
-int
-main(void)
-{
-	struct sysinfo si;
-	sysinfo(&si);
-	return 0;
-}
-		]])], [
-			tuklib_cv_physmem_method=sysinfo
-		], [
-			tuklib_cv_physmem_method=unknown
-		])
-		;;
-	*)
-		tuklib_cv_physmem_method=unknown
-		;;
-esac
-])])])])])])])])
-
-case $tuklib_cv_physmem_method in
-	aix)
-		AC_DEFINE([TUKLIB_PHYSMEM_AIX], [1],
-			[Define to 1 if the amount of physical memory
-			can be detected with _system_configuration.physmem.])
-		;;
-	sysconf)
-		AC_DEFINE([TUKLIB_PHYSMEM_SYSCONF], [1],
-			[Define to 1 if the amount of physical memory can
-			be detected with sysconf(_SC_PAGESIZE) and
-			sysconf(_SC_PHYS_PAGES).])
-		;;
-	sysctl)
-		AC_DEFINE([TUKLIB_PHYSMEM_SYSCTL], [1],
-			[Define to 1 if the amount of physical memory can
-			be detected with sysctl().])
-		;;
-	getsysinfo)
-		AC_DEFINE([TUKLIB_PHYSMEM_GETSYSINFO], [1],
-			[Define to 1 if the amount of physical memory can
-			be detected with getsysinfo().])
-		;;
-	pstat_getstatic)
-		AC_DEFINE([TUKLIB_PHYSMEM_PSTAT_GETSTATIC], [1],
-			[Define to 1 if the amount of physical memory can
-			be detected with pstat_getstatic().])
-		;;
-	getinvent_r)
-		AC_DEFINE([TUKLIB_PHYSMEM_GETINVENT_R], [1],
-			[Define to 1 if the amount of physical memory
-			can be detected with getinvent_r().])
-		;;
-	sysinfo)
-		AC_DEFINE([TUKLIB_PHYSMEM_SYSINFO], [1],
-			[Define to 1 if the amount of physical memory
-			can be detected with Linux sysinfo().])
-		;;
-esac
-])dnl

package/deps/xz/m4/tuklib_progname.m4

@@ -1,25 +0,0 @@
-#
-# SYNOPSIS
-#
-#   TUKLIB_PROGNAME
-#
-# DESCRIPTION
-#
-#   Put argv[0] into a global variable progname. On DOS-like systems,
-#   modify it so that it looks nice (no full path or .exe suffix).
-#
-#   This .m4 file is needed allow this module to use glibc's
-#   program_invocation_name.
-#
-# COPYING
-#
-#   Author: Lasse Collin
-#
-#   This file has been put into the public domain.
-#   You can do whatever you want with this file.
-#
-
-AC_DEFUN_ONCE([TUKLIB_PROGNAME], [
-AC_REQUIRE([TUKLIB_COMMON])
-AC_CHECK_DECLS([program_invocation_name], [], [], [#include <errno.h>])
-])dnl

package/deps/xz/m4/uintmax_t.m4

@@ -1,30 +0,0 @@
-# uintmax_t.m4 serial 12
-dnl Copyright (C) 1997-2004, 2007-2010 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-dnl From Paul Eggert.
-
-AC_PREREQ([2.13])
-
-# Define uintmax_t to 'unsigned long' or 'unsigned long long'
-# if it is not already defined in <stdint.h> or <inttypes.h>.
-
-AC_DEFUN([gl_AC_TYPE_UINTMAX_T],
-[
-  AC_REQUIRE([gl_AC_HEADER_INTTYPES_H])
-  AC_REQUIRE([gl_AC_HEADER_STDINT_H])
-  if test $gl_cv_header_inttypes_h = no && test $gl_cv_header_stdint_h = no; then
-    AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
-    test $ac_cv_type_unsigned_long_long_int = yes \
-      && ac_type='unsigned long long' \
-      || ac_type='unsigned long'
-    AC_DEFINE_UNQUOTED([uintmax_t], [$ac_type],
-      [Define to unsigned long or unsigned long long
-       if <stdint.h> and <inttypes.h> don't define.])
-  else
-    AC_DEFINE([HAVE_UINTMAX_T], [1],
-      [Define if you have the 'uintmax_t' type in <stdint.h> or <inttypes.h>.])
-  fi
-])

package/deps/xz/m4/visibility.m4

@@ -1,74 +0,0 @@
-# visibility.m4 serial 3 (gettext-0.18)
-dnl Copyright (C) 2005, 2008-2010 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-dnl From Bruno Haible.
-
-dnl Tests whether the compiler supports the command-line option
-dnl -fvisibility=hidden and the function and variable attributes
-dnl __attribute__((__visibility__("hidden"))) and
-dnl __attribute__((__visibility__("default"))).
-dnl Does *not* test for __visibility__("protected") - which has tricky
-dnl semantics (see the 'vismain' test in glibc) and does not exist e.g. on
-dnl MacOS X.
-dnl Does *not* test for __visibility__("internal") - which has processor
-dnl dependent semantics.
-dnl Does *not* test for #pragma GCC visibility push(hidden) - which is
-dnl "really only recommended for legacy code".
-dnl Set the variable CFLAG_VISIBILITY.
-dnl Defines and sets the variable HAVE_VISIBILITY.
-
-AC_DEFUN([gl_VISIBILITY],
-[
-  AC_REQUIRE([AC_PROG_CC])
-  CFLAG_VISIBILITY=
-  HAVE_VISIBILITY=0
-  if test -n "$GCC"; then
-    dnl First, check whether -Werror can be added to the command line, or
-    dnl whether it leads to an error because of some other option that the
-    dnl user has put into $CC $CFLAGS $CPPFLAGS.
-    AC_MSG_CHECKING([whether the -Werror option is usable])
-    AC_CACHE_VAL([gl_cv_cc_vis_werror], [
-      gl_save_CFLAGS="$CFLAGS"
-      CFLAGS="$CFLAGS -Werror"
-      AC_TRY_COMPILE([], [],
-        [gl_cv_cc_vis_werror=yes],
-        [gl_cv_cc_vis_werror=no])
-      CFLAGS="$gl_save_CFLAGS"])
-    AC_MSG_RESULT([$gl_cv_cc_vis_werror])
-    dnl Now check whether visibility declarations are supported.
-    AC_MSG_CHECKING([for simple visibility declarations])
-    AC_CACHE_VAL([gl_cv_cc_visibility], [
-      gl_save_CFLAGS="$CFLAGS"
-      CFLAGS="$CFLAGS -fvisibility=hidden"
-      dnl We use the option -Werror and a function dummyfunc, because on some
-      dnl platforms (Cygwin 1.7) the use of -fvisibility triggers a warning
-      dnl "visibility attribute not supported in this configuration; ignored"
-      dnl at the first function definition in every compilation unit, and we
-      dnl don't want to use the option in this case.
-      if test $gl_cv_cc_vis_werror = yes; then
-        CFLAGS="$CFLAGS -Werror"
-      fi
-      AC_TRY_COMPILE(
-        [extern __attribute__((__visibility__("hidden"))) int hiddenvar;
-         extern __attribute__((__visibility__("default"))) int exportedvar;
-         extern __attribute__((__visibility__("hidden"))) int hiddenfunc (void);
-         extern __attribute__((__visibility__("default"))) int exportedfunc (void);
-         void dummyfunc (void) {}],
-        [],
-        [gl_cv_cc_visibility=yes],
-        [gl_cv_cc_visibility=no])
-      CFLAGS="$gl_save_CFLAGS"])
-    AC_MSG_RESULT([$gl_cv_cc_visibility])
-    if test $gl_cv_cc_visibility = yes; then
-      CFLAG_VISIBILITY="-fvisibility=hidden"
-      HAVE_VISIBILITY=1
-    fi
-  fi
-  AC_SUBST([CFLAG_VISIBILITY])
-  AC_SUBST([HAVE_VISIBILITY])
-  AC_DEFINE_UNQUOTED([HAVE_VISIBILITY], [$HAVE_VISIBILITY],
-    [Define to 1 or 0, depending whether the compiler supports simple visibility declarations.])
-])

package/deps/xz/m4/wchar_t.m4

@@ -1,20 +0,0 @@
-# wchar_t.m4 serial 3 (gettext-0.18)
-dnl Copyright (C) 2002-2003, 2008-2010 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-dnl From Bruno Haible.
-dnl Test whether <stddef.h> has the 'wchar_t' type.
-dnl Prerequisite: AC_PROG_CC
-
-AC_DEFUN([gt_TYPE_WCHAR_T],
-[
-  AC_CACHE_CHECK([for wchar_t], [gt_cv_c_wchar_t],
-    [AC_TRY_COMPILE([#include <stddef.h>
-       wchar_t foo = (wchar_t)'\0';], ,
-       [gt_cv_c_wchar_t=yes], [gt_cv_c_wchar_t=no])])
-  if test $gt_cv_c_wchar_t = yes; then
-    AC_DEFINE([HAVE_WCHAR_T], [1], [Define if you have the 'wchar_t' type.])
-  fi
-])

package/deps/xz/m4/wint_t.m4

@@ -1,28 +0,0 @@
-# wint_t.m4 serial 4 (gettext-0.18)
-dnl Copyright (C) 2003, 2007-2010 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-dnl From Bruno Haible.
-dnl Test whether <wchar.h> has the 'wint_t' type.
-dnl Prerequisite: AC_PROG_CC
-
-AC_DEFUN([gt_TYPE_WINT_T],
-[
-  AC_CACHE_CHECK([for wint_t], [gt_cv_c_wint_t],
-    [AC_TRY_COMPILE([
-/* Tru64 with Desktop Toolkit C has a bug: <stdio.h> must be included before
-   <wchar.h>.
-   BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be included
-   before <wchar.h>.  */
-#include <stddef.h>
-#include <stdio.h>
-#include <time.h>
-#include <wchar.h>
-       wint_t foo = (wchar_t)'\0';], ,
-       [gt_cv_c_wint_t=yes], [gt_cv_c_wint_t=no])])
-  if test $gt_cv_c_wint_t = yes; then
-    AC_DEFINE([HAVE_WINT_T], [1], [Define if you have the 'wint_t' type.])
-  fi
-])

package/deps/xz/m4/xsize.m4

@@ -1,13 +0,0 @@
-# xsize.m4 serial 4
-dnl Copyright (C) 2003-2004, 2008-2010 Free Software Foundation, Inc.
-dnl This file is free software; the Free Software Foundation
-dnl gives unlimited permission to copy and/or distribute it,
-dnl with or without modifications, as long as this notice is preserved.
-
-AC_DEFUN([gl_XSIZE],
-[
-  dnl Prerequisites of lib/xsize.h.
-  AC_REQUIRE([gl_SIZE_MAX])
-  AC_REQUIRE([AC_C_INLINE])
-  AC_CHECK_HEADERS([stdint.h])
-])