redis-server 0.0.1

data/redis/redis-2.2.11/tests/support/server.tcl

@@ -0,0 +1,294 @@
+set ::global_overrides {}
+set ::tags {}
+
+proc error_and_quit {config_file error} {
+    puts "!!COULD NOT START REDIS-SERVER\n"
+    puts "CONFIGURATION:"
+    puts [exec cat $config_file]
+    puts "\nERROR:"
+    puts [string trim $error]
+    exit 1
+}
+
+proc check_valgrind_errors stderr {
+    set fd [open $stderr]
+    set buf [read $fd]
+    close $fd
+
+    if {![regexp -- {ERROR SUMMARY: 0 errors} $buf] ||
+        ![regexp -- {definitely lost: 0 bytes} $buf]} {
+        puts "*** VALGRIND ERRORS ***"
+        puts $buf
+        puts "--- press enter to continue ---"
+        gets stdin
+    }
+}
+
+proc kill_server config {
+    # nothing to kill when running against external server
+    if {$::external} return
+
+    # nevermind if its already dead
+    if {![is_alive $config]} { return }
+    set pid [dict get $config pid]
+
+    # check for leaks
+    if {![dict exists $config "skipleaks"]} {
+        catch {
+            if {[string match {*Darwin*} [exec uname -a]]} {
+                tags {"leaks"} {
+                    test "Check for memory leaks (pid $pid)" {
+                        exec leaks $pid
+                    } {*0 leaks*}
+                }
+            }
+        }
+    }
+
+    # kill server and wait for the process to be totally exited
+    while {[is_alive $config]} {
+        if {[incr wait 10] % 1000 == 0} {
+            puts "Waiting for process $pid to exit..."
+        }
+        catch {exec kill $pid}
+        after 10
+    }
+
+    # Check valgrind errors if needed
+    if {$::valgrind} {
+        check_valgrind_errors [dict get $config stderr]
+    }
+}
+
+proc is_alive config {
+    set pid [dict get $config pid]
+    if {[catch {exec ps -p $pid} err]} {
+        return 0
+    } else {
+        return 1
+    }
+}
+
+proc ping_server {host port} {
+    set retval 0
+    if {[catch {
+        set fd [socket $::host $::port]
+        fconfigure $fd -translation binary
+        puts $fd "PING\r\n"
+        flush $fd
+        set reply [gets $fd]
+        if {[string range $reply 0 4] eq {+PONG} ||
+            [string range $reply 0 3] eq {-ERR}} {
+            set retval 1
+        }
+        close $fd
+    } e]} {
+        if {$::verbose} {
+            puts -nonewline "."
+        }
+    } else {
+        if {$::verbose} {
+            puts -nonewline "ok"
+        }
+    }
+    return $retval
+}
+
+# doesn't really belong here, but highly coupled to code in start_server
+proc tags {tags code} {
+    set ::tags [concat $::tags $tags]
+    uplevel 1 $code
+    set ::tags [lrange $::tags 0 end-[llength $tags]]
+}
+
+proc start_server {options {code undefined}} {
+    # If we are runnign against an external server, we just push the
+    # host/port pair in the stack the first time
+    if {$::external} {
+        if {[llength $::servers] == 0} {
+            set srv {}
+            dict set srv "host" $::host
+            dict set srv "port" $::port
+            set client [redis $::host $::port]
+            dict set srv "client" $client
+            $client select 9
+
+            # append the server to the stack
+            lappend ::servers $srv
+        }
+        uplevel 1 $code
+        return
+    }
+
+    # setup defaults
+    set baseconfig "default.conf"
+    set overrides {}
+    set tags {}
+
+    # parse options
+    foreach {option value} $options {
+        switch $option {
+            "config" {
+                set baseconfig $value }
+            "overrides" {
+                set overrides $value }
+            "tags" {
+                set tags $value
+                set ::tags [concat $::tags $value] }
+            default {
+                error "Unknown option $option" }
+        }
+    }
+
+    set data [split [exec cat "tests/assets/$baseconfig"] "\n"]
+    set config {}
+    foreach line $data {
+        if {[string length $line] > 0 && [string index $line 0] ne "#"} {
+            set elements [split $line " "]
+            set directive [lrange $elements 0 0]
+            set arguments [lrange $elements 1 end]
+            dict set config $directive $arguments
+        }
+    }
+    
+    # use a different directory every time a server is started
+    dict set config dir [tmpdir server]
+    
+    # start every server on a different port
+    dict set config port [incr ::port]
+
+    # apply overrides from global space and arguments
+    foreach {directive arguments} [concat $::global_overrides $overrides] {
+        dict set config $directive $arguments
+    }
+    
+    # write new configuration to temporary file
+    set config_file [tmpfile redis.conf]
+    set fp [open $config_file w+]
+    foreach directive [dict keys $config] {
+        puts -nonewline $fp "$directive "
+        puts $fp [dict get $config $directive]
+    }
+    close $fp
+
+    set stdout [format "%s/%s" [dict get $config "dir"] "stdout"]
+    set stderr [format "%s/%s" [dict get $config "dir"] "stderr"]
+
+    if {$::valgrind} {
+        exec valgrind --suppressions=src/valgrind.sup src/redis-server $config_file > $stdout 2> $stderr &
+    } else {
+        exec src/redis-server $config_file > $stdout 2> $stderr &
+    }
+    
+    # check that the server actually started
+    # ugly but tries to be as fast as possible...
+    set retrynum 20
+    set serverisup 0
+
+    if {$::verbose} {
+        puts -nonewline "=== ($tags) Starting server ${::host}:${::port} "
+    }
+
+    after 10
+    if {$code ne "undefined"} {
+        while {[incr retrynum -1]} {
+            catch {
+                if {[ping_server $::host $::port]} {
+                    set serverisup 1
+                }
+            }
+            if {$serverisup} break
+            after 50
+        }
+    } else {
+        set serverisup 1
+    }
+
+    if {$::verbose} {
+        puts ""
+    }
+
+    if {!$serverisup} {
+        error_and_quit $config_file [exec cat $stderr]
+    }
+    
+    # find out the pid
+    while {![info exists pid]} {
+        regexp {^\[(\d+)\]} [exec head -n1 $stdout] _ pid
+        after 100
+    }
+
+    # setup properties to be able to initialize a client object
+    set host $::host
+    set port $::port
+    if {[dict exists $config bind]} { set host [dict get $config bind] }
+    if {[dict exists $config port]} { set port [dict get $config port] }
+
+    # setup config dict
+    dict set srv "config_file" $config_file
+    dict set srv "config" $config
+    dict set srv "pid" $pid
+    dict set srv "host" $host
+    dict set srv "port" $port
+    dict set srv "stdout" $stdout
+    dict set srv "stderr" $stderr
+
+    # if a block of code is supplied, we wait for the server to become
+    # available, create a client object and kill the server afterwards
+    if {$code ne "undefined"} {
+        set line [exec head -n1 $stdout]
+        if {[string match {*already in use*} $line]} {
+            error_and_quit $config_file $line
+        }
+
+        while 1 {
+            # check that the server actually started and is ready for connections
+            if {[exec cat $stdout | grep "ready to accept" | wc -l] > 0} {
+                break
+            }
+            after 10
+        }
+
+        # append the server to the stack
+        lappend ::servers $srv
+
+        # connect client (after server dict is put on the stack)
+        reconnect
+
+        # execute provided block
+        set num_tests $::num_tests
+        if {[catch { uplevel 1 $code } error]} {
+            set backtrace $::errorInfo
+
+            # Kill the server without checking for leaks
+            dict set srv "skipleaks" 1
+            kill_server $srv
+
+            # Print warnings from log
+            puts [format "\nLogged warnings (pid %d):" [dict get $srv "pid"]]
+            set warnings [warnings_from_file [dict get $srv "stdout"]]
+            if {[string length $warnings] > 0} {
+                puts "$warnings"
+            } else {
+                puts "(none)"
+            }
+            puts ""
+
+            error $error $backtrace
+        }
+
+        # Don't do the leak check when no tests were run
+        if {$num_tests == $::num_tests} {
+            dict set srv "skipleaks" 1
+        }
+
+        # pop the server object
+        set ::servers [lrange $::servers 0 end-1]
+
+        set ::tags [lrange $::tags 0 end-[llength $tags]]
+        kill_server $srv
+    } else {
+        set ::tags [lrange $::tags 0 end-[llength $tags]]
+        set _ $srv
+    }
+}

data/redis/redis-2.2.11/tests/support/test.tcl

@@ -0,0 +1,190 @@
+set ::num_tests 0
+set ::num_passed 0
+set ::num_failed 0
+set ::tests_failed {}
+
+proc assert {condition} {
+    if {![uplevel 1 expr $condition]} {
+        error "assertion:Expected '$value' to be true"
+    }
+}
+
+proc assert_match {pattern value} {
+    if {![string match $pattern $value]} {
+        error "assertion:Expected '$value' to match '$pattern'"
+    }
+}
+
+proc assert_equal {expected value} {
+    if {$expected ne $value} {
+        error "assertion:Expected '$value' to be equal to '$expected'"
+    }
+}
+
+proc assert_error {pattern code} {
+    if {[catch {uplevel 1 $code} error]} {
+        assert_match $pattern $error
+    } else {
+        error "assertion:Expected an error but nothing was catched"
+    }
+}
+
+proc assert_encoding {enc key} {
+    # Swapped out values don't have an encoding, so make sure that
+    # the value is swapped in before checking the encoding.
+    set dbg [r debug object $key]
+    while {[string match "* swapped at:*" $dbg]} {
+        r debug swapin $key
+        set dbg [r debug object $key]
+    }
+    assert_match "* encoding:$enc *" $dbg
+}
+
+proc assert_type {type key} {
+    assert_equal $type [r type $key]
+}
+
+# Test if TERM looks like to support colors
+proc color_term {} {
+    expr {[info exists ::env(TERM)] && [string match *xterm* $::env(TERM)]}
+}
+
+# This is called before starting the test
+proc announce_test {s} {
+    if {[color_term]} {
+        puts -nonewline "$s\033\[0K"
+        flush stdout
+        set ::backward_count [string length $s]
+    }
+}
+
+# This is called after the test finished
+proc colored_dot {tags passed} {
+    if {[color_term]} {
+        # Go backward and delete what announc_test function printed.
+        puts -nonewline "\033\[${::backward_count}D\033\[0K\033\[J"
+
+        # Print a coloured char, accordingly to test outcome and tags.
+        if {[lsearch $tags list] != -1} {
+            set colorcode {31}
+            set ch L
+        } elseif {[lsearch $tags hash] != -1} {
+            set colorcode {32}
+            set ch H
+        } elseif {[lsearch $tags set] != -1} {
+            set colorcode {33}
+            set ch S
+        } elseif {[lsearch $tags zset] != -1} {
+            set colorcode {34}
+            set ch Z
+        } elseif {[lsearch $tags basic] != -1} {
+            set colorcode {35}
+            set ch B
+        } else {
+            set colorcode {37}
+            set ch .
+        }
+        if {$colorcode ne {}} {
+            if {$passed} {
+                puts -nonewline "\033\[0;${colorcode};40m"
+            } else {
+                puts -nonewline "\033\[7;${colorcode};40m"
+            }
+            puts -nonewline $ch
+            puts -nonewline "\033\[0m"
+            flush stdout
+        }
+    } else {
+        if {$passed} {
+            puts -nonewline .
+        } else {
+            puts -nonewline F
+        }
+    }
+}
+
+proc test {name code {okpattern undefined}} {
+    # abort if tagged with a tag to deny
+    foreach tag $::denytags {
+        if {[lsearch $::tags $tag] >= 0} {
+            return
+        }
+    }
+
+    # check if tagged with at least 1 tag to allow when there *is* a list
+    # of tags to allow, because default policy is to run everything
+    if {[llength $::allowtags] > 0} {
+        set matched 0
+        foreach tag $::allowtags {
+            if {[lsearch $::tags $tag] >= 0} {
+                incr matched
+            }
+        }
+        if {$matched < 1} {
+            return
+        }
+    }
+
+    incr ::num_tests
+    set details {}
+    lappend details $::curfile
+    lappend details $::tags
+    lappend details $name
+
+    if {$::verbose} {
+        puts -nonewline [format "#%03d %-68s " $::num_tests $name]
+        flush stdout
+    } else {
+        announce_test $name
+    }
+
+    if {[catch {set retval [uplevel 1 $code]} error]} {
+        if {[string match "assertion:*" $error]} {
+            set msg [string range $error 10 end]
+            lappend details $msg
+            lappend ::tests_failed $details
+
+            incr ::num_failed
+            if {$::verbose} {
+                puts "FAILED"
+                puts "$msg\n"
+            } else {
+                colored_dot $::tags 0
+            }
+        } else {
+            # Re-raise, let handler up the stack take care of this.
+            error $error $::errorInfo
+        }
+    } else {
+        if {$okpattern eq "undefined" || $okpattern eq $retval || [string match $okpattern $retval]} {
+            incr ::num_passed
+            if {$::verbose} {
+                puts "PASSED"
+            } else {
+                colored_dot $::tags 1
+            }
+        } else {
+            set msg "Expected '$okpattern' to equal or match '$retval'"
+            lappend details $msg
+            lappend ::tests_failed $details
+
+            incr ::num_failed
+            if {$::verbose} {
+                puts "FAILED"
+                puts "$msg\n"
+            } else {
+                colored_dot $::tags 0
+            }
+        }
+    }
+    flush stdout
+
+    if {$::traceleaks} {
+        set output [exec leaks redis-server]
+        if {![string match {*0 leaks*} $output]} {
+            puts "--- Test \"$name\" leaked! ---"
+            puts $output
+            exit 1
+        }
+    }
+}