gdharness 1.3.2 → 1.3.4

package/build/godot/addons/gdharness_editor/animation_reads.gd

@@ -81,15 +81,7 @@ static func animations(player: AnimationPlayer, animation_name: String) -> Dicti
 			listed.append(summary)
 		return {"ok": true, "animations": listed}
 	if not player.has_animation(StringName(animation_name)):
-		var names: PackedStringArray = player.get_animation_list()
-		return {
-			"ok": false,
-			"error":
-			(
-				"%s has no animation %s. It has: %s."
-				% [player.name, animation_name, ", ".join(names) if not names.is_empty() else "none"]
-			)
-		}
+		return {"ok": false, "error": no_animation(player, str(player.name), animation_name)}
 	var anim: Animation = player.get_animation(StringName(animation_name))
 	var answer: Dictionary = _summary(anim)
 	answer["ok"] = true
@@ -102,6 +94,16 @@ static func animations(player: AnimationPlayer, animation_name: String) -> Dicti
 	return answer
 
 
+## Why [param player], called [param called], cannot be asked for [param animation_name], with the
+## animations it has.
+static func no_animation(player: AnimationPlayer, called: String, animation_name: String) -> String:
+	var names: PackedStringArray = player.get_animation_list()
+	return (
+		"%s has no animation %s. It has: %s."
+		% [called, animation_name, ", ".join(names) if not names.is_empty() else "none"]
+	)
+
+
 static func _summary(anim: Animation) -> Dictionary:
 	return {
 		"length": anim.length,
@@ -162,8 +164,9 @@ static func state_machine(tree: AnimationTree, state_machine_path: String) -> An
 static func no_machine(tree: AnimationTree, state_machine_path: String) -> String:
 	if tree == null or tree.tree_root == null:
 		return (
-			"The AnimationTree has no tree_root. Make one with resource_edit create of an "
-			+ "AnimationNodeStateMachine, then give its res:// path to tree_root with scene_node set."
+			"The AnimationTree has no tree_root. Give it one with scene_node set: tree_root "
+			+ '{"_type": "AnimationNodeStateMachine"} builds one into the scene, and the res:// path '
+			+ "of one made with resource_edit create keeps it in a file of its own."
 		)
 	var current: AnimationNodeStateMachine = tree.tree_root as AnimationNodeStateMachine
 	if current == null:

package/build/godot/addons/gdharness_editor/declared_values.gd

@@ -58,12 +58,46 @@ static func enum_named(choices: Dictionary, word: String) -> Variant:
 	return null
 
 
-static func enum_refusal(holder: String, property: String, word: String, choices: Dictionary) -> String:
+## The values of the engine enum [param property] of [param target] holds, by the constants its
+## class declares them as: blend_mode's Add is BLEND_MODE_ADD in a script, and the hint gives only
+## the inspector's word. Empty for an enum a script declares.
+##
+## The enum is named by the setter's argument, as Node.ProcessMode, since the property list gives
+## an engine enum property no class of its own.
+static func engine_constants(target: Object, property: String) -> Dictionary:
+	var values: Dictionary = {}
+	var engine_class: String = target.get_class()
+	var setter: String = str(ClassDB.class_get_property_setter(engine_class, property))
+	if setter.is_empty():
+		return values
+	var named: String = ""
+	for method: Dictionary in ClassDB.class_get_method_list(engine_class):
+		var arguments: Array = method.get("args", [])
+		if str(method.get("name", "")) == setter and not arguments.is_empty():
+			var value_argument: Dictionary = arguments[-1]
+			named = str(value_argument.get("class_name", ""))
+			break
+	var holder: String = named.get_slice(".", 0)
+	if named.count(".") != 1 or not ClassDB.class_exists(holder):
+		return values
+	for constant: String in ClassDB.class_get_enum_constants(holder, named.get_slice(".", 1)):
+		values[constant] = ClassDB.class_get_integer_constant(holder, constant)
+	return values
+
+
+static func enum_refusal(
+	holder: String, property: String, word: String, choices: Dictionary, constants: Dictionary = {}
+) -> String:
+	var ways: String = "by name or by number"
+	if not constants.is_empty():
+		ways = "by name, by number or by the engine's constant, such as %s" % str(constants.keys()[0])
 	var said: String = (
-		"%s.%s is an enum, and %s is none of its values: send %s by name or by number"
-		% [holder, property, word, _listed(choices)]
+		"%s.%s is an enum, and %s is none of its values: send %s %s"
+		% [holder, property, word, _listed(choices), ways]
 	)
-	var close: PackedStringArray = GdhRead.nearest(word, PackedStringArray(choices.keys()))
+	var named: PackedStringArray = PackedStringArray(choices.keys())
+	named.append_array(PackedStringArray(constants.keys()))
+	var close: PackedStringArray = GdhRead.nearest(word, named)
 	if close.is_empty():
 		return said + "."
 	return said + ". The nearest %s %s." % ["is" if close.size() == 1 else "are", ", ".join(close)]
@@ -76,6 +110,17 @@ static func outside(target: Object, declared: Dictionary, value: Variant, shown:
 	var hint: int = GdhRead.as_int(declared.get("hint", PROPERTY_HINT_NONE))
 	var hint_string: String = str(declared.get("hint_string", ""))
 	var property: String = str(declared.get("name", ""))
+	if hint == PROPERTY_HINT_ENUM and (typeof(value) == TYPE_STRING or typeof(value) == TYPE_STRING_NAME):
+		var names: PackedStringArray = PackedStringArray(enum_values(hint_string).keys())
+		if names.is_empty() or names.has(str(value)):
+			return ""
+		return (
+			(
+				"%s is none of the names %s lists: %s, which the inspector holds it to; the engine "
+				+ "stores it as given."
+			)
+			% [shown, property, ", ".join(names)]
+		)
 	if typeof(value) != TYPE_INT and typeof(value) != TYPE_FLOAT:
 		return ""
 	var number: float = GdhRead.as_float(value)
@@ -114,3 +159,111 @@ static func _listed(choices: Dictionary) -> String:
 ## A range's end as the script wrote it: the engine's hint gives @export_range(0, 10) as 0.0 and 10.0.
 static func _bound(end: float) -> String:
 	return str(int(end)) if end == floorf(end) and absf(end) < 1e15 else str(end)
+
+
+## Puts back on [param built] what its script set as it was attached and was not among
+## [param wanted], to the defaults it declares, outside the editor. Attaching runs the script's _init
+## there, which the editor never runs for a script that is not a tool, so a resource_name _init chose
+## was saved as if asked for. A property whose default the engine cannot report is left as made.
+static func unmade(built: Resource, wanted: Dictionary) -> void:
+	var attached: Variant = built.get_script()
+	if Engine.is_editor_hint() or not attached is Script:
+		return
+	var script: Script = attached
+	var asked: Dictionary = {}
+	for key: Variant in wanted:
+		asked[str(key).get_slice(":", 0)] = true
+	for entry: Dictionary in built.get_property_list():
+		var name: String = str(entry["name"])
+		var usage: int = GdhRead.as_int(entry["usage"])
+		if usage & PROPERTY_USAGE_STORAGE == 0 or name == "script" or asked.has(name):
+			continue
+		var declared: Variant = ClassDB.class_get_property_default_value(built.get_class(), name)
+		if usage & PROPERTY_USAGE_SCRIPT_VARIABLE:
+			declared = script.get_property_default_value(name)
+		var held: Variant = built.get(name)
+		if declared != null and not (typeof(held) == typeof(declared) and held == declared):
+			built.set(name, declared)
+
+
+## The element types a typed Array or Dictionary property declares: [element] for an array,
+## [key, value] for a dictionary, [] when nothing is declared.
+##
+## Read from the declaration because the value cannot say: a script's exported `Array[int]` sits
+## behind a placeholder in the editor, and measured on 4.7.2 that placeholder stores [1.5, 2.0]
+## as given, which the game then fails to load into the typed array.
+static func elements_of(declared: Dictionary) -> Array:
+	var type: int = GdhRead.as_int(declared.get("type", TYPE_NIL), TYPE_NIL)
+	var hint: int = GdhRead.as_int(declared.get("hint", PROPERTY_HINT_NONE))
+	var wanted: String = str(declared.get("hint_string", ""))
+	if wanted.is_empty():
+		return []
+	if hint == PROPERTY_HINT_TYPE_STRING:
+		var parts: PackedStringArray = wanted.split(";")
+		if type == TYPE_ARRAY and parts.size() == 1:
+			return [_type_in_hint(parts[0])]
+		if type == TYPE_DICTIONARY and parts.size() == 2:
+			return [_type_in_hint(parts[0]), _type_in_hint(parts[1])]
+		return []
+	if hint == PROPERTY_HINT_ARRAY_TYPE and type == TYPE_ARRAY:
+		return [_type_named(wanted)]
+	if hint == PROPERTY_HINT_DICTIONARY_TYPE and type == TYPE_DICTIONARY:
+		var parts: PackedStringArray = wanted.split(";")
+		if parts.size() == 2:
+			return [_type_named(parts[0]), _type_named(parts[1])]
+	return []
+
+
+## The type at the front of one entry of a type-string hint, "2:" or "24/17:Texture2D".
+static func _type_in_hint(entry: String) -> int:
+	var number: String = entry.get_slice(":", 0).get_slice("/", 0)
+	return number.to_int() if number.is_valid_int() else TYPE_NIL
+
+
+## The Variant type [param name] names, or TYPE_OBJECT for a class.
+static func _type_named(name: String) -> int:
+	var named: String = name.get_slice(":", 0).strip_edges()
+	for type: int in TYPE_MAX:
+		if type_string(type) == named:
+			return type
+	return TYPE_OBJECT if not named.is_empty() else TYPE_NIL
+
+
+## The class the objects of a typed list or map hold, and whether they are nodes, as
+## [class, nodes], read from entry [param at] of [param declared]'s hint: "24/17:Item" in a type
+## string, "Item" in an array or dictionary type.
+static func object_kind(declared: Dictionary, at: int) -> Array:
+	var entry: String = str(declared.get("hint_string", "")).get_slice(";", at)
+	if GdhRead.as_int(declared.get("hint", PROPERTY_HINT_NONE)) != PROPERTY_HINT_TYPE_STRING:
+		return [entry.strip_edges(), false]
+	var nodes: bool = entry.get_slice(":", 0).get_slice("/", 1) == str(PROPERTY_HINT_NODE_TYPE)
+	return [entry.get_slice(":", 1), nodes]
+
+
+## The base class and script that type a list or map holding [param wanted], as [class, script],
+## or [] when nothing in the project or the engine is called that.
+static func object_typing(wanted: String) -> Array:
+	if ClassDB.class_exists(wanted):
+		return [StringName(wanted), null]
+	var script: Script = script_class(wanted)
+	return [] if script == null else [script.get_instance_base_type(), script]
+
+
+## The script declaring the class_name [param name], or null.
+static func script_class(name: String) -> Script:
+	for entry: Dictionary in ProjectSettings.get_global_class_list():
+		if str(entry.get("class", "")) == name:
+			return load(str(entry.get("path", ""))) as Script
+	return null
+
+
+## Whether [param value] is the class [param name] names, an engine class or a script's class_name.
+static func is_a(value: Object, name: String) -> bool:
+	if value.is_class(name):
+		return true
+	var script: Script = value.get_script()
+	while script != null:
+		if str(script.get_global_name()) == name:
+			return true
+		script = script.get_base_script()
+	return false

package/build/godot/addons/gdharness_editor/file_reads.gd

@@ -10,8 +10,8 @@ extends RefCounted
 ## without making a node. Loading the file still does what loading does in the game: static
 ## initialisers run, and a resource with a script is made with it.
 
-const GdhPropertyValues = preload("property_values.gd")
 const GdhRead = preload("reading.gd")
+const GdhSame = preload("same_values.gd")
 const GdhSerialisation = preload("serialisation.gd")
 
 
@@ -188,6 +188,12 @@ static func _lay(
 					path,
 					state.get_node_index(index)
 				)
+		# Every file on the way puts the node in its own groups: the scene making it, and each scene
+		# instancing or inheriting that one.
+		var grouped: Array[String] = nodes[path]["groups"]
+		for group: StringName in state.get_node_groups(index):
+			if not grouped.has(str(group)):
+				grouped.append(str(group))
 		var held: Dictionary = nodes[path]["properties"]
 		for property: int in state.get_node_property_count(index):
 			held[str(state.get_node_property_name(index, property))] = state.get_node_property_value(
@@ -281,7 +287,8 @@ static func _by_id(nodes: Dictionary, owner: String, id: int) -> String:
 
 static func _made(type: String) -> Dictionary:
 	var children: Array[String] = []
-	return {"name": "", "type": type, "properties": {}, "children": children}
+	var groups: Array[String] = []
+	return {"name": "", "type": type, "properties": {}, "children": children, "groups": groups}
 
 
 ## Puts [param path] among [param parent]'s children, at [param at] when the file says where (a node
@@ -317,6 +324,11 @@ static func _entry(
 		data["instanceOf"] = node["instanceOf"]
 		if node.has("editableChildren"):
 			data["editableChildren"] = node["editableChildren"]
+	var groups: Array[String] = node["groups"]
+	if not groups.is_empty():
+		var sorted: Array[String] = groups.duplicate()
+		sorted.sort()
+		data["groups"] = sorted
 	if include_properties:
 		var given: Dictionary = node["properties"]
 		data["properties"] = _stored(str(node["type"]), given)
@@ -419,7 +431,7 @@ static func resource(res_path: String, include_defaults: bool) -> Dictionary:
 				if scripted.has(property)
 				else ClassDB.class_get_property_default_value(loaded.get_class(), property)
 			)
-			if GdhPropertyValues.same(value, default):
+			if GdhSame.same(value, default):
 				continue
 		properties[property] = serialiser.serialize_value(value)
 	var answer: Dictionary = {

package/build/godot/addons/gdharness_editor/file_walk.gd

@@ -0,0 +1,134 @@
+@tool
+extends RefCounted
+
+const GdhRead = preload("reading.gd")
+
+# Two walks rather than one because they disagree about hidden entries on purpose: a suffix
+# walk descends into every visible directory and matches whole names, while the extension walk
+# skips anything beginning with a dot, including .import sidecars that would otherwise answer
+# for the resource they belong to.
+#
+# Both stop at a `.gdignore`, because the engine does: nothing under one is imported, so what is
+# in there is not a resource, not a dependency and not a global class. Walking in anyway hands
+# every caller files the engine will never answer for.
+
+
+# Why [param path], a res:// or uid:// path a setting names, is not a file the engine can load, or
+# empty when it is. A uid:// path resolves through the project's uid cache, which the import writes,
+# so one that does not resolve is a file that has gone or a project not imported yet, and saying
+# only that the file does not exist sent a caller looking for a scene that was there.
+static func missing_reason(path: String) -> String:
+	if path.begins_with("uid://"):
+		var id: int = ResourceUID.text_to_id(path)
+		if id == ResourceUID.INVALID_ID or not ResourceUID.has_id(id):
+			return (
+				path
+				+ " does not resolve: no file in the project's uid cache has it, so the file has gone or the"
+				+ " project has not been imported yet (project_import refresh_uids imports it)"
+			)
+		var resolved: String = ResourceUID.get_id_path(id)
+		return (
+			"" if FileAccess.file_exists(resolved) else path + " names " + resolved + ", which does not exist"
+		)
+	return "" if FileAccess.file_exists(path) else path + " does not exist"
+
+
+## [param said], the refusal for [param path], a res:// path nothing is at, with the files of its
+## extension whose names are nearest its own, or every one when there are few and none is near, so
+## the caller has a path to send instead.
+func with_nearest_files(said: String, path: String) -> String:
+	var extension: String = path.get_extension()
+	if extension.is_empty():
+		return said
+	var files: Array[String] = find_files_with_extensions("res://", [extension])
+	# The walk lists a directory in the order the filesystem keeps it, which differs between
+	# platforms, so the same project was answered with its files in another order on Linux.
+	files.sort()
+	if files.is_empty():
+		return "%s. The project holds no .%s file." % [said, extension]
+	var names: PackedStringArray = []
+	for file: String in files:
+		var _named: bool = names.append(file.get_file().get_basename())
+	var close: PackedStringArray = GdhRead.nearest(path.get_file().get_basename(), names)
+	var offered: PackedStringArray = []
+	for file: String in files:
+		if file.get_file().get_basename() in close:
+			var _offered: bool = offered.append(file)
+	if not offered.is_empty():
+		var one: bool = offered.size() == 1
+		return (
+			"%s. The nearest .%s %s %s."
+			% [said, extension, "file is" if one else "files are", ", ".join(offered)]
+		)
+	if files.size() <= GdhRead.NAMED_CHILDREN:
+		return "%s. The project's .%s files are %s." % [said, extension, ", ".join(files)]
+	return "%s. None of the project's %d .%s files is named like it." % [said, files.size(), extension]
+
+
+# A directory the engine steps over, marker file and all.
+func is_stepped_over(path: String) -> bool:
+	return FileAccess.file_exists(path + ".gdignore")
+
+
+# An addon gdharness installed, told by the marker setup writes into it. The engine loads it, but
+# nobody on the project wrote it: the health check counted its thirty-odd scripts as the project's,
+# 39 beside the 5 project_info's own count gave, which the server's walks already step over.
+func is_installed_by_gdharness(path: String) -> bool:
+	return FileAccess.file_exists(path + ".gdharness-version")
+
+
+# Files under `path` whose name ends with `extension`, which is passed with its dot.
+func find_files(path: String, extension: String) -> Array[String]:
+	var files: Array[String] = []
+	if is_stepped_over(path) or is_installed_by_gdharness(path):
+		return files
+
+	var dir: DirAccess = DirAccess.open(path)
+
+	if dir:
+		if dir.list_dir_begin() != OK:
+			return files
+		var file_name: String = dir.get_next()
+
+		while file_name != "":
+			if dir.current_is_dir() and not file_name.begins_with("."):
+				files.append_array(find_files(path + file_name + "/", extension))
+			elif file_name.ends_with(extension):
+				files.append(path + file_name)
+
+			file_name = dir.get_next()
+
+	return files
+
+
+# Files under `path` whose extension is in `extensions`, which are passed without their dot.
+func find_files_with_extensions(path: String, extensions: Array) -> Array[String]:
+	var files: Array[String] = []
+	if is_stepped_over(path) or is_installed_by_gdharness(path):
+		return files
+
+	var dir: DirAccess = DirAccess.open(path)
+
+	if dir:
+		if dir.list_dir_begin() != OK:
+			return files
+		var file_name: String = dir.get_next()
+
+		while file_name != "":
+			if file_name.begins_with("."):
+				file_name = dir.get_next()
+				continue
+
+			var full_path: String = path + file_name
+			if dir.current_is_dir():
+				files.append_array(find_files_with_extensions(full_path + "/", extensions))
+			else:
+				var ext: String = file_name.get_extension().to_lower()
+				if ext in extensions:
+					files.append(full_path)
+
+			file_name = dir.get_next()
+
+		dir.list_dir_end()
+
+	return files

package/build/godot/addons/gdharness_editor/file_walk.gd.uid

@@ -0,0 +1 @@
+uid://c16785cs9xozr

package/build/godot/addons/gdharness_editor/headless_check.gd

@@ -11,8 +11,9 @@ extends RefCounted
 ## both, so a property a built-in setter derives (a Control's offsets from its size) is left alone
 ## unless a script that is not a tool is involved.
 
-const GdhPropertyValues = preload("property_values.gd")
+const GdhPropertyPaths = preload("property_paths.gd")
 const GdhRead = preload("reading.gd")
+const GdhSame = preload("same_values.gd")
 
 const REMEDY: String = (
 	"Open the project's editor (editor_launch with hidden: true) and ask again: the write then goes "
@@ -78,7 +79,7 @@ static func differing(object: Object, before: Dictionary, names: Dictionary) ->
 		if names.has(name):
 			continue
 		var was: Variant = before[name] if before.has(name) else default_of(object, name)
-		if not GdhPropertyValues.same(now[name], was):
+		if not GdhSame.same(now[name], was):
 			changed.append(name)
 	return changed
 
@@ -122,28 +123,46 @@ static func _initialised(script: Script, name: String, type: int) -> Variant:
 ## nothing a script did: the saver writes a property whose default the engine cannot report whatever
 ## it holds, the editor's save as well.
 static func at_default(object: Object, name: String) -> bool:
-	return GdhPropertyValues.same(object.get(name), default_of(object, name))
+	return GdhSame.same(object.get(name), default_of(object, name))
 
 
-## The ids, in the file, of the embedded resources [param property] reaches into on [param object],
-## such as the material of [code]material:albedo_color[/code], as a set.
+## What [param property] writes in the embedded resource it reaches into on [param object], by its
+## id in the file, as the set of names written in it: the hp of the resource built in as inner for
+## [code]inner/hp[/code], or position for [code]inner/position:x[/code]. Only those names are spared
+## from the check for what a script changed: the resource's _init still ran when it was loaded, and
+## sparing the whole resource saved what that set.
 static func reached(object: Object, property: String) -> Dictionary:
 	var ids: Dictionary = {}
-	var parts: PackedStringArray = property.split(":")
-	var current: Variant = object
-	for index: int in parts.size() - 1:
-		if not current is Object:
-			break
-		var holder: Object = current
-		current = holder.get(parts[index])
-		if current is Resource:
-			var resource: Resource = current
-			var id: String = resource.get_scene_unique_id()
-			if not id.is_empty():
-				ids[id] = true
+	var place: Array = GdhPropertyPaths.holder_of(object, property)
+	var through: Array[Resource] = place[2]
+	if through.is_empty():
+		return ids
+	var holder: Resource = through.back()
+	var name: String = place[1]
+	if GdhPropertyPaths.declared_on(holder, name).is_empty():
+		name = name.get_slice(":", 0)
+	var id: String = holder.get_scene_unique_id()
+	if not id.is_empty():
+		ids[id] = {name: true}
 	return ids
 
 
+## Adds what [param more] spares to [param into], both as [method reached] answers them; true for an
+## id spares the whole resource, as one a tool rebuilt.
+static func spare(into: Dictionary, more: Dictionary) -> void:
+	for id: Variant in more:
+		var held: Variant = into.get(id)
+		var given: Variant = more[id]
+		if held is bool or given is bool:
+			into[id] = true
+		elif held is Dictionary:
+			var names: Dictionary = held
+			var added: Dictionary = given
+			names.merge(added)
+		else:
+			into[id] = given
+
+
 ## Whether [param object] holds, at any depth, an embedded resource with a script that is not a tool.
 static func holds_scripted_embedded(object: Object, seen: Dictionary) -> bool:
 	for value: Variant in stored(object).values():
@@ -276,7 +295,7 @@ static func reads_the_same(was: Variant, now: Variant, default: Variant) -> bool
 			return false
 		else:
 			values.append(str_to_var(str(text)))
-	return GdhPropertyValues.same(values[0], values[1])
+	return GdhSame.same(values[0], values[1])
 
 
 static func _main_entries(text: String) -> Dictionary:
@@ -315,9 +334,9 @@ static func scripted_sections(text: String) -> Dictionary:
 
 ## Each property an embedded resource of [param after] sets differently from [param before], as
 ## [its id, name, whether before sets it, the text before gives it, the text after gives it or
-## null]. Only those with a script that
-## is not a tool are compared, since only a script runs differently here, and those in
-## [param reached_ids], which the tool changed, are left out.
+## null]. Only those with a script that is not a tool are compared, since only a script runs
+## differently here, and what [param reached_ids] says the tool wrote is left out, as
+## [method reached] answers it.
 static func embedded_changes(before: String, after: String, reached_ids: Dictionary) -> Array[Array]:
 	var changed: Array[Array] = []
 	if before.is_empty():
@@ -327,8 +346,10 @@ static func embedded_changes(before: String, after: String, reached_ids: Diction
 	for key: Variant in scripted_sections(before):
 		var section: String = str(key)
 		var id: String = section.trim_prefix("sub:")
-		if not section.begins_with("sub:") or reached_ids.has(id) or not new.has(section):
+		var spared: Variant = reached_ids.get(id, {})
+		if not section.begins_with("sub:") or spared is bool or not new.has(section):
 			continue
+		var written: Dictionary = spared
 		var was_section: Dictionary = old[section]
 		var now_section: Dictionary = new[section]
 		var was: Dictionary = entries_of(was_section)
@@ -337,7 +358,7 @@ static func embedded_changes(before: String, after: String, reached_ids: Diction
 		all.merge(now)
 		for entry: Variant in all:
 			var name: String = str(entry)
-			if was.get(name) != now.get(name):
+			if was.get(name) != now.get(name) and not written.has(name):
 				changed.append([id, name, was.has(name), str(was.get(name, "")), now.get(name)])
 	return changed