kuji-mercury-rails 0.3.2

data/vendor/assets/javascripts/mercury/dialog.js.coffee

@@ -0,0 +1,159 @@
+# # Mercury Dialog
+#
+# Dialog is a base class that's used by Palette, Select, Panel, and through Palette, the Toolbar.Expander.  It's basic
+# function is to provide an interface element that can be opened, interacted with, and then closed.
+#
+class @Mercury.Dialog
+
+  # The constructor expects a url to load, a name, and options.
+  #
+  # @url _string_ used to load the contents, either using Ajax or by pulling content from preloadedViews
+  #
+  # @name _string_ used in building of the element, and is assigned as part of the elements class (eg.
+  #     `mercury-[name]-dialog`)
+  #
+  # @options _object_
+  #
+  # **Options**
+  #
+  # @for _Toolbar.Button_ used so the dialog can be shown/hidden based on button interactions.
+  #
+  # @preload _boolean_ if true, the view for this dialog will be loaded prior to being shown, otherwise the view will be
+  #     loaded the first time it's shown, and cached for all future interactions.
+  #
+  # @appendTo _element_ you can append a dialog to any element by providing this option.
+  constructor: (@url, @name, @options = {}) ->
+    @button = @options.for
+
+    @build()
+    @bindEvents()
+    @preload()
+
+
+  # ## #build
+  #
+  # Builds the element and appends it to the DOM.  You can provide an element to append it to in the options, otherwise
+  # it will be appended to the body.
+  build: ->
+    @element = jQuery('<div>', {class: "mercury-dialog mercury-#{@name}-dialog loading", style: 'display:none'})
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  # ## #bindEvents
+  #
+  # Bind to all the events we should handle.  In this case we only stop the mousedown event, since dialogs aren't
+  # expected to have inputs etc.
+  #
+  # **Note:** By stopping the mousedown event we're limiting what's possible in dialogs, but this is needed to keep
+  # focus from being taken away from the active region when different things are clicked on in dialogs.
+  bindEvents: ->
+    @element.on 'mousedown', (event) ->
+      event.stopPropagation()
+
+
+  # ## #preload
+  #
+  # If the options dictate that the content should be preloaded we load the view before we do anything else.  This is
+  # useful if you don't want to make the user wait the half second or however long the server may take to respond when
+  # they open various dialogs.
+  preload: ->
+    @load() if @options.preload
+
+
+  # ## #toggle
+  #
+  # Toggle the dialog based on current visibility.
+  toggle: ->
+    if @visible then @hide() else @show()
+
+
+  # ## #resize
+  #
+  # In the base class resize just calls through to show, but in the implementation classes resize typically adjusts the
+  # size based on it's contents.
+  resize: ->
+    @show()
+
+
+  # ## #show
+  #
+  # When showing a dialog it's expected that all other dialogs will close, and we fire an event for this.  The dialog is
+  # then positioned and shown.  The show animation of the dialog is typically dictated by the implementation class.
+  show: ->
+    # Tell all other dialogs to close.
+    Mercury.trigger('hide:dialogs', @)
+    @visible = true
+    if @loaded
+      @element.css({width: 'auto', height: 'auto'})
+      @position(@visible)
+    else
+      @position()
+    # Then show the element.
+    @appear()
+
+
+  # ## #position
+  #
+  # Interface method.  Implementations are expected to position the dialog themselves.
+  #
+  # @keepVisible _boolean_ specifies if the element should stay visible if it's already visible.
+  position: (keepVisible) ->
+
+
+  # ## #appear
+  #
+  # Animate the element into view.  After it's done showing, we load and resize it if it's not already loaded, so in
+  # cases where content is not preloaded we can display the dialog, fill it's contents, and then animate the resize.
+  appear: ->
+    @element.css({display: 'block', opacity: 0})
+    @element.animate {opacity: 0.95}, 200, 'easeInOutSine', =>
+      @load(=> @resize()) unless @loaded
+
+
+  # ## #hide
+  #
+  # Hides the element and keeps track of it's visibility.
+  hide: ->
+    @element.hide()
+    @visible = false
+
+
+  # ## #load
+  #
+  # Fetches the content that will be loaded into the dialog.
+  #
+  # @callback _function_ will be called after the content is loaded.
+  load: (callback) ->
+    return unless @url
+    if Mercury.preloadedViews[@url]
+      # If there's a preloadedView defined for the url being requested, load that one.
+      @loadContent(Mercury.preloadedViews[@url])
+      # And call the dialog handler if there's one.  We've broken the handlers out into separate files so they can be
+      # tested more easily, but you can define your own by putting them in dialogHandlers.
+      Mercury.dialogHandlers[@name].call(@) if Mercury.dialogHandlers[@name]
+      callback() if callback
+    else
+      # Otherwise make an Ajax request to get the content.
+      jQuery.ajax @url, {
+        success: (data) =>
+          @loadContent(data)
+          Mercury.dialogHandlers[@name].call(@) if Mercury.dialogHandlers[@name]
+          callback() if callback
+        error: =>
+          # If the Ajax fails, we hide the dialog and alert the user about the error.
+          @hide()
+          @button.removeClass('pressed') if @button
+          Mercury.notify('Mercury was unable to load %s for the "%s" dialog.', @url, @name)
+      }
+
+
+  # ## #loadContent
+  #
+  # Loads content into the element, and removes the loading class.
+  #
+  # @data _mixed_ a string or jQuery object that can be inserted into the dialog.
+  loadContent: (data) ->
+    @loaded = true
+    @element.removeClass('loading')
+    @element.html(data)
+    @element.localize(Mercury.locale()) if Mercury.config.localization.enabled

data/vendor/assets/javascripts/mercury/dialogs/backcolor.js.coffee

@@ -0,0 +1,6 @@
+@Mercury.dialogHandlers.backColor = ->
+  @element.find('.picker, .last-picked').on 'click', (event) =>
+    color = jQuery(event.target).css('background-color')
+    @element.find('.last-picked').css({background: color})
+    @button.css({backgroundColor: color})
+    Mercury.trigger('action', {action: 'backColor', value: color})

data/vendor/assets/javascripts/mercury/dialogs/forecolor.js.coffee

@@ -0,0 +1,6 @@
+@Mercury.dialogHandlers.foreColor = ->
+  @element.find('.picker, .last-picked').on 'click', (event) =>
+    color = jQuery(event.target).css('background-color')
+    @element.find('.last-picked').css({background: color})
+    @button.css({backgroundColor: color})
+    Mercury.trigger('action', {action: 'foreColor', value: color})

data/vendor/assets/javascripts/mercury/dialogs/formatblock.js.coffee

@@ -0,0 +1,4 @@
+@Mercury.dialogHandlers.formatblock = ->
+  @element.find('[data-tag]').on 'click', (event) =>
+    tag = jQuery(event.target).data('tag')
+    Mercury.trigger('action', {action: 'formatblock', value: tag})

data/vendor/assets/javascripts/mercury/dialogs/snippetpanel.js.coffee

@@ -0,0 +1,10 @@
+@Mercury.dialogHandlers.snippetPanel = ->
+  # make the filter work
+  @element.find('input.filter').on 'keyup', =>
+    value = @element.find('input.filter').val()
+    for snippet in @element.find('li[data-filter]')
+      if LiquidMetal.score(jQuery(snippet).data('filter'), value) == 0 then jQuery(snippet).hide() else jQuery(snippet).show()
+
+  # when an element is dragged, set it so we have a global object
+  @element.find('img[data-snippet]').on 'dragstart', ->
+    Mercury.snippet = jQuery(@).data('snippet')

data/vendor/assets/javascripts/mercury/dialogs/style.js.coffee

@@ -0,0 +1,4 @@
+@Mercury.dialogHandlers.style = ->
+  @element.find('[data-class]').on 'click', (event) =>
+    className = jQuery(event.target).data('class')
+    Mercury.trigger('action', {action: 'style', value: className})

data/vendor/assets/javascripts/mercury/finalize.js.coffee

@@ -0,0 +1,3 @@
+# tell everyone that Mercury has loaded
+Mercury.onload() if Mercury.onload
+jQuery(window).trigger('mercury:loaded')

data/vendor/assets/javascripts/mercury/history_buffer.js.coffee

@@ -0,0 +1,30 @@
+class @Mercury.HistoryBuffer
+
+  constructor: (@maxLength = 200) ->
+    @index = 0
+    @stack = []
+    @markerRegExp = /<em class="mercury-marker"><\/em>/g
+
+
+  push: (item) ->
+    if jQuery.type(item) == 'string'
+      return if @stack[@index] && @stack[@index].replace(@markerRegExp, '') == item.replace(@markerRegExp, '')
+    else if jQuery.type(item) == 'object' && item.html
+      return if @stack[@index] && @stack[@index].html == item.html
+
+    @stack = @stack[0...@index + 1]
+    @stack.push(item)
+    @stack.shift() if @stack.length > @maxLength
+    @index = @stack.length - 1
+
+
+  undo: ->
+    return null if @index < 1
+    @index -= 1
+    return @stack[@index]
+
+
+  redo: ->
+    return null if @index >= @stack.length - 1
+    @index += 1
+    return @stack[@index]

data/vendor/assets/javascripts/mercury/lightview.js.coffee

@@ -0,0 +1,205 @@
+@Mercury.lightview = (url, options = {}) ->
+  Mercury.lightview.show(url, options)
+  return Mercury.lightview
+
+jQuery.extend Mercury.lightview,
+  minWidth: 400
+
+  show: (@url, @options = {}) ->
+    Mercury.trigger('focus:window')
+    @initialize()
+    if @visible then @update() else @appear()
+    if @options.content
+      setTimeout 500, => @loadContent(@options.content)
+
+
+  initialize: ->
+    return if @initialized
+    @build()
+    @bindEvents()
+    @initialized = true
+
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-lightview loading'})
+    @element.html('<h1 class="mercury-lightview-title"><span></span></h1>')
+    @element.append('<div class="mercury-lightview-content"></div>')
+
+    @overlay = jQuery('<div>', {class: 'mercury-lightview-overlay'})
+
+    @titleElement = @element.find('.mercury-lightview-title')
+    @titleElement.append('<a class="mercury-lightview-close"></a>') if @options.closeButton
+
+    @contentElement = @element.find('.mercury-lightview-content')
+
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+    @overlay.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'refresh', => @resize(true)
+    Mercury.on 'resize', => @position() if @visible
+
+    @overlay.on 'click', =>
+      @hide() unless @options.closeButton
+
+    @titleElement.find('.mercury-lightview-close').on 'click', =>
+      @hide()
+
+    @element.on 'ajax:beforeSend', (event, xhr, options) =>
+      options.success = (content) =>
+        @loadContent(content)
+
+    jQuery(document).on 'keydown', (event) =>
+       @hide() if event.keyCode == 27 && @visible
+
+
+  appear: ->
+    @showing = true
+    @position()
+
+    @overlay.show().css({opacity: 0})
+    @overlay.animate {opacity: 1}, 200, 'easeInOutSine', =>
+      @setTitle()
+      @element.show().css({opacity: 0})
+      @element.stop().animate {opacity: 1}, 200, 'easeInOutSine', =>
+        @visible = true
+        @showing = false
+        @load()
+
+
+  resize: (keepVisible) ->
+    visibility = if keepVisible then 'visible' else 'hidden'
+
+    viewportWidth = Mercury.displayRect.width
+    viewportHeight = Mercury.displayRect.fullHeight
+
+    titleHeight = @titleElement.outerHeight()
+
+    width = @contentElement.outerWidth()
+    width = viewportWidth - 40 if width > viewportWidth - 40 || @options.fullSize
+
+    @contentPane.css({height: 'auto'}) if @contentPane
+    @contentElement.css({height: 'auto', visibility: visibility, display: 'block'})
+
+    height = @contentElement.outerHeight() + titleHeight
+    height = viewportHeight - 20 if height > viewportHeight - 20 || @options.fullSize
+
+    width = 300 if width < 300
+    height = 150 if height < 150
+
+    @element.stop().animate {top: ((viewportHeight - height) / 2) + 10, left: (Mercury.displayRect.width - width) / 2, width: width, height: height}, 200, 'easeInOutSine', =>
+      @contentElement.css({visibility: 'visible', display: 'block'})
+      if @contentPane.length
+        @contentElement.css({height: height - titleHeight, overflow: 'visible'})
+        controlHeight = if @contentControl.length then @contentControl.outerHeight() else 0
+        @contentPane.css({height: height - titleHeight - controlHeight - 40})
+        @contentPane.find('.mercury-display-pane').css({width: width - 40})
+      else
+        @contentElement.css({height: height - titleHeight - 30, overflow: 'auto'})
+
+
+  position: ->
+    viewportWidth = Mercury.displayRect.width
+    viewportHeight = Mercury.displayRect.fullHeight
+
+    @contentPane.css({height: 'auto'}) if @contentPane
+    @contentElement.css({height: 'auto'})
+    @element.css({width: 'auto', height: 'auto', display: 'block', visibility: 'hidden'})
+
+    width = @contentElement.width() + 40
+    height = @contentElement.height() + @titleElement.outerHeight() + 30
+
+    width = viewportWidth - 40 if width > viewportWidth - 40 || @options.fullSize
+    height = viewportHeight - 20 if height > viewportHeight - 20 || @options.fullSize
+
+    width = 300 if width < 300
+    height = 150 if height < 150
+
+    titleHeight = @titleElement.outerHeight()
+    if @contentPane && @contentPane.length
+      @contentElement.css({height: height - titleHeight, overflow: 'visible'})
+      controlHeight = if @contentControl.length then @contentControl.outerHeight() else 0
+      @contentPane.css({height: height - titleHeight - controlHeight - 40})
+      @contentPane.find('.mercury-display-pane').css({width: width - 40})
+    else
+      @contentElement.css({height: height - titleHeight - 30, overflow: 'auto'})
+
+    @element.css {
+      top: ((viewportHeight - height) / 2) + 10,
+      left: (viewportWidth - width) / 2,
+      width: width
+      height: height
+      display: if @visible then 'block' else 'none'
+      visibility: 'visible'
+    }
+
+
+  update:  ->
+    @reset()
+    @resize()
+    @load()
+
+
+  load: ->
+    @setTitle()
+    return unless @url
+    @element.addClass('loading')
+    if Mercury.preloadedViews[@url]
+      setTimeout(10, => @loadContent(Mercury.preloadedViews[@url]))
+    else
+      jQuery.ajax @url, {
+        headers: Mercury.ajaxHeaders()
+        type: @options.loadType || 'GET'
+        data: @options.loadData
+        success: (data) => @loadContent(data)
+        error: =>
+          @hide()
+          Mercury.notify('Mercury was unable to load %s for the lightview.', @url)
+      }
+
+
+  loadContent: (data, options = null) ->
+    @initialize()
+    @options = options || @options
+    @setTitle()
+    @loaded = true
+    @element.removeClass('loading')
+    @contentElement.html(data)
+    @contentElement.css({display: 'none', visibility: 'hidden'})
+
+    # for complex lightview content, we provide panes and controls
+    @contentPane = @element.find('.mercury-display-pane-container')
+    @contentControl = @element.find('.mercury-display-controls')
+
+    @options.afterLoad.call(@) if @options.afterLoad
+    if @options.handler
+      if Mercury.modalHandlers[@options.handler]
+        Mercury.modalHandlers[@options.handler].call(@)
+      else if Mercury.lightviewHandlers[@options.handler]
+        Mercury.lightviewHandlers[@options.handler].call(@)
+
+    @element.localize(Mercury.locale()) if Mercury.config.localization.enabled
+    @resize()
+
+
+  setTitle: ->
+    @titleElement.find('span').html(Mercury.I18n(@options.title))
+
+
+  reset: ->
+    @titleElement.find('span').html('')
+    @contentElement.html('')
+
+
+  hide: ->
+    return if @showing
+    @options = {}
+    @initialized = false
+
+    Mercury.trigger('focus:frame')
+    @element.hide()
+    @overlay.hide()
+    @reset()
+
+    @visible = false

data/vendor/assets/javascripts/mercury/locales/ar.locale.js.coffee

@@ -0,0 +1,207 @@
+Mercury.I18n['ar'] =
+  # ## Javascript Strings
+
+  # ### Default Configuration
+  "Save": "حفظ"
+  "Save this page": "حفظ الصفحة"
+  "Preview": "معاينة"
+  "Preview this page": "معاينة هذه الضفحة"
+  "Undo": "تراجع"
+  "Undo your last action": "تراجع عن أخر فعل"
+  "Redo": "إعادة"
+  "Redo your last action": "إعادة أخر فعل"
+  "Link": "رابط"
+  "Insert Link": "إدراج رابط"
+  "Media": "ملف ميديا"
+  "Insert Media (images and videos)": "إدراج ملف ميديا (صور أو فيديو)"
+  "Table": "جدول"
+  "Insert Table": "إدراج جدول"
+  "Character": "حرف"
+  "Special Characters": "حرف مميز "
+  "Snippet": "قصاصة"
+  "Snippet Panel": "لوحة قصاصات"
+  "History": "سجل"
+  "Page Version History": "نسج مسجلة من الصفحة"
+  "Notes": "ملاحظات"
+  "Page Notes": "ملاحظات الصفحة"
+  "Style": "نمط"
+  "Block Format": "تنسيق كتلة"
+  "Background Color": "لون الخلفية"
+  "Text Color": "لون النص"
+  "Bold": "واضح"
+  "Italicize": "مائلة"
+  "Overline": "خط فوق"
+  "Strikethrough": " خط فى الوسط "
+  "Underline": "خط تحت"
+  "Subscript": " نص سفلى"
+  "Superscript": " نص علوى"
+  "Align Left": "محاذاة إلى اليسار"
+  "Center": "محاذاة إلى  الوسط"
+  "Align Right": "محاذاة إلى اليمين"
+  "Justify Full": "ضبط كامل"
+  "Unordered List": "قائمة غير مرتبة"
+  "Numbered List": "قائمة مرقمة"
+  "Decrease Indentation": "إنقاص المسافة البادئة"
+  "Increase Indentation": "زيادة المسافة البادئة"
+  "Insert Table Row": "إدراج صف "
+  "Insert a table row before the cursor": "إدراج صف قبل المؤشر"
+  "Insert a table row after the cursor": "إدراج صف بعد المؤشر"
+  "Delete Table Row": "حذف صف"
+  "Delete this table row": "حذف هذا الصف"
+  "Insert Table Column": "إضافة عمود للجدول"
+  "Insert a table column before the cursor": "إدراج عمود قبل المؤشر"
+  "Insert a table column after the cursor": "إدراج عمود بعد المؤشر"
+  "Delete Table Column": "حذف عمود جدول"
+  "Delete this table column": "حذف هذا العمود"
+  "Increase Cell Columns": "زيادة أعمدة الخلية"
+  "Decrease Cell Columns": "إنقاص أعمدة الخلية"
+  "Increase Cell Rows": "زيادة صفوف الخلية"
+  "Decrease Cell Rows": "إنقاص صفوف الخلية"
+  "Horizontal Rule": "مسطرة أفقية"
+  "Insert a horizontal rule": "إدراج مسطرة أفقية"
+  "Remove Formatting": "إزالة التنسيق"
+  "Remove formatting for the selection": "إزالة التنسيق لاختيار"
+  "Edit HTML": "تعديل ال HTML"
+  "Edit the HTML content": "تعديل ال HTML"
+  "Edit Snippet Settings": "تعديل ضبط قصاصة"
+  "Remove Snippet": "إزالة القصاصات"
+
+  # ### General
+  # Error Messages
+  "Mercury.Regions.%s is unsupported in this client. Supported browsers are %s.": "Mercury.Regions.%s غير غير مدعوم فى هذا المتصفح. المتصفحات المدعومة هى %s"
+  "Mercury.PageEditor can only be instantiated once.": "Mercury.PageEditor لا يمكن إلا أن يمثل مرة واحدة.."
+  "Opera isn't a fully supported browser, your results may not be optimal.": "أوبرا ليست متصفح متوافق بالكامل، قد لا تكون نتائجك الأمثل."
+  "Mercury.PageEditor failed to load: %s\n\nPlease try refreshing.": "Mercury.PageEditor غير قاد على تحميل: %s\n\nمن فضلك حدث الصفحة ."
+  "Region type is malformed, no data-type provided, or \"%s\" is unknown for the \"%s\" region.": "نوع المساحة تالف, لا يوجد نوع , أو \"%s\" غير معروف للمساحة \"%s\""
+  "Mercury was unable to save to the url: %s": "غير قادر على حفظ الرابط: %s"
+  # Confirmations
+  "You have unsaved changes.Are you sure you want to leave without saving them first?": "لديك تغييرات غير محفوظة. هل أنت متأكد أنك تريد أن تترك دون حفظها أولا؟"
+
+  # ### Toolbar / Buttons
+  # Error Messages
+  "Unknown button type \"%s\" used for the \"%s\" button.": "نوع زر غير معروف \"%s\" مستخدمة ل \"%s\""
+  "Unknown button structure -- please provide an array, object, or string for \"%s\".": "بنية زر غير معروفة - يرجى تقديم مجموعة واسعة، كائنات، أو كلمة \"%s\"."
+
+  # ### Modals / Dialogs / Etc.
+  # Error Messages
+  "Mercury was unable to load %s for the \"%s\" dialog.": "غير قادر على تحميل %s للنافذة \"%s\"."
+  "Mercury was unable to load %s for the lightview.": "غير قادر على تحميل %s للضوء."
+  "Mercury was unable to load %s for the modal.": "غير قادر على تحميل %s للنافذة."
+
+  # ### Snippets
+  # Error Messages
+  "Error loading the preview for the \"%s\" snippet.": "خطأ فى تحميل معاينة القصاصة \"%s\"."
+  # Misc
+  "Snippet Options": "خيارات القصاصة"
+
+  # ### Uploader
+  # Error Messages
+  "Unable to process response: %s": "غير قادر على معالجة الرد: %s"
+  "Error: Unable to upload the file": "خطأ: غير قادر على رفع الملف"
+  "Malformed response from server": "استجابة من الخادم متلوفة"
+  "Too large": "كبير جدا"
+  "Unsupported format": "تنسيق غير مدعوم"
+  # Statuses
+  "Processing...": "معالجة..."
+  "Uploading...": "رفع..."
+  "Aborted": "ملغى"
+  "Successfully uploaded...": "تم الرفع بنجاح..."
+  "Name: %s": "اسم: %s"
+  "Size: %s": "حجم: %s"
+  "Type: %s": "نوع: %s"
+
+  # Inserting Media
+  "Error: The provided youtube share url was invalid.": "خطأ: عنوان اليوتيوب غير صحيح"
+  "Error: The provided vimeo url was invalid.": "خطأ: عنوان فيميو غير صحيح"
+
+  # Statusbar
+  "Path:": "مسار:"
+
+
+  # ## HTML / Template Strings
+
+  # ### Modals
+  # Insert Link Modal (link.html)
+  "Link Content": "محتوى الرابط"
+  "Standard Links": "رابط قياسى"
+  "URL": "عنوان"
+  "Index / Bookmark Links": "روابط فهرس / الإشارة المرجعية"
+  "Existing Links": "الروابط الموجودة"
+  "Bookmark": "الإشارة المرجعية"
+  "Options": "خيارات"
+  "Link Target": "هدف الرابط"
+  "Self (the same window or tab)": "الذاتية (نفس النافذة أو التبويب)"
+  "Blank (a new window or tab)": "فارغة (نافذة جديدة أو علامة التبويب)"
+  "Top (removes any frames)": "أعلى (يزيل أي إطارات)"
+  "Popup Window (javascript new window popup)": "نافذة منبثقة (جافا سكريبت نافذة منبثقة جديد)"
+  "Popup Width": "عرض  النافذة المنبثقة"
+  "Popup Height": "طول  النافذة المنبثقة"
+  "Insert Link": "إدراج رابط"
+
+  # Insert Media Modal (media.html)
+  "Images": "صور"
+  "Videos": "فيديو"
+  "YouTube Share URL": "رابط يوتيوب"
+  "Vimeo URL": "رابط فيميو"
+  "Alignment": "المحاذاة"
+  "None": "لا شيء"
+  "Left": "يسار"
+  "Right": "يمين"
+  "Top": "أعلى"
+  "Middle": "وسط"
+  "Bottom": "أسفل"
+  "Absolute Middle": "أوسط مطلق"
+  "Absolute Bottom": "أسفل مطلق"
+  "Width": "عرض"
+  "Height": "ارتفاع"
+  "Insert Media": "إدراج ملف ميديا"
+
+  # Insert Table Modal (table.html)
+  "Rows": "صفوف"
+  "Add Before": "إضافة قبل"
+  "Add After": "إضافة بعد"
+  "Remove": "حذف"
+  "Columns": "أعمدة"
+  "Row Span": "إمتداد الصف"
+  "Column Span": "إمتداد العمود"
+  "Options": "الخيارات"
+  "Alignment": "المحاذاة"
+  "Border": "الحدود"
+  "Spacing": "تباعد"
+  "Insert Table": "إدراج جدول"
+
+  # HTML Editor Modal (htmleditor.html)
+  "HTML Editor": "HTML محرر"
+  "Save and Replace": "حفظ واستبدال"
+
+  # ### Dialogs / Etc.
+  # Color Palettes (forecolor.html, backcolor.html)
+  "Last Color Picked": "التقطت آخر لون"
+
+  # Block Format Select (formatblock.html)
+  "Heading 1": "العنوان 1"
+  "Heading 2": "العنوان 2"
+  "Heading 3": "العنوان 3"
+  "Heading 4": "العنوان 4"
+  "Heading 5": "العنوان 5"
+  "Heading 6": "العنوان 6"
+  "Paragraph": "فقرة"
+  "Blockquote": "قتباس فقرة"
+  "Formatted": "منسقة"
+
+  # About Mercury Panel (about.html)
+  "Project Home": "صفحة المشروع"
+  "Project Source": "مصدر المشروع"
+
+  # ### Demo / Placeholder / Defaults
+  "The history panel is expected to be implemented with a server back end.  Since this is a demo, we didn't include it.": "لوحة التواريخ متوقع أن تكن مبرمجة. بما أن هد نسخة تجربية فهى غير محتواه."
+
+  "The notes panel is expected to be implemented with a server back end.  Since this is a demo, we didn't include it.": "لوحة الملاحظات متوقع أن تكن مبرمجة. بما أن هد نسخة تجربية فهى غير محتواه"
+
+  "Snippet Name": "اسم قصاصة"
+  "A one or two line long description of what this snippet does.": "وصف سطر واحد أو اثنين عما تفعل هذه القصاصة."
+
+  "First Name": "اﻷسم اﻷول"
+  "Favorite Beer": "المفضلة"
+  "Insert Snippet": "إدراج قصاصة"
+