rugged 0.27.10 → 0.27.10.1

data/vendor/libgit2/cmake/Modules/FindmbedTLS.cmake

@@ -1,93 +0,0 @@
-# - Try to find mbedTLS
-# Once done this will define
-#
-# Read-Only variables
-#  MBEDTLS_FOUND - system has mbedTLS
-#  MBEDTLS_INCLUDE_DIR - the mbedTLS include directory
-#  MBEDTLS_LIBRARY_DIR - the mbedTLS library directory
-#  MBEDTLS_LIBRARIES - Link these to use mbedTLS
-#  MBEDTLS_LIBRARY - path to mbedTLS library
-#  MBEDX509_LIBRARY - path to mbedTLS X.509 library
-#  MBEDCRYPTO_LIBRARY - path to mbedTLS Crypto library
-#
-# Hint
-#  MBEDTLS_ROOT_DIR can be pointed to a local mbedTLS installation.
-
-SET(_MBEDTLS_ROOT_HINTS
-    ${MBEDTLS_ROOT_DIR}
-    ENV MBEDTLS_ROOT_DIR
-)
-
-SET(_MBEDTLS_ROOT_HINTS_AND_PATHS
-    HINTS ${_MBEDTLS_ROOT_HINTS}
-    PATHS ${_MBEDTLS_ROOT_PATHS}
-)
-
-FIND_PATH(MBEDTLS_INCLUDE_DIR
-    NAMES mbedtls/version.h
-    ${_MBEDTLS_ROOT_HINTS_AND_PATHS}
-    PATH_SUFFIXES include
-)
-
-IF(MBEDTLS_INCLUDE_DIR AND MBEDTLS_LIBRARIES)
-    # Already in cache, be silent
-    SET(MBEDTLS_FIND_QUIETLY TRUE)
-ENDIF()
-
-FIND_LIBRARY(MBEDTLS_LIBRARY
-    NAMES mbedtls libmbedtls
-    ${_MBEDTLS_ROOT_HINTS_AND_PATHS}
-    PATH_SUFFIXES library
-)
-FIND_LIBRARY(MBEDX509_LIBRARY
-    NAMES mbedx509 libmbedx509
-    ${_MBEDTLS_ROOT_HINTS_AND_PATHS}
-    PATH_SUFFIXES library
-)
-FIND_LIBRARY(MBEDCRYPTO_LIBRARY
-    NAMES mbedcrypto libmbedcrypto
-    ${_MBEDTLS_ROOT_HINTS_AND_PATHS}
-    PATH_SUFFIXES library
-)
-
-IF(MBEDTLS_INCLUDE_DIR AND MBEDTLS_LIBRARY AND MBEDX509_LIBRARY AND MBEDCRYPTO_LIBRARY)
-     SET(MBEDTLS_FOUND TRUE)
-ENDIF()
-
-IF(MBEDTLS_FOUND)
-    # split mbedTLS into -L and -l linker options, so we can set them for pkg-config
-    GET_FILENAME_COMPONENT(MBEDTLS_LIBRARY_DIR ${MBEDTLS_LIBRARY} PATH)
-    GET_FILENAME_COMPONENT(MBEDTLS_LIBRARY_FILE ${MBEDTLS_LIBRARY} NAME_WE)
-    GET_FILENAME_COMPONENT(MBEDX509_LIBRARY_FILE ${MBEDX509_LIBRARY} NAME_WE)
-    GET_FILENAME_COMPONENT(MBEDCRYPTO_LIBRARY_FILE ${MBEDCRYPTO_LIBRARY} NAME_WE)
-    STRING(REGEX REPLACE "^lib" "" MBEDTLS_LIBRARY_FILE ${MBEDTLS_LIBRARY_FILE})
-    STRING(REGEX REPLACE "^lib" "" MBEDX509_LIBRARY_FILE ${MBEDX509_LIBRARY_FILE})
-    STRING(REGEX REPLACE "^lib" "" MBEDCRYPTO_LIBRARY_FILE ${MBEDCRYPTO_LIBRARY_FILE})
-    SET(MBEDTLS_LIBRARIES "-L${MBEDTLS_LIBRARY_DIR} -l${MBEDTLS_LIBRARY_FILE} -l${MBEDX509_LIBRARY_FILE} -l${MBEDCRYPTO_LIBRARY_FILE}")
-
-    IF(NOT MBEDTLS_FIND_QUIETLY)
-        MESSAGE(STATUS "Found mbedTLS:")
-        FILE(READ ${MBEDTLS_INCLUDE_DIR}/mbedtls/version.h MBEDTLSCONTENT)
-        STRING(REGEX MATCH "MBEDTLS_VERSION_STRING +\"[0-9|.]+\"" MBEDTLSMATCH ${MBEDTLSCONTENT})
-        IF (MBEDTLSMATCH)
-            STRING(REGEX REPLACE "MBEDTLS_VERSION_STRING +\"([0-9|.]+)\"" "\\1" MBEDTLS_VERSION ${MBEDTLSMATCH})
-            MESSAGE(STATUS "  version ${MBEDTLS_VERSION}")
-        ENDIF(MBEDTLSMATCH)
-        MESSAGE(STATUS "  TLS: ${MBEDTLS_LIBRARY}")
-        MESSAGE(STATUS "  X509: ${MBEDX509_LIBRARY}")
-        MESSAGE(STATUS "  Crypto: ${MBEDCRYPTO_LIBRARY}")
-    ENDIF(NOT MBEDTLS_FIND_QUIETLY)
-ELSE(MBEDTLS_FOUND)
-    IF(MBEDTLS_FIND_REQUIRED)
-        MESSAGE(FATAL_ERROR "Could not find mbedTLS")
-    ENDIF(MBEDTLS_FIND_REQUIRED)
-ENDIF(MBEDTLS_FOUND)
-
-MARK_AS_ADVANCED(
-    MBEDTLS_INCLUDE_DIR
-    MBEDTLS_LIBRARY_DIR
-    MBEDTLS_LIBRARIES
-    MBEDTLS_LIBRARY
-    MBEDX509_LIBRARY
-    MBEDCRYPTO_LIBRARY
-)

data/vendor/libgit2/cmake/Modules/PkgBuildConfig.cmake

@@ -1,110 +0,0 @@
-# pkg-config file generation
-#
-# Uses the following globals:
-# - PKG_BUILD_PREFIX: the build location (aka prefix). Defaults to CMAKE_INSTALL_PREFIX
-# - PKG_BUILD_LIBDIR: the libdir location. Defaults to ${prefix}/lib.
-# - PKG_BUILD_INCLUDEDIR: the includedir location. Defaults to ${prefix}/include.
-#
-
-function(pkg_build_config)
-    set(options)
-    set(oneValueArgs NAME DESCRIPTION VERSION FILENAME LIBS_SELF)
-    set(multiValueArgs LIBS PRIVATE_LIBS REQUIRES CFLAGS)
-
-    cmake_parse_arguments(PKGCONFIG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
-
-    if (NOT DEFINED PKGCONFIG_FILENAME AND DEFINED PKGCONFIG_NAME)
-        set(PKGCONFIG_FILENAME ${PKGCONFIG_NAME})
-    endif()
-    if (NOT DEFINED PKGCONFIG_FILENAME)
-        message(FATAL_ERROR "Missing FILENAME argument")
-    endif()
-    set(PKGCONFIG_FILE "${PROJECT_BINARY_DIR}/${PKGCONFIG_FILENAME}.pc")
-
-    if (NOT DEFINED PKGCONFIG_DESCRIPTION)
-        message(FATAL_ERROR "Missing DESCRIPTION argument")
-    endif()
-
-    if (NOT DEFINED PKGCONFIG_VERSION)
-        message(FATAL_ERROR "Missing VERSION argument")
-    endif()
-
-    if (DEFINED PKG_BUILD_PREFIX)
-        set(PKGCONFIG_PREFIX "${PKG_BUILD_PREFIX}")
-    else()
-        set(PKGCONFIG_PREFIX "${CMAKE_INSTALL_PREFIX}")
-    endif()
-
-    if(DEFINED PKG_BUILD_LIBDIR)
-        if (IS_ABSOLUTE ${PKG_BUILD_LIBDIR})
-            set(PKGCONFIG_LIBDIR ${PKG_BUILD_LIBDIR})
-        else()
-            set(PKGCONFIG_LIBDIR "\${prefix}/${PKG_BUILD_LIBDIR}")
-        endif()
-    else()
-        set(PKGCONFIG_LIBDIR "\${prefix}/lib")
-    endif()
-
-    if(DEFINED PKG_BUILD_INCLUDEDIR)
-        if (IS_ABSOLUTE ${PKG_BUILD_INCLUDEDIR})
-            set(PKGCONFIG_INCLUDEDIR ${PKG_BUILD_INCLUDEDIR})
-        else()
-            set(PKGCONFIG_INCLUDEDIR "\${prefix}/${PKG_BUILD_INCLUDEDIR}")
-        endif()
-    else()
-        set(PKGCONFIG_INCLUDEDIR "\${prefix}/include")
-    endif()
-
-    # Write .pc "header"
-    file(WRITE "${PKGCONFIG_FILE}"
-        "prefix=\"${PKGCONFIG_PREFIX}\"\n"
-        "libdir=\"${PKGCONFIG_LIBDIR}\"\n"
-        "includedir=\"${PKGCONFIG_INCLUDEDIR}\"\n"
-        "\n"
-        "Name: ${PKGCONFIG_NAME}\n"
-        "Description: ${PKGCONFIG_DESCRIPTION}\n"
-        "Version: ${PKGCONFIG_VERSION}\n"
-    )
-
-    # Prepare Libs
-    if(NOT DEFINED PKGCONFIG_LIBS_SELF)
-        set(PKGCONFIG_LIBS_SELF "${PKGCONFIG_FILE}")
-    endif()
-
-    if(NOT DEFINED PKGCONFIG_LIBS)
-        set(PKGCONFIG_LIBS "-l${PKGCONFIG_LIBS_SELF}")
-    else()
-        list(INSERT PKGCONFIG_LIBS 0 "-l${PKGCONFIG_LIBS_SELF}")
-    endif()
-
-    list(REMOVE_DUPLICATES PKGCONFIG_LIBS)
-    string(REPLACE ";" " " PKGCONFIG_LIBS "${PKGCONFIG_LIBS}")
-    file(APPEND "${PKGCONFIG_FILE}" "Libs: -L\${libdir} ${PKGCONFIG_LIBS}\n")
-
-    # Prepare Libs.private
-    if(DEFINED PKGCONFIG_PRIVATE_LIBS)
-        list(REMOVE_DUPLICATES PKGCONFIG_PRIVATE_LIBS)
-        string(REPLACE ";" " " PKGCONFIG_PRIVATE_LIBS "${PKGCONFIG_PRIVATE_LIBS}")
-        file(APPEND "${PKGCONFIG_FILE}" "Libs.private: ${PKGCONFIG_PRIVATE_LIBS}\n")
-    endif()
-
-    # Prepare Requires.private
-    if(DEFINED PKGCONFIG_REQUIRES)
-        list(REMOVE_DUPLICATES PKGCONFIG_REQUIRES)
-        string(REPLACE ";" " " PKGCONFIG_REQUIRES "${PKGCONFIG_REQUIRES}")
-        file(APPEND "${PKGCONFIG_FILE}" "Requires.private: ${PKGCONFIG_REQUIRES}\n")
-    endif()
-
-    # Prepare Cflags
-    if(DEFINED PKGCONFIG_CFLAGS)
-        string(REPLACE ";" " " PKGCONFIG_CFLAGS "${PKGCONFIG_CFLAGS}")
-    else()
-        set(PKGCONFIG_CFLAGS "")
-    endif()
-    file(APPEND "${PKGCONFIG_FILE}" "Cflags: -I\${includedir} ${PKGCONFIG_CFLAGS}\n")
-
-    # Install .pc file
-    install(FILES "${PKGCONFIG_FILE}"
-        DESTINATION "${PKGCONFIG_PREFIX}/${PKGCONFIG_LIBDIR}/pkgconfig"
-    )
-endfunction()

data/vendor/libgit2/cmake/Modules/SelectGSSAPI.cmake

@@ -1,53 +0,0 @@
-# Select the backend to use
-
-# We try to find any packages our backends might use
-
-FIND_PACKAGE(GSSAPI)
-IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
-	INCLUDE(FindGSSFramework)
-ENDIF()
-
-# Auto-select GSS backend
-IF (USE_GSSAPI STREQUAL ON)
-	IF (GSSFRAMEWORK_FOUND)
-		SET(GSS_BACKEND "GSS.framework")
-	ELSEIF(GSSAPI_FOUND)
-		SET(GSS_BACKEND "gssapi")
-	ELSE()
-		MESSAGE(FATAL_ERROR "Unable to autodetect a usable GSS backend."
-			"Please pass the backend name explicitly (-DUSE_GSS=backend)")
-	ENDIF()
-ELSEIF(USE_GSSAPI)
-	# Backend was explicitly set
-	SET(GSS_BACKEND ${USE_GSSAPI})
-ELSE()
-	SET(GSS_BACKEND NO)
-ENDIF()
-
-IF(GSS_BACKEND)
-	# Check that we can find what's required for the selected backend
-	IF (GSS_BACKEND STREQUAL "GSS.framework")
-		IF (NOT GSSFRAMEWORK_FOUND)
-			MESSAGE(FATAL_ERROR "Asked for GSS.framework backend, but it wasn't found")
-		ENDIF()
-
-		LIST(APPEND LIBGIT2_LIBS ${GSSFRAMEWORK_LIBRARIES})
-
-		SET(GIT_GSSFRAMEWORK 1)
-		ADD_FEATURE_INFO(SPNEGO GIT_GSSFRAMEWORK "SPNEGO authentication support (${GSS_BACKEND})")
-	ELSEIF (GSS_BACKEND STREQUAL "gssapi")
-		IF (NOT GSSAPI_FOUND)
-			MESSAGE(FATAL_ERROR "Asked for gssapi GSS backend, but it wasn't found")
-		ENDIF()
-
-		LIST(APPEND LIBGIT2_LIBS ${GSSAPI_LIBRARIES})
-
-		SET(GIT_GSSAPI 1)
-		ADD_FEATURE_INFO(SPNEGO GIT_GSSAPI "SPNEGO authentication support (${GSS_BACKEND})")
-	ELSE()
-		MESSAGE(FATAL_ERROR "Asked for backend ${GSS_BACKEND} but it wasn't found")
-	ENDIF()
-ELSE()
-	SET(GIT_GSSAPI 0)
-	ADD_FEATURE_INFO(SPNEGO NO "")
-ENDIF()

data/vendor/libgit2/cmake/Modules/SelectHTTPSBackend.cmake

@@ -1,124 +0,0 @@
-# Select the backend to use
-
-# We try to find any packages our backends might use
-FIND_PACKAGE(OpenSSL)
-FIND_PACKAGE(mbedTLS)
-IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
-	FIND_PACKAGE(Security)
-	FIND_PACKAGE(CoreFoundation)
-ENDIF()
-
-# Auto-select TLS backend
-IF (USE_HTTPS STREQUAL ON)
-	IF (SECURITY_FOUND)
-		IF (SECURITY_HAS_SSLCREATECONTEXT)
-			SET(HTTPS_BACKEND "SecureTransport")
-		ELSE()
-			MESSAGE(STATUS "Security framework is too old, falling back to OpenSSL")
-			SET(HTTPS_BACKEND "OpenSSL")
-		ENDIF()
-	ELSEIF (WINHTTP)
-		SET(HTTPS_BACKEND "WinHTTP")
-	ELSEIF(OPENSSL_FOUND)
-		SET(HTTPS_BACKEND "OpenSSL")
-	ELSEIF(MBEDTLS_FOUND)
-		SET(HTTPS_BACKEND "mbedTLS")
-	ELSE()
-		MESSAGE(FATAL_ERROR "Unable to autodetect a usable HTTPS backend."
-			"Please pass the backend name explicitly (-DUSE_HTTPS=backend)")
-	ENDIF()
-ELSEIF(USE_HTTPS)
-	# HTTPS backend was explicitly set
-	SET(HTTPS_BACKEND ${USE_HTTPS})
-ELSE()
-	SET(HTTPS_BACKEND NO)
-ENDIF()
-
-IF(HTTPS_BACKEND)
-	# Check that we can find what's required for the selected backend
-	IF (HTTPS_BACKEND STREQUAL "SecureTransport")
-		IF (NOT COREFOUNDATION_FOUND)
-			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, CoreFoundation.framework not found")
-		ENDIF()
-		IF (NOT SECURITY_FOUND)
-			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, Security.framework not found")
-		ENDIF()
-		IF (NOT SECURITY_HAS_SSLCREATECONTEXT)
-			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, SSLCreateContext not supported")
-		ENDIF()
-
-		SET(GIT_SECURE_TRANSPORT 1)
-		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${SECURITY_INCLUDE_DIR})
-		LIST(APPEND LIBGIT2_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
-		LIST(APPEND LIBGIT2_PC_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
-	ELSEIF (HTTPS_BACKEND STREQUAL "OpenSSL")
-		IF (NOT OPENSSL_FOUND)
-			MESSAGE(FATAL_ERROR "Asked for OpenSSL TLS backend, but it wasn't found")
-		ENDIF()
-
-		SET(GIT_OPENSSL 1)
-		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${OPENSSL_INCLUDE_DIR})
-		LIST(APPEND LIBGIT2_LIBS ${OPENSSL_LIBRARIES})
-		LIST(APPEND LIBGIT2_PC_LIBS ${OPENSSL_LDFLAGS})
-		LIST(APPEND LIBGIT2_PC_REQUIRES "openssl")
-	ELSEIF(HTTPS_BACKEND STREQUAL "mbedTLS")
-		IF (NOT MBEDTLS_FOUND)
-			MESSAGE(FATAL_ERROR "Asked for mbedTLS backend, but it wasn't found")
-		ENDIF()
-
-		IF(NOT CERT_LOCATION)
-			MESSAGE(STATUS "Auto-detecting default certificates location")
-			IF(CMAKE_SYSTEM_NAME MATCHES Darwin)
-				# Check for an Homebrew installation
-				SET(OPENSSL_CMD "/usr/local/opt/openssl/bin/openssl")
-			ELSE()
-				SET(OPENSSL_CMD "openssl")
-			ENDIF()
-			EXECUTE_PROCESS(COMMAND ${OPENSSL_CMD} version -d OUTPUT_VARIABLE OPENSSL_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
-			IF(OPENSSL_DIR)
-				STRING(REGEX REPLACE "^OPENSSLDIR: \"(.*)\"$" "\\1/" OPENSSL_DIR ${OPENSSL_DIR})
-
-				SET(OPENSSL_CA_LOCATIONS
-					"ca-bundle.pem"             # OpenSUSE Leap 42.1
-					"cert.pem"                  # Ubuntu 14.04, FreeBSD
-					"certs/ca-certificates.crt" # Ubuntu 16.04
-					"certs/ca.pem"              # Debian 7
-				)
-				FOREACH(SUFFIX IN LISTS OPENSSL_CA_LOCATIONS)
-					SET(LOC "${OPENSSL_DIR}${SUFFIX}")
-					IF(NOT CERT_LOCATION AND EXISTS "${OPENSSL_DIR}${SUFFIX}")
-						SET(CERT_LOCATION ${LOC})
-					ENDIF()
-				ENDFOREACH()
-			ELSE()
-				MESSAGE(FATAL_ERROR "Unable to find OpenSSL executable. Please provide default certificate location via CERT_LOCATION")
-			ENDIF()
-		ENDIF()
-
-		IF(CERT_LOCATION)
-			IF(NOT EXISTS ${CERT_LOCATION})
-				MESSAGE(FATAL_ERROR "Cannot use CERT_LOCATION=${CERT_LOCATION} as it doesn't exist")
-			ENDIF()
-			ADD_FEATURE_INFO(CERT_LOCATION ON "using certificates from ${CERT_LOCATION}")
-			ADD_DEFINITIONS(-DGIT_DEFAULT_CERT_LOCATION="${CERT_LOCATION}")
-		ENDIF()
-
-		SET(GIT_MBEDTLS 1)
-		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${MBEDTLS_INCLUDE_DIR})
-		LIST(APPEND LIBGIT2_LIBS ${MBEDTLS_LIBRARIES})
-		# mbedTLS has no pkgconfig file, hence we can't require it
-		# https://github.com/ARMmbed/mbedtls/issues/228
-		# For now, pass its link flags as our own
-		LIST(APPEND LIBGIT2_PC_LIBS ${MBEDTLS_LIBRARIES})
-	ELSEIF (HTTPS_BACKEND STREQUAL "WinHTTP")
-		# WinHTTP setup was handled in the WinHTTP-specific block above
-	ELSE()
-		MESSAGE(FATAL_ERROR "Asked for backend ${HTTPS_BACKEND} but it wasn't found")
-	ENDIF()
-
-	SET(GIT_HTTPS 1)
-	ADD_FEATURE_INFO(HTTPS GIT_HTTPS "using ${HTTPS_BACKEND}")
-ELSE()
-	SET(GIT_HTTPS 0)
-	ADD_FEATURE_INFO(HTTPS NO "")
-ENDIF()

data/vendor/libgit2/cmake/Modules/SelectHashes.cmake

@@ -1,66 +0,0 @@
-# Select a hash backend
-
-# USE_SHA1=CollisionDetection(ON)/HTTPS/Generic/OFF
-
-IF(USE_SHA1 STREQUAL ON OR USE_SHA1 STREQUAL "CollisionDetection")
-	SET(SHA1_BACKEND "CollisionDetection")
-ELSEIF(USE_SHA1 STREQUAL "HTTPS")
-	message(STATUS "Checking HTTPS backend… ${HTTPS_BACKEND}")
-	IF(HTTPS_BACKEND STREQUAL "SecureTransport")
-		SET(SHA1_BACKEND "CommonCrypto")
-	ELSEIF(HTTPS_BACKEND STREQUAL "WinHTTP")
-		SET(SHA1_BACKEND "Win32")
-	ELSEIF(HTTPS_BACKEND)
-		SET(SHA1_BACKEND ${HTTPS_BACKEND})
-	ELSE()
-	ENDIF()
-	IF(NOT HTTPS_BACKEND)
-		SET(SHA1_BACKEND "CollisionDetection")
-	ENDIF()
-	message(STATUS "Using SHA1 backend ${SHA1_BACKEND}")
-ELSEIF(USE_SHA1 STREQUAL "Generic")
-	SET(SHA1_BACKEND "Generic")
-# ELSEIF(NOT USE_SHA1)
-ELSE()
-	MESSAGE(FATAL_ERROR "Invalid value for USE_SHA1: ${USE_SHA1}")
-ENDIF()
-
-IF(SHA1_BACKEND STREQUAL "CollisionDetection")
-	SET(GIT_SHA1_COLLISIONDETECT 1)
-	ADD_DEFINITIONS(-DSHA1DC_NO_STANDARD_INCLUDES=1)
-	ADD_DEFINITIONS(-DSHA1DC_CUSTOM_INCLUDE_SHA1_C=\"common.h\")
-	ADD_DEFINITIONS(-DSHA1DC_CUSTOM_INCLUDE_UBC_CHECK_C=\"common.h\")
-	FILE(GLOB SRC_SHA1 hash/sha1/collisiondetect.* hash/sha1/sha1dc/*)
-ELSEIF(SHA1_BACKEND STREQUAL "OpenSSL")
-	# OPENSSL_FOUND should already be set, we're checking HTTPS_BACKEND
-
-	SET(GIT_SHA1_OPENSSL 1)
-	IF(CMAKE_SYSTEM_NAME MATCHES "FreeBSD")
-		LIST(APPEND LIBGIT2_PC_LIBS "-lssl")
-	ELSE()
-		LIST(APPEND LIBGIT2_PC_REQUIRES "openssl")
-	ENDIF()
-	FILE(GLOB SRC_SHA1 hash/sha1/openssl.*)
-ELSEIF(SHA1_BACKEND STREQUAL "CommonCrypto")
-	SET(GIT_SHA1_COMMON_CRYPTO 1)
-	FILE(GLOB SRC_SHA1 hash/sha1/common_crypto.*)
-ELSEIF(SHA1_BACKEND STREQUAL "mbedTLS")
-	SET(GIT_SHA1_MBEDTLS 1)
-	FILE(GLOB SRC_SHA1 hash/sha1/mbedtls.*)
-	LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${MBEDTLS_INCLUDE_DIR})
-	LIST(APPEND LIBGIT2_LIBS ${MBEDTLS_LIBRARIES})
-	# mbedTLS has no pkgconfig file, hence we can't require it
-	# https://github.com/ARMmbed/mbedtls/issues/228
-	# For now, pass its link flags as our own
-	LIST(APPEND LIBGIT2_PC_LIBS ${MBEDTLS_LIBRARIES})
-ELSEIF(SHA1_BACKEND STREQUAL "Win32")
-	SET(GIT_SHA1_WIN32 1)
-	FILE(GLOB SRC_SHA1 hash/sha1/win32.*)
-ELSEIF(SHA1_BACKEND STREQUAL "Generic")
-	FILE(GLOB SRC_SHA1 hash/sha1/generic.*)
-# ELSEIF(NOT USE_SHA1)
-ELSE()
-	MESSAGE(FATAL_ERROR "Asked for unknown SHA1 backend: ${SHA1_BACKEND}")
-ENDIF()
-
-ADD_FEATURE_INFO(SHA ON "using ${SHA1_BACKEND}")