@hyperlane-xyz/core 1.5.6-beta0 → 1.5.8

package/contracts/GasRouter.sol

@@ -0,0 +1,103 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+import {Router} from "./Router.sol";
+
+abstract contract GasRouter is Router {
+    // ============ Mutable Storage ============
+    mapping(uint32 => uint256) public destinationGas;
+
+    // ============ Events ============
+
+    /**
+     * @notice Emitted when a domain's destination gas is set.
+     * @param domain The domain of the router.
+     * @param gas The gas amount used by the handle function of the domain's router.
+     */
+    event DestinationGasSet(uint32 indexed domain, uint256 gas);
+
+    struct GasRouterConfig {
+        uint32 domain;
+        uint256 gas;
+    }
+
+    /**
+     * @notice Sets the gas amount dispatched for each configured domain.
+     * @param gasConfigs The array of GasRouterConfig structs
+     */
+    function setDestinationGas(GasRouterConfig[] calldata gasConfigs)
+        external
+        onlyOwner
+    {
+        for (uint256 i = 0; i < gasConfigs.length; i += 1) {
+            _setDestinationGas(gasConfigs[i].domain, gasConfigs[i].gas);
+        }
+    }
+
+    /**
+     * @notice Returns the gas payment required to dispatch a message to the given domain's router.
+     * @param _destinationDomain The domain of the router.
+     * @return _gasPayment Payment computed by the registered InterchainGasPaymaster.
+     */
+    function quoteGasPayment(uint32 _destinationDomain)
+        external
+        view
+        returns (uint256 _gasPayment)
+    {
+        return
+            interchainGasPaymaster.quoteGasPayment(
+                _destinationDomain,
+                destinationGas[_destinationDomain]
+            );
+    }
+
+    function _setDestinationGas(uint32 domain, uint256 gas) internal {
+        destinationGas[domain] = gas;
+        emit DestinationGasSet(domain, gas);
+    }
+
+    /**
+     * @dev Uses the destinationGas mapping to populate the gas amount for the message.
+     * @notice Dispatches a message to an enrolled router via the local router's Mailbox
+     * and pays for it to be relayed to the destination.
+     * @dev Reverts if there is no enrolled router for _destinationDomain.
+     * @param _destinationDomain The domain of the chain to which to send the message.
+     * @param _messageBody Raw bytes content of message.
+     * @param _gasPayment The amount of native tokens to pay for the message to be relayed.
+     * @param _gasPaymentRefundAddress The address to refund any gas overpayment to.
+     */
+    function _dispatchWithGas(
+        uint32 _destinationDomain,
+        bytes memory _messageBody,
+        uint256 _gasPayment,
+        address _gasPaymentRefundAddress
+    ) internal returns (bytes32 _messageId) {
+        return
+            _dispatchWithGas(
+                _destinationDomain,
+                _messageBody,
+                destinationGas[_destinationDomain],
+                _gasPayment,
+                _gasPaymentRefundAddress
+            );
+    }
+
+    /**
+     * @dev Passes `msg.value` as gas payment and `msg.sender` as gas payment refund address.
+     * @dev Uses the destinationGas mapping to populate the gas amount for the message.
+     * @param _destinationDomain The domain of the chain to send the message.
+     * @param _messageBody Raw bytes content of message.
+     */
+    function _dispatchWithGas(
+        uint32 _destinationDomain,
+        bytes memory _messageBody
+    ) internal returns (bytes32 _messageId) {
+        return
+            _dispatchWithGas(
+                _destinationDomain,
+                _messageBody,
+                msg.value,
+                msg.sender
+            );
+    }
+}

package/contracts/HyperlaneConnectionClient.sol

@@ -0,0 +1,168 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity >=0.6.11;
+
+// ============ Internal Imports ============
+import {IInterchainGasPaymaster} from "./interfaces/IInterchainGasPaymaster.sol";
+import {IInterchainSecurityModule} from "./interfaces/IInterchainSecurityModule.sol";
+import {IHyperlaneConnectionClient} from "./interfaces/IHyperlaneConnectionClient.sol";
+import {IMailbox} from "./interfaces/IMailbox.sol";
+
+// ============ External Imports ============
+import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
+import {Address} from "@openzeppelin/contracts/utils/Address.sol";
+
+abstract contract HyperlaneConnectionClient is
+    OwnableUpgradeable,
+    IHyperlaneConnectionClient
+{
+    // ============ Mutable Storage ============
+
+    IMailbox public mailbox;
+    // Interchain Gas Paymaster contract. The relayer associated with this contract
+    // must be willing to relay messages dispatched from the current Mailbox contract,
+    // otherwise payments made to the paymaster will not result in relayed messages.
+    IInterchainGasPaymaster public interchainGasPaymaster;
+
+    IInterchainSecurityModule public interchainSecurityModule;
+
+    uint256[48] private __GAP; // gap for upgrade safety
+
+    // ============ Events ============
+    /**
+     * @notice Emitted when a new mailbox is set.
+     * @param mailbox The address of the mailbox contract
+     */
+    event MailboxSet(address indexed mailbox);
+
+    /**
+     * @notice Emitted when a new Interchain Gas Paymaster is set.
+     * @param interchainGasPaymaster The address of the Interchain Gas Paymaster.
+     */
+    event InterchainGasPaymasterSet(address indexed interchainGasPaymaster);
+
+    event InterchainSecurityModuleSet(address indexed module);
+
+    // ============ Modifiers ============
+
+    /**
+     * @notice Only accept messages from an Hyperlane Mailbox contract
+     */
+    modifier onlyMailbox() {
+        require(msg.sender == address(mailbox), "!mailbox");
+        _;
+    }
+
+    /**
+     * @notice Only accept addresses that at least have contract code
+     */
+    modifier onlyContract(address _contract) {
+        require(Address.isContract(_contract), "!contract");
+        _;
+    }
+
+    // ======== Initializer =========
+
+    function __HyperlaneConnectionClient_initialize(address _mailbox)
+        internal
+        onlyInitializing
+    {
+        _setMailbox(_mailbox);
+        __Ownable_init();
+    }
+
+    function __HyperlaneConnectionClient_initialize(
+        address _mailbox,
+        address _interchainGasPaymaster
+    ) internal onlyInitializing {
+        _setInterchainGasPaymaster(_interchainGasPaymaster);
+        __HyperlaneConnectionClient_initialize(_mailbox);
+    }
+
+    function __HyperlaneConnectionClient_initialize(
+        address _mailbox,
+        address _interchainGasPaymaster,
+        address _interchainSecurityModule
+    ) internal onlyInitializing {
+        _setInterchainSecurityModule(_interchainSecurityModule);
+        __HyperlaneConnectionClient_initialize(
+            _mailbox,
+            _interchainGasPaymaster
+        );
+    }
+
+    function __HyperlaneConnectionClient_initialize(
+        address _mailbox,
+        address _interchainGasPaymaster,
+        address _interchainSecurityModule,
+        address _owner
+    ) internal onlyInitializing {
+        _setMailbox(_mailbox);
+        _setInterchainGasPaymaster(_interchainGasPaymaster);
+        _setInterchainSecurityModule(_interchainSecurityModule);
+        _transferOwnership(_owner);
+    }
+
+    // ============ External functions ============
+
+    /**
+     * @notice Sets the address of the application's Mailbox.
+     * @param _mailbox The address of the Mailbox contract.
+     */
+    function setMailbox(address _mailbox) external virtual onlyOwner {
+        _setMailbox(_mailbox);
+    }
+
+    /**
+     * @notice Sets the address of the application's InterchainGasPaymaster.
+     * @param _interchainGasPaymaster The address of the InterchainGasPaymaster contract.
+     */
+    function setInterchainGasPaymaster(address _interchainGasPaymaster)
+        external
+        virtual
+        onlyOwner
+    {
+        _setInterchainGasPaymaster(_interchainGasPaymaster);
+    }
+
+    function setInterchainSecurityModule(address _module)
+        external
+        virtual
+        onlyOwner
+    {
+        _setInterchainSecurityModule(_module);
+    }
+
+    // ============ Internal functions ============
+
+    /**
+     * @notice Sets the address of the application's InterchainGasPaymaster.
+     * @param _interchainGasPaymaster The address of the InterchainGasPaymaster contract.
+     */
+    function _setInterchainGasPaymaster(address _interchainGasPaymaster)
+        internal
+        onlyContract(_interchainGasPaymaster)
+    {
+        interchainGasPaymaster = IInterchainGasPaymaster(
+            _interchainGasPaymaster
+        );
+        emit InterchainGasPaymasterSet(_interchainGasPaymaster);
+    }
+
+    /**
+     * @notice Modify the contract the Application uses to validate Mailbox contracts
+     * @param _mailbox The address of the mailbox contract
+     */
+    function _setMailbox(address _mailbox) internal onlyContract(_mailbox) {
+        mailbox = IMailbox(_mailbox);
+        emit MailboxSet(_mailbox);
+    }
+
+    function _setInterchainSecurityModule(address _module) internal {
+        require(
+            _module == address(0) || Address.isContract(_module),
+            "!contract"
+        );
+        interchainSecurityModule = IInterchainSecurityModule(_module);
+        emit InterchainSecurityModuleSet(_module);
+    }
+}