kuji-mercury-rails 0.3.2

data/vendor/assets/javascripts/mercury/toolbar.button.js.coffee

@@ -0,0 +1,173 @@
+class @Mercury.Toolbar.Button
+
+  constructor: (@name, @title, @summary = null, @types = {}, @options = {}) ->
+    @title = Mercury.I18n(@title) if @title
+    @summary = Mercury.I18n(@summary) if @summary
+
+    @build()
+    @bindEvents()
+    return @element
+
+
+  build: ->
+    @element = jQuery('<div>', {title: @summary ? @title, class: "mercury-button mercury-#{@name}-button"}).html("<em>#{@title}</em>")
+    @element.data('expander', "<div class=\"mercury-expander-button\" data-button=\"#{@name}\"><em></em><span>#{@title}</span></div>")
+
+    @handled = {}
+
+    for own type, mixed of @types
+      switch type
+        when 'preload' then true
+
+        when 'regions'
+          @element.addClass('disabled')
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+
+        when 'toggle'
+          @handled[type] = true
+
+        when 'mode'
+          @handled[type] = if mixed == true then @name else mixed
+
+        when 'context'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed else Mercury.Toolbar.Button.contexts[@name]
+
+        when 'palette'
+          @element.addClass("mercury-button-palette")
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled[type] = new Mercury.Palette(url, @name, @defaultDialogOptions())
+
+        when 'select'
+          @element.addClass("mercury-button-select").find('em').html(@title)
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled[type] = new Mercury.Select(url, @name, @defaultDialogOptions())
+
+        when 'panel'
+          @element.addClass('mercury-button-panel')
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled['toggle'] = true
+          @handled[type] = new Mercury.Panel(url, @name, @defaultDialogOptions())
+
+        when 'modal'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+
+        when 'lightview'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+
+        else throw Mercury.I18n('Unknown button type \"%s\" used for the \"%s\" button.', type, @name)
+
+
+  bindEvents: ->
+    Mercury.on 'button', (event, options) => @element.click() if options.action == @name
+    Mercury.on 'mode', (event, options) => @togglePressed() if @handled.mode == options.mode && @handled.toggle
+
+    Mercury.on 'region:update', (event, options) =>
+      if @handled.context && options.region && jQuery.type(options.region.currentElement) == 'function'
+        element = options.region.currentElement()
+        if element.length && @handled.context.call(@, element, options.region.element)
+          @element.addClass('active')
+        else
+          @element.removeClass('active')
+      else
+        @element.removeClass('active')
+
+    Mercury.on 'region:focused', (event, options) =>
+      if @handled.regions && options.region && options.region.type
+        if @handled.regions.indexOf(options.region.type) > -1
+          @element.removeClass('disabled')
+        else
+          @element.addClass('disabled')
+
+    Mercury.on 'region:blurred', =>
+      @element.addClass('disabled') if @handled.regions
+
+    @element.on 'mousedown', =>
+      @element.addClass('active')
+
+    @element.on 'mouseup', =>
+      @element.removeClass('active')
+
+    @element.on 'click', (event) =>
+      if @element.closest('.disabled').length then return
+
+      handled = false
+      for own type, mixed of @handled
+        switch type
+          when 'toggle'
+            @togglePressed() unless @handled.mode
+
+          when 'mode'
+            handled = true
+            Mercury.trigger('mode', {mode: mixed})
+
+          when 'modal'
+            handled = true
+            Mercury.modal(@handled.modal, {title: @summary || @title, handler: @name})
+
+          when 'lightview'
+            handled = true
+            Mercury.lightview(@handled.lightview, {title: @summary || @title, handler: @name, closeButton: true})
+
+          when 'palette', 'select', 'panel'
+            event.stopPropagation()
+            handled = true
+            @handled[type].toggle()
+
+      Mercury.trigger('action', {action: @name}) unless handled
+      Mercury.trigger('focus:frame') if @options['regions'] && @options['regions'].length
+
+
+  defaultDialogOptions: ->
+    return {
+      title: @summary || @title
+      preload: @types.preload
+      appendTo: @options.appendDialogsTo || 'body'
+      closeButton: true
+      for: @element
+    }
+
+
+  togglePressed: ->
+    @element.toggleClass('pressed')
+
+
+
+# Button contexts
+@Mercury.Toolbar.Button.contexts =
+
+  backColor: (node) -> @element.css('background-color', node.css('background-color'))
+
+  foreColor: (node) -> @element.css('background-color', node.css('color'))
+
+  bold: (node) ->
+    weight = node.css('font-weight')
+    weight == 'bold' || weight > 400
+
+  italic: (node) -> node.css('font-style') == 'italic'
+
+  # overline is weird because <u> and <strike> override text-decoration -- we can't always tell without checking parents
+  overline: (node) ->
+    return true if node.css('text-decoration') == 'overline'
+    for parent in node.parentsUntil(@element)
+      return true if jQuery(parent).css('text-decoration') == 'overline'
+    return false
+
+  strikethrough: (node, region) -> node.css('text-decoration') == 'line-through' || !!node.closest('strike', region).length
+
+  underline: (node, region) -> node.css('text-decoration') == 'underline' || !!node.closest('u', region).length
+
+  subscript: (node, region) -> !!node.closest('sub', region).length
+
+  superscript: (node, region) -> !!node.closest('sup', region).length
+
+  justifyLeft: (node) -> node.css('text-align').indexOf('left') > -1
+
+  justifyCenter: (node) -> node.css('text-align').indexOf('center') > -1
+
+  justifyRight: (node) -> node.css('text-align').indexOf('right') > -1
+
+  justifyFull: (node) -> node.css('text-align').indexOf('justify') > -1
+
+  insertOrderedList: (node, region) -> !!node.closest('ol', region.element).length
+
+  insertUnorderedList: (node, region) -> !!node.closest('ul', region.element).length

data/vendor/assets/javascripts/mercury/toolbar.button_group.js.coffee

@@ -0,0 +1,42 @@
+class @Mercury.Toolbar.ButtonGroup
+
+  constructor: (@name, @options = {}) ->
+    @build()
+    @bindEvents()
+    @regions = @options._regions
+    return @element
+
+
+  build: ->
+    @element = jQuery('<div>', {class: "mercury-button-group mercury-#{@name}-group"})
+    if @options._context || @options._regions
+      @element.addClass('disabled')
+
+
+  bindEvents: ->
+    Mercury.on 'region:update', (event, options) =>
+      context = Mercury.Toolbar.ButtonGroup.contexts[@name]
+      if context
+        if options.region && jQuery.type(options.region.currentElement) == 'function'
+          element = options.region.currentElement()
+          if element.length && context.call(@, element, options.region.element)
+            @element.removeClass('disabled')
+          else
+            @element.addClass('disabled')
+
+    Mercury.on 'region:focused', (event, options) =>
+      if @regions && options.region && options.region.type
+        if @regions.indexOf(options.region.type) > -1
+          @element.removeClass('disabled') unless @options._context
+        else
+          @element.addClass('disabled')
+
+    Mercury.on 'region:blurred', (event, options) =>
+      @element.addClass('disabled') if @options.regions
+
+
+
+# ButtonGroup contexts
+@Mercury.Toolbar.ButtonGroup.contexts =
+
+  table: (node, region) -> !!node.closest('table', region).length

data/vendor/assets/javascripts/mercury/toolbar.expander.js.coffee

@@ -0,0 +1,56 @@
+class @Mercury.Toolbar.Expander extends Mercury.Palette
+
+  constructor: (@name, @options) ->
+    @container = @options.for
+    @containerWidth = @container.outerWidth()
+    super(null, @name, @options)
+    return @element
+
+
+  build: ->
+    @container.css({whiteSpace: 'normal'})
+    @trigger = jQuery('<div>', {class: 'mercury-toolbar-expander'}).appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+    @element = jQuery('<div>', {class: "mercury-palette mercury-expander mercury-#{@name}-expander", style: 'display:none'})
+    @windowResize()
+
+
+  bindEvents: ->
+    Mercury.on 'hide:dialogs', (event, dialog) => @hide() unless dialog == @
+    Mercury.on 'resize', => @windowResize()
+
+    super
+
+    @trigger.click (event) =>
+      event.stopPropagation()
+      hiddenButtons = []
+      for button in @container.find('.mercury-button')
+        button = jQuery(button)
+        hiddenButtons.push(button.data('expander')) if button.position().top > 5
+
+      @loadContent(hiddenButtons.join(''))
+      @toggle()
+
+    @element.click (event) =>
+      buttonName = jQuery(event.target).closest('[data-button]').data('button')
+      button = @container.find(".mercury-#{buttonName}-button")
+      button.click()
+
+
+  windowResize: ->
+    if @containerWidth > jQuery(window).width() then @trigger.show() else @trigger.hide()
+    @hide()
+
+
+  position: (keepVisible) ->
+    @element.css({top: 0, left: 0, display: 'block', visibility: 'hidden'})
+    position = @trigger.offset()
+    width = @element.width()
+
+    position.left = position.left - width + @trigger.width() if position.left + width > jQuery(window).width()
+
+    @element.css {
+      top: position.top + @trigger.height()
+      left: position.left
+      display: if keepVisible then 'block' else 'none'
+      visibility: 'visible'
+    }

data/vendor/assets/javascripts/mercury/toolbar.js.coffee

@@ -0,0 +1,86 @@
+class @Mercury.Toolbar
+
+  constructor: (@options = {}) ->
+    @visible = @options.visible
+    @build()
+    @bindEvents()
+
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-toolbar-container', style: 'width:10000px'})
+    @element.css({display: 'none'}) unless @visible
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+    for own toolbarName, buttons of Mercury.config.toolbars
+      continue if buttons._custom
+      toolbar = jQuery('<div>', {class: "mercury-toolbar mercury-#{toolbarName}-toolbar"}).appendTo(@element)
+      toolbar.attr('data-regions', buttons._regions) if buttons._regions
+      container = jQuery('<div>', {class: 'mercury-toolbar-button-container'}).appendTo(toolbar)
+
+      for own buttonName, options of buttons
+        continue if buttonName == '_regions'
+        button = @buildButton(buttonName, options)
+        button.appendTo(container) if button
+
+      if container.css('white-space') == 'nowrap'
+        expander = new Mercury.Toolbar.Expander(toolbarName, {appendTo: toolbar, for: container})
+        expander.appendTo(@element)
+
+      toolbar.addClass('disabled') if Mercury.config.toolbars['primary'] && toolbarName != 'primary'
+
+    @element.css({width: '100%'})
+
+
+  buildButton: (name, options) ->
+    return false if name[0] == '_'
+    switch jQuery.type(options)
+      when 'array' # button
+        [title, summary, handled] = options
+        new Mercury.Toolbar.Button(name, title, summary, handled, {appendDialogsTo: @element})
+
+      when 'object' # button group
+        group = new Mercury.Toolbar.ButtonGroup(name, options)
+        for own action, opts of options
+          button = @buildButton(action, opts)
+          button.appendTo(group) if button
+        group
+
+      when 'string' # separator
+        jQuery('<hr>', {class: "mercury-#{if options == '-' then 'line-separator' else 'separator'}"})
+
+      else throw Mercury.I18n('Unknown button structure -- please provide an array, object, or string for "%s".', name)
+
+
+  bindEvents: ->
+    Mercury.on 'region:focused', (event, options) =>
+      for toolbar in @element.find(".mercury-toolbar")
+        toolbar = jQuery(toolbar)
+        if regions = toolbar.data('regions')
+          toolbar.removeClass('disabled') if regions.split(',').indexOf(options.region.type) > -1
+
+    Mercury.on 'region:blurred', (event, options) =>
+      for toolbar in @element.find(".mercury-toolbar")
+        toolbar = jQuery(toolbar)
+        if regions = toolbar.data('regions')
+          toolbar.addClass('disabled') if regions.split(',').indexOf(options.region.type) > -1
+
+    @element.on 'click', ->
+      Mercury.trigger('hide:dialogs')
+
+    @element.on 'mousedown', (event) ->
+      event.preventDefault()
+
+
+  height: ->
+    if @visible then @element.outerHeight() else 0
+
+
+  show: ->
+    @visible = true
+    @element.css({top: -@element.outerHeight(), display: 'block'})
+    @element.animate({top: 0}, 200, 'easeInOutSine')
+
+
+  hide: ->
+    @visible = false
+    @element.hide()

data/vendor/assets/javascripts/mercury/tooltip.js.coffee

@@ -0,0 +1,74 @@
+@Mercury.tooltip = (forElement, content, options = {}) ->
+  Mercury.tooltip.show(forElement, content, options)
+  return Mercury.tooltip
+
+jQuery.extend Mercury.tooltip,
+
+  show: (@forElement, @content, @options = {}) ->
+    @document = @forElement.get(0).ownerDocument
+    @initialize()
+    if @visible then @update() else @appear()
+
+
+  initialize: ->
+    return if @initialized
+    @build()
+    @bindEvents()
+    @initialized = true
+
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-tooltip'})
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'resize', => @position() if @visible
+
+    @element.on 'mousedown', (event) ->
+      event.preventDefault()
+      event.stopPropagation()
+
+    for parent in @forElement.parentsUntil(jQuery('body', @document))
+      continue unless parent.scrollHeight > parent.clientHeight
+      jQuery(parent).on 'scroll', =>
+        @position() if @visible
+
+    jQuery(@document).on 'scroll', =>
+      @position() if @visible
+
+
+  appear: ->
+    @update()
+
+    @element.show()
+    @element.animate {opacity: 1}, 200, 'easeInOutSine', =>
+      @visible = true
+
+
+  update: ->
+    @element.html(@content)
+    @position()
+
+
+  position: ->
+    offset = @forElement.offset()
+    width = @element.width()
+
+    top = offset.top + (Mercury.displayRect.top - jQuery(@document).scrollTop()) + @forElement.outerHeight()
+    left = offset.left - jQuery(@document).scrollLeft()
+
+    left = left - (left + width + 25) - Mercury.displayRect.width if (left + width + 25) > Mercury.displayRect.width
+    left = if left <= 0 then 0 else left
+
+    @element.css {
+      top: top
+      left: left
+    }
+
+
+  hide: ->
+    return unless @initialized
+    @element.hide()
+    @visible = false
+

data/vendor/assets/javascripts/mercury/uploader.js.coffee

@@ -0,0 +1,244 @@
+@Mercury.uploader = (file, options) ->
+  Mercury.uploader.show(file, options) if Mercury.config.uploading.enabled
+  return Mercury.uploader
+
+jQuery.extend Mercury.uploader,
+
+  show: (file, @options = {}) ->
+    @file = new Mercury.uploader.File(file)
+    if @file.errors
+      alert("Error: #{@file.errors}")
+      return
+    return unless @supported()
+
+    Mercury.trigger('focus:window')
+    @initialize()
+    @appear()
+
+
+  initialize: ->
+    return if @initialized
+    @build()
+    @bindEvents()
+    @initialized = true
+
+
+  supported: ->
+    xhr = new XMLHttpRequest
+
+    if window.Uint8Array && window.ArrayBuffer && !XMLHttpRequest.prototype.sendAsBinary
+      XMLHttpRequest::sendAsBinary = (datastr) ->
+        ui8a = new Uint8Array(datastr.length)
+        ui8a[index] = (datastr.charCodeAt(index) & 0xff) for data, index in datastr
+        @send(ui8a.buffer)
+
+    return !!(xhr.upload && xhr.sendAsBinary && (Mercury.uploader.fileReaderSupported() || Mercury.uploader.formDataSupported()))
+
+  fileReaderSupported: ->
+    !!(window.FileReader)
+  
+  formDataSupported: ->
+    !!(window.FormData)
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-uploader', style: 'display:none'})
+    @element.append('<div class="mercury-uploader-preview"><b><img/></b></div>')
+    @element.append('<div class="mercury-uploader-details"></div>')
+    @element.append('<div class="mercury-uploader-progress"><span></span><div class="mercury-uploader-indicator"><div><b>0%</b></div></div></div>')
+
+    @updateStatus('Processing...')
+
+    @overlay = jQuery('<div>', {class: 'mercury-uploader-overlay', style: 'display:none'})
+
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+    @overlay.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'resize', => @position()
+
+
+  appear: ->
+    @fillDisplay()
+    @position()
+
+    @overlay.show()
+    @overlay.animate {opacity: 1}, 200, 'easeInOutSine', =>
+      @element.show()
+      @element.animate {opacity: 1}, 200, 'easeInOutSine', =>
+        @visible = true
+        @loadImage()
+
+
+  position: ->
+    width = @element.outerWidth()
+    height = @element.outerHeight()
+
+    @element.css {
+      top: (Mercury.displayRect.height - height) / 2
+      left: (Mercury.displayRect.width - width) / 2
+    }
+
+
+  fillDisplay: ->
+    details = [
+      Mercury.I18n('Name: %s', @file.name),
+      Mercury.I18n('Size: %s', @file.readableSize),
+      Mercury.I18n('Type: %s', @file.type)
+    ]
+    @element.find('.mercury-uploader-details').html(details.join('<br/>'))
+
+
+  loadImage: ->
+    if Mercury.uploader.fileReaderSupported()
+      @file.readAsDataURL (result) =>
+        @element.find('.mercury-uploader-preview b').html(jQuery('<img>', {src: result}))
+        @upload()
+    else
+      @upload()
+
+
+  upload: ->
+    xhr = new XMLHttpRequest
+    jQuery.each ['onloadstart', 'onprogress', 'onload', 'onabort', 'onerror'], (index, eventName) =>
+      xhr.upload[eventName] = (event) => @uploaderEvents[eventName].call(@, event)
+    xhr.onload = (event) =>
+      if (event.currentTarget.status >= 400)
+        @updateStatus('Error: Unable to upload the file')
+        Mercury.notify('Unable to process response: %s', event.currentTarget.status)
+        @hide()
+      else
+        try
+          response =
+            if Mercury.config.uploading.handler
+              Mercury.config.uploading.handler(event.target.responseText)
+            else
+              jQuery.parseJSON(event.target.responseText)
+          src = response.url || response.image.url
+          throw 'Malformed response from server.' unless src
+          Mercury.trigger('action', {action: 'insertImage', value: {src: src}})
+          @hide()
+        catch error
+          @updateStatus('Error: Unable to upload the file')
+          Mercury.notify('Unable to process response: %s', error)
+          @hide()
+
+    xhr.open('post', Mercury.config.uploading.url, true)
+    xhr.setRequestHeader('Accept', 'application/json, text/javascript, text/html, application/xml, text/xml, */*')
+    xhr.setRequestHeader('X-Requested-With', 'XMLHttpRequest')
+    xhr.setRequestHeader(Mercury.config.csrfHeader, Mercury.csrfToken)
+
+    # Homespun multipart uploads. Chrome 18, Firefox 11.
+    #
+    if Mercury.uploader.fileReaderSupported()
+      @file.readAsBinaryString (result) =>
+        
+        multipart = new Mercury.uploader.MultiPartPost(Mercury.config.uploading.inputName, @file, result)
+
+        # update the content size so we can calculate
+        @file.updateSize(multipart.delta)
+
+        # set the content type and send
+        xhr.setRequestHeader('Content-Type', 'multipart/form-data; boundary=' + multipart.boundary)
+        xhr.sendAsBinary(multipart.body)
+    
+    # FormData based. Safari 5.1.2.
+    #
+    else
+      formData = new FormData()
+      formData.append(Mercury.config.uploading.inputName, @file.file, @file.file.name)
+
+      xhr.send(formData)
+
+
+
+  updateStatus: (message, loaded) ->
+    @element.find('.mercury-uploader-progress span').html(Mercury.I18n(message).toString())
+    if loaded
+      percent = Math.floor(loaded * 100 / @file.size) + '%'
+      @element.find('.mercury-uploader-indicator div').css({width: percent})
+      @element.find('.mercury-uploader-indicator b').html(percent).show()
+
+
+  hide: (delay = 0) ->
+    setTimeout delay * 1000, =>
+      @element.animate {opacity: 0}, 200, 'easeInOutSine', =>
+        @overlay.animate {opacity: 0}, 200, 'easeInOutSine', =>
+          @overlay.hide()
+          @element.hide()
+          @reset()
+          @visible = false
+          Mercury.trigger('focus:frame')
+
+
+  reset: ->
+    @element.find('.mercury-uploader-preview b').html('')
+    @element.find('.mercury-uploader-indicator div').css({width: 0})
+    @element.find('.mercury-uploader-indicator b').html('0%').hide()
+    @updateStatus('Processing...')
+
+
+  uploaderEvents:
+    onloadstart: -> @updateStatus('Uploading...')
+
+    onprogress: (event) -> @updateStatus('Uploading...', event.loaded)
+
+    onabort: ->
+      @updateStatus('Aborted')
+      @hide(1)
+
+    onload: ->
+      @updateStatus('Successfully uploaded...', @file.size)
+
+    onerror: ->
+      @updateStatus('Error: Unable to upload the file')
+      @hide(3)
+
+
+
+class Mercury.uploader.File
+
+  constructor: (@file) ->
+    @fullSize = @size = @file.size || @file.fileSize
+    @readableSize = @size.toBytes()
+    @name = @file.name || @file.fileName
+    @type = @file.type || @file.fileType
+
+    # add any errors if we need to
+    errors = []
+    errors.push(Mercury.I18n('Too large')) if @size >= Mercury.config.uploading.maxFileSize
+    errors.push(Mercury.I18n('Unsupported format')) unless Mercury.config.uploading.allowedMimeTypes.indexOf(@type) > -1
+    @errors = errors.join(' / ') if errors.length
+
+
+  readAsDataURL: (callback = null) ->
+    reader = new FileReader()
+    reader.readAsDataURL(@file)
+    reader.onload = => callback(reader.result) if callback
+
+
+  readAsBinaryString: (callback = null) ->
+    reader = new FileReader()
+    reader.readAsBinaryString(@file)
+    reader.onload = => callback(reader.result) if callback
+
+
+  updateSize: (delta) ->
+    @fullSize = @size + delta
+
+
+
+class Mercury.uploader.MultiPartPost
+
+  constructor: (@inputName, @file, @contents, @formInputs = {}) ->
+    @boundary = 'Boundaryx20072377098235644401115438165x'
+    @body = ''
+    @buildBody()
+    @delta = @body.length - @file.size
+
+
+  buildBody: ->
+    boundary = '--' + @boundary
+    for own name, value of @formInputs
+      @body += "#{boundary}\r\nContent-Disposition: form-data; name=\"#{name}\"\r\n\r\n#{unescape(encodeURIComponent(value))}\r\n"
+    @body += "#{boundary}\r\nContent-Disposition: form-data; name=\"#{@inputName}\"; filename=\"#{@file.name}\"\r\nContent-Type: #{@file.type}\r\nContent-Transfer-Encoding: binary\r\n\r\n#{@contents}\r\n#{boundary}--"