kiteditor 1.0.1

data/vendor/assets/javascripts/mercury/page_editor.js.coffee

@@ -0,0 +1,241 @@
+class @Mercury.PageEditor
+
+  # options
+  # saveStyle: 'form', or 'json' (defaults to json)
+  # saveDataType: 'xml', 'json', 'jsonp', 'script', 'text', 'html' (defaults to json)
+  # saveMethod: 'POST', or 'PUT', create or update actions on save (defaults to POST)
+  # visible: boolean, if the interface should start visible or not (defaults to true)
+  constructor: (@saveUrl = null, @options = {}) ->
+    throw Mercury.I18n('Mercury.PageEditor can only be instantiated once.') if window.mercuryInstance
+
+    @options.visible = true unless (@options.visible == false || @options.visible == 'no')
+    @visible = @options.visible
+
+    window.mercuryInstance = @
+    @regions = []
+    @initializeInterface()
+    Mercury.csrfToken = token if token = jQuery(Mercury.config.csrfSelector).attr('content')
+
+
+  initializeInterface: ->
+    @focusableElement = jQuery('<input>', {class: 'mercury-focusable', type: 'text'}).appendTo(@options.appendTo ? 'body')
+
+    @iframe = jQuery('<iframe>', {id: 'mercury_iframe', class: 'mercury-iframe', seamless: 'true', frameborder: '0', src: 'about:blank'})
+    @iframe.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+    @toolbar = new Mercury.Toolbar(@options)
+    @statusbar = new Mercury.Statusbar(@options)
+    @resize()
+
+    @iframe.on 'load', => @initializeFrame()
+    @iframe.get(0).contentWindow.document.location.href = @iframeSrc(null, true)
+
+
+  initializeFrame: ->
+    try
+      return if @iframe.data('loaded')
+      @iframe.data('loaded', true)
+      Mercury.notify("Opera isn't a fully supported browser, your results may not be optimal.") if jQuery.browser.opera
+      @document = jQuery(@iframe.get(0).contentWindow.document)
+      stylesToInject = Mercury.config.injectedStyles.replace(/{{regionClass}}/g, Mercury.config.regions.className)
+      jQuery("<style mercury-styles=\"true\">").html(stylesToInject).appendTo(@document.find('head'))
+
+      # jquery: make jQuery evaluate scripts within the context of the iframe window
+      iframeWindow = @iframe.get(0).contentWindow
+      jQuery.globalEval = (data) -> (iframeWindow.execScript || (data) -> iframeWindow["eval"].call(iframeWindow, data))(data) if (data && /\S/.test(data))
+
+      iframeWindow.Mercury = Mercury
+      iframeWindow.History = History if window.History && History.Adapter
+
+      @bindEvents()
+      @resize()
+      @initializeRegions()
+      @finalizeInterface()
+      Mercury.trigger('ready')
+      jQuery(iframeWindow).trigger('mercury:ready')
+      iframeWindow.Event.fire(iframeWindow, 'mercury:ready') if iframeWindow.Event && iframeWindow.Event.fire
+      iframeWindow.onMercuryReady() if iframeWindow.onMercuryReady
+
+      @iframe.css({visibility: 'visible'})
+    catch error
+      Mercury.notify('Mercury.PageEditor failed to load: %s\n\nPlease try refreshing.', error)
+
+
+  initializeRegions: ->
+    @regions = []
+    @buildRegion(jQuery(region)) for region in jQuery(".#{Mercury.config.regions.className}", @document)
+    return unless @options.visible
+    for region in @regions
+      if region.focus
+        region.focus()
+        break
+
+
+  buildRegion: (region) ->
+    if region.data('region')
+      region = region.data('region')
+    else
+      type = (
+        region.data('type') ||
+        ( jQuery.type(Mercury.config.regions.determineType) == 'function' && Mercury.config.regions.determineType(region) ) ||
+        'unknown'
+      ).titleize()
+      throw Mercury.I18n('Region type is malformed, no data-type provided, or "%s" is unknown for the "%s" region.', type, region.attr('id') || 'unknown') if type == 'Unknown' || !Mercury.Regions[type]
+      if !Mercury.Regions[type].supported
+        Mercury.notify('Mercury.Regions.%s is unsupported in this client. Supported browsers are %s.', type, Mercury.Regions[type].supportedText)
+        return false
+      region = new Mercury.Regions[type](region, @iframe.get(0).contentWindow)
+      region.togglePreview() if @previewing
+    @regions.push(region)
+
+
+  finalizeInterface: ->
+    @santizerElement = jQuery('<div>', {id: 'mercury_sanitizer', contenteditable: 'true', style: 'position:fixed;width:100px;height:100px;top:0;left:-100px;opacity:0;overflow:hidden'})
+    @santizerElement.appendTo(@options.appendTo ? @document.find('body'))
+
+    @snippetToolbar = new Mercury.SnippetToolbar(@document)
+
+    @hijackLinksAndForms()
+    Mercury.trigger('mode', {mode: 'preview'}) unless @options.visible
+
+
+  bindEvents: ->
+    Mercury.on 'autosave', =>  @autosave()
+    Mercury.on 'initialize:frame', => setTimeout(100, @initializeFrame)
+    Mercury.on 'focus:frame', => @iframe.focus()
+    Mercury.on 'focus:window', => setTimeout(10, => @focusableElement.focus())
+    Mercury.on 'toggle:interface', => @toggleInterface()
+    Mercury.on 'reinitialize', => @initializeRegions()
+    Mercury.on 'mode', (event, options) => @previewing = !@previewing if options.mode == 'preview'
+    Mercury.on 'action', (event, options) =>
+      action = Mercury.config.globalBehaviors[options.action] || @[options.action]
+      return unless typeof(action) == 'function'
+      options.already_handled = true
+      action.call(@, options)
+
+    @document.on 'mousedown', (event) ->
+      Mercury.trigger('hide:dialogs')
+      if Mercury.region
+        Mercury.trigger('unfocus:regions') unless jQuery(event.target).closest(".#{Mercury.config.regions.className}").get(0) == Mercury.region.element.get(0)
+
+    jQuery(window).on 'resize', =>
+      @resize()
+
+    jQuery(@document).bind 'keydown', (event) =>
+      return unless event.ctrlKey || event.metaKey
+      if (event.keyCode == 83) # meta+S
+        Mercury.trigger('action', {action: 'save'})
+        event.preventDefault()
+
+    jQuery(window).bind 'keydown', (event) =>
+      return unless event.ctrlKey || event.metaKey
+      if (event.keyCode == 83) # meta+S
+        Mercury.trigger('action', {action: 'save'})
+        event.preventDefault()
+
+    window.onbeforeunload = @beforeUnload
+
+
+  toggleInterface: ->
+    if @visible
+      Mercury.trigger('mode', {mode: 'preview'}) if @previewing
+      @visible = false
+      @toolbar.hide()
+      @statusbar.hide()
+    else
+      @visible = true
+      @toolbar.show()
+      @statusbar.show()
+    Mercury.trigger('mode', {mode: 'preview'})
+    @resize()
+
+
+  resize: ->
+    width = jQuery(window).width()
+    height = @statusbar.top()
+    toolbarHeight = @toolbar.height()
+
+    Mercury.displayRect = {top: toolbarHeight, left: 0, width: width, height: height - toolbarHeight, fullHeight: height}
+
+    @iframe.css {
+      top: toolbarHeight
+      left: 0
+      height: height - toolbarHeight
+    }
+
+    Mercury.trigger('resize')
+
+
+  iframeSrc: (url = null, params = false) ->
+    url = (url ? window.location.href).replace(Mercury.config.editorUrlRegEx ?= /([http|https]:\/\/.[^\/]*)\/editor\/?(.*)/i,  "$1/$2")
+    url = url.replace(/[\?|\&]mercury_frame=true/gi, '')
+    if params
+      return "#{url}#{if url.indexOf('?') > -1 then '&' else '?'}mercury_frame=true"
+    else
+      return url
+
+
+  hijackLinksAndForms: ->
+    for element in jQuery('a, form', @document)
+      ignored = false
+      for classname in Mercury.config.nonHijackableClasses || []
+        if jQuery(element).hasClass(classname)
+          ignored = true
+          continue
+      if !ignored && (element.target == '' || element.target == '_self') && !jQuery(element).closest(".#{Mercury.config.regions.className}").length
+        jQuery(element).attr('target', '_parent')
+
+
+  beforeUnload: ->
+    if Mercury.changes && !Mercury.silent
+      return Mercury.I18n('You might have unsaved changes.  Are you sure you want to leave without saving them first?')
+    Mercury.trigger('unload')
+    return null
+
+
+  getRegionByName: (id) ->
+    for region in @regions
+      return region if region.name == id
+    return null
+
+  autosave: ->
+    Mercury.log("Autosave")
+    url = @saveUrl ? Mercury.saveURL ? @iframeSrc()
+    data = @serialize()
+    data = jQuery.toJSON(data) unless @options.saveStyle == 'form'
+    method = 'PUT' if @options.saveMethod == 'PUT'
+    jQuery.ajax url+"&auto=1", {
+      headers: Mercury.ajaxHeaders()
+      type: method || 'POST'
+      dataType: @options.saveDataType || 'json'
+      data: {content: data, _method: method}
+      success: =>
+        Mercury.trigger('autosaved')
+    }
+
+  save: (callback) ->
+    url = @saveUrl ? Mercury.saveURL ? @iframeSrc()
+    data = @serialize()
+    Mercury.log('saving', data)
+    data = jQuery.toJSON(data) unless @options.saveStyle == 'form'
+    method = 'PUT' if @options.saveMethod == 'PUT'
+    jQuery.ajax url, {
+      headers: Mercury.ajaxHeaders()
+      type: method || 'POST'
+      dataType: @options.saveDataType || 'json'
+      data: {content: data, _method: method}
+      success: =>
+        Mercury.changes = false
+        Mercury.trigger('saved')
+        callback() if typeof(callback) == 'function'
+      error: =>
+        Mercury.notify('Mercury was unable to save to the url: %s', url)
+    }
+
+
+  serialize: ->
+    serialized = {}
+    for region in @regions
+      Mercury.log("region", region)
+      serialized[region.name] = region.serialize() 
+    return serialized

data/vendor/assets/javascripts/mercury/palette.js.coffee

@@ -0,0 +1,29 @@
+class @Mercury.Palette extends Mercury.Dialog
+
+  constructor: (@url, @name, @options = {}) ->
+    super
+
+
+  build: ->
+    @element = jQuery('<div>', {class: "mercury-palette mercury-#{@name}-palette loading", style: 'display:none'})
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'hide:dialogs', (event, dialog) => @hide() unless dialog == @
+    super
+
+
+  position: (keepVisible) ->
+    @element.css({top: 0, left: 0, display: 'block', visibility: 'hidden'})
+    position = @button.offset()
+    width = @element.width()
+
+    position.left = position.left - width + @button.width() if position.left + width > jQuery(window).width()
+
+    @element.css {
+      top: position.top + @button.height()
+      left: position.left
+      display: if keepVisible then 'block' else 'none'
+      visibility: 'visible'
+    }

data/vendor/assets/javascripts/mercury/panel.js.coffee

@@ -0,0 +1,115 @@
+class @Mercury.Panel extends Mercury.Dialog
+
+  constructor: (@url, @name, @options = {}) ->
+    super
+
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-panel loading', style: 'display:none;'})
+    @titleElement = jQuery("<h1>#{Mercury.I18n(@options.title)}</h1>").appendTo(@element)
+    @paneElement = jQuery('<div>', {class: 'mercury-panel-pane'}).appendTo(@element)
+
+    if @options.closeButton
+      jQuery('<a/>', {class: 'mercury-panel-close'}).appendTo(@titleElement).css({opacity: 0})
+
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'resize', => @position(@visible)
+
+    Mercury.on 'hide:panels', (event, panel) =>
+      return if panel == @
+      @button.removeClass('pressed')
+      @hide()
+
+    @titleElement.find('.mercury-panel-close').on 'click', (event) ->
+      event.preventDefault()
+      Mercury.trigger('hide:panels')
+
+    @element.on 'mousedown', (event) ->
+      event.stopPropagation()
+
+    @element.on 'ajax:beforeSend', (event, xhr, options) =>
+      options.success = (content) =>
+        @loadContent(content)
+        @resize()
+
+    super
+
+
+  show: ->
+    Mercury.trigger('hide:panels', @)
+    super
+
+
+  resize: ->
+    @titleElement.find('.mercury-panel-close').css({opacity: 0})
+    @paneElement.css({display: 'none'})
+    preWidth = @element.width()
+
+    @paneElement.css({visibility: 'hidden', width: 'auto', display: 'block'})
+    postWidth = @element.width()
+
+    @paneElement.css({visibility: 'visible', display: 'none'})
+    position = @element.offset()
+    @element.animate {left: position.left - (postWidth - preWidth), width: postWidth}, 200, 'easeInOutSine', =>
+      @titleElement.find('.mercury-panel-close').animate({opacity: 1}, 100)
+
+      @paneElement.css({display: 'block', width: postWidth})
+      @makeDraggable()
+
+    @hide() unless @visible
+
+
+  position: (keepVisible) ->
+    @element.css({display: 'block', visibility: 'hidden'})
+    offset = @element.offset()
+    elementWidth = @element.width()
+    height = Mercury.displayRect.height - 16
+
+    paneHeight = height - @titleElement.outerHeight()
+    @paneElement.css({height: paneHeight, overflowY: if paneHeight < 30 then 'hidden' else 'auto'})
+
+    left = Mercury.displayRect.width - elementWidth - 20 unless @moved
+    left = 8 if left <= 8
+
+    if @pinned || elementWidth + offset.left > Mercury.displayRect.width - 20
+      left = Mercury.displayRect.width - elementWidth - 20
+
+    @element.css {
+      top: Mercury.displayRect.top + 8,
+      left: left,
+      height: height,
+      display: if keepVisible then 'block' else 'none',
+      visibility: 'visible'
+    }
+
+    @makeDraggable()
+    @element.hide() unless keepVisible
+
+
+  loadContent: (data) ->
+    @loaded = true
+    @element.removeClass('loading')
+    @paneElement.css({visibility: 'hidden'})
+    @paneElement.html(data)
+    @paneElement.localize(Mercury.locale()) if Mercury.config.localization.enabled
+
+
+  makeDraggable: ->
+    elementWidth = @element.width()
+    @element.draggable {
+      handle: 'h1',
+      axis: 'x',
+      opacity: 0.70
+      scroll: false,
+      addClasses: false,
+      iframeFix: true,
+      containment: [8, 0, Mercury.displayRect.width - elementWidth - 20, 0]  #[x1, y1, x2, y2]
+      stop: =>
+        left = @element.offset().left
+        @moved = true
+        @pinned = if left > Mercury.displayRect.width - elementWidth - 30 then true else false
+        return true
+    }

data/vendor/assets/javascripts/mercury/plugins/save_as_xml/mercury/page_editor.js.coffee

@@ -0,0 +1,28 @@
+class Mercury.PageEditor extends Mercury.PageEditor
+
+  save: ->
+    url = @saveUrl ? Mercury.saveURL ? @iframeSrc()
+    data = @serializeAsXml()
+    console.log('saving', data)
+    return
+    method = 'PUT' if @options.saveMethod == 'PUT'
+    jQuery.ajax url, {
+      headers: Mercury.ajaxHeaders()
+      type: method || 'POST'
+      dataType: 'xml'
+      data: data
+      success: =>
+        Mercury.changes = false
+      error: =>
+        alert("Mercury was unable to save to the url: #{url}")
+    }
+
+  serializeAsXml: ->
+    data = @serialize()
+    regionNodes = []
+    for regionName, regionProperties of data
+      snippetNodes = []
+      for snippetName, snippetProperties of regionProperties['snippets']
+        snippetNodes.push("<#{snippetName} name=\"#{snippetProperties['name']}\"><![CDATA[#{jQuery.toJSON(snippetProperties['options'])}]]></#{snippetName}>")
+      regionNodes.push("<region name=\"#{regionName}\" type=\"#{regionProperties['type']}\"><value>\n<![CDATA[#{regionProperties['value']}]]>\n</value><snippets>#{snippetNodes.join('')}</snippets></region>")
+    return "<regions>#{regionNodes.join('')}</regions>"

data/vendor/assets/javascripts/mercury/plugins/save_as_xml/plugin.js

@@ -0,0 +1,9 @@
+/*!
+ * This is an example plugin that will serialize to XML instead of JSON before saving.  This could be useful to someone,
+ * but is mostly provided as an example of how to write a simple plugin.
+ *
+ * This file is could be a nice place to provide configuration options for your plugin.
+ *
+ *= require_self
+ *= require_tree ./mercury
+ */

data/vendor/assets/javascripts/mercury/region.js.coffee

@@ -0,0 +1,107 @@
+class @Mercury.Region
+  type = 'region'
+
+  constructor: (@element, @window, @options = {}) ->
+    @type = 'region' unless @type
+    Mercury.log("building #{@type}", @element, @options)
+
+    @document = @window.document
+    @name = @element.attr(Mercury.config.regions.identifier)
+    @history = new Mercury.HistoryBuffer()
+    @build()
+    @bindEvents()
+    @pushHistory()
+    @element.data('region', @)
+
+
+  build: ->
+
+
+  focus: ->
+
+
+  bindEvents: ->
+    Mercury.on 'mode', (event, options) => @togglePreview() if options.mode == 'preview'
+
+    Mercury.on 'focus:frame', =>
+      return if @previewing || Mercury.region != @
+      @focus()
+
+    Mercury.on 'action', (event, options) =>
+      return if @previewing || Mercury.region != @
+      @execCommand(options.action, options) if options.action
+
+    @element.on 'mousemove', (event) =>
+      return if @previewing || Mercury.region != @
+      snippet = jQuery(event.target).closest('.mercury-snippet')
+      if snippet.length
+        @snippet = snippet
+        Mercury.trigger('show:toolbar', {type: 'snippet', snippet: @snippet})
+
+    @element.on 'mouseout', =>
+      return if @previewing
+      Mercury.trigger('hide:toolbar', {type: 'snippet', immediately: false})
+
+
+  content: (value = null, filterSnippets = false) ->
+    if value != null
+      @element.html(value)
+    else
+      # sanitize the html before we return it
+      container = jQuery('<div>').appendTo(@document.createDocumentFragment())
+      container.html(@element.html().replace(/^\s+|\s+$/g, ''))
+
+      # replace snippet contents to be an identifier
+      if filterSnippets then for snippet in container.find('.mercury-snippet')
+        snippet = jQuery(snippet)
+        snippet.attr({contenteditable: null, 'data-version': null})
+        snippet.html("[#{snippet.data('snippet')}]")
+
+      return container.html()
+
+
+  togglePreview: ->
+    if @previewing
+      @previewing = false
+      @element.addClass(Mercury.config.regions.className).removeClass("#{Mercury.config.regions.className}-preview")
+      @focus() if Mercury.region == @
+    else
+      @previewing = true
+      @element.addClass("#{Mercury.config.regions.className}-preview").removeClass(Mercury.config.regions.className)
+      Mercury.trigger('region:blurred', {region: @})
+
+
+  execCommand: (action, options = {}) ->
+    @focus()
+    @pushHistory() unless action == 'redo'
+
+    Mercury.log('execCommand', action, options.value)
+    Mercury.changes = true unless options.already_handled
+
+
+  pushHistory: ->
+    @history.push(@content())
+
+
+  snippets: ->
+    snippets = {}
+    for element in @element.find('[data-snippet]')
+      snippet = Mercury.Snippet.find(jQuery(element).data('snippet'))
+      snippet.setVersion(jQuery(element).data('version'))
+      snippets[snippet.identity] = snippet.serialize()
+    return snippets
+
+
+  dataAttributes: ->
+    data = {}
+    o = if @type=='simple' then jQuery(this.container[0]) else @element
+    data[attr] = o.attr('data-' + attr) for attr in Mercury.config.regions.dataAttributes
+    return data
+
+  serialize: ->
+    return {
+      type: @type
+      data: @dataAttributes()
+      value: @content(null, true)
+      snippets: @snippets()
+    }