@hyperlane-xyz/core 1.5.6-beta0 → 1.5.8

package/contracts/Router.sol

@@ -0,0 +1,224 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+// ============ Internal Imports ============
+import {HyperlaneConnectionClient} from "./HyperlaneConnectionClient.sol";
+import {IInterchainGasPaymaster} from "./interfaces/IInterchainGasPaymaster.sol";
+import {IMessageRecipient} from "./interfaces/IMessageRecipient.sol";
+import {IMailbox} from "./interfaces/IMailbox.sol";
+import {EnumerableMapExtended} from "./libs/EnumerableMapExtended.sol";
+
+abstract contract Router is HyperlaneConnectionClient, IMessageRecipient {
+    using EnumerableMapExtended for EnumerableMapExtended.UintToBytes32Map;
+
+    string private constant NO_ROUTER_ENROLLED_REVERT_MESSAGE =
+        "No router enrolled for domain. Did you specify the right domain ID?";
+
+    // ============ Mutable Storage ============
+    EnumerableMapExtended.UintToBytes32Map internal _routers;
+    uint256[49] private __GAP; // gap for upgrade safety
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when a router is set.
+     * @param domain The domain of the new router
+     * @param router The address of the new router
+     */
+    event RemoteRouterEnrolled(uint32 indexed domain, bytes32 router);
+
+    // ============ Modifiers ============
+    /**
+     * @notice Only accept messages from a remote Router contract
+     * @param _origin The domain the message is coming from
+     * @param _router The address the message is coming from
+     */
+    modifier onlyRemoteRouter(uint32 _origin, bytes32 _router) {
+        require(
+            _isRemoteRouter(_origin, _router),
+            NO_ROUTER_ENROLLED_REVERT_MESSAGE
+        );
+        _;
+    }
+
+    // ======== Initializer =========
+    function __Router_initialize(address _mailbox) internal onlyInitializing {
+        __HyperlaneConnectionClient_initialize(_mailbox);
+    }
+
+    function __Router_initialize(
+        address _mailbox,
+        address _interchainGasPaymaster
+    ) internal onlyInitializing {
+        __HyperlaneConnectionClient_initialize(
+            _mailbox,
+            _interchainGasPaymaster
+        );
+    }
+
+    function __Router_initialize(
+        address _mailbox,
+        address _interchainGasPaymaster,
+        address _interchainSecurityModule
+    ) internal onlyInitializing {
+        __HyperlaneConnectionClient_initialize(
+            _mailbox,
+            _interchainGasPaymaster,
+            _interchainSecurityModule
+        );
+    }
+
+    // ============ External functions ============
+    function domains() external view returns (uint32[] memory) {
+        return _routers.uint32Keys();
+    }
+
+    /**
+     * @notice Returns the address of the Router contract for the given domain
+     * @param _domain The remote domain ID.
+     * @dev Returns 0 address if no router is enrolled for the given domain
+     * @return router The address of the Router contract for the given domain
+     */
+    function routers(uint32 _domain) public view virtual returns (bytes32) {
+        (, bytes32 _router) = _routers.tryGet(_domain);
+        return _router;
+    }
+
+    /**
+     * @notice Register the address of a Router contract for the same Application on a remote chain
+     * @param _domain The domain of the remote Application Router
+     * @param _router The address of the remote Application Router
+     */
+    function enrollRemoteRouter(uint32 _domain, bytes32 _router)
+        external
+        virtual
+        onlyOwner
+    {
+        _enrollRemoteRouter(_domain, _router);
+    }
+
+    /**
+     * @notice Batch version of `enrollRemoteRouter`
+     * @param _domains The domaisn of the remote Application Routers
+     * @param _addresses The addresses of the remote Application Routers
+     */
+    function enrollRemoteRouters(
+        uint32[] calldata _domains,
+        bytes32[] calldata _addresses
+    ) external virtual onlyOwner {
+        require(_domains.length == _addresses.length, "!length");
+        uint256 length = _domains.length;
+        for (uint256 i = 0; i < length; i += 1) {
+            _enrollRemoteRouter(_domains[i], _addresses[i]);
+        }
+    }
+
+    /**
+     * @notice Handles an incoming message
+     * @param _origin The origin domain
+     * @param _sender The sender address
+     * @param _message The message
+     */
+    function handle(
+        uint32 _origin,
+        bytes32 _sender,
+        bytes calldata _message
+    ) external virtual override onlyMailbox onlyRemoteRouter(_origin, _sender) {
+        _handle(_origin, _sender, _message);
+    }
+
+    // ============ Virtual functions ============
+    function _handle(
+        uint32 _origin,
+        bytes32 _sender,
+        bytes calldata _message
+    ) internal virtual;
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Set the router for a given domain
+     * @param _domain The domain
+     * @param _address The new router
+     */
+    function _enrollRemoteRouter(uint32 _domain, bytes32 _address)
+        internal
+        virtual
+    {
+        _routers.set(_domain, _address);
+        emit RemoteRouterEnrolled(_domain, _address);
+    }
+
+    /**
+     * @notice Return true if the given domain / router is the address of a remote Application Router
+     * @param _domain The domain of the potential remote Application Router
+     * @param _address The address of the potential remote Application Router
+     */
+    function _isRemoteRouter(uint32 _domain, bytes32 _address)
+        internal
+        view
+        returns (bool)
+    {
+        return routers(_domain) == _address;
+    }
+
+    /**
+     * @notice Assert that the given domain has a Application Router registered and return its address
+     * @param _domain The domain of the chain for which to get the Application Router
+     * @return _router The address of the remote Application Router on _domain
+     */
+    function _mustHaveRemoteRouter(uint32 _domain)
+        internal
+        view
+        returns (bytes32)
+    {
+        (bool contained, bytes32 _router) = _routers.tryGet(_domain);
+        require(contained, NO_ROUTER_ENROLLED_REVERT_MESSAGE);
+        return _router;
+    }
+
+    /**
+     * @notice Dispatches a message to an enrolled router via the local router's Mailbox
+     * and pays for it to be relayed to the destination.
+     * @dev Reverts if there is no enrolled router for _destinationDomain.
+     * @param _destinationDomain The domain of the chain to which to send the message.
+     * @param _messageBody Raw bytes content of message.
+     * @param _gasAmount The amount of destination gas for the message that is requested via the InterchainGasPaymaster.
+     * @param _gasPayment The amount of native tokens to pay for the message to be relayed.
+     * @param _gasPaymentRefundAddress The address to refund any gas overpayment to.
+     */
+    function _dispatchWithGas(
+        uint32 _destinationDomain,
+        bytes memory _messageBody,
+        uint256 _gasAmount,
+        uint256 _gasPayment,
+        address _gasPaymentRefundAddress
+    ) internal returns (bytes32 _messageId) {
+        _messageId = _dispatch(_destinationDomain, _messageBody);
+        // Call the IGP even if the gas payment is zero. This is to support on-chain
+        // fee quoting in IGPs, which should always revert if gas payment is insufficient.
+        interchainGasPaymaster.payForGas{value: _gasPayment}(
+            _messageId,
+            _destinationDomain,
+            _gasAmount,
+            _gasPaymentRefundAddress
+        );
+    }
+
+    /**
+     * @notice Dispatches a message to an enrolled router via the provided Mailbox.
+     * @dev Does not pay interchain gas.
+     * @dev Reverts if there is no enrolled router for _destinationDomain.
+     * @param _destinationDomain The domain of the chain to which to send the message.
+     * @param _messageBody Raw bytes content of message.
+     */
+    function _dispatch(uint32 _destinationDomain, bytes memory _messageBody)
+        internal
+        virtual
+        returns (bytes32)
+    {
+        // Ensure that destination chain has an enrolled router.
+        bytes32 _router = _mustHaveRemoteRouter(_destinationDomain);
+        return mailbox.dispatch(_destinationDomain, _router, _messageBody);
+    }
+}

package/contracts/ValidatorAnnounce.sol

@@ -0,0 +1,117 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+// ============ Internal Imports ============
+import {IValidatorAnnounce} from "./interfaces/IValidatorAnnounce.sol";
+import {IMailbox} from "./interfaces/IMailbox.sol";
+import {TypeCasts} from "./libs/TypeCasts.sol";
+import {ValidatorAnnouncements} from "./libs/ValidatorAnnouncements.sol";
+// ============ External Imports ============
+import {EnumerableSet} from "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
+import {ECDSA} from "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
+
+/**
+ * @title ValidatorAnnounce
+ * @notice Stores the location(s) of validator signed checkpoints
+ */
+contract ValidatorAnnounce is IValidatorAnnounce {
+    // ============ Libraries ============
+
+    using EnumerableSet for EnumerableSet.AddressSet;
+    using TypeCasts for address;
+
+    // ============ Constants ============
+
+    // Address of the mailbox being validated
+    address public immutable mailbox;
+    // Domain of chain on which the contract is deployed
+    uint32 public immutable localDomain;
+
+    // ============ Public Storage ============
+
+    // The set of validators that have announced
+    EnumerableSet.AddressSet private validators;
+    // Storage locations of validator signed checkpoints
+    mapping(address => string[]) private storageLocations;
+    // Mapping to prevent the same announcement from being registered
+    // multiple times.
+    mapping(bytes32 => bool) private replayProtection;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when a new validator announcement is made
+     * @param validator The address of the announcing validator
+     * @param storageLocation The storage location being announced
+     */
+    event ValidatorAnnouncement(
+        address indexed validator,
+        string storageLocation
+    );
+
+    // ============ Constructor ============
+
+    constructor(address _mailbox) {
+        mailbox = _mailbox;
+        localDomain = IMailbox(mailbox).localDomain();
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Announces a validator signature storage location
+     * @param _storageLocation Information encoding the location of signed
+     * checkpoints
+     * @param _signature The signed validator announcement
+     * @return True upon success
+     */
+    function announce(
+        address _validator,
+        string calldata _storageLocation,
+        bytes calldata _signature
+    ) external returns (bool) {
+        // Ensure that the same storage metadata isn't being announced
+        // multiple times for the same validator.
+        bytes32 _replayId = keccak256(
+            abi.encodePacked(_validator, _storageLocation)
+        );
+        require(replayProtection[_replayId] == false, "replay");
+        replayProtection[_replayId] = true;
+
+        // Verify that the signature matches the declared validator
+        bytes32 _announcementDigest = ValidatorAnnouncements
+            .getAnnouncementDigest(mailbox, localDomain, _storageLocation);
+        address _signer = ECDSA.recover(_announcementDigest, _signature);
+        require(_signer == _validator, "!signature");
+
+        // Store the announcement
+        if (!validators.contains(_validator)) {
+            validators.add(_validator);
+        }
+        storageLocations[_validator].push(_storageLocation);
+        emit ValidatorAnnouncement(_validator, _storageLocation);
+        return true;
+    }
+
+    /**
+     * @notice Returns a list of all announced storage locations
+     * @param _validators The list of validators to get registrations for
+     * @return A list of registered storage metadata
+     */
+    function getAnnouncedStorageLocations(address[] calldata _validators)
+        external
+        view
+        returns (string[][] memory)
+    {
+        string[][] memory _metadata = new string[][](_validators.length);
+        for (uint256 i = 0; i < _validators.length; i++) {
+            _metadata[i] = storageLocations[_validators[i]];
+        }
+        return _metadata;
+    }
+
+    /// @notice Returns a list of validators that have made announcements
+    function getAnnouncedValidators() external view returns (address[] memory) {
+        return validators.values();
+    }
+}

package/contracts/hooks/ERC5164/ERC5164MessageHook.sol

@@ -0,0 +1,95 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {TypeCasts} from "../../libs/TypeCasts.sol";
+import {IMessageHook} from "../../interfaces/hooks/IMessageHook.sol";
+import {IMessageDispatcher} from "./interfaces/IMessageDispatcher.sol";
+import {ERC5164ISM} from "../../isms/hook/ERC5164ISM.sol";
+
+// ============ External Imports ============
+
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title 5164MessageHook
+ * @notice Message hook to inform the 5164 ISM of messages published through
+ * any of the 5164 adapters.
+ */
+contract ERC5164MessageHook is IMessageHook {
+    using TypeCasts for address;
+    // ============ Constants ============
+
+    // Domain of chain on which the ERC5164ISM is deployed
+    uint32 public immutable destinationDomain;
+    // Dispatcher used to send messages
+    IMessageDispatcher public immutable dispatcher;
+    // address for ERC5164ISM to verify messages
+    address public immutable ism;
+
+    // ============ Constructor ============
+
+    constructor(
+        uint32 _destinationDomain,
+        address _dispatcher,
+        address _ism
+    ) {
+        require(
+            _destinationDomain != 0,
+            "ERC5164Hook: invalid destination domain"
+        );
+        require(_ism != address(0), "ERC5164Hook: invalid ISM");
+        destinationDomain = _destinationDomain;
+
+        require(
+            Address.isContract(_dispatcher),
+            "ERC5164Hook: invalid dispatcher"
+        );
+        dispatcher = IMessageDispatcher(_dispatcher);
+        ism = _ism;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Hook to inform the ERC5164ISM of messages published through.
+     * @dev anyone can call this function, that's why we need to send msg.sender
+     * @param _destinationDomain The destination domain of the message.
+     * @param _messageId The message ID.
+     * @return gasOverhead The gas overhead for the function call on destination.
+     */
+    function postDispatch(uint32 _destinationDomain, bytes32 _messageId)
+        public
+        payable
+        override
+        returns (uint256)
+    {
+        require(msg.value == 0, "ERC5164Hook: no value allowed");
+        require(
+            _destinationDomain == destinationDomain,
+            "ERC5164Hook: invalid destination domain"
+        );
+
+        bytes memory _payload = abi.encodeCall(
+            ERC5164ISM.verifyMessageId,
+            (msg.sender.addressToBytes32(), _messageId)
+        );
+
+        dispatcher.dispatchMessage(_destinationDomain, ism, _payload);
+
+        // EIP-5164 doesn't specify a gas overhead
+        return 0;
+    }
+}

package/contracts/hooks/OptimismMessageHook.sol

@@ -0,0 +1,98 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.8.0;
+
+/*@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+     @@@@@  HYPERLANE  @@@@@@@
+    @@@@@@@@@@@@@@@@@@@@@@@@@
+   @@@@@@@@@       @@@@@@@@@
+  @@@@@@@@@       @@@@@@@@@
+ @@@@@@@@@       @@@@@@@@@
+@@@@@@@@@       @@@@@@@@*/
+
+// ============ Internal Imports ============
+import {IMessageHook} from "../interfaces/hooks/IMessageHook.sol";
+import {OptimismISM} from "../isms/hook/OptimismISM.sol";
+import {TypeCasts} from "../libs/TypeCasts.sol";
+
+// ============ External Imports ============
+import {ICrossDomainMessenger} from "@eth-optimism/contracts/libraries/bridge/ICrossDomainMessenger.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+/**
+ * @title OptimismMessageHook
+ * @notice Message hook to inform the Optimism ISM of messages published through
+ * the native Optimism bridge.
+ */
+contract OptimismMessageHook is IMessageHook {
+    using TypeCasts for address;
+    // ============ Constants ============
+
+    // Domain of chain on which the optimism ISM is deployed
+    uint32 public immutable destinationDomain;
+    // Messenger used to send messages from L1 -> L2
+    ICrossDomainMessenger public immutable l1Messenger;
+    // address for Optimism ISM to verify messages
+    address public immutable ism;
+    // Gas limit for sending messages to L2
+    // First 1.92e6 gas is provided by Optimism, see more here:
+    // https://community.optimism.io/docs/developers/bridge/messaging/#for-l1-%E2%87%92-l2-transactions
+    uint32 internal constant GAS_LIMIT = 1_920_000;
+
+    // ============ Constructor ============
+
+    constructor(
+        uint32 _destinationDomain,
+        address _messenger,
+        address _ism
+    ) {
+        require(
+            _destinationDomain != 0,
+            "OptimismHook: invalid destination domain"
+        );
+        require(_ism != address(0), "OptimismHook: invalid ISM");
+        destinationDomain = _destinationDomain;
+
+        require(
+            Address.isContract(_messenger),
+            "OptimismHook: invalid messenger"
+        );
+        l1Messenger = ICrossDomainMessenger(_messenger);
+        ism = _ism;
+    }
+
+    // ============ External Functions ============
+
+    /**
+     * @notice Hook to inform the optimism ISM of messages published through.
+     * @dev anyone can call this function, that's why we need to send msg.sender
+     * @param _destination The destination domain of the message.
+     * @param _messageId The message ID.
+     * @return gasOverhead The gas overhead for the function call on L2.
+     */
+    function postDispatch(uint32 _destination, bytes32 _messageId)
+        public
+        payable
+        override
+        returns (uint256)
+    {
+        require(msg.value == 0, "OptimismHook: no value allowed");
+        require(
+            _destination == destinationDomain,
+            "OptimismHook: invalid destination domain"
+        );
+
+        bytes memory _payload = abi.encodeCall(
+            OptimismISM.verifyMessageId,
+            (msg.sender.addressToBytes32(), _messageId)
+        );
+
+        l1Messenger.sendMessage(ism, _payload, GAS_LIMIT);
+
+        // calling the verifyMessageId function is ~25k gas but we get 1.92m gas from Optimism
+        return 0;
+    }
+}