RubyGems - kiteditor - Versions diffs - 1.0.1 - Mend

kiteditor 1.0.1

Files changed (229) hide show

data/vendor/assets/javascripts/mercury/statusbar.js.coffee ADDED Viewed

@@ -0,0 +1,51 @@
+class @Mercury.Statusbar
+  constructor: (@options = {}) ->
+    @visible = @options.visible
+    @build()
+    @bindEvents()
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-statusbar'})
+    @aboutElement = jQuery('<a>', {class: "mercury-statusbar-about"}).appendTo(@element).html("DSC Kit Editor")
+    @pathElement = jQuery('<div>', {class: 'mercury-statusbar-path'}).appendTo(@element)
+    @element.css({visibility: 'hidden'}) unless @visible
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+  bindEvents: ->
+    Mercury.on 'region:update', (event, options) =>
+      @setPath(options.region.path()) if options.region && jQuery.type(options.region.path) == 'function'
+    @aboutElement.on 'click', =>
+      document.location = 'http://www.dsc.net'
+  height: ->
+    @element.outerHeight()
+  top: ->
+    top =  @element.offset().top
+    currentTop = if parseInt(@element.css('bottom')) < 0 then top - @element.outerHeight() else top
+    if @visible then currentTop else top + @element.outerHeight()
+  setPath: (elements) ->
+    path = []
+    path.push("<a>#{element.tagName.toLowerCase()}</a>") for element in elements
+    @pathElement.html("<span><strong>#{Mercury.I18n('Path:')} </strong>#{path.reverse().join(' &raquo; ')}</span>")
+  show: ->
+    @visible = true
+    @element.css({opacity: 0, visibility: 'visible'})
+    @element.animate({opacity: 1}, 200, 'easeInOutSine')
+  hide: ->
+    @visible = false
+    @element.css({visibility: 'hidden'})

data/vendor/assets/javascripts/mercury/support/history.js ADDED Viewed

@@ -0,0 +1 @@

data/vendor/assets/javascripts/mercury/table_editor.js.coffee ADDED Viewed

@@ -0,0 +1,265 @@
+@Mercury.tableEditor = (table, cell, cellContent) ->
+  Mercury.tableEditor.load(table, cell, cellContent)
+  return Mercury.tableEditor
+jQuery.extend Mercury.tableEditor,
+  load: (@table, @cell, @cellContent = '') ->
+    @row = @cell.parent('tr')
+    @columnCount = @getColumnCount()
+    @rowCount = @getRowCount()
+  addColumn: (position = 'after') ->
+    sig = @cellSignatureFor(@cell)
+    for row, i in @table.find('tr')
+      rowSpan = 1
+      matchOptions = if position == 'after' then {right: sig.right} else {left: sig.left}
+      if matching = @findCellByOptionsFor(row, matchOptions)
+        newCell = jQuery("<#{matching.cell.get(0).tagName}>").html(@cellContent)
+        @setRowspanFor(newCell, matching.height)
+        if position == 'before' then matching.cell.before(newCell) else matching.cell.after(newCell)
+        i += matching.height - 1
+      else if intersecting = @findCellByIntersectionFor(row, sig)
+        @setColspanFor(intersecting.cell, intersecting.width + 1)
+  removeColumn: ->
+    sig = @cellSignatureFor(@cell)
+    return if sig.width > 1
+    removing = []
+    adjusting = []
+    for row, i in @table.find('tr')
+      if matching = @findCellByOptionsFor(row, {left: sig.left, width: sig.width})
+        removing.push(matching.cell)
+        i += matching.height - 1
+      else if intersecting = @findCellByIntersectionFor(row, sig)
+        adjusting.push(intersecting.cell)
+    jQuery(cell).remove() for cell in removing
+    @setColspanFor(cell, @colspanFor(cell) - 1) for cell in adjusting
+  addRow: (position = 'after') ->
+    newRow = jQuery('<tr>')
+    if (rowspan = @rowspanFor(@cell)) > 1 && position == 'after'
+      @row = jQuery(@row.nextAll('tr')[rowspan - 2])
+    cellCount = 0
+    for cell in @row.find('th, td')
+      colspan = @colspanFor(cell)
+      newCell = jQuery("<#{cell.tagName}>").html(@cellContent)
+      @setColspanFor(newCell, colspan)
+      cellCount += colspan
+      if (rowspan = @rowspanFor(cell)) > 1 && position == 'after'
+        @setRowspanFor(cell, rowspan + 1)
+        continue
+      newRow.append(newCell)
+    if cellCount < @columnCount
+      rowCount = 0
+      for previousRow in @row.prevAll('tr')
+        rowCount += 1
+        for cell in jQuery(previousRow).find('td[rowspan], th[rowspan]')
+          rowspan = @rowspanFor(cell)
+          if rowspan - 1 >= rowCount && position == 'before'
+            @setRowspanFor(cell, rowspan + 1)
+          else if rowspan - 1 >= rowCount && position == 'after'
+            if rowspan - 1 == rowCount
+              newCell = jQuery("<#{cell.tagName}>").html(@cellContent)
+              @setColspanFor(newCell, @colspanFor(cell))
+              newRow.append(newCell)
+            else
+              @setRowspanFor(cell, rowspan + 1)
+    if position == 'before' then @row.before(newRow) else @row.after(newRow)
+  removeRow: ->
+    # check to see that all cells have the same rowspan, and figure out the minimum rowspan
+    rowspansMatch = true
+    prevRowspan = 0
+    minRowspan = 0
+    for cell in @row.find('td, th')
+      rowspan = @rowspanFor(cell)
+      rowspansMatch = false if prevRowspan && rowspan != prevRowspan
+      minRowspan = rowspan if rowspan < minRowspan || !minRowspan
+      prevRowspan = rowspan
+    return if !rowspansMatch && @rowspanFor(@cell) > minRowspan
+    # remove any emtpy rows below
+    if minRowspan > 1
+      jQuery(@row.nextAll('tr')[i]).remove() for i in [0..minRowspan - 2]
+    # find and move down any cells that have a larger rowspan
+    for cell in @row.find('td[rowspan], th[rowspan]')
+      sig = @cellSignatureFor(cell)
+      continue if sig.height == minRowspan
+      if match = @findCellByOptionsFor(@row.nextAll('tr')[minRowspan - 1], {left: sig.left, forceAdjacent: true})
+        @setRowspanFor(cell, @rowspanFor(cell) - @rowspanFor(@cell))
+        if match.direction == 'before' then match.cell.before(jQuery(cell).clone()) else match.cell.after(jQuery(cell).clone())
+    if @columnsFor(@row.find('td, th')) < @columnCount
+      # move up rows looking for cells with rowspans that might intersect
+      rowsAbove = 0
+      for aboveRow in @row.prevAll('tr')
+        rowsAbove += 1
+        for cell in jQuery(aboveRow).find('td[rowspan], th[rowspan]')
+          # if the cell intersects with the row we're trying to calculate on, and it's index is less than where we've
+          # gotten so far, add it
+          rowspan = @rowspanFor(cell)
+          @setRowspanFor(cell, rowspan - @rowspanFor(@cell)) if rowspan > rowsAbove
+    @row.remove()
+  increaseColspan: ->
+    cell = @cell.next('td, th')
+    return unless cell.length
+    return if @rowspanFor(cell) != @rowspanFor(@cell)
+    return if @cellIndexFor(cell) > @cellIndexFor(@cell) + @colspanFor(@cell)
+    @setColspanFor(@cell, @colspanFor(@cell) + @colspanFor(cell))
+    cell.remove()
+  decreaseColspan: ->
+    return if @colspanFor(@cell) == 1
+    @setColspanFor(@cell, @colspanFor(@cell) - 1)
+    newCell = jQuery("<#{@cell.get(0).tagName}>").html(@cellContent)
+    @setRowspanFor(newCell, @rowspanFor(@cell))
+    @cell.after(newCell)
+  increaseRowspan: ->
+    sig = @cellSignatureFor(@cell)
+    nextRow = @row.nextAll('tr')[sig.height - 1]
+    if nextRow && match = @findCellByOptionsFor(nextRow, {left: sig.left, width: sig.width})
+      @setRowspanFor(@cell, sig.height + match.height)
+      match.cell.remove()
+  decreaseRowspan: ->
+    sig = @cellSignatureFor(@cell)
+    return if sig.height == 1
+    nextRow = @row.nextAll('tr')[sig.height - 2]
+    if match = @findCellByOptionsFor(nextRow, {left: sig.left, forceAdjacent: true})
+      newCell = jQuery("<#{@cell.get(0).tagName}>").html(@cellContent)
+      @setColspanFor(newCell, @colspanFor(@cell))
+      @setRowspanFor(@cell, sig.height - 1)
+      if match.direction == 'before' then match.cell.before(newCell) else match.cell.after(newCell)
+  # Counts the columns of the first row (alpha row) in the table.  We can safely rely on the first row always being
+  # comprised of a full set of cells or cells with colspans.
+  getColumnCount: ->
+    return @columnsFor(@table.find('thead tr:first-child, tbody tr:first-child, tfoot tr:first-child').first().find('td, th'))
+  # Counts the rows of the table.
+  getRowCount: ->
+    return @table.find('tr').length
+  # Gets the index for a given cell, taking into account that rows above it can have cells that have rowspans.
+  cellIndexFor: (cell) ->
+    cell = jQuery(cell)
+    # get the row for the cell and calculate all the columns in it
+    row = cell.parent('tr')
+    columns = @columnsFor(row.find('td, th'))
+    index = @columnsFor(cell.prevAll('td, th'))
+    # if the columns is less than expected, we need to look above for rowspans
+    if columns < @columnCount
+      # move up rows looking for cells with rowspans that might intersect
+      rowsAbove = 0
+      for aboveRow in row.prevAll('tr')
+        rowsAbove += 1
+        for aboveCell in jQuery(aboveRow).find('td[rowspan], th[rowspan]')
+          # if the cell intersects with the row we're trying to calculate on, and it's index is less than where we've
+          # gotten so far, add it
+          if @rowspanFor(aboveCell) > rowsAbove && @cellIndexFor(aboveCell) <= index
+            index += @colspanFor(aboveCell)
+    return index
+  # Creates a signature for a given cell, which is made up if it's size, and itself.
+  cellSignatureFor: (cell) ->
+    sig = {cell: jQuery(cell)}
+    sig.left = @cellIndexFor(cell)
+    sig.width = @colspanFor(cell)
+    sig.height = @rowspanFor(cell)
+    sig.right = sig.left + sig.width
+    return sig
+  # Find a cell based on options.  Options can be:
+  # right
+  # or
+  # left, [width], [forceAdjacent]
+  # eg. findCellByOptionsFor(@row, {left: 1, width: 2, forceAdjacent: true})
+  findCellByOptionsFor: (row, options) ->
+    for cell in jQuery(row).find('td, th')
+      sig = @cellSignatureFor(cell)
+      if typeof(options.right) != 'undefined'
+        return sig if sig.right == options.right
+      if typeof(options.left) != 'undefined'
+        if options.width
+          return sig if sig.left == options.left && sig.width == options.width
+        else if !options.forceAdjacent
+          return sig if sig.left == options.left
+        else if options.forceAdjacent
+          if sig.left > options.left
+            prev = jQuery(cell).prev('td, th')
+            if prev.length
+              sig = @cellSignatureFor(prev)
+              sig.direction = 'after'
+            else
+              sig.direction = 'before'
+            return sig
+    if options.forceAdjacent
+      sig.direction = 'after'
+      return sig
+    return null
+  # Finds a cell that intersects with the current signature
+  findCellByIntersectionFor: (row, signature) ->
+    for cell in jQuery(row).find('td, th')
+      sig = @cellSignatureFor(cell)
+      return sig if sig.right - signature.left >= 0 && sig.right > signature.left
+    return null
+  # Counts all the columns in a given array of columns, taking colspans into
+  # account.
+  columnsFor: (cells) ->
+    count = 0
+    count += @colspanFor(cell) for cell in cells
+    return count
+  # Tries to get the colspan of a cell, falling back to 1 if there's none
+  # specified.
+  colspanFor: (cell) ->
+    return parseInt(jQuery(cell).attr('colspan')) || 1
+  # Tries to get the rowspan of a cell, falling back to 1 if there's none
+  # specified.
+  rowspanFor: (cell) ->
+    return parseInt(jQuery(cell).attr('rowspan')) || 1
+  # Sets the colspan of a cell, removing it if it's 1.
+  setColspanFor: (cell, value) ->
+    jQuery(cell).attr('colspan', if value > 1 then value else null)
+  # Sets the rowspan of a cell, removing it if it's 1
+  setRowspanFor: (cell, value) ->
+    jQuery(cell).attr('rowspan', if value > 1 then value else null)

data/vendor/assets/javascripts/mercury/toolbar.button.js.coffee ADDED Viewed

@@ -0,0 +1,173 @@
+class @Mercury.Toolbar.Button
+  constructor: (@name, @title, @summary = null, @types = {}, @options = {}) ->
+    @title = Mercury.I18n(@title) if @title
+    @summary = Mercury.I18n(@summary) if @summary
+    @build()
+    @bindEvents()
+    return @element
+  build: ->
+    @element = jQuery('<div>', {title: @summary ? @title, class: "mercury-button mercury-#{@name}-button"}).html("<em>#{@title}</em>")
+    @element.data('expander', "<div class=\"mercury-expander-button\" data-button=\"#{@name}\"><em></em><span>#{@title}</span></div>")
+    @handled = {}
+    for own type, mixed of @types
+      switch type
+        when 'preload' then true
+        when 'regions'
+          @element.addClass('disabled')
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+        when 'toggle'
+          @handled[type] = true
+        when 'mode'
+          @handled[type] = if mixed == true then @name else mixed
+        when 'context'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed else Mercury.Toolbar.Button.contexts[@name]
+        when 'palette'
+          @element.addClass("mercury-button-palette")
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled[type] = new Mercury.Palette(url, @name, @defaultDialogOptions())
+        when 'select'
+          @element.addClass("mercury-button-select").find('em').html(@title)
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled[type] = new Mercury.Select(url, @name, @defaultDialogOptions())
+        when 'panel'
+          @element.addClass('mercury-button-panel')
+          url = if jQuery.isFunction(mixed) then mixed.call(@, @name) else mixed
+          @handled['toggle'] = true
+          @handled[type] = new Mercury.Panel(url, @name, @defaultDialogOptions())
+        when 'modal'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.apply(@, @name) else mixed
+        when 'lightview'
+          @handled[type] = if jQuery.isFunction(mixed) then mixed.apply(@, @name) else mixed
+        else throw Mercury.I18n('Unknown button type \"%s\" used for the \"%s\" button.', type, @name)
+  bindEvents: ->
+    Mercury.on 'button', (event, options) => @element.click() if options.action == @name
+    Mercury.on 'mode', (event, options) => @togglePressed() if @handled.mode == options.mode && @handled.toggle
+    Mercury.on 'region:update', (event, options) =>
+      if @handled.context && options.region && jQuery.type(options.region.currentElement) == 'function'
+        element = options.region.currentElement()
+        if element.length && @handled.context.call(@, element, options.region.element)
+          @element.addClass('active')
+        else
+          @element.removeClass('active')
+      else
+        @element.removeClass('active')
+    Mercury.on 'region:focused', (event, options) =>
+      if @handled.regions && options.region && options.region.type
+        if @handled.regions.indexOf(options.region.type) > -1
+          @element.removeClass('disabled')
+        else
+          @element.addClass('disabled')
+    Mercury.on 'region:blurred', =>
+      @element.addClass('disabled') if @handled.regions
+    @element.on 'mousedown', =>
+      @element.addClass('active')
+    @element.on 'mouseup', =>
+      @element.removeClass('active')
+    @element.on 'click', (event) =>
+      if @element.closest('.disabled').length then return
+      handled = false
+      for own type, mixed of @handled
+        switch type
+          when 'toggle'
+            @togglePressed() unless @handled.mode
+          when 'mode'
+            handled = true
+            Mercury.trigger('mode', {mode: mixed})
+          when 'modal'
+            handled = true
+            Mercury.modal(@handled.modal, {title: @summary || @title, handler: @name})
+          when 'lightview'
+            handled = true
+            Mercury.lightview(@handled.lightview, {title: @summary || @title, handler: @name, closeButton: true})
+          when 'palette', 'select', 'panel'
+            event.stopPropagation()
+            handled = true
+            @handled[type].toggle()
+      Mercury.trigger('action', {action: @name}) unless handled
+      Mercury.trigger('focus:frame') if @options['regions'] && @options['regions'].length
+  defaultDialogOptions: ->
+    return {
+      title: @summary || @title
+      preload: @types.preload
+      appendTo: @options.appendDialogsTo || 'body'
+      closeButton: true
+      for: @element
+    }
+  togglePressed: ->
+    @element.toggleClass('pressed')
+# Button contexts
+@Mercury.Toolbar.Button.contexts =
+  backColor: (node) -> @element.css('background-color', node.css('background-color'))
+  foreColor: (node) -> @element.css('background-color', node.css('color'))
+  bold: (node) ->
+    weight = node.css('font-weight')
+    weight == 'bold' || weight > 400
+  italic: (node) -> node.css('font-style') == 'italic'
+  # overline is weird because <u> and <strike> override text-decoration -- we can't always tell without checking parents
+  overline: (node) ->
+    return true if node.css('text-decoration') == 'overline'
+    for parent in node.parentsUntil(@element)
+      return true if jQuery(parent).css('text-decoration') == 'overline'
+    return false
+  strikethrough: (node, region) -> node.css('text-decoration') == 'line-through' || !!node.closest('strike', region).length
+  underline: (node, region) -> node.css('text-decoration') == 'underline' || !!node.closest('u', region).length
+  subscript: (node, region) -> !!node.closest('sub', region).length
+  superscript: (node, region) -> !!node.closest('sup', region).length
+  justifyLeft: (node) -> node.css('text-align').indexOf('left') > -1
+  justifyCenter: (node) -> node.css('text-align').indexOf('center') > -1
+  justifyRight: (node) -> node.css('text-align').indexOf('right') > -1
+  justifyFull: (node) -> node.css('text-align').indexOf('justify') > -1
+  insertOrderedList: (node, region) -> !!node.closest('ol', region.element).length
+  insertUnorderedList: (node, region) -> !!node.closest('ul', region.element).length

data/vendor/assets/javascripts/mercury/toolbar.button_group.js.coffee ADDED Viewed

@@ -0,0 +1,42 @@
+class @Mercury.Toolbar.ButtonGroup
+  constructor: (@name, @options = {}) ->
+    @build()
+    @bindEvents()
+    @regions = @options._regions
+    return @element
+  build: ->
+    @element = jQuery('<div>', {class: "mercury-button-group mercury-#{@name}-group"})
+    if @options._context || @options._regions
+      @element.addClass('disabled')
+  bindEvents: ->
+    Mercury.on 'region:update', (event, options) =>
+      context = Mercury.Toolbar.ButtonGroup.contexts[@name]
+      if context
+        if options.region && jQuery.type(options.region.currentElement) == 'function'
+          element = options.region.currentElement()
+          if element.length && context.call(@, element, options.region.element)
+            @element.removeClass('disabled')
+          else
+            @element.addClass('disabled')
+    Mercury.on 'region:focused', (event, options) =>
+      if @regions && options.region && options.region.type
+        if @regions.indexOf(options.region.type) > -1
+          @element.removeClass('disabled') unless @options._context
+        else
+          @element.addClass('disabled')
+    Mercury.on 'region:blurred', (event, options) =>
+      @element.addClass('disabled') if @options.regions
+# ButtonGroup contexts
+@Mercury.Toolbar.ButtonGroup.contexts =
+  table: (node, region) -> !!node.closest('table', region).length

data/vendor/assets/javascripts/mercury/toolbar.expander.js.coffee ADDED Viewed

@@ -0,0 +1,56 @@
+class @Mercury.Toolbar.Expander extends Mercury.Palette
+  constructor: (@name, @options) ->
+    @container = @options.for
+    @containerWidth = @container.outerWidth()
+    super(null, @name, @options)
+    return @element
+  build: ->
+    @container.css({whiteSpace: 'normal'})
+    @trigger = jQuery('<div>', {class: 'mercury-toolbar-expander'}).appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+    @element = jQuery('<div>', {class: "mercury-palette mercury-expander mercury-#{@name}-expander", style: 'display:none'})
+    @windowResize()
+  bindEvents: ->
+    Mercury.on 'hide:dialogs', (event, dialog) => @hide() unless dialog == @
+    Mercury.on 'resize', => @windowResize()
+    super
+    @trigger.click (event) =>
+      event.stopPropagation()
+      hiddenButtons = []
+      for button in @container.find('.mercury-button')
+        button = jQuery(button)
+        hiddenButtons.push(button.data('expander')) if button.position().top > 5
+      @loadContent(hiddenButtons.join(''))
+      @toggle()
+    @element.click (event) =>
+      buttonName = jQuery(event.target).closest('[data-button]').data('button')
+      button = @container.find(".mercury-#{buttonName}-button")
+      button.click()
+  windowResize: ->
+    if @containerWidth > jQuery(window).width() then @trigger.show() else @trigger.hide()
+    @hide()
+  position: (keepVisible) ->
+    @element.css({top: 0, left: 0, display: 'block', visibility: 'hidden'})
+    position = @trigger.offset()
+    width = @element.width()
+    position.left = position.left - width + @trigger.width() if position.left + width > jQuery(window).width()
+    @element.css {
+      top: position.top + @trigger.height()
+      left: position.left
+      display: if keepVisible then 'block' else 'none'
+      visibility: 'visible'
+    }