@bananapus/core-v6 0.0.36 → 0.0.38

package/test/TestPayBurnRedeemFlow.sol

@@ -1,195 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.6;
-
-import {TestBaseWorkflow} from "./helpers/TestBaseWorkflow.sol";
-import {JBController} from "../src/JBController.sol";
-import {JBTerminalStore} from "../src/JBTerminalStore.sol";
-import {JBTokens} from "../src/JBTokens.sol";
-import {IJBController} from "../src/interfaces/IJBController.sol";
-import {IJBMultiTerminal} from "../src/interfaces/IJBMultiTerminal.sol";
-import {IJBRulesetApprovalHook} from "../src/interfaces/IJBRulesetApprovalHook.sol";
-import {IJBTerminal} from "../src/interfaces/IJBTerminal.sol";
-import {JBConstants} from "../src/libraries/JBConstants.sol";
-import {JBAccountingContext} from "../src/structs/JBAccountingContext.sol";
-import {JBFundAccessLimitGroup} from "../src/structs/JBFundAccessLimitGroup.sol";
-import {JBRulesetConfig} from "../src/structs/JBRulesetConfig.sol";
-import {JBRulesetMetadata} from "../src/structs/JBRulesetMetadata.sol";
-import {JBSplitGroup} from "../src/structs/JBSplitGroup.sol";
-import {JBTerminalConfig} from "../src/structs/JBTerminalConfig.sol";
-import {mul as UD60x18mul, unwrap as UD60x18unwrap, wrap as UD60x18wrap} from "@prb/math/src/UD60x18.sol";
-
-// Project can issue token, receive payments in exchange for tokens, burn some of the claimed tokens, and allow holders
-// to cash out the rest of tokens.
-contract TestPayBurnCashOutFlow_Local is TestBaseWorkflow {
-    IJBController private _controller;
-    IJBMultiTerminal private _terminal;
-    JBTokens private _tokens;
-    uint112 private _weight;
-    JBRulesetMetadata _metadata;
-    uint256 private _projectId;
-    address private _projectOwner;
-    address private _beneficiary;
-
-    function setUp() public override {
-        super.setUp();
-
-        _projectOwner = multisig();
-        _beneficiary = beneficiary();
-        _controller = jbController();
-        _terminal = jbMultiTerminal();
-        _tokens = jbTokens();
-        _weight = 1000 * 10 ** 18;
-        _metadata = JBRulesetMetadata({
-            reservedPercent: 0,
-            cashOutTaxRate: JBConstants.MAX_CASH_OUT_TAX_RATE,
-            baseCurrency: uint32(uint160(JBConstants.NATIVE_TOKEN)),
-            pausePay: false,
-            pauseCreditTransfers: false,
-            allowOwnerMinting: false,
-            allowSetCustomToken: true,
-            allowTerminalMigration: false,
-            allowSetTerminals: false,
-            ownerMustSendPayouts: false,
-            allowSetController: false,
-            allowAddAccountingContext: true,
-            allowAddPriceFeed: false,
-            holdFees: false,
-            useTotalSurplusForCashOuts: false,
-            useDataHookForPay: false,
-            useDataHookForCashOut: false,
-            dataHook: address(0),
-            metadata: 0
-        });
-
-        IJBTerminal[] memory _terminals = new IJBTerminal[](1);
-        _terminals[0] = (_terminal);
-
-        // Package up ruleset configuration.
-        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
-        _rulesetConfig[0].mustStartAtOrAfter = 0;
-        _rulesetConfig[0].duration = 0;
-        _rulesetConfig[0].weight = _weight;
-        _rulesetConfig[0].weightCutPercent = 0;
-        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
-        _rulesetConfig[0].metadata = _metadata;
-        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
-        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
-
-        // Package up terminal configuration.
-        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
-        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
-        _tokensToAccept[0] = JBAccountingContext({
-            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
-        });
-        _terminalConfigurations[0] =
-            JBTerminalConfig({terminal: _terminal, accountingContextsToAccept: _tokensToAccept});
-
-        // Dummy project that will receive fees.
-        _controller.launchProjectFor({
-            owner: _projectOwner,
-            projectUri: "myIPFSHash",
-            rulesetConfigurations: _rulesetConfig,
-            terminalConfigurations: _terminalConfigurations,
-            memo: ""
-        });
-
-        _projectId = _controller.launchProjectFor({
-            owner: _projectOwner,
-            projectUri: "myIPFSHash",
-            rulesetConfigurations: _rulesetConfig,
-            terminalConfigurations: _terminalConfigurations,
-            memo: ""
-        });
-    }
-
-    function testFuzzPayBurnCashOutFlow(
-        uint112 _nativePayAmount,
-        uint256 _burnTokenAmount,
-        uint256 _cashOutAmount
-    )
-        external
-    {
-        // Issue an ERC-20 token for project.
-        vm.prank(_projectOwner);
-        _controller.deployERC20For(_projectId, "TestName", "TestSymbol", bytes32(0));
-
-        address someRandomUser = vm.addr(1);
-        vm.prank(someRandomUser);
-        vm.deal(someRandomUser, _nativePayAmount);
-        // Make a payment.
-        _terminal.pay{value: _nativePayAmount}({
-            projectId: _projectId,
-            amount: _nativePayAmount,
-            token: JBConstants.NATIVE_TOKEN, // Unused.
-            beneficiary: _beneficiary,
-            minReturnedTokens: 0,
-            memo: "Take my money!",
-            metadata: new bytes(0)
-        });
-
-        // Make sure the beneficiary has a balance of project tokens.
-        uint256 _beneficiaryTokenBalance =
-            UD60x18unwrap(UD60x18mul(UD60x18wrap(_nativePayAmount), UD60x18wrap(_weight)));
-        assertEq(_tokens.totalBalanceOf(_beneficiary, _projectId), _beneficiaryTokenBalance);
-
-        // Make sure the native token balance in terminal is up to date.
-        uint256 _terminalBalance = _nativePayAmount;
-        assertEq(
-            jbTerminalStore().balanceOf(address(_terminal), _projectId, JBConstants.NATIVE_TOKEN), _terminalBalance
-        );
-
-        // Burn tokens from beneficiary.
-        if (_burnTokenAmount == 0) {
-            vm.expectRevert(JBController.JBController_ZeroTokensToBurn.selector);
-        } else if (_burnTokenAmount > _beneficiaryTokenBalance) {
-            vm.expectRevert(
-                abi.encodeWithSelector(
-                    JBTokens.JBTokens_InsufficientTokensToBurn.selector, _burnTokenAmount, _beneficiaryTokenBalance
-                )
-            );
-        } else {
-            _beneficiaryTokenBalance -= _burnTokenAmount;
-        }
-
-        vm.prank(_beneficiary);
-        _controller.burnTokensOf({
-            holder: _beneficiary, projectId: _projectId, tokenCount: _burnTokenAmount, memo: "I hate tokens!"
-        });
-
-        // Make sure the beneficiary should has a new balance of project tokens.
-        assertEq(_tokens.totalBalanceOf(_beneficiary, _projectId), _beneficiaryTokenBalance);
-
-        // Cash out tokens.
-        if (_cashOutAmount > _beneficiaryTokenBalance) {
-            vm.expectRevert(
-                abi.encodeWithSelector(
-                    JBTerminalStore.JBTerminalStore_InsufficientTokens.selector,
-                    _cashOutAmount,
-                    _beneficiaryTokenBalance
-                )
-            );
-        } else {
-            _beneficiaryTokenBalance -= _cashOutAmount;
-        }
-
-        vm.prank(_beneficiary);
-        uint256 _reclaimAmt = _terminal.cashOutTokensOf({
-            holder: _beneficiary,
-            projectId: _projectId,
-            cashOutCount: _cashOutAmount,
-            tokenToReclaim: JBConstants.NATIVE_TOKEN, // Unused.
-            minTokensReclaimed: 0,
-            beneficiary: payable(_beneficiary),
-            metadata: new bytes(0)
-        });
-
-        // Make sure the beneficiary has a new balance of project tokens.
-        assertEq(_tokens.totalBalanceOf(_beneficiary, _projectId), _beneficiaryTokenBalance);
-
-        // Make sure the native token balance in terminal is up to date.
-        assertEq(
-            jbTerminalStore().balanceOf(address(_terminal), _projectId, JBConstants.NATIVE_TOKEN),
-            _terminalBalance - _reclaimAmt
-        );
-    }
-}

package/test/TestPayHooks.sol

@@ -1,209 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity >=0.8.6;
-
-import {TestBaseWorkflow} from "./helpers/TestBaseWorkflow.sol";
-import {IJBController} from "../src/interfaces/IJBController.sol";
-import {IJBPayHook} from "../src/interfaces/IJBPayHook.sol";
-import {IJBRulesetApprovalHook} from "../src/interfaces/IJBRulesetApprovalHook.sol";
-import {IJBRulesetDataHook} from "../src/interfaces/IJBRulesetDataHook.sol";
-import {IJBTerminal} from "../src/interfaces/IJBTerminal.sol";
-import {JBConstants} from "../src/libraries/JBConstants.sol";
-import {JBAccountingContext} from "../src/structs/JBAccountingContext.sol";
-import {JBAfterPayRecordedContext} from "../src/structs/JBAfterPayRecordedContext.sol";
-import {JBFundAccessLimitGroup} from "../src/structs/JBFundAccessLimitGroup.sol";
-import {JBPayHookSpecification} from "../src/structs/JBPayHookSpecification.sol";
-import {JBRuleset} from "../src/structs/JBRuleset.sol";
-import {JBRulesetConfig} from "../src/structs/JBRulesetConfig.sol";
-import {JBRulesetMetadata} from "../src/structs/JBRulesetMetadata.sol";
-import {JBSplitGroup} from "../src/structs/JBSplitGroup.sol";
-import {JBTerminalConfig} from "../src/structs/JBTerminalConfig.sol";
-import {JBTokenAmount} from "../src/structs/JBTokenAmount.sol";
-import {mulDiv} from "@prb/math/src/Common.sol";
-
-contract TestPayHooks_Local is TestBaseWorkflow {
-    uint8 private constant _WEIGHT_DECIMALS = 18;
-    uint8 private constant _NATIVE_TOKEN_DECIMALS = 18;
-    uint112 private constant _WEIGHT = uint112(1000 * 10 ** _WEIGHT_DECIMALS);
-    uint256 private constant _DATA_HOOK_WEIGHT = 2000 * 10 ** _WEIGHT_DECIMALS;
-    address private constant _DATA_HOOK = address(bytes20(keccak256("datahook")));
-    bytes private constant _PAYER_METADATA = bytes("Some payer metadata");
-
-    IJBController private _controller;
-    IJBTerminal private _terminal;
-    address private _projectOwner;
-    address private _beneficiary;
-    address private _payer;
-
-    uint64 _projectId;
-
-    function setUp() public override {
-        super.setUp();
-
-        _controller = jbController();
-        _projectOwner = multisig();
-        _beneficiary = beneficiary();
-        _payer = address(1_234_567);
-        _terminal = jbMultiTerminal();
-
-        JBRulesetMetadata memory _metadata = JBRulesetMetadata({
-            reservedPercent: 0,
-            cashOutTaxRate: 0,
-            baseCurrency: uint32(uint160(JBConstants.NATIVE_TOKEN)),
-            pausePay: false,
-            pauseCreditTransfers: false,
-            allowOwnerMinting: false,
-            allowSetCustomToken: false,
-            allowTerminalMigration: false,
-            allowSetTerminals: false,
-            ownerMustSendPayouts: false,
-            allowSetController: false,
-            allowAddAccountingContext: true,
-            allowAddPriceFeed: false,
-            holdFees: false,
-            useTotalSurplusForCashOuts: false,
-            useDataHookForPay: true,
-            useDataHookForCashOut: true,
-            dataHook: _DATA_HOOK,
-            metadata: 0
-        });
-
-        // Package up ruleset configuration.
-        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
-        _rulesetConfig[0].mustStartAtOrAfter = 0;
-        _rulesetConfig[0].duration = 0;
-        _rulesetConfig[0].weight = _WEIGHT;
-        _rulesetConfig[0].weightCutPercent = 0;
-        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
-        _rulesetConfig[0].metadata = _metadata;
-        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
-        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
-
-        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
-        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
-        _tokensToAccept[0] = JBAccountingContext({
-            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
-        });
-        _terminalConfigurations[0] =
-            JBTerminalConfig({terminal: _terminal, accountingContextsToAccept: _tokensToAccept});
-
-        _projectId = uint64(
-            _controller.launchProjectFor({
-                owner: _projectOwner,
-                projectUri: "myIPFSHash",
-                rulesetConfigurations: _rulesetConfig,
-                terminalConfigurations: _terminalConfigurations,
-                memo: ""
-            })
-        );
-    }
-
-    function testPayHooks(uint256 _numberOfSpecifications, uint256 _nativePayAmount) public {
-        // Bound the number of specifications to a reasonable amount.
-        _numberOfSpecifications = bound(_numberOfSpecifications, 1, 20);
-        // Make sure the amount of tokens generated fits in a register, and that each specification can get some.
-        _nativePayAmount = bound(_nativePayAmount, _numberOfSpecifications, type(uint256).max / _DATA_HOOK_WEIGHT);
-
-        // epa * weight / epad < max*epad/weight
-
-        // Keep a reference to the specifications.
-        JBPayHookSpecification[] memory _specifications = new JBPayHookSpecification[](_numberOfSpecifications);
-
-        // Keep a reference to the amounts in the specifications.
-        uint256[] memory _payHookAmounts = new uint256[](_numberOfSpecifications);
-
-        // Keep a reference to the amount that'll be paid and sent to pay hooks.
-        uint256 _totalToAllocate = _nativePayAmount;
-
-        // Spread the paid amount through all specifications, in various chunks, omitting the last entry.
-        for (uint256 i; i < _numberOfSpecifications - 1; i++) {
-            _payHookAmounts[i] = _totalToAllocate / (_payHookAmounts.length * 2);
-            _totalToAllocate -= _payHookAmounts[i];
-        }
-
-        // Send the rest to the last entry.
-        _payHookAmounts[_payHookAmounts.length - 1] = _totalToAllocate;
-
-        // Keep a reference to the current ruleset.
-        (JBRuleset memory _ruleset,) = _controller.currentRulesetOf(_projectId);
-
-        // Iterate through each specification.
-        for (uint256 i = 0; i < _numberOfSpecifications; i++) {
-            // Make up an address for the hook.
-            address _hookAddress = address(bytes20(keccak256(abi.encodePacked("PayHook", i))));
-
-            // Send along some metadata to the pay hook.
-            bytes memory _hookMetadata = bytes("Some data hook metadata");
-
-            // Package up the specification struct.
-            _specifications[i] = JBPayHookSpecification({
-                hook: IJBPayHook(_hookAddress), noop: false, amount: _payHookAmounts[i], metadata: _hookMetadata
-            });
-
-            // Keep a reference to the data that'll be received by the hook.
-            JBAfterPayRecordedContext memory _postRecordPayContext = JBAfterPayRecordedContext({
-                payer: _payer,
-                projectId: _projectId,
-                rulesetId: _ruleset.id,
-                amount: JBTokenAmount({
-                    token: JBConstants.NATIVE_TOKEN,
-                    decimals: _terminal.accountingContextForTokenOf(_projectId, JBConstants.NATIVE_TOKEN).decimals,
-                    currency: _terminal.accountingContextForTokenOf(_projectId, JBConstants.NATIVE_TOKEN).currency,
-                    value: _nativePayAmount
-                }),
-                forwardedAmount: JBTokenAmount({
-                    token: JBConstants.NATIVE_TOKEN,
-                    decimals: _terminal.accountingContextForTokenOf(_projectId, JBConstants.NATIVE_TOKEN).decimals,
-                    currency: _terminal.accountingContextForTokenOf(_projectId, JBConstants.NATIVE_TOKEN).currency,
-                    value: _payHookAmounts[i]
-                }),
-                weight: _WEIGHT,
-                newlyIssuedTokenCount: mulDiv(_nativePayAmount, _DATA_HOOK_WEIGHT, 10 ** _NATIVE_TOKEN_DECIMALS),
-                beneficiary: _beneficiary,
-                hookMetadata: _hookMetadata,
-                payerMetadata: _PAYER_METADATA
-            });
-
-            // Mock the hook.
-            vm.mockCall(
-                _hookAddress,
-                abi.encodeWithSelector(IJBPayHook.afterPayRecordedWith.selector),
-                abi.encode(_postRecordPayContext)
-            );
-
-            // Assert that the hook gets called with the expected value.
-            vm.expectCall(
-                _hookAddress,
-                _payHookAmounts[i],
-                abi.encodeWithSelector(IJBPayHook.afterPayRecordedWith.selector, _postRecordPayContext)
-            );
-
-            // Expect an event to be emitted for every hook.
-            vm.expectEmit(true, true, true, true);
-            emit HookAfterRecordPay(IJBPayHook(_hookAddress), _postRecordPayContext, _payHookAmounts[i], _payer);
-        }
-
-        vm.mockCall(
-            _DATA_HOOK,
-            abi.encodeWithSelector(IJBRulesetDataHook.beforePayRecordedWith.selector),
-            abi.encode(_DATA_HOOK_WEIGHT, _specifications)
-        );
-
-        vm.deal(_payer, _nativePayAmount);
-        vm.prank(_payer);
-
-        // Pay the project such that the `_beneficiary` receives project tokens.
-        _terminal.pay{value: _nativePayAmount}({
-            projectId: _projectId,
-            amount: _nativePayAmount,
-            token: JBConstants.NATIVE_TOKEN,
-            beneficiary: _beneficiary,
-            minReturnedTokens: 0,
-            memo: "Forge Test",
-            metadata: _PAYER_METADATA
-        });
-    }
-
-    event HookAfterRecordPay(
-        IJBPayHook indexed hook, JBAfterPayRecordedContext context, uint256 specificationAmount, address caller
-    );
-}