freighthop 0.2.1 → 0.3.0

data/modules/apache/manifests/mod/worker.pp

@@ -0,0 +1,75 @@
+class apache::mod::worker (
+  $startservers        = '2',
+  $maxclients          = '150',
+  $minsparethreads     = '25',
+  $maxsparethreads     = '75',
+  $threadsperchild     = '25',
+  $maxrequestsperchild = '0',
+  $serverlimit         = '25',
+) {
+  if defined(Class['apache::mod::event']) {
+    fail('May not include both apache::mod::worker and apache::mod::event on the same node')
+  }
+  if defined(Class['apache::mod::itk']) {
+    fail('May not include both apache::mod::worker and apache::mod::itk on the same node')
+  }
+  if defined(Class['apache::mod::peruser']) {
+    fail('May not include both apache::mod::worker and apache::mod::peruser on the same node')
+  }
+  if defined(Class['apache::mod::prefork']) {
+    fail('May not include both apache::mod::worker and apache::mod::prefork on the same node')
+  }
+  File {
+    owner => 'root',
+    group => $apache::params::root_group,
+    mode  => '0644',
+  }
+
+  # Template uses:
+  # - $startservers
+  # - $maxclients
+  # - $minsparethreads
+  # - $maxsparethreads
+  # - $threadsperchild
+  # - $maxrequestsperchild
+  # - $serverlimit
+  file { "${apache::mod_dir}/worker.conf":
+    ensure  => file,
+    content => template('apache/mod/worker.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+
+  case $::osfamily {
+    'redhat': {
+      file_line { '/etc/sysconfig/httpd worker enable':
+        ensure => present,
+        path   => '/etc/sysconfig/httpd',
+        line   => 'HTTPD=/usr/sbin/httpd.worker',
+        match  => '#?HTTPD=/usr/sbin/httpd.worker',
+        notify => Service['httpd'],
+      }
+    }
+    'debian': {
+      file { "${apache::mod_enable_dir}/worker.conf":
+        ensure  => link,
+        target  => "${apache::mod_dir}/worker.conf",
+        require => Exec["mkdir ${apache::mod_enable_dir}"],
+        before  => File[$apache::mod_enable_dir],
+        notify  => Service['httpd'],
+      }
+      package { 'apache2-mpm-worker':
+        ensure => present,
+      }
+    }
+    'freebsd' : {
+      class { 'apache::package':
+        mpm_module => 'worker'
+      }
+    }
+    default: {
+      fail("Unsupported osfamily ${::osfamily}")
+    }
+  }
+}

data/modules/apache/manifests/mod/wsgi.pp

@@ -0,0 +1,21 @@
+class apache::mod::wsgi (
+  $wsgi_socket_prefix = undef,
+  $wsgi_python_path   = undef,
+  $wsgi_python_home   = undef,
+){
+  apache::mod { 'wsgi': }
+
+  # Template uses:
+  # - $wsgi_socket_prefix
+  # - $wsgi_python_path
+  # - $wsgi_python_home
+  file {'wsgi.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/wsgi.conf",
+    content => template('apache/mod/wsgi.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd']
+  }
+}
+

data/modules/apache/manifests/mod/xsendfile.pp

@@ -0,0 +1,4 @@
+class apache::mod::xsendfile {
+  include apache::params
+  apache::mod { 'xsendfile': }
+}

data/modules/apache/manifests/mod.pp

@@ -0,0 +1,120 @@
+define apache::mod (
+  $package = undef,
+  $package_ensure = 'present',
+  $lib = undef,
+  $lib_path = $apache::params::lib_path,
+  $id = undef,
+  $path = undef,
+) {
+  if ! defined(Class['apache']) {
+    fail('You must include the apache base class before using any apache defined resources')
+  }
+
+  $mod = $name
+  #include apache #This creates duplicate resources in rspec-puppet
+  $mod_dir = $apache::mod_dir
+
+  # Determine if we have special lib
+  $mod_libs = $apache::params::mod_libs
+  $mod_lib = $mod_libs[$mod] # 2.6 compatibility hack
+  if $lib {
+    $_lib = $lib
+  } elsif "${mod_lib}" {
+    $_lib = $mod_lib
+  } else {
+    $_lib = "mod_${mod}.so"
+  }
+
+  # Determine if declaration specified a path to the module
+  if $path {
+    $_path = $path
+  } else {
+    $_path = "${lib_path}/${_lib}"
+  }
+
+  if $id {
+    $_id = $id
+  } else {
+    $_id = "${mod}_module"
+  }
+
+  # Determine if we have a package
+  $mod_packages = $apache::params::mod_packages
+  $mod_package = $mod_packages[$mod] # 2.6 compatibility hack
+  if $package {
+    $_package = $package
+  } elsif "${mod_package}" {
+    $_package = $mod_package
+  }
+  if $_package and ! defined(Package[$_package]) {
+    # note: FreeBSD/ports uses apxs tool to activate modules; apxs clutters
+    # httpd.conf with 'LoadModule' directives; here, by proper resource
+    # ordering, we ensure that our version of httpd.conf is reverted after
+    # the module gets installed.
+    $package_before = $::osfamily ? {
+      'freebsd' => [
+        File["${mod_dir}/${mod}.load"],
+        File["${apache::params::conf_dir}/${apache::params::conf_file}"]
+      ],
+      default => File["${mod_dir}/${mod}.load"],
+    }
+    # $_package may be an array
+    package { $_package:
+      ensure  => $package_ensure,
+      require => Package['httpd'],
+      before  => $package_before,
+    }
+  }
+
+  file { "${mod}.load":
+    ensure  => file,
+    path    => "${mod_dir}/${mod}.load",
+    owner   => 'root',
+    group   => $apache::params::root_group,
+    mode    => '0644',
+    content => "LoadModule ${_id} ${_path}\n",
+    require => [
+      Package['httpd'],
+      Exec["mkdir ${mod_dir}"],
+    ],
+    before  => File[$mod_dir],
+    notify  => Service['httpd'],
+  }
+
+  if $::osfamily == 'Debian' {
+    $enable_dir = $apache::mod_enable_dir
+    file{ "${mod}.load symlink":
+      ensure  => link,
+      path    => "${enable_dir}/${mod}.load",
+      target  => "${mod_dir}/${mod}.load",
+      owner   => 'root',
+      group   => $apache::params::root_group,
+      mode    => '0644',
+      require => [
+        File["${mod}.load"],
+        Exec["mkdir ${enable_dir}"],
+      ],
+      before  => File[$enable_dir],
+      notify  => Service['httpd'],
+    }
+    # Each module may have a .conf file as well, which should be
+    # defined in the class apache::mod::module
+    # Some modules do not require this file.
+    if defined(File["${mod}.conf"]) {
+      file{ "${mod}.conf symlink":
+        ensure  => link,
+        path    => "${enable_dir}/${mod}.conf",
+        target  => "${mod_dir}/${mod}.conf",
+        owner   => 'root',
+        group   => $apache::params::root_group,
+        mode    => '0644',
+        require => [
+          File["${mod}.conf"],
+          Exec["mkdir ${enable_dir}"],
+        ],
+        before  => File[$enable_dir],
+        notify  => Service['httpd'],
+      }
+    }
+  }
+}

data/modules/apache/manifests/namevirtualhost.pp

@@ -0,0 +1,9 @@
+define apache::namevirtualhost {
+  $addr_port = $name
+
+  # Template uses: $addr_port
+  concat::fragment { "NameVirtualHost ${addr_port}":
+    target  => $apache::ports_file,
+    content => template('apache/namevirtualhost.erb'),
+  }
+}

data/modules/apache/manifests/package.pp

@@ -0,0 +1,48 @@
+class apache::package (
+  $ensure     = 'present',
+  $mpm_module = $apache::params::mpm_module,
+) {
+  case $::osfamily {
+    'freebsd' : {
+      $all_mpms = [
+        'www/apache22',
+        'www/apache22-worker-mpm',
+        'www/apache22-event-mpm',
+        'www/apache22-itk-mpm',
+        'www/apache22-peruser-mpm',
+      ]
+      if $mpm_module {
+        $apache_package = $mpm_module ? {
+          'prefork' => 'www/apache22',
+          default   => "www/apache22-${mpm_module}-mpm"
+        }
+      } else {
+        $apache_package = 'www/apache22'
+      }
+      $other_mpms = delete($all_mpms, $apache_package)
+      # Configure ports to have apache module packages dependent on correct
+      # version of apache package (apache22, apache22-worker-mpm, ...)
+      file_line { 'APACHE_PORT in /etc/make.conf':
+        ensure => $ensure,
+        path   => '/etc/make.conf',
+        line   => "APACHE_PORT=${apache_package}",
+        match  => "^\\s*#?\\s*APACHE_PORT\\s*=\\s*",
+        before => Package['httpd'],
+      }
+      # remove other packages
+      ensure_resource('package', $other_mpms, {
+        ensure  => absent,
+        before  => Package['httpd'],
+        require => File_line['APACHE_PORT in /etc/make.conf'],
+      })
+    }
+    default: {
+      $apache_package = $apache::params::apache_name
+    }
+  }
+  package { 'httpd':
+    ensure => $ensure,
+    name   => $apache_package,
+    notify => Class['Apache::Service'],
+  }
+}

data/modules/apache/manifests/params.pp

@@ -0,0 +1,207 @@
+# Class: apache::params
+#
+# This class manages Apache parameters
+#
+# Parameters:
+# - The $user that Apache runs as
+# - The $group that Apache runs as
+# - The $apache_name is the name of the package and service on the relevant
+#   distribution
+# - The $php_package is the name of the package that provided PHP
+# - The $ssl_package is the name of the Apache SSL package
+# - The $apache_dev is the name of the Apache development libraries package
+# - The $conf_contents is the contents of the Apache configuration file
+#
+# Actions:
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache::params {
+  # This will be 5 or 6 on RedHat, 6 or wheezy on Debian, 12 or quantal on Ubuntu, 3 on Amazon, etc.
+  $osr_array = split($::operatingsystemrelease,'[\/\.]')
+  $distrelease = $osr_array[0]
+  if ! $distrelease {
+    fail("Class['apache::params']: Unparsable \$::operatingsystemrelease: ${::operatingsystemrelease}")
+  }
+
+  if($::fqdn) {
+    $servername = $::fqdn
+  } else {
+    $servername = $::hostname
+  }
+
+  # The default error log level
+  $log_level = 'warn'
+
+  if $::osfamily == 'RedHat' or $::operatingsystem == 'amazon' {
+    $user                 = 'apache'
+    $group                = 'apache'
+    $root_group           = 'root'
+    $apache_name          = 'httpd'
+    $service_name         = 'httpd'
+    $httpd_dir            = '/etc/httpd'
+    $server_root          = '/etc/httpd'
+    $conf_dir             = "${httpd_dir}/conf"
+    $confd_dir            = "${httpd_dir}/conf.d"
+    $mod_dir              = "${httpd_dir}/conf.d"
+    $vhost_dir            = "${httpd_dir}/conf.d"
+    $conf_file            = 'httpd.conf'
+    $ports_file           = "${conf_dir}/ports.conf"
+    $logroot              = '/var/log/httpd'
+    $lib_path             = 'modules'
+    $mpm_module           = 'prefork'
+    $dev_packages         = 'httpd-devel'
+    $default_ssl_cert     = '/etc/pki/tls/certs/localhost.crt'
+    $default_ssl_key      = '/etc/pki/tls/private/localhost.key'
+    $ssl_certs_dir        = '/etc/pki/tls/certs'
+    $passenger_root       = '/usr/share/rubygems/gems/passenger-3.0.17'
+    $passenger_ruby       = '/usr/bin/ruby'
+    $suphp_addhandler     = 'php5-script'
+    $suphp_engine         = 'off'
+    $suphp_configpath     = undef
+    $mod_packages         = {
+      'auth_kerb'   => 'mod_auth_kerb',
+      'authnz_ldap' => 'mod_authz_ldap',
+      'fastcgi'     => 'mod_fastcgi',
+      'fcgid'       => 'mod_fcgid',
+      'passenger'   => 'mod_passenger',
+      'perl'        => 'mod_perl',
+      'php5'        => $distrelease ? {
+        '5'     => 'php53',
+        default => 'php',
+      },
+      'proxy_html'  => 'mod_proxy_html',
+      'python'      => 'mod_python',
+      'shibboleth'  => 'shibboleth',
+      'ssl'         => 'mod_ssl',
+      'wsgi'        => 'mod_wsgi',
+      'dav_svn'     => 'mod_dav_svn',
+      'suphp'       => 'mod_suphp',
+      'xsendfile'   => 'mod_xsendfile',
+      'nss'         => 'mod_nss',
+    }
+    $mod_libs             = {
+      'php5' => 'libphp5.so',
+      'nss'  => 'libmodnss.so',
+    }
+    $conf_template        = 'apache/httpd.conf.erb'
+    $keepalive            = 'Off'
+    $keepalive_timeout    = 15
+    $fastcgi_lib_path     = undef
+    $mime_support_package = 'mailcap'
+    $mime_types_config    = '/etc/mime.types'
+  } elsif $::osfamily == 'Debian' {
+    $user             = 'www-data'
+    $group            = 'www-data'
+    $root_group       = 'root'
+    $apache_name      = 'apache2'
+    $service_name     = 'apache2'
+    $httpd_dir        = '/etc/apache2'
+    $server_root      = '/etc/apache2'
+    $conf_dir         = $httpd_dir
+    $confd_dir        = "${httpd_dir}/conf.d"
+    $mod_dir          = "${httpd_dir}/mods-available"
+    $mod_enable_dir   = "${httpd_dir}/mods-enabled"
+    $vhost_dir        = "${httpd_dir}/sites-available"
+    $vhost_enable_dir = "${httpd_dir}/sites-enabled"
+    $conf_file        = 'apache2.conf'
+    $ports_file       = "${conf_dir}/ports.conf"
+    $logroot          = '/var/log/apache2'
+    $lib_path         = '/usr/lib/apache2/modules'
+    $mpm_module       = 'worker'
+    $dev_packages     = ['libaprutil1-dev', 'libapr1-dev', 'apache2-prefork-dev']
+    $default_ssl_cert = '/etc/ssl/certs/ssl-cert-snakeoil.pem'
+    $default_ssl_key  = '/etc/ssl/private/ssl-cert-snakeoil.key'
+    $ssl_certs_dir    = '/etc/ssl/certs'
+    $passenger_root   = '/usr'
+    $passenger_ruby   = '/usr/bin/ruby'
+    $suphp_addhandler  = 'x-httpd-php'
+    $suphp_engine      = 'off'
+    $suphp_configpath  = '/etc/php5/apache2'
+    $mod_packages     = {
+      'auth_kerb'   => 'libapache2-mod-auth-kerb',
+      'dav_svn'     => 'libapache2-svn',
+      'fastcgi'     => 'libapache2-mod-fastcgi',
+      'fcgid'       => 'libapache2-mod-fcgid',
+      'nss'         => 'libapache2-mod-nss',
+      'passenger'   => 'libapache2-mod-passenger',
+      'perl'        => 'libapache2-mod-perl2',
+      'php5'        => 'libapache2-mod-php5',
+      'proxy_html'  => 'libapache2-mod-proxy-html',
+      'python'      => 'libapache2-mod-python',
+      'rpaf'        => 'libapache2-mod-rpaf',
+      'suphp'       => 'libapache2-mod-suphp',
+      'wsgi'        => 'libapache2-mod-wsgi',
+      'xsendfile'   => 'libapache2-mod-xsendfile',
+    }
+    $mod_libs         = {
+      'php5' => 'libphp5.so',
+    }
+    $conf_template     = 'apache/httpd.conf.erb'
+    $keepalive         = 'Off'
+    $keepalive_timeout = 15
+    $fastcgi_lib_path  = '/var/lib/apache2/fastcgi'
+    $mime_support_package = 'mime-support'
+    $mime_types_config = '/etc/mime.types'
+  } elsif $::osfamily == 'FreeBSD' {
+    $user             = 'www'
+    $group            = 'www'
+    $root_group       = 'wheel'
+    $apache_name      = 'apache22'
+    $service_name     = 'apache22'
+    $httpd_dir        = '/usr/local/etc/apache22'
+    $server_root      = '/usr/local'
+    $conf_dir         = $httpd_dir
+    $confd_dir        = "${httpd_dir}/Includes"
+    $mod_dir          = "${httpd_dir}/Modules"
+    $mod_enable_dir   = undef
+    $vhost_dir        = "${httpd_dir}/Vhosts"
+    $vhost_enable_dir = undef
+    $conf_file        = 'httpd.conf'
+    $ports_file       = "${conf_dir}/ports.conf"
+    $logroot          = '/var/log/apache22'
+    $lib_path         = '/usr/local/libexec/apache22'
+    $mpm_module       = 'prefork'
+    $dev_packages     = undef
+    $default_ssl_cert = '/usr/local/etc/apache22/server.crt'
+    $default_ssl_key  = '/usr/local/etc/apache22/server.key'
+    $ssl_certs_dir    = '/usr/local/etc/apache22'
+    $passenger_root   = '/usr/local/lib/ruby/gems/1.9/gems/passenger-4.0.10'
+    $passenger_ruby   = '/usr/bin/ruby'
+    $suphp_addhandler = 'php5-script'
+    $suphp_engine     = 'off'
+    $suphp_configpath = undef
+    $mod_packages     = {
+      # NOTE: I list here only modules that are not included in www/apache22
+      # NOTE: 'passenger' needs to enable APACHE_SUPPORT in make config
+      # NOTE: 'php' needs to enable APACHE option in make config
+      # NOTE: 'dav_svn' needs to enable MOD_DAV_SVN make config
+      # NOTE: not sure where the shibboleth should come from
+      # NOTE: don't know where the shibboleth module should come from
+      'auth_kerb'  => 'www/mod_auth_kerb2',
+      'fcgid'      => 'www/mod_fcgid',
+      'passenger'  => 'www/rubygem-passenger',
+      'perl'       => 'www/mod_perl2',
+      'php5'       => 'lang/php5',
+      'proxy_html' => 'www/mod_proxy_html',
+      'python'     => 'www/mod_python3',
+      'wsgi'       => 'www/mod_wsgi',
+      'dav_svn'    => 'devel/subversion',
+      'xsendfile'  => 'www/mod_xsendfile',
+      'rpaf'       => 'www/mod_rpaf2'
+    }
+    $mod_libs         = {
+      'php5' => 'libphp5.so',
+    }
+    $conf_template        = 'apache/httpd.conf.erb'
+    $keepalive            = 'Off'
+    $keepalive_timeout    = 15
+    $fastcgi_lib_path     = undef # TODO: revisit
+    $mime_support_package = 'misc/mime-support'
+    $mime_types_config    = '/usr/local/etc/mime.types'
+  } else {
+    fail("Class['apache::params']: Unsupported osfamily: ${::osfamily}")
+  }
+}

data/modules/apache/manifests/peruser/multiplexer.pp

@@ -0,0 +1,17 @@
+define apache::peruser::multiplexer (
+  $user = $apache::user,
+  $group = $apache::group,
+  $file = undef,
+) {
+  if ! $file {
+    $filename = "${name}.conf"
+  } else {
+    $filename = $file
+  }
+  file { "${apache::mod_dir}/peruser/multiplexers/${filename}":
+    ensure  => file,
+    content => "Multiplexer ${user} ${group}\n",
+    require => File["${apache::mod_dir}/peruser/multiplexers"],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/peruser/processor.pp

@@ -0,0 +1,17 @@
+define apache::peruser::processor (
+  $user,
+  $group,
+  $file = undef,
+) {
+  if ! $file {
+    $filename = "${name}.conf"
+  } else {
+    $filename = $file
+  }
+  file { "${apache::mod_dir}/peruser/processors/${filename}":
+    ensure  => file,
+    content => "Processor ${user} ${group}\n",
+    require => File["${apache::mod_dir}/peruser/processors"],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/php.pp

@@ -0,0 +1,18 @@
+# Class: apache::php
+#
+# This class installs PHP for Apache
+#
+# Parameters:
+# - $php_package
+#
+# Actions:
+#   - Install Apache PHP package
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache::php {
+  warning('apache::php is deprecated; please use apache::mod::php')
+  include apache::mod::php
+}

data/modules/apache/manifests/proxy.pp

@@ -0,0 +1,15 @@
+# Class: apache::proxy
+#
+# This class enabled the proxy module for Apache
+#
+# Actions:
+#   - Enables Apache Proxy module
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache::proxy {
+  warning('apache::proxy is deprecated; please use apache::mod::proxy')
+  include apache::mod::proxy
+}

data/modules/apache/manifests/python.pp

@@ -0,0 +1,18 @@
+# Class: apache::python
+#
+# This class installs Python for Apache
+#
+# Parameters:
+# - $php_package
+#
+# Actions:
+#   - Install Apache Python package
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache::python {
+  warning('apache::python is deprecated; please use apache::mod::python')
+  include apache::mod::python
+}

data/modules/apache/manifests/service.pp

@@ -0,0 +1,35 @@
+# Class: apache::service
+#
+# Manages the Apache daemon
+#
+# Parameters:
+#
+# Actions:
+#   - Manage Apache service
+#
+# Requires:
+#
+# Sample Usage:
+#
+#    sometype { 'foo':
+#      notify => Class['apache::service],
+#    }
+#
+#
+class apache::service (
+  $service_name   = $apache::params::service_name,
+  $service_enable = true,
+  $service_ensure = 'running',
+) {
+  # The base class must be included first because parameter defaults depend on it
+  if ! defined(Class['apache::params']) {
+    fail('You must include the apache::params class before using any apache defined resources')
+  }
+  validate_bool($service_enable)
+
+  service { 'httpd':
+    ensure => $service_ensure,
+    name   => $service_name,
+    enable => $service_enable,
+  }
+}

data/modules/apache/manifests/ssl.pp

@@ -0,0 +1,18 @@
+# Class: apache::ssl
+#
+# This class installs Apache SSL capabilities
+#
+# Parameters:
+# - The $ssl_package name from the apache::params class
+#
+# Actions:
+#   - Install Apache SSL capabilities
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache::ssl {
+  warning('apache::ssl is deprecated; please use apache::mod::ssl')
+  include apache::mod::ssl
+}