@nataliapc/mcp-openmsx 1.1.15 → 1.2.2

package/resources/programming/basic_wiki/COLOR_SPRITE$().md

@@ -0,0 +1,83 @@
+# COLOR SPRITE$()
+
+## Effect
+
+Changes the color for an horizontal line of a sprite on screens 4 to 8 and 10 to 12 and optionally changes collision rules for this line + applies a shift effect to this line. Several lines can also be modified.
+
+This handling line per line allows to create multi-colored sprites. In screen 6, it allows to have sprites with one color for the even lines and another color for the odd lines. The shift effect allows to create "mini-sprites".
+
+_Note: In screen 8, the colors for the sprites are different from the 'standard' colors._
+
+## Syntax
+
+`COLOR SPRITE$(<SpriteNumber>)=<String>`
+
+## Parameters
+
+`<SpriteNumber>` is a number between 0 and 31 that specifies the sprite number.
+
+`<String>` is a string of 8 or 16 characters according the sprites size (8x8 or 16x16). Each character number is the color value for the corresponding horizontal line of the sprite including extra bits functions described below.
+
+Characters can be specified by the function `CHR$()` that converts a value to a MSX character (see the example for CHR$() use). Remember the bit 4 is unused.
+
+Table below is the detail for the color value format in the 8-bit VDP Sprite Color Register, used only for the sprites type 2:
+
+|Bits|Effect|
+|:-:|---|
+|7|1 to enable moving of the horizontal line of the sprite to left by 32 dots|
+|6|1 to enable OR operation with bits pattern of linked sprites for the horizontal line of the sprite. The linked sprites are sprites displayed below with the bit 6 at 0. Four sprites can be linked.<br>Each bit at 1 in sprite patterns corresponds to the specified color of sprite. The OR operation is performed with the sprite colors on each bit superposed when displayed. The colors are taken into account for operation only when the bit is at 1. Thus the color of each pixel of the sprite at the top (with bit 6 to 1) will take the color resulting from each operation. (See `OR color` for more info).|
+|5|1 to ignore collision of the horizontal line of the sprite with another sprite. (`ON SPRITE GOSUB` will have no effect).|
+|4|Unused.|
+|3-0|Color is used for the horizontal line of the sprite (0~15 in decimal). The used colors are different in screen 8.|
+
+To get the value in decimal, you can input one of the following instructions:
+
+|Bits|Instruction|
+|5 set|`PRINT C+&B00100000`|
+|5 and 6 set|`PRINT C+&B01100000`|
+|6 set|`PRINT C+&B01000000`|
+|5 and 7 set|`PRINT C+&B01100000`|
+|7 set|`PRINT C+&B10000000`|
+|6 and 7 set|`PRINT C+&B11000000`|
+|5, 6 and 7 set|`PRINT C+&B11100000`|
+
+`C` is the color number (0~15) that you want to use.
+
+Here is the detail with the decimal values and the different effects:
+
+|Line color|Effects|
+|:-:|---|
+|0-15|The corresponding color is used for the concerned horizontal line of the sprite.|
+|32-47|- The color corresponding to (number - 32) is used for the concerned horizontal line of the sprite.<br>- Collision  of this part of the  sprite with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).|
+|64-79|- The color corresponding to (number - 64) is used for the concerned horizontal line of the sprite.<br>- The logical operator `OR` is applied for this horizontal line between colors of previous sprite pattern and new sprite pattern.|
+|96-111|- The color corresponding to (number - 96) is used for the concerned horizontal line of the sprite.<br>- Collision of this part of the  sprite with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).<br>- The logical operator `OR` is applied for this horizontal line between colors of previous sprite pattern and new sprite pattern.|
+|128-143|- The color corresponding to (number - 128) is used for the concerned horizontal line of the sprite.<br>- This part of the sprite is moved to left by 32 dots.|
+|160-175|- The color corresponding to (number - 160) is used for the concerned horizontal line of the sprite.<br>- This part of the sprite is moved to left by 32 dots.<br>- Collision of this part of the sprite with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).|
+|192-207|- The color corresponding to (number - 192) is used for the concerned horizontal line of the sprite.<br>- This part of the sprite is moved to left by 32 dots.<br>- The logical operator `OR` is applied for this horizontal line between colors of previous sprite pattern and new sprite pattern.|
+|224-239|- The palette color corresponding to (number - 224) is used for the concerned horizontal line of the sprite.<br>- This part of the sprite is moved to left by 32 dots.<br>- Collision  of this part of the  sprite with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).<br>- The logical operator `OR` is applied for this horizontal line between colors of previous sprite pattern and new sprite pattern.|
+
+## Example
+
+```basic
+10 COLOR 15,1,7: SCREEN 5,0
+20 B$=""
+30 FOR I=0 TO 7: READ A: B$=B$+CHR$(A): NEXT
+40 SPRITE$(0)=B$
+50 PUT SPRITE 0, (100,100),15,0
+60 FOR I=0 TO 2000: NEXT
+70 COLOR SPRITE$(0)=CHR$(12)+CHR$(1)+CHR$(130)
+80 FOR I=0 TO 2000: NEXT
+90 DATA 24,60,126,255,36,36,66,129
+```
+
+## Related to
+
+`COLOR SPRITE()`, `ON SPRITE GOSUB`, `PUT SPRITE`, `SPRITE`, `SPRITE$()`
+
+## Compatibility
+
+MSX-BASIC 2.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/COLOR_SPRITE$()"

package/resources/programming/basic_wiki/COLOR_SPRITE().md

@@ -0,0 +1,85 @@
+# COLOR SPRITE()
+
+## Effect
+
+Changes entirely the color of a sprite on screens 4 to 8 and 10 to 12 and optionally changes collision rules.
+
+_Notes:_
+- In screen 8, the colors for the sprites are different from the 'standard' colors.
+- When you use this instruction, don't specify the sprite color with PUT SPRITE.
+
+## Syntax
+
+`COLOR SPRITE(<SpriteDisplayNumber>)=<Color>`
+
+## Parameters
+
+`<SpriteDisplayNumber>` is a number between 0 and 31 that specifies the display priority number of sprite. When the number is bigger, the sprite is displayed over the others.
+
+`<Color>` is a number between 0 and 127 that specifies the color number + possibly some modifications. It is the result of values 0 or 1 in the 8-bit VDP Sprite Color Register, used only for the sprites type 2. As bit 4 is not used, some values are useless.
+
+Table below is the detail for the color value format:
+
+|Bits|Effect|
+|:-:|---|
+|7|Remember to set this bit to 0 otherwise an error _"Illegal function call"_ occurs.|
+|6|1 to enable OR operation with bits pattern of linked sprites. The linked sprites are sprites displayed below with the bit 6 at 0. Four sprites can be linked.<br>Each bit at 1 in sprite patterns corresponds to the specified color of sprite. The OR operation is performed with the sprite colors on each bit superposed when displayed. The colors are taken into account for operation only when the bit is at 1. Thus the color of each pixel of the sprite at the top (with bit 6 to 1) will take the color resulting from each operation. (See "OR Color" for more info).|
+|5|1 to ignore the sprite collision with another sprite. (ON SPRITE GOSUB## will have no effect).|
+|4|Unused.|
+|3-0|Color is used for the sprite (0~15 in decimal). The used colors are different in screen 8.|
+
+To get the decimal value, you can input one of the following instructions:
+
+|Bit|Instruction|
+|:-:|---|
+|5 set|`PRINT C+&B0100000`|
+|5 and 6 set|`PRINT C+&B1100000`|
+|6 set|`PRINT C+&B1000000`|
+
+`C` is the color number (0~15) that you want to use.
+
+Here is the detail with the decimal values and the different effects:
+
+|Color|Effects|
+|---|---|
+|0-15|The corresponding color is used for the sprite.|
+|32-47|- The color corresponding to (number - 32) is used for the sprite.<br>- Collision with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).|
+|64-79|- The color corresponding to (number - 64) is used for the sprite.<br>- The logical operator `OR` is applied between colors of previous sprite pattern and new sprite pattern.|
+|96-111|- The color corresponding to (number - 96) is used for the sprite.<br>- Collision with another sprite is ignored (`ON SPRITE GOSUB` will have no effect).<br>- The logical operator `OR` is applied between colors of previous sprite pattern and new sprite pattern.|
+
+## Examples
+
+```basic
+10 COLOR 15,1,7: SCREEN 5,0
+20 B$=""
+30 FOR I=0 TO 7: READ A: B$=B$+CHR$(A): NEXT
+40 SPRITE$(0)=B$
+50 COLOR SPRITE(0)=12
+60 FOR I=0 TO 212: PUT SPRITE 0,(I,I),,0:NEXT
+70 DATA 24,60,126,255,36,36,66,129
+```
+
+```basic
+10 SCREEN5
+15 ON SPRITE GOSUB 90: SPRITE ON 'Enable collision for all sprites
+20 SPRITE$(0)=STRING$(8,255)
+30 COLOR SPRITE(1)=38 'is color 6 + &amp;B0100000 to disable collision for sprite 1
+40 PUTSPRITE 0,(50,50),10,0
+50 PUTSPRITE 1,(54,54),,0 ' The color parameter must be omitted
+60 IF NOT STRIG(0) GOTO 60 'Press Space to enable OR operator
+70 COLOR SPRITE(1)=79 'color 15 + &amp;B1000000 to enable OR operation
+80 GOTO 80
+90 SCREEN 0: PRINT"Sprite collision OK": BEEP: END
+```
+
+## Related to
+
+`COLOR SPRITE$()`, `ON SPRITE GOSUB`, `PUT SPRITE`, `SPRITE`, `SPRITE$()`
+
+## Compatibility
+
+MSX-BASIC 2.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/COLOR_SPRITE()"

package/resources/programming/basic_wiki/CONT.md

@@ -0,0 +1,23 @@
+# CONT
+
+## Effect
+
+Attempts to continue an MSX-BASIC program from where it was interrupted by either a `CTRL`+`BREAK` or a `STOP` instruction or by pressing on `CTRL`+`STOP` keys.
+
+Please note that this instruction does not restore things like screen mode or sound output, and can't be used inside a program otherwise the error _"Can't continue"_ occurs.
+
+## Syntax
+
+`CONT`
+
+## Related to
+
+`END`, `STOP`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/CONT"

package/resources/programming/basic_wiki/COPY.md

@@ -0,0 +1,215 @@
+# COPY
+
+## Effect
+
+Copies data between RAM, VRAM and disk.
+
+## Syntaxes
+
+`COPY (<XS>,<YS>)-STEP(<XS2>,<YS2>),<SourcePage> TO (<XD>,<YD>),<DestinationPage>,<Operator>`
+
+`COPY (<XS>,<YS>)-STEP(<XS2>,<YS2>),<SourcePage> TO <Array>`
+
+`COPY <Array>,<Direction> TO (<XD>,<YD>),<DestinationPage>,<Operator>`
+
+`COPY (<XS>,<YS>)-STEP(<XS2>,<YS2>),<SourcePage> TO "<Device>:\<Path>\<Filename>"`
+
+`COPY <Array> TO "<Device>:\<Path>\<Filename>"`
+
+`COPY "<Device>:\<Path>\<Filename>",<Direction> TO (<XD>,<YD>),<DestinationPage>,<Operator>`
+
+`COPY "<Device>:\<Path>\<Filename>",<Direction> TO "<Device>:\<Path>\<Filename>"`
+
+`COPY "<Device>:\<Path>\<Filename>",<Direction> TO <Array>`
+
+_Notes:_
+- Character backslash `\` serves as a separator between the folders and the file name in MSX-DOS2. You don't have to put it after the colon of the device name.
+- Character backslash is replaced by the character yen `¥` on Japanese MSX or the character won `₩` on Korean MSX.
+- Parameters can not end with a comma alone.
+
+## Parameters
+
+_Note: Coordinates, pages, operators, arrays and directions can be used only in screen modes 5 to 8 and 10 to 12. (MSX-BASIC 2.0 or newer)_
+
+### Coordinates and pages
+
+`<XS>` and `<YS>` are upper-left coordinates of transfer source (`X`=0-255/511, `Y`=0-211). If it is omited the current coordinates of cursor will be chosen.
+
+`<XS2>` and `<YS2>` are lower-right coordinates of transfer source (`X2`=0-255/511, `Y2`=0-211).
+
+`STEP` parameter changes `X2` and `Y2` coordinates to relative coordinates (and therefore allows the use of negative values) when specified.
+
+`<SourcePage>` is the page number in VRAM of transfer source. The number can be 0/1 or 0~3 depending used screen mode (current page by default).
+
+`<XD>` and `<YD>` are upper-left coordinates of transfer destination (`X`=0-255/511, `Y`=0-211).
+
+`<DestinationPage>` is the page number in VRAM of transfer destination. The number can be 0/1 or 0~3 depending used screen mode (current page by default).
+
+### Operators
+
+`<Operator>` defines the logical operations to operate, how copied picture data is mixed with existing picture data. If logical operation is not defined, `PSET` (do not mix) is expected.
+
+The available operators are `AND`, `OR`, `PRESET`, `PSET` (default), `TAND`, `TOR`, `TPRESET`, `TPSET`, `TXOR`, `XOR`. Specifying a logical operation preceded by "T" causes nothing to be done when copied color is transparent (color 0).
+
+The effect of the operators is done on each corresponding bit as shown in the following table.
+
+|Current bit|Copied color bit|AND|OR|PRESET|PSET|XOR|
+|:-:|:-:|:-:|:-:|:-:|:-:|:-:|
+|0|0|0|0|1|0|0|
+|0|1|0|1|0|1|1|
+|1|0|0|1|1|0|1|
+|1|1|1|1|0|1|0|
+
+### Arrays
+
+`<Array>` must be an array variable with one or two parameters (to transfer line X and Y pixel data) (Parameter available since MSX-BASIC 2.0).
+
+Array variables must be large enough to hold all the image data to be copied. The size can be determined using the following formula:  
+`INT (((((ABS(XS2-XS) + 1)*(ABS(YS2-YS) + 1)*pixel_size +7)/8)+4)/data_size)+1`
+
+The `pixel_size` (the number of bits in VRAM corresponding to a point on the screen) varies depending on the `SCREEN` mode:
+
+|SCREEN|Pixel size|
+|:-:|:-:|
+|5|4|
+|6|2|
+|7|4|
+|8|8|
+|10-12|8|
+
+The `data_size` is determined by the type of the array variable:
+
+|Array type|Data size|
+|:-:|:-:|
+|Integer|2|
+|Single precision|4|
+|Double precision|8|
+
+### Directions
+
+`<Direction>` determines the rotation of the picture and must be an integer. This parameter can be used only if destination is graphics coordinate.
+
+- Bit 0: Invert X-direction
+- Bit 1: Invert Y-direction
+
+|Direction|Picture rotation|
+|:-:|:--|
+|0|No rotation|
+|1|Left - Right|
+|2|Up - Down|
+|3|Left - Right +  Up - Down|
+
+### Devices and files
+
+`<Device>` is the name for used device. It can only be a disk drive.
+
+If you don't specify the drive, the computer will copy file(s) from or to the currently active drive (by default, it's drive `A:`).
+
+|Device type|Device name|Remark|
+|:-:|:-:|:-:|
+|Disk drive|A, B, C, D, E, F, G, H|A floppy disk interface can control until 2 drives.|
+
+_Note: the destination device can be the text screen with `CON` (without :) instead of CRT (followed by :)._
+
+`<Path>` is used to specify the location in folders where you want display files. Each folder name in path are separate by a backslash `\` (parameter available with the Disk BASIC 2.0 or newer).
+
+`<Filename>` is the file name in the format 8 characters followed by a point and an extension with 3 characters.
+
+When copying from one diskdrive to another diskdrive:
+- the source name will be used as destination name if you don't specify the destination name.
+- several files can be handled together by COPY in a similar way as for other Disk BASIC commands.
+
+Wildcards can replace some characters in source filename to copy several files. The asterisk `*` and question mark `?` are used as wildcard characters. The asterisk matches any sequence of characters, whereas the question mark matches any single character.
+
+## Examples
+
+```basic
+COPY "README.TXT" TO "CON" ' Display file on text screen
+```
+```basic
+COPY "M*.*" TO "B:"  'Copy all files with M as 1st character in the name from drive A to drive B
+ 
+COPY "*.BAS" TO "B:"  'Copy all files with the extension ".BAS" from drive A to drive B
+ 
+COPY "TEST.BAS" TO "B:GAME.BAS" 'Copy one file from drive A to drive B and rename it
+ 
+COPY  "*.*" TO "B:"  'Copy all the files from drive A to drive B
+```
+
+Next examples are made by: NYYRIKKI - Please contact him in case of questions:
+
+```basic
+' Endless lives to Xyzolog
+DEFINT D:DIM D(8191):COPY "XYZOLOG.ROM" TO D:D(3342)=2072:COPY D TO "XYZOLOGC.ROM"
+```
+```basic
+10 ' Create 3 little programs to change display Hz rate under DOS
+20 DEFINT A-Z:DIM D(7):FOR I=0 TO 7:READ D(I):NEXT
+30 FOR I=0 TO 2:IF I THEN N$=OCT$(32+I*8):READ D(2)
+40 COPY D TO N$+"Hz.COM":NEXT
+50 DATA -6111,32511,750,-3209,-26157,-30402,-26157,201,758,-538
+```
+```basic
+10 ' Fill screen with cute pattern
+20 SCREEN 5
+30 PSET (0,0):PSET(4,4):CIRCLE(4,4),3
+40 COPY (0,0)-(247,7) TO (8,0)
+50 COPY (0,0)-(255,199) TO (0,8)
+60 A$=INPUT$(1)
+```
+```basic
+10 ' Creating outline of an object using COPY-command
+20 ' ------------------------------------------------
+30 'Example object
+40 COLOR 15,0,0:SCREEN 5
+50 CIRCLE (32,32),28,8,,,.2:PAINT(32,32),8
+60 CIRCLE (32,32),28,2,,,5:PAINT(32,32),2
+70 CIRCLE (32,32),12,4:PAINT(32,32),4
+80 CIRCLE (32,32),5,0:PAINT(32,32),0
+90 'Example of object outline outside
+100 FOR I=0 TO 3:COPY(-(I=0),-(I=1))-(63,63)TO(64-(I=2),-(I=3)),,TPSET:NEXT
+110 COPY(64,0)-STEP(63,63) TO (128,0),,TPRESET
+120 COPY(64,0)-STEP(63,63) TO (128,0),,TOR
+130 COPY(0,0)-STEP(63,63) TO (128,0),,TPSET
+140 COPY(0,0)-STEP(63,63) TO (128,0),,XOR
+150 'Example of object outline inside
+160 COPY(0,0)-STEP(63,63) TO (64,64),,TPRESET
+170 COPY(0,0)-STEP(63,63) TO (64,64),,OR
+180 COPY(64,64)-STEP(63,63) TO (128,64)
+190 FOR I=0 TO 3:COPY(64-(I=0),64-(I=1))-(127,127)TO(128-(I=2),64-(I=3)),,AND:NEXT
+200 COPY(64,64)-STEP(63,63) TO (128,64),,XOR
+210 'Both together
+220 COPY(128,0)-STEP(63,63) TO (128,128)
+230 COPY(128,64)-STEP(63,63) TO (128,128),,OR
+240 A$=INPUT$(1)
+```
+```basic
+10 DIM D(16)
+20 SCREEN 5
+30 PSET (0,0):OPEN"GRP:" FOR OUTPUT AS #1:PRINT#1,"Copy":CLOSE
+40 COPY (0,0)-(31,7) TO D ' Copy to array
+50 COPY D,3 TO (255,211) ' Copy back to screen but upside down
+60 A$=INPUT$(1)
+10 ' Some Sierpinski-triangles
+20 COLOR 15,0,0:SCREEN 5
+30 FOR I=RND(-5048) TO 6:PSET(RND(1)*255,RND(1)*211),RND(1)*13+2:NEXT I
+40 FOR I=0 TO 211:H=IAND254:L=(IAND1)*2
+50 COPY (1,H)-STEP(253,0) TO (L,H+2),,XOR
+60 COPY (1,211-H)-STEP(253,0) TO (L,209-H),,XOR
+70 NEXT I
+80 A$=INPUT$(1)
+```
+
+## Related to
+
+`AND`, `DIM`, `KILL`, `NAME`, `OR`, `SET PAGE`, `SCREEN`, `XOR`
+
+## Compatibility
+
+Disk BASIC 1.0 or higher / both modes of Nextor OS
+
+Array variable, graphical coordinates and logical operations require MSX-BASIC 2.0 or higher.
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/COPY"

package/resources/programming/basic_wiki/COPY_SCREEN.md

@@ -0,0 +1,61 @@
+# COPY SCREEN
+
+## Effect
+
+Digitizes picture from video input and copies it to VRAM. It can be used in screens 5 to 8 and 10 to 12 and requires to first set the computer in digitize mode with `SET VIDEO`.
+
+## Syntax
+
+`COPY SCREEN <Mode>,<InputColor>`
+
+## Parameters
+
+`<Mode>` is a value to set or not interlaced mode:
+- If the value equals 0 (default value), the digitized picture is stored in the current page.
+- If the value equals 1, two images are stored: one in the active page -1, and the second in the active page. These two images then create one (interlaced) image.
+
+`<InputColor>` is optional to specify the RGB color of the input to the computer, in binary or decimal format. This color will be used as mask to alter the digitized picture.
+
+The binary format is &B11111111 where:
+- the highest three bits are for R (red)
+- the next three bits are for G (green)
+- the lowest two bits are for B (blue)
+
+This format is actually the one used for the fixed colors of Screen 8. Use this formula for the color code in decimal format:
+```
+Color code = 32 x (Green intensity) + 4 x (Red intensity) + (Blue intensity)
+```
+with:
+- Green intensity: an integer from 0 to 7
+- Red intensity: an integer from 0 to 7
+- Blue intensity: an integer from 0 to 3
+
+## Example
+
+```basic
+110 ON STOP GOSUB 210
+120 STOP ON
+130 SCREEN 8
+140 COLOR,,255
+150 SET VIDEO 1
+160 COPY SCREEN
+170 TIME=0
+180 IF INKEY$="" GOTO 180
+190 IF TIME&lt;4 GOTO 190
+200 IF INKEY$="" GOTO 200 ELSE 140
+210 'REM STOP
+220 SET VIDEO 0,0
+230 END
+```
+
+## Related to
+
+`SCREEN`, `SET PAGE`, `SET VIDEO`
+
+## Compatibility 
+
+MSX-BASIC 2.0 or higher - Requires a computer with digitizing/superimposing unit
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/COPY_SCREEN"

package/resources/programming/basic_wiki/COS().md

@@ -0,0 +1,37 @@
+# COS()
+
+## Effect
+
+Returns the cosine of a variable in radians.
+
+## Syntax
+
+`COS(<Number>)`
+
+## Parameter
+
+`<Number>` can be a value, a numeric variable or an expression.
+
+## Example
+
+```basic
+10 D1 = ATN(1)*8/360
+20 PRINT "The cosine of a 45 degree angle is ";COS(45*D1)
+30 PRINT "The cosine of a 0 degree angle is ";COS(0)
+ 
+RUN
+The cosine of a 45 degree angle is .70710678118655
+The cosine of a 0 degree angle is 1
+```
+
+## Related to
+
+`ATN()`, `SIN()`, `TAN()`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/COS()"

package/resources/programming/basic_wiki/CSAVE.md

@@ -0,0 +1,35 @@
+# CSAVE
+
+## Effect
+
+Saves a BASIC program to cassette in tokenized mode. 
+
+## Syntax
+
+`CSAVE "<Filename>",<BaudRate>`
+
+## Parameters
+
+`<Filename>` is the specific name of the BASIC program to be saved in tokenized mode.
+
+The format of file name is case sensitive and limited to 6 characters without extension. "`<Filename>`" can be replaced by a alphanumeric variable containing the name.
+
+`<BaudRate>` specifies the baud rate at which the program should be saved, which can be either 1 (1200 baud) or 2 (2400 baud). Default value is 1. Do not put the comma if this parameter is omitted.
+
+## ASCII text and Tokenized format
+
+The tokenized format allows a faster loading than the loading of the same BASIC program in ASCII text and the loaded program takes less space in the MSX memory.
+
+However, contrary to the ASCII text, the listing of the program can't be directly displayed and read. Besides, `RUN` needs to be used after loading with `CLOAD` instead of using `RUN` as unique instruction.
+
+## Related to
+
+`CLOAD`, `CLOAD?`, `LOAD`, `RUN`, `SAVE`
+
+## Compatibility
+
+MSX-BASIC versions before 4.0
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/CSAVE"

package/resources/programming/basic_wiki/CSNG().md

@@ -0,0 +1,36 @@
+# CSNG()
+
+## Effect
+
+Converts a variable to a single precision number. Single precision numbers have an accuracy of 6 digits.
+
+## Syntax
+
+`CSNG (<Expression>)`
+
+## Parameter
+
+`<Expression>` can be a value, a numeric variable or an mathematical expression.
+
+## Example
+
+```basic
+10 PRINT "7 divided by 6 is ";CSNG(7/6)
+20 PRINT "10 divided by 11 ";CSNG(10/11)
+ 
+RUN
+7 divided by 6 is 1.16667
+10 divided by 11 is .909091
+```
+
+## Related to
+
+`CDBL`, `CINT`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/CSNG()"

package/resources/programming/basic_wiki/CSRLIN.md

@@ -0,0 +1,33 @@
+# CSRLIN
+
+## Effect
+
+Returns the vertical coordinate of the cursor.
+
+## Syntax
+
+`CSRLIN`
+
+## Example
+
+```basic
+10 CLS
+20 PRINT "Example of CSRLIN"
+30 PRINT CSRLIN
+ 
+RUN
+Example of CSRLIN
+1
+```
+
+## Related to
+
+`LOCATE`, `POS`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/CSRLIN"

package/resources/programming/basic_wiki/DATA.md

@@ -0,0 +1,47 @@
+# DATA
+
+## Effect
+
+Stores data in a program (e.g. graphics), to be read with the `READ` instruction.
+
+_Note: Unlike the other BASIC instructions, `DATA` doesn't need to be executed by the interpreter. Data is stored at the same time as the program is entered. You can therefore group the `DATA` at the end of the program._
+
+## Syntax
+
+`DATA <Data>,<Data>...`
+
+_Note: Parameters can not end with a comma alone._
+
+## Parameter
+
+`<Data>` is a value or a character string. We can put several `<Data>` separated by a comma.
+
+All data types are allowed. Strings only have to be enclosed in double quotes `"` if they contain commas, colons or leading or trailing spaces.
+
+## Example
+
+```basic
+10 READ A$
+20 PRINT A$
+30 READ A,B
+40 PRINT A
+50 PRINT B
+60 DATA "TEST",10,20
+ 
+RUN
+TEST
+ 10
+ 20
+```
+
+## Related to
+
+`READ`, `RESTORE`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/DATA"