@hyperlane-xyz/core 1.5.6-beta0 → 1.5.8

package/contracts/igps/InterchainGasPaymaster.sol

@@ -0,0 +1,210 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+// ============ Internal Imports ============
+import {IGasOracle} from "../interfaces/IGasOracle.sol";
+import {IInterchainGasPaymaster} from "../interfaces/IInterchainGasPaymaster.sol";
+// ============ External Imports ============
+import {Strings} from "@openzeppelin/contracts/utils/Strings.sol";
+import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
+
+/**
+ * @title InterchainGasPaymaster
+ * @notice Manages payments on a source chain to cover gas costs of relaying
+ * messages to destination chains.
+ */
+contract InterchainGasPaymaster is
+    IInterchainGasPaymaster,
+    IGasOracle,
+    OwnableUpgradeable
+{
+    // ============ Constants ============
+
+    /// @notice The scale of gas oracle token exchange rates.
+    uint256 internal constant TOKEN_EXCHANGE_RATE_SCALE = 1e10;
+
+    // ============ Public Storage ============
+
+    /// @notice Keyed by remote domain, the gas oracle to use for the domain.
+    mapping(uint32 => IGasOracle) public gasOracles;
+
+    /// @notice The benficiary that can receive native tokens paid into this contract.
+    address public beneficiary;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when the gas oracle for a remote domain is set.
+     * @param remoteDomain The remote domain.
+     * @param gasOracle The gas oracle.
+     */
+    event GasOracleSet(uint32 indexed remoteDomain, address gasOracle);
+
+    /**
+     * @notice Emitted when the beneficiary is set.
+     * @param beneficiary The new beneficiary.
+     */
+    event BeneficiarySet(address beneficiary);
+
+    struct GasOracleConfig {
+        uint32 remoteDomain;
+        address gasOracle;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @param _owner The owner of the contract.
+     * @param _beneficiary The beneficiary.
+     */
+    function initialize(address _owner, address _beneficiary)
+        public
+        initializer
+    {
+        __Ownable_init();
+        _transferOwnership(_owner);
+        _setBeneficiary(_beneficiary);
+    }
+
+    /**
+     * @notice Deposits msg.value as a payment for the relaying of a message
+     * to its destination chain.
+     * @dev Overpayment will result in a refund of native tokens to the _refundAddress.
+     * Callers should be aware that this may present reentrancy issues.
+     * @param _messageId The ID of the message to pay for.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasAmount The amount of destination gas to pay for.
+     * @param _refundAddress The address to refund any overpayment to.
+     */
+    function payForGas(
+        bytes32 _messageId,
+        uint32 _destinationDomain,
+        uint256 _gasAmount,
+        address _refundAddress
+    ) external payable override {
+        uint256 _requiredPayment = quoteGasPayment(
+            _destinationDomain,
+            _gasAmount
+        );
+        require(
+            msg.value >= _requiredPayment,
+            "insufficient interchain gas payment"
+        );
+        uint256 _overpayment = msg.value - _requiredPayment;
+        if (_overpayment > 0) {
+            (bool _success, ) = _refundAddress.call{value: _overpayment}("");
+            require(_success, "Interchain gas payment refund failed");
+        }
+
+        emit GasPayment(_messageId, _gasAmount, _requiredPayment);
+    }
+
+    /**
+     * @notice Transfers the entire native token balance to the beneficiary.
+     * @dev The beneficiary must be able to receive native tokens.
+     */
+    function claim() external {
+        // Transfer the entire balance to the beneficiary.
+        (bool success, ) = beneficiary.call{value: address(this).balance}("");
+        require(success, "!transfer");
+    }
+
+    /**
+     * @notice Sets the gas oracles for remote domains specified in the config array.
+     * @param _configs An array of configs including the remote domain and gas oracles to set.
+     */
+    function setGasOracles(GasOracleConfig[] calldata _configs)
+        external
+        onlyOwner
+    {
+        uint256 _len = _configs.length;
+        for (uint256 i = 0; i < _len; i++) {
+            _setGasOracle(_configs[i].remoteDomain, _configs[i].gasOracle);
+        }
+    }
+
+    /**
+     * @notice Sets the beneficiary.
+     * @param _beneficiary The new beneficiary.
+     */
+    function setBeneficiary(address _beneficiary) external onlyOwner {
+        _setBeneficiary(_beneficiary);
+    }
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice Quotes the amount of native tokens to pay for interchain gas.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasAmount The amount of destination gas to pay for.
+     * @return The amount of native tokens required to pay for interchain gas.
+     */
+    function quoteGasPayment(uint32 _destinationDomain, uint256 _gasAmount)
+        public
+        view
+        virtual
+        override
+        returns (uint256)
+    {
+        // Get the gas data for the destination domain.
+        (
+            uint128 _tokenExchangeRate,
+            uint128 _gasPrice
+        ) = getExchangeRateAndGasPrice(_destinationDomain);
+
+        // The total cost quoted in destination chain's native token.
+        uint256 _destinationGasCost = _gasAmount * uint256(_gasPrice);
+
+        // Convert to the local native token.
+        return
+            (_destinationGasCost * _tokenExchangeRate) /
+            TOKEN_EXCHANGE_RATE_SCALE;
+    }
+
+    /**
+     * @notice Gets the token exchange rate and gas price from the configured gas oracle
+     * for a given destination domain.
+     * @param _destinationDomain The destination domain.
+     * @return tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @return gasPrice The gas price on the remote chain.
+     */
+    function getExchangeRateAndGasPrice(uint32 _destinationDomain)
+        public
+        view
+        override
+        returns (uint128 tokenExchangeRate, uint128 gasPrice)
+    {
+        IGasOracle _gasOracle = gasOracles[_destinationDomain];
+
+        require(
+            address(_gasOracle) != address(0),
+            string.concat(
+                "Configured IGP doesn't support domain ",
+                Strings.toString(_destinationDomain)
+            )
+        );
+
+        return _gasOracle.getExchangeRateAndGasPrice(_destinationDomain);
+    }
+
+    // ============ Internal Functions ============
+
+    /**
+     * @notice Sets the beneficiary.
+     * @param _beneficiary The new beneficiary.
+     */
+    function _setBeneficiary(address _beneficiary) internal {
+        beneficiary = _beneficiary;
+        emit BeneficiarySet(_beneficiary);
+    }
+
+    /**
+     * @notice Sets the gas oracle for a remote domain.
+     * @param _remoteDomain The remote domain.
+     * @param _gasOracle The gas oracle.
+     */
+    function _setGasOracle(uint32 _remoteDomain, address _gasOracle) internal {
+        gasOracles[_remoteDomain] = IGasOracle(_gasOracle);
+        emit GasOracleSet(_remoteDomain, _gasOracle);
+    }
+}

package/contracts/igps/OverheadIgp.sol

@@ -0,0 +1,133 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+// ============ Internal Imports ============
+import {IInterchainGasPaymaster} from "../interfaces/IInterchainGasPaymaster.sol";
+// ============ External Imports ============
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+/**
+ * @notice An IGP that adds configured gas overheads to gas amounts and forwards
+ * calls to an "inner" IGP.
+ * @dev The intended use of this contract is to store overhead gas amounts for destination
+ * domains, e.g. Mailbox and/or ISM gas usage, such that users of this IGP are only required
+ * to specify the gas amount used by their own applications.
+ */
+contract OverheadIgp is IInterchainGasPaymaster, Ownable {
+    // ============ Constants ============
+
+    /// @notice The IGP that is called when paying for or quoting gas
+    /// after applying overhead gas amounts.
+    IInterchainGasPaymaster public immutable innerIgp;
+
+    // ============ Public Storage ============
+
+    /// @notice Destination domain => overhead gas amount on that domain.
+    mapping(uint32 => uint256) public destinationGasOverhead;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when an entry in the destinationGasOverhead mapping is set.
+     * @param domain The destination domain.
+     * @param gasOverhead The gas overhead amount on that domain.
+     */
+    event DestinationGasOverheadSet(uint32 indexed domain, uint256 gasOverhead);
+
+    struct DomainConfig {
+        uint32 domain;
+        uint256 gasOverhead;
+    }
+
+    // ============ Constructor ============
+
+    constructor(address _innerIgp) {
+        innerIgp = IInterchainGasPaymaster(_innerIgp);
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Adds the stored destinationGasOverhead to the _gasAmount and forwards the
+     * call to the innerIgp's `payForGas` function.
+     * @param _messageId The ID of the message to pay for.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasAmount The amount of destination gas to pay for. This should not
+     * consider any gas that is accounted for in the stored destinationGasOverhead.
+     * @param _refundAddress The address to refund any overpayment to.
+     */
+    function payForGas(
+        bytes32 _messageId,
+        uint32 _destinationDomain,
+        uint256 _gasAmount,
+        address _refundAddress
+    ) external payable {
+        innerIgp.payForGas{value: msg.value}(
+            _messageId,
+            _destinationDomain,
+            destinationGasAmount(_destinationDomain, _gasAmount),
+            _refundAddress
+        );
+    }
+
+    /**
+     * @notice Sets destination gas overheads for multiple domains.
+     * @dev Only callable by the owner.
+     * @param configs A list of destination domains and gas overheads.
+     */
+    function setDestinationGasOverheads(DomainConfig[] calldata configs)
+        external
+        onlyOwner
+    {
+        for (uint256 i; i < configs.length; i++) {
+            _setDestinationGasOverhead(configs[i]);
+        }
+    }
+
+    // ============ Public Functions ============
+
+    /**
+     * @notice Adds the stored destinationGasOverhead to the _gasAmount and forwards the
+     * call to the innerIgp's `quoteGasPayment` function.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasAmount The amount of destination gas to pay for. This should not
+     * consider any gas that is accounted for in the stored destinationGasOverhead.
+     * @return The amount of native tokens required to pay for interchain gas.
+     */
+    function quoteGasPayment(uint32 _destinationDomain, uint256 _gasAmount)
+        public
+        view
+        returns (uint256)
+    {
+        return
+            innerIgp.quoteGasPayment(
+                _destinationDomain,
+                destinationGasAmount(_destinationDomain, _gasAmount)
+            );
+    }
+
+    /**
+     * @notice Returns the stored destinationGasOverhead added to the _gasAmount.
+     * @dev If there is no stored destinationGasOverhead, 0 is used.
+     * @param _destinationDomain The domain of the message's destination chain.
+     * @param _gasAmount The amount of destination gas to pay for. This should not
+     * consider any gas that is accounted for in the stored destinationGasOverhead.
+     * @return The stored destinationGasOverhead added to the _gasAmount.
+     */
+    function destinationGasAmount(uint32 _destinationDomain, uint256 _gasAmount)
+        public
+        view
+        returns (uint256)
+    {
+        return destinationGasOverhead[_destinationDomain] + _gasAmount;
+    }
+
+    /**
+     * @notice Sets the destination gas overhead for a single domain.
+     * @param config The destination domain and gas overhead.
+     */
+    function _setDestinationGasOverhead(DomainConfig calldata config) internal {
+        destinationGasOverhead[config.domain] = config.gasOverhead;
+        emit DestinationGasOverheadSet(config.domain, config.gasOverhead);
+    }
+}

package/contracts/igps/gas-oracles/StorageGasOracle.sol

@@ -0,0 +1,104 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+// ============ Internal Imports ============
+import {IGasOracle} from "../../interfaces/IGasOracle.sol";
+// ============ External Imports ============
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+
+/**
+ * @notice A gas oracle that uses data stored within the contract.
+ * @dev This contract is intended to be owned by an address that will
+ * update the stored remote gas data.
+ */
+contract StorageGasOracle is IGasOracle, Ownable {
+    // ============ Public Storage ============
+
+    /// @notice Keyed by remote domain, gas data on that remote domain.
+    mapping(uint32 => IGasOracle.RemoteGasData) public remoteGasData;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when an entry in `remoteGasData` is set.
+     * @param remoteDomain The remote domain in which the gas data was set for.
+     * @param tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @param gasPrice The gas price on the remote chain.
+     */
+    event RemoteGasDataSet(
+        uint32 indexed remoteDomain,
+        uint128 tokenExchangeRate,
+        uint128 gasPrice
+    );
+
+    struct RemoteGasDataConfig {
+        uint32 remoteDomain;
+        uint128 tokenExchangeRate;
+        uint128 gasPrice;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Returns the stored `remoteGasData` for the `_destinationDomain`.
+     * @param _destinationDomain The destination domain.
+     * @return tokenExchangeRate The exchange rate of the remote native token quoted in the local native token.
+     * @return gasPrice The gas price on the remote chain.
+     */
+    function getExchangeRateAndGasPrice(uint32 _destinationDomain)
+        external
+        view
+        override
+        returns (uint128 tokenExchangeRate, uint128 gasPrice)
+    {
+        // Intentionally allow unset / zero values
+        IGasOracle.RemoteGasData memory _data = remoteGasData[
+            _destinationDomain
+        ];
+        return (_data.tokenExchangeRate, _data.gasPrice);
+    }
+
+    /**
+     * @notice Sets the remote gas data for many remotes at a time.
+     * @param _configs The configs to use when setting the remote gas data.
+     */
+    function setRemoteGasDataConfigs(RemoteGasDataConfig[] calldata _configs)
+        external
+        onlyOwner
+    {
+        uint256 _len = _configs.length;
+        for (uint256 i = 0; i < _len; i++) {
+            _setRemoteGasData(_configs[i]);
+        }
+    }
+
+    /**
+     * @notice Sets the remote gas data using the values in `_config`.
+     * @param _config The config to use when setting the remote gas data.
+     */
+    function setRemoteGasData(RemoteGasDataConfig calldata _config)
+        external
+        onlyOwner
+    {
+        _setRemoteGasData(_config);
+    }
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Sets the remote gas data using the values in `_config`.
+     * @param _config The config to use when setting the remote gas data.
+     */
+    function _setRemoteGasData(RemoteGasDataConfig calldata _config) internal {
+        remoteGasData[_config.remoteDomain] = IGasOracle.RemoteGasData({
+            tokenExchangeRate: _config.tokenExchangeRate,
+            gasPrice: _config.gasPrice
+        });
+
+        emit RemoteGasDataSet(
+            _config.remoteDomain,
+            _config.tokenExchangeRate,
+            _config.gasPrice
+        );
+    }
+}

package/contracts/interfaces/IHyperlaneConnectionClient.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+import {IInterchainGasPaymaster} from "./IInterchainGasPaymaster.sol";
+import {ISpecifiesInterchainSecurityModule} from "./IInterchainSecurityModule.sol";
+import {IMailbox} from "./IMailbox.sol";
+
+interface IHyperlaneConnectionClient is ISpecifiesInterchainSecurityModule {
+    function mailbox() external view returns (IMailbox);
+
+    function interchainGasPaymaster()
+        external
+        view
+        returns (IInterchainGasPaymaster);
+
+    function setMailbox(address) external;
+
+    function setInterchainGasPaymaster(address) external;
+
+    function setInterchainSecurityModule(address) external;
+}

package/contracts/interfaces/IInterchainGasPaymaster.sol

@@ -10,13 +10,11 @@ interface IInterchainGasPaymaster {
     /**
      * @notice Emitted when a payment is made for a message's gas costs.
      * @param messageId The ID of the message to pay for.
-     * @param destinationDomain The domain of the destination chain.
      * @param gasAmount The amount of destination gas paid for.
      * @param payment The amount of native tokens paid.
      */
     event GasPayment(
         bytes32 indexed messageId,
-        uint32 indexed destinationDomain,
         uint256 gasAmount,
         uint256 payment
     );

package/contracts/interfaces/IMailbox.sol

@@ -2,7 +2,6 @@
 pragma solidity >=0.8.0;
 
 import {IInterchainSecurityModule} from "./IInterchainSecurityModule.sol";
-import {IPostDispatchHook} from "./hooks/IPostDispatchHook.sol";
 
 interface IMailbox {
     // ============ Events ============
@@ -50,58 +49,23 @@ interface IMailbox {
 
     function defaultIsm() external view returns (IInterchainSecurityModule);
 
-    function defaultHook() external view returns (IPostDispatchHook);
-
-    function latestDispatchedId() external view returns (bytes32);
-
     function dispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata messageBody
-    ) external payable returns (bytes32 messageId);
+        uint32 _destinationDomain,
+        bytes32 _recipientAddress,
+        bytes calldata _messageBody
+    ) external returns (bytes32);
 
-    function quoteDispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata messageBody
-    ) external view returns (uint256 fee);
+    function process(bytes calldata _metadata, bytes calldata _message)
+        external;
 
-    function dispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata body,
-        bytes calldata defaultHookMetadata
-    ) external payable returns (bytes32 messageId);
+    function count() external view returns (uint32);
 
-    function quoteDispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata messageBody,
-        bytes calldata defaultHookMetadata
-    ) external view returns (uint256 fee);
+    function root() external view returns (bytes32);
 
-    function dispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata body,
-        bytes calldata customHookMetadata,
-        IPostDispatchHook customHook
-    ) external payable returns (bytes32 messageId);
-
-    function quoteDispatch(
-        uint32 destinationDomain,
-        bytes32 recipientAddress,
-        bytes calldata messageBody,
-        bytes calldata customHookMetadata,
-        IPostDispatchHook customHook
-    ) external view returns (uint256 fee);
-
-    function process(bytes calldata metadata, bytes calldata message)
-        external
-        payable;
+    function latestCheckpoint() external view returns (bytes32, uint32);
 
-    function recipientIsm(address recipient)
+    function recipientIsm(address _recipient)
         external
         view
-        returns (IInterchainSecurityModule module);
+        returns (IInterchainSecurityModule);
 }

package/contracts/interfaces/IMessageRecipient.sol

@@ -6,5 +6,5 @@ interface IMessageRecipient {
         uint32 _origin,
         bytes32 _sender,
         bytes calldata _message
-    ) external payable;
+    ) external;
 }

package/contracts/interfaces/IValidatorAnnounce.sol

@@ -2,6 +2,12 @@
 pragma solidity >=0.6.11;
 
 interface IValidatorAnnounce {
+    /// @notice Returns the local domain for validator announcements
+    function localDomain() external view returns (uint32);
+
+    /// @notice Returns the mailbox contract for validator announcements
+    function mailbox() external view returns (address);
+
     /// @notice Returns a list of validators that have made announcements
     function getAnnouncedValidators() external view returns (address[] memory);
 

package/contracts/interfaces/hooks/IMessageHook.sol

@@ -0,0 +1,9 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+interface IMessageHook {
+    function postDispatch(uint32 _destination, bytes32 _messageId)
+        external
+        payable
+        returns (uint256);
+}

package/contracts/interfaces/middleware/IInterchainAccountRouter.sol

@@ -0,0 +1,50 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+import {OwnableMulticall} from "../../OwnableMulticall.sol";
+import {CallLib} from "../../libs/Call.sol";
+
+interface IInterchainAccountRouter {
+    function callRemote(
+        uint32 _destination,
+        address _to,
+        uint256 _value,
+        bytes calldata _data
+    ) external returns (bytes32);
+
+    function callRemote(uint32 _destination, CallLib.Call[] calldata calls)
+        external
+        returns (bytes32);
+
+    function callRemoteWithOverrides(
+        uint32 _destination,
+        bytes32 _router,
+        bytes32 _ism,
+        CallLib.Call[] calldata calls
+    ) external returns (bytes32);
+
+    function getLocalInterchainAccount(
+        uint32 _origin,
+        bytes32 _router,
+        bytes32 _owner,
+        address _ism
+    ) external view returns (OwnableMulticall);
+
+    function getLocalInterchainAccount(
+        uint32 _origin,
+        address _router,
+        address _owner,
+        address _ism
+    ) external view returns (OwnableMulticall);
+
+    function getRemoteInterchainAccount(
+        address _router,
+        address _owner,
+        address _ism
+    ) external view returns (address);
+
+    function getRemoteInterchainAccount(uint32 _destination, address _owner)
+        external
+        view
+        returns (address);
+}

package/contracts/interfaces/middleware/IInterchainQueryRouter.sol

@@ -0,0 +1,18 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+import {CallLib} from "../../libs/Call.sol";
+
+interface IInterchainQueryRouter {
+    function query(
+        uint32 _destination,
+        address _to,
+        bytes memory _data,
+        bytes memory _callback
+    ) external returns (bytes32);
+
+    function query(
+        uint32 _destination,
+        CallLib.StaticCallWithCallback[] calldata calls
+    ) external returns (bytes32);
+}

package/contracts/isms/aggregation/AbstractAggregationIsm.sol

@@ -7,7 +7,7 @@ import {ECDSA} from "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
 // ============ Internal Imports ============
 import {IInterchainSecurityModule} from "../../interfaces/IInterchainSecurityModule.sol";
 import {IAggregationIsm} from "../../interfaces/isms/IAggregationIsm.sol";
-import {AggregationIsmMetadata} from "../../isms/libs/AggregationIsmMetadata.sol";
+import {AggregationIsmMetadata} from "../../libs/isms/AggregationIsmMetadata.sol";
 
 /**
  * @title AggregationIsm

package/contracts/isms/aggregation/StaticAggregationIsm.sol

@@ -3,7 +3,7 @@ pragma solidity >=0.8.0;
 
 // ============ Internal Imports ============
 import {AbstractAggregationIsm} from "./AbstractAggregationIsm.sol";
-import {AggregationIsmMetadata} from "../../isms/libs/AggregationIsmMetadata.sol";
+import {AggregationIsmMetadata} from "../../libs/isms/AggregationIsmMetadata.sol";
 import {MetaProxy} from "../../libs/MetaProxy.sol";
 
 /**