@nataliapc/mcp-openmsx 1.1.14 → 1.2.2

package/resources/programming/basic_wiki/OCT$().md

@@ -0,0 +1,36 @@
+# OCT$()
+
+## Effect
+
+Returns a string with the octal representation of a value.
+
+## Syntax
+
+`OCT$(<Value>)`
+
+## Parameter
+
+`<Value>` must be an expression, a numeric variable or a value between -32768 and 65535. A single or double precision value can be used but digits after the decimal point will be ignored.
+
+## Example
+
+```basic
+10 PRINT "The octal representation of 8 is ";OCT$(8)
+20 PRINT "The octal representation of 127 is ";OCT$(127)
+ 
+RUN
+The octal representation of 8 is 10
+The octal representation of 127 is 177
+```
+
+## Related to
+
+`BIN$`, `HEX$`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/OCT$()"

package/resources/programming/basic_wiki/ON...GOSUB.md

@@ -0,0 +1,45 @@
+# ON...GOSUB
+
+## Effect
+
+Calls a subroutine located on the specified line number, that varies according the value of a variable, used as condition.
+
+## Syntax
+
+`ON <ConditionExpression> GOSUB <LineNumber>,<LineNumber>,...`
+
+_Note: Parameters can not end with a comma alone._
+
+## Parameters
+
+`<ConditionExpression>` is an expression that can result to value between 0-255.
+
+`<LineNumber>` is a program line number of a subroutine. Each number needs to be separated by a comma. If `<ConditionExpression>` equals 1 the program execution will go to the first specified line number, if it equals 2 the execution will go to the 2nd specified line number, and so on up to 255. If there is no matching line number no `GOSUB` will be made.
+
+The subroutine must be terminated with the `RETURN` instruction.
+
+## Example
+
+```basic
+10 CLS
+20 LOCATE 0,0
+30 ON STICK(0) GOSUB 60,50,90,50,70,50,80
+40 GOSUB 50:GOTO 20
+50 PRINT "     ":RETURN
+60 PRINT "UP   ":RETURN
+70 PRINT "DOWN ":RETURN
+80 PRINT "LEFT ":RETURN
+90 PRINT "RIGHT":RETURN
+```
+
+## Related to
+
+`GOSUB`, `IF...GOTO...ELSE`, `IF...THEN...ELSE`, `ON...GOTO`, `RETURN`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON...GOSUB"

package/resources/programming/basic_wiki/ON...GOTO.md

@@ -0,0 +1,42 @@
+# ON...GOTO
+
+## Effect
+
+Jumps to a specified line number that varies according the value of a variable, used as condition, and executes the instructions from there.
+
+## Syntax
+
+`ON <ConditionExpression> GOTO <LineNumber>,<LineNumber>,...`
+
+_Note: Parameters can not end with a comma alone._
+
+## Parameters
+
+`<ConditionExpression>` is an expression that can result to value between 0-255.
+
+`<LineNumber>` is a program line number. Each number needs to be separated by a comma. If `<ConditionExpression>` equals 1 the program execution will go to the first specified line number, if it equals 2 the execution will go to the 2nd specified line number, and so on up to 255. The number of next line is taken by default.
+
+## Example
+
+```basic
+10 CLS
+20 LOCATE 1,1
+30 ON STICK(0) GOTO 50,,80,,60,,70
+40 PRINT "     ":GOTO 20
+50 PRINT "UP   ":GOTO 20
+60 PRINT "DOWN ":GOTO 20
+70 PRINT "LEFT ":GOTO 20
+80 PRINT "RIGHT":GOTO 20
+```
+
+## Related to
+
+`GOTO`, `IF...GOTO...ELSE`, `IF...THEN...ELSE`, `ON...GOSUB`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON...GOTO"

package/resources/programming/basic_wiki/ON_ERROR_GOTO.md

@@ -0,0 +1,61 @@
+# ON ERROR GOTO
+
+## Effect
+
+Jumps to a specified line of an error handling routine, whenever an eror occurs.
+
+It's useful in the following situations:
+- for defined errors in MSX-BASIC and Disk Basic, you want to avoid the display of the error messages.
+- for non-defined errors, you decide to define them and to handle them directly in your program.
+
+## Syntax
+
+`ON ERROR GOTO <LineNumber>`
+
+## Parameter
+
+`<LineNumber>`  is a program line number of your error handling routine. The subroutine must be terminated with the `RESUME` instruction.
+
+If you execute `ON ERROR GOTO` with 0 as line number, it cancels the effect of the `ON ERROR GOTO` executed previously, stops the execution of the program and displays the error in progress. Placed alone in the last line of your program, this will have the effect of disabling the error handling routine of your program when execution is interrupted.
+
+_Note:_  
+Take care to handle errors properly otherwise your program will behave weirdly. Error handling is not disabled when the program execution is ended or stopped except if you put `ON ERROR GOTO 0` alone in the last line of your program. `CLEAR`, `NEW` and `RUN` also disables the effect of the `ON ERROR GOTO` executed previously.
+
+## Examples
+
+If you create the file named "MYDISK" for example with `BSAVE"MYDISK",0,0,S` the following program will be able to detect if this is your disk that is inserted or not.
+
+```basic
+10 ON ERROR GOTO 1000
+20 BLOAD"MYDISK",S
+30 PRINT"This is the right disk. :)"
+40 END
+1000 IF ERL<>20 THEN ON ERROR GOTO 0
+1010 IF ERR=70 THEN PRINT"Insert a disk!"
+1020 IF ERR=53 THEN PRINT"This disk is not the right one!"
+1030 RESUME 40
+```
+Alternate code with the same effect:
+```basic
+10 ON ERROR GOTO 1000
+20 BLOAD"MYDISK",S
+30 PRINT"This is the right disk. :)"
+40 END
+1000 IF ERL<>20 THEN 1040
+1010 IF ERR=70 THEN PRINT"Insert a disk!"
+1020 IF ERR=53 THEN PRINT"This disk is not the right one!"
+1030 RESUME 40
+1040 ON ERROR GOTO 0
+```
+
+## Related to
+
+`ERL`, `ERR`, `ERROR`, `RESUME`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_ERROR_GOTO"

package/resources/programming/basic_wiki/ON_INTERVAL_GOSUB.md

@@ -0,0 +1,54 @@
+# ON INTERVAL GOSUB
+
+## Effect
+
+Calls a subroutine after the specified timeout has been elapsed.
+
+## Syntax
+
+`ON INTERVAL=<TimeoutNumber> GOSUB<LineNumber>`
+
+## Parameters
+
+`<TimeoutNumber>` is a number to specify the timeout, which is equal to number*1/60 (or number*1/50) seconds.
+
+`<LineNumber>` is a program line number of your subroutine. The subroutine must be terminated with the `RETURN` instruction.
+
+## Examples
+
+```basic
+10 ' Interrupt once every second on all MSX models
+15 ON INTERVAL=60-10*(PEEK(&H2B)\128) GOSUB 50
+20 INTERVAL ON
+30 X=X+1:IF INKEY$="" THEN 30
+40 END
+50 PRINT X:RETURN
+```
+
+```basic
+10 ON INTERVAL=300 GOSUB 60
+20 INTERVAL ON
+30 FOR I=1 TO 10000:NEXT I
+40 INTERVAL OFF
+50 END
+60 K=K+6:PRINT K;"seconds"
+70 RETURN
+ 
+RUN
+ 6 seconds
+ 12 seconds
+ 18 seconds
+ 24 seconds
+```
+
+## Related to
+
+`INTERVAL`, `RETURN`, `TIME`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_INTERVAL_GOSUB"

package/resources/programming/basic_wiki/ON_KEY_GOSUB.md

@@ -0,0 +1,56 @@
+# ON KEY GOSUB
+
+## Effect
+
+Defines a subroutine to execute when a function key is pressed down.
+
+This 'rule' is activated only when the function key is enabled.
+
+## Syntax
+
+`ON KEY GOSUB <LineNumber>,<LineNumber>,<LineNumber>...`
+
+_Note: Each parameter is optional except the last specified. Do not put a comma after this parameter._
+
+## Parameters
+
+`<LineNumber>` is a program line number of subroutine that will be called when the corresponding function key is pressed. We can put until 10 line numbers behind `GOSUB` (one per function key). If there is no matching line number no `GOSUB` will be made.
+The subroutines must be terminated with the `RETURN` instruction.
+
+## Example
+
+```basic
+10 FOR I=1 TO 3: KEY(I) STOP: NEXT ' F1 to F3 are stopped
+20 FOR I=4 TO 10: KEY(I) OFF: NEXT ' F4 to F10 are disabled
+30 ON KEY GOSUB 170,180,190 ' Subroutine will only be active from line 130
+40 CLS
+50 PRINT"TEST 1: No effect"
+60 PRINT
+70 PRINT"Press a function key or ESC key"
+80 A$=INPUT$(1)
+90 IF A$=CHR$(27) THEN 100 ELSE 80
+100 CLS
+110 PRINT"TEST 2"
+120 PRINT"Press a function key"
+130 KEY(1)ON: KEY(2)ON: KEY(3)ON ' F1 to F3 and the subroutine in line 30 are enabled
+140 GOTO 160
+150 PRINT:PRINT a$+" pressed"
+160 GOTO 160
+170 A$="F1": RETURN 150
+180 A$="F2": RETURN 150
+190 A$="F3": RETURN 150
+```
+
+Each line number after `ON KEY GOSUB` refers to a specific function key according its position in the instruction.
+
+## Related to
+
+`KEY`, `KEY()`, `RETURN`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_KEY_GOSUB"

package/resources/programming/basic_wiki/ON_SPRITE_GOSUB.md

@@ -0,0 +1,41 @@
+# ON SPRITE GOSUB
+
+## Effect
+
+Defines a subroutine to execute when two or more sprites have collided on screen.
+
+This 'rule' is activated only when the handling is enabled with `SPRITE` instruction.
+
+## Syntax
+
+`ON SPRITE GOSUB <LineNumber>`
+
+## Parameter
+
+`<LineNumber>` is a program line number of your subroutine. The subroutine must be terminated with the `RETURN` or `END` instruction.
+
+## Example
+
+```basic
+10 SCREEN5
+15 ON SPRITE GOSUB 80: SPRITE ON 'Enable colision for all sprites
+20 SPRITE$(0)=STRING$(8,255)
+30 PUTSPRITE 0,(50,50),10,0
+40 PUTSPRITE 1,(54,54),38,0 ' 38 is color 6 + &B0100000 to disable collision for sprite 1
+50 IF NOT STRIG(0) GOTO 50 'Press Space to enable OR operator
+60 COLOR SPRITE(1)=79 ' 79 is color 15 + &B1000000 to enable OR operation
+70 GOTO 70
+80 SCREEN 0: PRINT"Sprite collision OK": BEEP: END
+```
+
+## Related to
+
+`END`, `PUT SPRITE`, `RETURN`, `SPRITE`, `SPRITE$()`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_SPRITE_GOSUB"

package/resources/programming/basic_wiki/ON_STOP_GOSUB.md

@@ -0,0 +1,56 @@
+# ON STOP GOSUB
+
+## Effect
+
+Defines a subroutine to execute when CTRL+STOP is pressed down.
+
+This 'rule' is activated only when the checking of the simultaneous pressing of `CTRL`+`STOP` is enabled.
+
+## Syntax
+
+`ON STOP GOSUB <LineNumber>`
+
+## Parameter
+
+`<LineNumber>` is a program line number of your subroutine. The subroutine must be terminated with the `RETURN` instruction.
+
+## Examples
+
+```basic
+10 ON STOP GOSUB 100 : STOP ON
+20 CLS: PRINT "ON STOP ENABLED"
+30 FOR I = 1 TO 2000 : NEXT
+40 STOP OFF
+50 PRINT: PRINT "ON STOP DISABLED"
+60 FOR I = 1 TO 2000 : NEXT
+70 STOP ON : GOTO 20
+80 PRINT: INPUT A$
+90 IF A$="END" THEN STOP OFF:END ELSE 80
+100 PRINT "Enter END and press Return":RETURN 80
+```
+```basic
+10 ON STOP GOSUB 100 : STOP ON
+…
+30 CLS
+…
+90 GOTO 30
+100 RETURN
+```
+
+## Using
+
+This instruction can be useful for inserting surprises in a program or for testing when developing the program.
+
+With `ON STOP GOSUB`, `STOP ON` and `RETURN`, as in the second example, it is possible to prevent the exit from the program with `CTRL`+`STOP`. However, if you have enabled a Debug warm start with `POKE &HFBB0,1` (using system variable ENSTOP for example in line 20), the user will be able to re-start MSX-BASIC by pressing simultaneously `CTRL`+`SHIFT`+`GRAPH`+`CODE`/`KANA`.
+
+## Related to
+
+`RETURN`, `STOP`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_STOP_GOSUB"

package/resources/programming/basic_wiki/ON_STRIG_GOSUB.md

@@ -0,0 +1,70 @@
+# ON STRIG GOSUB
+
+## Effect
+
+Defines a subroutine to execute when the space key or a joystick/mouse button is pressed down.
+
+This 'rule' is activated only when the checking of the space key or the joystick/mouse button is enabled.
+
+## Syntax
+
+`ON STRIG GOSUB <LineNumber>,<LineNumber>,<LineNumber>...`
+
+Each parameter is optional.
+
+## Parameters
+
+`<LineNumber>` is a program line number of your subroutine. Each line number after `ON STRIG GOSUB` refers to a number according the triggers status. Triggers can be the space key or a joystick button/mouse (see table below).
+
+|STRIG number|Description|
+|---|---|
+|0|Space key|
+|1|Button 1 of joystick/mouse in port 1|
+|2|Button 1 of joystick/mouse in port 2|
+|3|Button 2 of joystick/mouse in port 1|
+|4|Button 2 of joystick/mouse 2 in port 2|
+
+The subroutines must be terminated with the `RETURN` instruction.
+
+## Examples
+
+```basic
+10 ON STRIG GOSUB 80 : STRIG(0) ON
+20 CLS: PRINT "SPACEBAR ROUTINE ENABLED"
+30 FOR I = 1 TO 2000 : NEXT
+40 STRIG(0) OFF
+50 PRINT: PRINT "SPACEBAR ROUTINE DISABLED"
+60 FOR I = 1 TO 2000 : NEXT
+70 STRIG(0) ON : GOTO 20
+80 PRINT: PRINT "SPACEBAR PRESSED DOWN"
+90 FOR I = 1 TO 2000 : NEXT
+100 RETURN 70
+```
+
+```basic
+10 FOR I = 0 TO 4: STRIG(I) ON: NEXT
+20 ON STRIG GOSUB 90, 100, 110, 120, 130
+30 CLS
+40 PRINT"Press spacebar or a button joystick"
+50 PRINT
+60 GOTO 80
+70 PRINT " pressed"
+80 GOTO 80
+90 PRINT "Spacebar";:RETURN 70
+100 PRINT "Button 1 of joystick 1";:RETURN 70
+110 PRINT "Button 1 of joystick 2";:RETURN 70
+120 PRINT "Button 2 of joystick 1";:RETURN 70
+130 PRINT "Button 2 of joystick 2";:RETURN 70
+```
+
+## Related to
+
+`PAD()`, `RETURN`, `STRIG()`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/ON_STRIG_GOSUB"

package/resources/programming/basic_wiki/OPEN.md

@@ -0,0 +1,103 @@
+# OPEN
+
+## Effect
+
+Opens a file for a specific direction in a specified device.
+
+## Syntax
+
+`OPEN "<Device>:\<Path>\<Filename>" FOR <Direction> AS #<FileNumber> LEN=<RecordLength>`
+
+_Notes:_
+- Character backslash `\` serves as a separator between the folders and the file name in MSX-DOS2. You don't have to put it after the colon of the device name.
+- Character backslash is replaced by the character yen `¥` on Japanese MSX or the character won `₩` on Korean MSX.
+- Parameters can not end with a comma alone.
+
+## Parameters
+
+`<Device>` specifies the used device. By default, the device will be the standard data recorder on a system without any disk drive, the current active drive (generally drive A) in the other cases.
+
+Here are the useful devices for OPEN and the different types of access for these devices:
+
+|Device type|Device name<br>followed by:|Remark|Sequential<br>OUTPUT|Sequential<br>INPUT|Sequential<br>APPEND|Random|
+|---|---|---|:-:|:-:|:-:|:-:|
+|Disk drive|A:, B:, C:, D:, E:, F:, G:, H:||X|X|X|X|
+|Data recorder|CAS:|Not available on MSX turbo R|X|X|-|-|
+|Serial device|COM[n]:|Requires RS-232C interface|X|X|-|-|
+|Text screen|CRT:|Filename and direction not required|X|-|-|-|
+|Data cartridge (Yamaha)|DC:|Requires Yamaha UDC-01 + YRM-104 or YRM-504|X|X|-|-|
+|Graphic screen|GRP:|Filename and direction not required|X|-|-|-|
+|High Graphic screen<sup>(*)</sup>|HIGRP:<sup>(**)</sup>|Filename and direction not required|X|-|-|-|
+|Printer|LPT:|Filename and direction not required|X|-|-|-|
+|Memory disk|MEM:|Created with CALL MEMINI|X|X|X|-|
+|Quick Disk drive|QD[n]:|n=0 by default Can vary between 0 and 7|X|X|-|-|
+|Device controlled by Pioneer UC-V102|RS[n]:|Requires Pioneer UK-V104 RS-232C board|X|X|-|-|
+|Stringy Floppy Drive (special data recorder)|S:|Requires Spectravideo SVI-777 Not available on MSX turbo R|X|X|-|-|
+
+|Device type|Device name<br>not followed by:|Remark|Sequential<br>OUTPUT|Sequential<br>INPUT|Sequential<br>APPEND|Random|
+|---|---|---|:-:|:-:|:-:|:-:|
+|Auxiliary device|AUX||X|X|X|X|
+|Console|CON|Filename and direction not required|X|X|X|X|
+|Printer|LST|Filename and direction not required|X|X|X|X|
+|Bit heaven|NUL|Filename and direction not required|X|X|X|X|
+|Printer|PRN|Filename and direction not required|X|X|X|X|
+
+<sup>(\*)</sup> only on screen 6, after installation of HI-GRAPhics, written by Arjen Schrijvers (see Interlacing Demo).  
+<sup>(\*\*)</sup> it must be `OPEN "HIGRP:NTSC"` or `OPEN "HIGRP:PAL"`.
+
+`<Path>` is used to specify the location in folders of file to load. Each folder name in path are separate by a backslash `\`. This parameter is only available in version 2 of Disk BASIC.
+
+`<Filename>` is the name of the file to be opened. This parameter is not required for text screen, graphic screen and printer.
+
+The format of file name is limited to 6 characters without extension, when using cassette. If another device is used, then the format is 8 characters followed by a point and an extension with 3 characters.
+
+`<Direction>` must be preceded by `FOR` to be used. It is one of the 3 types of sequential access:
+- OUTPUT = sequential write.
+- INPUT = sequential read.
+- APPEND = sequential write to the end of an existing file.
+
+This parameter is not required for text screen, graphic screen and printer, but the listing is more easy to read when you use it. To open a file with random access on disk, you need to skip the `FOR <direction>` parameter.
+
+`<FileNumber>` is a number that you must assign to open the file. It can vary between 1 and 15, but can't exceed the maximum number of files eventually defined with `MAXFILES`. The `#` in front can be omitted.
+
+`<RecordLength>` must be preceded by `LEN` to be used. It is an optional parameter to use only if you choose to open a file in random access on disk. It must be an integer. The default value is 256. In case `FIELD` definitions exceed record length _"Field overflow"_ error is generated. Reading/writing is always done whole record at a time.
+
+## Examples
+
+```basic
+10 SCREEN 2:COLOR 15,4,7
+20 OPEN "GRP:" FOR OUTPUT AS #1
+30 LINE (32,32)-(120,120),6,B
+40 CIRCLE (120,120),56,1
+50 PRESET (40,8)
+60 PRINT #1,"Text in graphic screen"
+70 FOR I=1 TO 2000: NEXT I
+80 END
+```
+
+```basic
+5 'Open a random file on disk with 512 as length
+10 OPEN "A:RECORD.DAT" AS #1 LEN 512
+10 ' Create a text file
+20 OPEN"hello!.txt" FOR OUTPUT AS #1
+30 PRINT#1,"Hello world!"+CHR$(10)+CHR$(13)+"I'm the saved text from"
+40 PRINT#1,"the file HELLO!.TXT"
+50 CLOSE
+60 ' Print a text file
+70 OPEN"hello!.txt" FOR INPUT AS #1
+80 INPUT#1,A$:PRINT A$
+90 IF NOT EOF(1) THEN 80
+100 CLOSE
+```
+
+## Related to
+
+`CALL MEMINI`, `CLOSE`, `EOF()`, `FIELD`, `INPUT`, `MAXFILES`, `PRINT`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/OPEN"

package/resources/programming/basic_wiki/OR.md

@@ -0,0 +1,75 @@
+# OR - MSX Wiki
+
+
+## Effect
+
+Performs a bitwise `OR`-operation (logical inclusive or) between two expressions.
+
+The bit is set if either one of the bits is set. For each bit, the results are:
+```
+0 OR 0  =  0 
+0 OR 1  =  1 
+1 OR 0  =  1 
+1 OR 1  =  1
+```
+
+## Syntax
+
+`<Value> OR <Value>`
+
+## Parameter
+
+`<Value>` is a value between -32768 and 32767. It can also be a numeric variable, a mathematical expression or expression from a condition.
+
+_Notes:_
+- If you use binary expressions, it is best to put the first expression in parenthesis to avoid the bug in interpreter that causes a syntax error. This problem does not happen with decimal, hexadecimal or octal expressions.
+- When the expression is performed in a condition (`IF...THEN...ELSE` or `IF...GOTO...ELSE`), if the result of the whole expression is zero the value is taken as false, otherwise it's taken as true.
+
+## Examples
+
+```basic
+PRINT 15 OR 11
+15
+```
+Binary explanation:
+```
+1111 
+1011  OR
+----
+1111
+```
+
+---
+```basic
+PRINT 5 OR 13
+5
+```
+Binary explanation:
+```
+0101 
+1101  OR
+----
+1101
+```
+---
+```basic
+PRINT &B00001111 OR &B11110001
+Syntax error
+Ok
+```
+```basic
+PRINT (&B00001111) OR &B11110001
+255
+```
+
+## Related to
+
+`AND`, `EQV`, `IMP`, `MOD`, `NOT`, `XOR`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/OR"

package/resources/programming/basic_wiki/OUT.md

@@ -0,0 +1,35 @@
+# OUT
+
+## Effect
+
+Writes a value to an output port.
+
+## Syntax
+
+`OUT <PortNumber>,<Value>`
+
+## Parameters
+
+`<PortNumber>` is the I/O port number to write. It needs to be between 0 and 255.
+
+`<Value>` is a value between 0 and 255 to write at port.
+
+## Example
+
+Example to modify color 7 on MSX2 and higher with the following RGB values: R=4, G=3, B=5. Binary value of R is 100, of G is 011 and of B is 101, first binary value for OUT is 01000101 = 69, second binary value for OUT is 00000011 = 3.
+
+```basic
+VDP(17)=7: OUT &H9A,69: OUT &H9A,3
+```
+
+## Related to
+
+`INP()`, `SOUND`, `VDP()`, `WAIT`
+
+## Compatibility
+
+MSX-BASIC 1.0 or higher
+
+## Source
+
+Retrieved from "https://www.msx.org/wiki/OUT"