kiteditor 1.0.1

data/vendor/assets/javascripts/mercury/dialog.js.coffee

@@ -0,0 +1,159 @@
+# # Mercury Dialog
+#
+# Dialog is a base class that's used by Palette, Select, Panel, and through Palette, the Toolbar.Expander.  It's basic
+# function is to provide an interface element that can be opened, interacted with, and then closed.
+#
+class @Mercury.Dialog
+
+  # The constructor expects a url to load, a name, and options.
+  #
+  # @url _string_ used to load the contents, either using Ajax or by pulling content from preloadedViews
+  #
+  # @name _string_ used in building of the element, and is assigned as part of the elements class (eg.
+  #     `mercury-[name]-dialog`)
+  #
+  # @options _object_
+  #
+  # **Options**
+  #
+  # @for _Toolbar.Button_ used so the dialog can be shown/hidden based on button interactions.
+  #
+  # @preload _boolean_ if true, the view for this dialog will be loaded prior to being shown, otherwise the view will be
+  #     loaded the first time it's shown, and cached for all future interactions.
+  #
+  # @appendTo _element_ you can append a dialog to any element by providing this option.
+  constructor: (@url, @name, @options = {}) ->
+    @button = @options.for
+
+    @build()
+    @bindEvents()
+    @preload()
+
+
+  # ## #build
+  #
+  # Builds the element and appends it to the DOM.  You can provide an element to append it to in the options, otherwise
+  # it will be appended to the body.
+  build: ->
+    @element = jQuery('<div>', {class: "mercury-dialog mercury-#{@name}-dialog loading", style: 'display:none'})
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  # ## #bindEvents
+  #
+  # Bind to all the events we should handle.  In this case we only stop the mousedown event, since dialogs aren't
+  # expected to have inputs etc.
+  #
+  # **Note:** By stopping the mousedown event we're limiting what's possible in dialogs, but this is needed to keep
+  # focus from being taken away from the active region when different things are clicked on in dialogs.
+  bindEvents: ->
+    @element.on 'mousedown', (event) ->
+      event.stopPropagation()
+
+
+  # ## #preload
+  #
+  # If the options dictate that the content should be preloaded we load the view before we do anything else.  This is
+  # useful if you don't want to make the user wait the half second or however long the server may take to respond when
+  # they open various dialogs.
+  preload: ->
+    @load() if @options.preload
+
+
+  # ## #toggle
+  #
+  # Toggle the dialog based on current visibility.
+  toggle: ->
+    if @visible then @hide() else @show()
+
+
+  # ## #resize
+  #
+  # In the base class resize just calls through to show, but in the implementation classes resize typically adjusts the
+  # size based on it's contents.
+  resize: ->
+    @show()
+
+
+  # ## #show
+  #
+  # When showing a dialog it's expected that all other dialogs will close, and we fire an event for this.  The dialog is
+  # then positioned and shown.  The show animation of the dialog is typically dictated by the implementation class.
+  show: ->
+    # Tell all other dialogs to close.
+    Mercury.trigger('hide:dialogs', @)
+    @visible = true
+    if @loaded
+      @element.css({width: 'auto', height: 'auto'})
+      @position(@visible)
+    else
+      @position()
+    # Then show the element.
+    @appear()
+
+
+  # ## #position
+  #
+  # Interface method.  Implementations are expected to position the dialog themselves.
+  #
+  # @keepVisible _boolean_ specifies if the element should stay visible if it's already visible.
+  position: (keepVisible) ->
+
+
+  # ## #appear
+  #
+  # Animate the element into view.  After it's done showing, we load and resize it if it's not already loaded, so in
+  # cases where content is not preloaded we can display the dialog, fill it's contents, and then animate the resize.
+  appear: ->
+    @element.css({display: 'block', opacity: 0})
+    @element.animate {opacity: 0.95}, 200, 'easeInOutSine', =>
+      @load(=> @resize()) unless @loaded
+
+
+  # ## #hide
+  #
+  # Hides the element and keeps track of it's visibility.
+  hide: ->
+    @element.hide()
+    @visible = false
+
+
+  # ## #load
+  #
+  # Fetches the content that will be loaded into the dialog.
+  #
+  # @callback _function_ will be called after the content is loaded.
+  load: (callback) ->
+    return unless @url
+    if Mercury.preloadedViews[@url]
+      # If there's a preloadedView defined for the url being requested, load that one.
+      @loadContent(Mercury.preloadedViews[@url])
+      # And call the dialog handler if there's one.  We've broken the handlers out into separate files so they can be
+      # tested more easily, but you can define your own by putting them in dialogHandlers.
+      Mercury.dialogHandlers[@name].call(@) if Mercury.dialogHandlers[@name]
+      callback() if callback
+    else
+      # Otherwise make an Ajax request to get the content.
+      jQuery.ajax @url, {
+        success: (data) =>
+          @loadContent(data)
+          Mercury.dialogHandlers[@name].call(@) if Mercury.dialogHandlers[@name]
+          callback() if callback
+        error: =>
+          # If the Ajax fails, we hide the dialog and alert the user about the error.
+          @hide()
+          @button.removeClass('pressed') if @button
+          Mercury.notify('Mercury was unable to load %s for the "%s" dialog.', @url, @name)
+      }
+
+
+  # ## #loadContent
+  #
+  # Loads content into the element, and removes the loading class.
+  #
+  # @data _mixed_ a string or jQuery object that can be inserted into the dialog.
+  loadContent: (data) ->
+    @loaded = true
+    @element.removeClass('loading')
+    @element.html(data)
+    @element.localize(Mercury.locale()) if Mercury.config.localization.enabled

data/vendor/assets/javascripts/mercury/dialogs/backcolor.js.coffee

@@ -0,0 +1,6 @@
+@Mercury.dialogHandlers.backColor = ->
+  @element.find('.picker, .last-picked').on 'click', (event) =>
+    color = jQuery(event.target).css('background-color')
+    @element.find('.last-picked').css({background: color})
+    @button.css({backgroundColor: color})
+    Mercury.trigger('action', {action: 'backColor', value: color})

data/vendor/assets/javascripts/mercury/dialogs/forecolor.js.coffee

@@ -0,0 +1,6 @@
+@Mercury.dialogHandlers.foreColor = ->
+  @element.find('.picker, .last-picked').on 'click', (event) =>
+    color = jQuery(event.target).css('background-color')
+    @element.find('.last-picked').css({background: color})
+    @button.css({backgroundColor: color})
+    Mercury.trigger('action', {action: 'foreColor', value: color})

data/vendor/assets/javascripts/mercury/dialogs/formatblock.js.coffee

@@ -0,0 +1,4 @@
+@Mercury.dialogHandlers.formatblock = ->
+  @element.find('[data-tag]').on 'click', (event) =>
+    tag = jQuery(event.target).data('tag')
+    Mercury.trigger('action', {action: 'formatblock', value: tag})

data/vendor/assets/javascripts/mercury/dialogs/snippetpanel.js.coffee

@@ -0,0 +1,10 @@
+@Mercury.dialogHandlers.snippetPanel = ->
+  # make the filter work
+  @element.find('input.filter').on 'keyup', =>
+    value = @element.find('input.filter').val()
+    for snippet in @element.find('li[data-filter]')
+      if LiquidMetal.score(jQuery(snippet).data('filter'), value) == 0 then jQuery(snippet).hide() else jQuery(snippet).show()
+
+  # when an element is dragged, set it so we have a global object
+  @element.find('img[data-snippet]').on 'dragstart', ->
+    Mercury.snippet = jQuery(@).data('snippet')

data/vendor/assets/javascripts/mercury/dialogs/style.js.coffee

@@ -0,0 +1,4 @@
+@Mercury.dialogHandlers.style = ->
+  @element.find('[data-class]').on 'click', (event) =>
+    className = jQuery(event.target).data('class')
+    Mercury.trigger('action', {action: 'style', value: className})

data/vendor/assets/javascripts/mercury/finalize.js.coffee

@@ -0,0 +1,3 @@
+# tell everyone that Mercury has loaded
+Mercury.onload() if Mercury.onload
+jQuery(window).trigger('mercury:loaded')

data/vendor/assets/javascripts/mercury/history_buffer.js.coffee

@@ -0,0 +1,30 @@
+class @Mercury.HistoryBuffer
+
+  constructor: (@maxLength = 200) ->
+    @index = 0
+    @stack = []
+    @markerRegExp = /<em class="mercury-marker"><\/em>/g
+
+
+  push: (item) ->
+    if jQuery.type(item) == 'string'
+      return if @stack[@index] && @stack[@index].replace(@markerRegExp, '') == item.replace(@markerRegExp, '')
+    else if jQuery.type(item) == 'object' && item.html
+      return if @stack[@index] && @stack[@index].html == item.html
+
+    @stack = @stack[0...@index + 1]
+    @stack.push(item)
+    @stack.shift() if @stack.length > @maxLength
+    @index = @stack.length - 1
+
+
+  undo: ->
+    return null if @index < 1
+    @index -= 1
+    return @stack[@index]
+
+
+  redo: ->
+    return null if @index >= @stack.length - 1
+    @index += 1
+    return @stack[@index]

data/vendor/assets/javascripts/mercury/lightview.js.coffee

@@ -0,0 +1,205 @@
+@Mercury.lightview = (url, options = {}) ->
+  Mercury.lightview.show(url, options)
+  return Mercury.lightview
+
+jQuery.extend Mercury.lightview,
+  minWidth: 400
+
+  show: (@url, @options = {}) ->
+    Mercury.trigger('focus:window')
+    @initialize()
+    if @visible then @update() else @appear()
+    if @options.content
+      setTimeout 500, => @loadContent(@options.content)
+
+
+  initialize: ->
+    return if @initialized
+    @build()
+    @bindEvents()
+    @initialized = true
+
+
+  build: ->
+    @element = jQuery('<div>', {class: 'mercury-lightview loading'})
+    @element.html('<h1 class="mercury-lightview-title"><span></span></h1>')
+    @element.append('<div class="mercury-lightview-content"></div>')
+
+    @overlay = jQuery('<div>', {class: 'mercury-lightview-overlay'})
+
+    @titleElement = @element.find('.mercury-lightview-title')
+    @titleElement.append('<a class="mercury-lightview-close"></a>') if @options.closeButton
+
+    @contentElement = @element.find('.mercury-lightview-content')
+
+    @element.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+    @overlay.appendTo(jQuery(@options.appendTo).get(0) ? 'body')
+
+
+  bindEvents: ->
+    Mercury.on 'refresh', => @resize(true)
+    Mercury.on 'resize', => @position() if @visible
+
+    @overlay.on 'click', =>
+      @hide() unless @options.closeButton
+
+    @titleElement.find('.mercury-lightview-close').on 'click', =>
+      @hide()
+
+    @element.on 'ajax:beforeSend', (event, xhr, options) =>
+      options.success = (content) =>
+        @loadContent(content)
+
+    jQuery(document).on 'keydown', (event) =>
+       @hide() if event.keyCode == 27 && @visible
+
+
+  appear: ->
+    @showing = true
+    @position()
+
+    @overlay.show().css({opacity: 0})
+    @overlay.animate {opacity: 1}, 200, 'easeInOutSine', =>
+      @setTitle()
+      @element.show().css({opacity: 0})
+      @element.stop().animate {opacity: 1}, 200, 'easeInOutSine', =>
+        @visible = true
+        @showing = false
+        @load()
+
+
+  resize: (keepVisible) ->
+    visibility = if keepVisible then 'visible' else 'hidden'
+
+    viewportWidth = Mercury.displayRect.width
+    viewportHeight = Mercury.displayRect.fullHeight
+
+    titleHeight = @titleElement.outerHeight()
+
+    width = @contentElement.outerWidth()
+    width = viewportWidth - 40 if width > viewportWidth - 40 || @options.fullSize
+
+    @contentPane.css({height: 'auto'}) if @contentPane
+    @contentElement.css({height: 'auto', visibility: visibility, display: 'block'})
+
+    height = @contentElement.outerHeight() + titleHeight
+    height = viewportHeight - 20 if height > viewportHeight - 20 || @options.fullSize
+
+    width = 300 if width < 300
+    height = 150 if height < 150
+
+    @element.stop().animate {top: ((viewportHeight - height) / 2) + 10, left: (Mercury.displayRect.width - width) / 2, width: width, height: height}, 200, 'easeInOutSine', =>
+      @contentElement.css({visibility: 'visible', display: 'block'})
+      if @contentPane.length
+        @contentElement.css({height: height - titleHeight, overflow: 'visible'})
+        controlHeight = if @contentControl.length then @contentControl.outerHeight() else 0
+        @contentPane.css({height: height - titleHeight - controlHeight - 40})
+        @contentPane.find('.mercury-display-pane').css({width: width - 40})
+      else
+        @contentElement.css({height: height - titleHeight - 30, overflow: 'auto'})
+
+
+  position: ->
+    viewportWidth = Mercury.displayRect.width
+    viewportHeight = Mercury.displayRect.fullHeight
+
+    @contentPane.css({height: 'auto'}) if @contentPane
+    @contentElement.css({height: 'auto'})
+    @element.css({width: 'auto', height: 'auto', display: 'block', visibility: 'hidden'})
+
+    width = @contentElement.width() + 40
+    height = @contentElement.height() + @titleElement.outerHeight() + 30
+
+    width = viewportWidth - 40 if width > viewportWidth - 40 || @options.fullSize
+    height = viewportHeight - 20 if height > viewportHeight - 20 || @options.fullSize
+
+    width = 300 if width < 300
+    height = 150 if height < 150
+
+    titleHeight = @titleElement.outerHeight()
+    if @contentPane && @contentPane.length
+      @contentElement.css({height: height - titleHeight, overflow: 'visible'})
+      controlHeight = if @contentControl.length then @contentControl.outerHeight() else 0
+      @contentPane.css({height: height - titleHeight - controlHeight - 40})
+      @contentPane.find('.mercury-display-pane').css({width: width - 40})
+    else
+      @contentElement.css({height: height - titleHeight - 30, overflow: 'auto'})
+
+    @element.css {
+      top: ((viewportHeight - height) / 2) + 10,
+      left: (viewportWidth - width) / 2,
+      width: width
+      height: height
+      display: if @visible then 'block' else 'none'
+      visibility: 'visible'
+    }
+
+
+  update:  ->
+    @reset()
+    @resize()
+    @load()
+
+
+  load: ->
+    @setTitle()
+    return unless @url
+    @element.addClass('loading')
+    if Mercury.preloadedViews[@url]
+      setTimeout(10, => @loadContent(Mercury.preloadedViews[@url]))
+    else
+      jQuery.ajax @url, {
+        headers: Mercury.ajaxHeaders()
+        type: @options.loadType || 'GET'
+        data: @options.loadData
+        success: (data) => @loadContent(data)
+        error: =>
+          @hide()
+          Mercury.notify('Mercury was unable to load %s for the lightview.', @url)
+      }
+
+
+  loadContent: (data, options = null) ->
+    @initialize()
+    @options = options || @options
+    @setTitle()
+    @loaded = true
+    @element.removeClass('loading')
+    @contentElement.html(data)
+    @contentElement.css({display: 'none', visibility: 'hidden'})
+
+    # for complex lightview content, we provide panes and controls
+    @contentPane = @element.find('.mercury-display-pane-container')
+    @contentControl = @element.find('.mercury-display-controls')
+
+    @options.afterLoad.call(@) if @options.afterLoad
+    if @options.handler
+      if Mercury.modalHandlers[@options.handler]
+        Mercury.modalHandlers[@options.handler].call(@)
+      else if Mercury.lightviewHandlers[@options.handler]
+        Mercury.lightviewHandlers[@options.handler].call(@)
+
+    @element.localize(Mercury.locale()) if Mercury.config.localization.enabled
+    @resize()
+
+
+  setTitle: ->
+    @titleElement.find('span').html(Mercury.I18n(@options.title))
+
+
+  reset: ->
+    @titleElement.find('span').html('')
+    @contentElement.html('')
+
+
+  hide: ->
+    return if @showing
+    @options = {}
+    @initialized = false
+
+    Mercury.trigger('focus:frame')
+    @element.hide()
+    @overlay.hide()
+    @reset()
+
+    @visible = false

data/vendor/assets/javascripts/mercury/locales/de.locale.js.coffee

@@ -0,0 +1,206 @@
+Mercury.I18n['de'] =
+  # ## Javascript Strings
+
+  # ### Default Configuration
+  "Save": "Speichern"
+  "Save this page": "Diese Seite speichern"
+  "Preview": "Vorschau"
+  "Preview this page": "Diese Seite in der Vorschau betrachten"
+  "Undo": "Rückgängig"
+  "Undo your last action": "Letzte Aktion rückgängig machen"
+  "Redo": "Wiederherstellen"
+  "Redo your last action": "Letzte Aktion wiederherstellen"
+  "Link": "Link"
+  "Insert Link": "Link einfügen"
+  "Media": "Media"
+  "Insert Media (images and videos)": "Bilder und Videos einfügen"
+  "Table": "Tabelle"
+  "Insert Table": "Tabelle einfügen"
+  "Character": "Zeichen"
+  "Special Characters": "Sonderzeichen"
+  "Snippet": "Snippet"
+  "Snippet Panel": "Snippet-Fenster"
+  "History": "Verlauf"
+  "Page Version History": "Versionsverlauf der Seite"
+  "Notes": "Notizen"
+  "Page Notes": "Notizen der Seite"
+  "Style": "Stil"
+  "Block Format": "Blockformatierung"
+  "Background Color": "Hintergrundfarbe"
+  "Text Color": "Textfarbe"
+  "Bold": "Fett"
+  "Italicize": "Kursiv"
+  "Overline": "Überstrichen"
+  "Strikethrough": "Durchgestrichen"
+  "Underline": "Unterstrichen"
+  "Subscript": "Tiefgestellt"
+  "Superscript": "Hochgestellt"
+  "Align Left": "Linksbündig ausgerichtet"
+  "Center": "Zentriert"
+  "Align Right": "Rechtsbündig ausgerichtet"
+  "Justify Full": "Blocksatz"
+  "Unordered List": "Ungeordnete Liste"
+  "Numbered List": "Numerierte Liste"
+  "Decrease Indentation": "Einzug verkleinern"
+  "Increase Indentation": "Einzug vergrößern"
+  "Insert Table Row": "Zeile einfügen"
+  "Insert a table row before the cursor": "Zeile vor dem Cursor einfügen"
+  "Insert a table row after the cursor": "Zeile nach dem Cursor einfügen"
+  "Delete Table Row": "Zeile löschen"
+  "Delete this table row": "Aktuelle Zeile löschen"
+  "Insert Table Column": "Spalte einfügen"
+  "Insert a table column before the cursor": "Spalte vor dem Cursor einfügen"
+  "Insert a table column after the cursor": "Spalte nach dem Cursor einfügen"
+  "Delete Table Column": "Spalte löschen"
+  "Delete this table column": "Aktuelle Spalte löschen"
+  "Increase Cell Columns": "Mehr Spalten"
+  "Decrease Cell Columns": "Weniger Spalten"
+  "Increase Cell Rows": "Mehr Reihen"
+  "Decrease Cell Rows": "Weniger Reihen"
+  "Horizontal Rule": "Horizontaler Trennstrich"
+  "Insert a horizontal rule": "Horizontalen Trennstrich einfügen"
+  "Remove Formatting": "Formatierung löschen"
+  "Remove formatting for the selection": "Formatierung der Auswahl löschen"
+  "Edit HTML": "HTML bearbeiten"
+  "Edit the HTML content": "HTML-Inhalt bearbeiten"
+  "Edit Snippet Settings": "Snippet-Einstellungen bearbeiten"
+  "Remove Snippet": "Snippet entfernen"
+
+  # ### General
+  # Error Messages
+  "Mercury.Regions.%s is unsupported in this client. Supported browsers are %s.": "Mercury.Regions.%s wird von diesem Client nicht unterstützt. Unterstützte Browser sind: %s."
+  "Mercury.PageEditor can only be instantiated once.": "Mercury.PageEditor kann nur einmal instanziiert werden."
+  "Opera isn't a fully supported browser, your results may not be optimal.": "Opera ist ein nicht vollständig unterstützter Browser, daher sind nicht-optimale Ergebnisse möglich."
+  "Mercury.PageEditor failed to load: %s\n\nPlease try refreshing.": "Mercury.PageEditor konnte nicht geladen werden: %s\n\nBitte versuche die Seite neu zu laden."
+  "Region type is malformed, no data-type provided, or \"%s\" is unknown for the \"%s\" region.": "Regionstyp ist ungültig, kein Datentyp angegeben, oder \"%s\" ist unbekannt für die \"%s\"-Region."
+  "Mercury was unable to save to the url: %s": "Mercury war nicht in der Lage unter der URL zu speichern: %s"
+  # Confirmations
+  "You have unsaved changes.  Are you sure you want to leave without saving them first?": "Es gibt ungespeicherte Änderungen. Möchtest du wirklich beenden, ohne die Änderungen vorher zu speichern?"
+
+  # ### Toolbar / Buttons
+  # Error Messages
+  "Unknown button type \"%s\" used for the \"%s\" button.": "Unbekannter Button-Typ \"%s\" wurde für den Button \"%s\" benutzt."
+  "Unknown button structure -- please provide an array, object, or string for \"%s\".": "Unbekannte Button-Struktur – bitte gib ein Array, Objekt oder einen String für \"%s\" an."
+
+  # ### Modals / Dialogs / Etc.
+  # Error Messages
+  "Mercury was unable to load %s for the \"%s\" dialog.": "Mercury konnte %s nicht für den \"%s\"-Dialog laden."
+  "Mercury was unable to load %s for the lightview.": "Mercury konnte %s nicht für die Lightansicht laden."
+  "Mercury was unable to load %s for the modal.": "Mercury konnte %s nicht für den Modaldialog laden."
+
+  # ### Snippets
+  # Error Messages
+  "Error loading the preview for the \"%s\" snippet.": "Fehler beim Laden der Vorschau für das \"%s\"-Snippet."
+  # Misc
+  "Snippet Options": "Snippet-Optionen"
+
+  # ### Uploader
+  # Error Messages
+  "Unable to process response: %s": "Nicht in der Lage, die folgende Antwort zu verarbeiten: %s"
+  "Error: Unable to upload the file": "Fehler: Nicht in der Lage, die Datei hochzuladen"
+  "Malformed response from server": "Fehlerhafte Antwort des Servers"
+  "Too large": "Zu groß"
+  "Unsupported format": "Nicht unterstütztes Format"
+  # Statuses
+  "Processing...": "Verarbeite…"
+  "Uploading...": "Lade hoch…"
+  "Aborted": "Abgebrochen"
+  "Successfully uploaded...": "Erfolgreich hochgeladen…"
+  "Name: %s": "Name: %s"
+  "Size: %s": "Größe: %s"
+  "Type: %s": "Typ: %s"
+
+  # Inserting Media
+  "Error: The provided youtube share url was invalid.": "Fehler: Die angegebene YouTube Share-URL war ungültig."
+  "Error: The provided vimeo url was invalid.": "Fehler: Die angegebene Vimeo-URL war ungültig."
+
+  # Statusbar
+  "Path:": "Pfad"
+
+
+  # ## HTML / Template Strings
+
+  # ### Modals
+  # Insert Link Modal (link.html)
+  "Link Content": "Linkbeschreibung"
+  "Standard Links": "Standardlinks"
+  "URL": "URL"
+  "Index / Bookmark Links": "Index/Lesezeichen-Link"
+  "Existing Links": "Existierender Link"
+  "Bookmark": "Lesezeichen"
+  "Options": "Optionen"
+  "Link Target": "Link-Ziel"
+  "Self (the same window or tab)": "Self (das gleiche Fenster oder Tab)"
+  "Blank (a new window or tab)": "Blank (ein neues Fenster oder Tab)"
+  "Top (removes any frames)": "Top (entfernt Frames)"
+  "Popup Window (javascript new window popup)": "Popupfenster"
+  "Popup Width": "Popup-Breite"
+  "Popup Height": "Popup-Höhe"
+  "Insert Link": "Link einfügen"
+
+  # Insert Media Modal (media.html)
+  "Images": "Bilder"
+  "Videos": "Videos"
+  "YouTube Share URL": "YouTube Share-URL"
+  "Vimeo URL": "Vimeo-URL"
+  "Alignment": "Ausrichtung"
+  "None": "Normal"
+  "Left": "Links"
+  "Right": "Rechts"
+  "Top": "Oben"
+  "Middle": "Mitte"
+  "Bottom": "Unten"
+  "Absolute Middle": "Mitte, absolut"
+  "Absolute Bottom": "Unten, absolut"
+  "Width": "Breite"
+  "Height": "Höhe"
+  "Insert Media": "Element einfügen"
+
+  # Insert Table Modal (table.html)
+  "Rows": "Reihen"
+  "Add Before": "Davor hinzufügen"
+  "Add After": "Danach hinzufügen"
+  "Remove": "Entfernen"
+  "Columns": "Spalten"
+  "Row Span": "Reihenabstand"
+  "Column Span": "Spaltenabstand"
+  "Options": "Optionen"
+  "Alignment": "Ausrichtung"
+  "Border": "Rahmen"
+  "Spacing": "Zwischenraum"
+  "Insert Table": "Tabelle einfügen"
+
+  # HTML Editor Modal (htmleditor.html)
+  "HTML Editor": "HTML-Editor"
+  "Save and Replace": "Speichern und ersetzen"
+
+  # ### Dialogs / Etc.
+  # Color Palettes (forecolor.html, backcolor.html)
+  "Last Color Picked": "Zuletzt gewählte Farbe"
+
+  # Block Format Select (formatblock.html)
+  "Heading 1": "Überschrift 1"
+  "Heading 2": "Überschrift 2"
+  "Heading 3": "Überschrift 3"
+  "Heading 4": "Überschrift 4"
+  "Heading 5": "Überschrift 5"
+  "Heading 6": "Überschrift 6"
+  "Paragraph": "Absatz"
+  "Blockquote": "Zitat"
+  "Formatted": "Formatiert"
+
+  # About Mercury Panel (about.html)
+  "Project Home": "Projekt-Website"
+  "Project Source": "Projekt-Quelltext"
+
+  # ### Demo / Placeholder / Defaults
+  "The history panel is expected to be implemented with a server back end.  Since this is a demo, we didn't include it.": "Der Verlaufsdialog setzt ein Server-Backend voraus. Da dies eine Demo ist, steht es nicht zur Verfügung."
+
+  "The notes panel is expected to be implemented with a server back end.  Since this is a demo, we didn't include it.": "Der Notizendialog setzt ein Server-Backend voraus. Da dies eine Demo ist, steht es nicht zur Verfügung."
+
+  "Snippet Name": "Snippet-Name"
+  "A one or two line long description of what this snippet does.": "Eine ein- oder zweizeilige Beschreibung dessen, was dieses Snippet tut."
+
+  "First Name": "Vorname"
+  "Favorite Beer": "Lieblingsbier"
+  "Insert Snippet": "Snippet einfügen"