freighthop 0.2.1 → 0.3.0

data/modules/apache/manifests/dev.pp

@@ -0,0 +1,11 @@
+class apache::dev {
+  if $::osfamily == 'FreeBSD' and !defined(Class['apache::package']) {
+    fail('apache::dev requires apache::package; please include apache or apache::package class first')
+  }
+  include apache::params
+  $packages = $apache::params::dev_packages
+  package { $packages:
+    ensure  => present,
+    require => Package['httpd'],
+  }
+}

data/modules/apache/manifests/init.pp

@@ -0,0 +1,329 @@
+# Class: apache
+#
+# This class installs Apache
+#
+# Parameters:
+#
+# Actions:
+#   - Install Apache
+#   - Manage Apache service
+#
+# Requires:
+#
+# Sample Usage:
+#
+class apache (
+  $service_name         = $apache::params::service_name,
+  $default_mods         = true,
+  $default_vhost        = true,
+  $default_confd_files  = true,
+  $default_ssl_vhost    = false,
+  $default_ssl_cert     = $apache::params::default_ssl_cert,
+  $default_ssl_key      = $apache::params::default_ssl_key,
+  $default_ssl_chain    = undef,
+  $default_ssl_ca       = undef,
+  $default_ssl_crl_path = undef,
+  $default_ssl_crl      = undef,
+  $ip                   = undef,
+  $service_enable       = true,
+  $service_ensure       = 'running',
+  $purge_configs        = true,
+  $purge_vdir           = false,
+  $serveradmin          = 'root@localhost',
+  $sendfile             = 'On',
+  $error_documents      = false,
+  $timeout              = '120',
+  $httpd_dir            = $apache::params::httpd_dir,
+  $server_root          = $apache::params::server_root,
+  $confd_dir            = $apache::params::confd_dir,
+  $vhost_dir            = $apache::params::vhost_dir,
+  $vhost_enable_dir     = $apache::params::vhost_enable_dir,
+  $mod_dir              = $apache::params::mod_dir,
+  $mod_enable_dir       = $apache::params::mod_enable_dir,
+  $mpm_module           = $apache::params::mpm_module,
+  $conf_template        = $apache::params::conf_template,
+  $servername           = $apache::params::servername,
+  $manage_user          = true,
+  $manage_group         = true,
+  $user                 = $apache::params::user,
+  $group                = $apache::params::group,
+  $keepalive            = $apache::params::keepalive,
+  $keepalive_timeout    = $apache::params::keepalive_timeout,
+  $logroot              = $apache::params::logroot,
+  $log_level            = $apache::params::log_level,
+  $ports_file           = $apache::params::ports_file,
+  $server_tokens        = 'OS',
+  $server_signature     = 'On',
+  $trace_enable         = 'On',
+  $package_ensure       = 'installed',
+) inherits apache::params {
+
+  validate_bool($default_vhost)
+  validate_bool($default_ssl_vhost)
+  validate_bool($default_confd_files)
+  # true/false is sufficient for both ensure and enable
+  validate_bool($service_enable)
+
+  $valid_mpms_re = $::osfamily ? {
+    'FreeBSD' => '(event|itk|peruser|prefork|worker)',
+    default   => '(itk|prefork|worker)'
+  }
+
+  if $mpm_module {
+    validate_re($mpm_module, $valid_mpms_re)
+  }
+
+  # NOTE: on FreeBSD it's mpm module's responsibility to install httpd package.
+  # NOTE: the same strategy may be introduced for other OSes. For this, you
+  # should delete the 'if' block below and modify all MPM modules' manifests
+  # such that they include apache::package class (currently event.pp, itk.pp,
+  # peruser.pp, prefork.pp, worker.pp).
+  if $::osfamily != 'FreeBSD' {
+    package { 'httpd':
+      ensure => $package_ensure,
+      name   => $apache::params::apache_name,
+      notify => Class['Apache::Service'],
+    }
+  }
+  validate_re($sendfile, [ '^[oO]n$' , '^[oO]ff$' ])
+
+  # declare the web server user and group
+  # Note: requiring the package means the package ought to create them and not puppet
+  validate_bool($manage_user)
+  if $manage_user {
+    user { $user:
+      ensure  => present,
+      gid     => $group,
+      require => Package['httpd'],
+    }
+  }
+  validate_bool($manage_group)
+  if $manage_group {
+    group { $group:
+      ensure  => present,
+      require => Package['httpd']
+    }
+  }
+
+  $valid_log_level_re = '(emerg|alert|crit|error|warn|notice|info|debug)'
+
+  validate_re($log_level, $valid_log_level_re,
+  "Log level '${log_level}' is not one of the supported Apache HTTP Server log levels.")
+
+  class { 'apache::service':
+    service_name   => $service_name,
+    service_enable => $service_enable,
+    service_ensure => $service_ensure,
+  }
+
+  # Deprecated backwards-compatibility
+  if $purge_vdir {
+    warning('Class[\'apache\'] parameter purge_vdir is deprecated in favor of purge_configs')
+    $purge_confd = $purge_vdir
+  } else {
+    $purge_confd = $purge_configs
+  }
+
+  Exec {
+    path => '/bin:/sbin:/usr/bin:/usr/sbin',
+  }
+
+  exec { "mkdir ${confd_dir}":
+    creates => $confd_dir,
+    require => Package['httpd'],
+  }
+  file { $confd_dir:
+    ensure  => directory,
+    recurse => true,
+    purge   => $purge_confd,
+    notify  => Class['Apache::Service'],
+    require => Package['httpd'],
+  }
+
+  if ! defined(File[$mod_dir]) {
+    exec { "mkdir ${mod_dir}":
+      creates => $mod_dir,
+      require => Package['httpd'],
+    }
+    file { $mod_dir:
+      ensure  => directory,
+      recurse => true,
+      purge   => $purge_configs,
+      notify  => Class['Apache::Service'],
+      require => Package['httpd'],
+    }
+  }
+
+  if $mod_enable_dir and ! defined(File[$mod_enable_dir]) {
+    $mod_load_dir = $mod_enable_dir
+    exec { "mkdir ${mod_enable_dir}":
+      creates => $mod_enable_dir,
+      require => Package['httpd'],
+    }
+    file { $mod_enable_dir:
+      ensure  => directory,
+      recurse => true,
+      purge   => $purge_configs,
+      notify  => Class['Apache::Service'],
+      require => Package['httpd'],
+    }
+  } else {
+    $mod_load_dir = $mod_dir
+  }
+
+  if ! defined(File[$vhost_dir]) {
+    exec { "mkdir ${vhost_dir}":
+      creates => $vhost_dir,
+      require => Package['httpd'],
+    }
+    file { $vhost_dir:
+      ensure  => directory,
+      recurse => true,
+      purge   => $purge_configs,
+      notify  => Class['Apache::Service'],
+      require => Package['httpd'],
+    }
+  }
+
+  if $vhost_enable_dir and ! defined(File[$vhost_enable_dir]) {
+    $vhost_load_dir = $vhost_enable_dir
+    exec { "mkdir ${vhost_load_dir}":
+      creates => $vhost_load_dir,
+      require => Package['httpd'],
+    }
+    file { $vhost_enable_dir:
+      ensure  => directory,
+      recurse => true,
+      purge   => $purge_configs,
+      notify  => Class['Apache::Service'],
+      require => Package['httpd'],
+    }
+  } else {
+    $vhost_load_dir = $vhost_dir
+  }
+
+  concat { $ports_file:
+    owner   => 'root',
+    group   => $apache::params::root_group,
+    mode    => '0644',
+    notify  => Class['Apache::Service'],
+    require => Package['httpd'],
+  }
+  concat::fragment { 'Apache ports header':
+    target  => $ports_file,
+    content => template('apache/ports_header.erb')
+  }
+
+  if $apache::params::conf_dir and $apache::params::conf_file {
+    if $::osfamily == 'redhat' or $::operatingsystem == 'amazon' {
+      $docroot              = '/var/www/html'
+      $pidfile              = 'run/httpd.pid'
+      $error_log            = 'error_log'
+      $error_documents_path = '/var/www/error'
+      $scriptalias          = '/var/www/cgi-bin'
+      $access_log_file      = 'access_log'
+    } elsif $::osfamily == 'debian' {
+      $docroot              = '/var/www'
+      $pidfile              = '${APACHE_PID_FILE}'
+      $error_log            = 'error.log'
+      $error_documents_path = '/usr/share/apache2/error'
+      $scriptalias          = '/usr/lib/cgi-bin'
+      $access_log_file      = 'access.log'
+    } elsif $::osfamily == 'freebsd' {
+      $docroot              = '/usr/local/www/apache22/data'
+      $pidfile              = '/var/run/httpd.pid'
+      $error_log            = 'httpd-error.log'
+      $error_documents_path = '/usr/local/www/apache22/error'
+      $scriptalias          = '/usr/local/www/apache22/cgi-bin'
+      $access_log_file      = 'httpd-access.log'
+    } else {
+      fail("Unsupported osfamily ${::osfamily}")
+  }
+
+    $apxs_workaround = $::osfamily ? {
+      'freebsd' => true,
+      default   => false
+    }
+
+    # Template uses:
+    # - $pidfile
+    # - $user
+    # - $group
+    # - $logroot
+    # - $error_log
+    # - $sendfile
+    # - $mod_dir
+    # - $ports_file
+    # - $confd_dir
+    # - $vhost_dir
+    # - $error_documents
+    # - $error_documents_path
+    # - $apxs_workaround
+    # - $keepalive
+    # - $keepalive_timeout
+    # - $server_root
+    # - $server_tokens
+    # - $server_signature
+    # - $trace_enable
+    file { "${apache::params::conf_dir}/${apache::params::conf_file}":
+      ensure  => file,
+      content => template($conf_template),
+      notify  => Class['Apache::Service'],
+      require => Package['httpd'],
+    }
+
+    # preserve back-wards compatibility to the times when default_mods was
+    # only a boolean value. Now it can be an array (too)
+    if is_array($default_mods) {
+      class { 'apache::default_mods':
+        all  => false,
+        mods => $default_mods,
+      }
+    } else {
+      class { 'apache::default_mods':
+        all => $default_mods,
+      }
+    }
+    class { 'apache::default_confd_files':
+      all => $default_confd_files
+    }
+    if $mpm_module {
+      class { "apache::mod::${mpm_module}": }
+    }
+
+    $default_vhost_ensure = $default_vhost ? {
+      true  => 'present',
+      false => 'absent'
+    }
+    $default_ssl_vhost_ensure = $default_ssl_vhost ? {
+      true  => 'present',
+      false => 'absent'
+    }
+
+    apache::vhost { 'default':
+      ensure          => $default_vhost_ensure,
+      port            => 80,
+      docroot         => $docroot,
+      scriptalias     => $scriptalias,
+      serveradmin     => $serveradmin,
+      access_log_file => $access_log_file,
+      priority        => '15',
+      ip              => $ip,
+    }
+    $ssl_access_log_file = $::osfamily ? {
+      'freebsd' => $access_log_file,
+      default   => "ssl_${access_log_file}",
+    }
+    apache::vhost { 'default-ssl':
+      ensure          => $default_ssl_vhost_ensure,
+      port            => 443,
+      ssl             => true,
+      docroot         => $docroot,
+      scriptalias     => $scriptalias,
+      serveradmin     => $serveradmin,
+      access_log_file => $ssl_access_log_file,
+      priority        => '15',
+      ip              => $ip,
+    }
+  }
+}

data/modules/apache/manifests/listen.pp

@@ -0,0 +1,9 @@
+define apache::listen {
+  $listen_addr_port = $name
+
+  # Template uses: $listen_addr_port
+  concat::fragment { "Listen ${listen_addr_port}":
+    target  => $apache::ports_file,
+    content => template('apache/listen.erb'),
+  }
+}

data/modules/apache/manifests/mod/alias.pp

@@ -0,0 +1,17 @@
+class apache::mod::alias {
+  $icons_path = $::osfamily ? {
+    'debian'  => '/usr/share/apache2/icons',
+    'redhat'  => '/var/www/icons',
+    'freebsd' => '/usr/local/www/apache22/icons',
+  }
+  apache::mod { 'alias': }
+  # Template uses $icons_path
+  file { 'alias.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/alias.conf",
+    content => template('apache/mod/alias.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/auth_basic.pp

@@ -0,0 +1,3 @@
+class apache::mod::auth_basic {
+  apache::mod { 'auth_basic': }
+}

data/modules/apache/manifests/mod/auth_kerb.pp

@@ -0,0 +1,5 @@
+class apache::mod::auth_kerb {
+  apache::mod { 'auth_kerb': }
+}
+
+

data/modules/apache/manifests/mod/authnz_ldap.pp

@@ -0,0 +1,19 @@
+class apache::mod::authnz_ldap (
+  $verifyServerCert = true,
+) {
+  include 'apache::mod::ldap'
+  apache::mod { 'authnz_ldap': }
+
+  validate_bool($verifyServerCert)
+
+  # Template uses:
+  # - $verifyServerCert
+  file { 'authnz_ldap.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/authnz_ldap.conf",
+    content => template('apache/mod/authnz_ldap.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/autoindex.pp

@@ -0,0 +1,12 @@
+class apache::mod::autoindex {
+  apache::mod { 'autoindex': }
+  # Template uses no variables
+  file { 'autoindex.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/autoindex.conf",
+    content => template('apache/mod/autoindex.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/cache.pp

@@ -0,0 +1,3 @@
+class apache::mod::cache {
+  apache::mod { 'cache': }
+}

data/modules/apache/manifests/mod/cgi.pp

@@ -0,0 +1,4 @@
+class apache::mod::cgi {
+  Class['apache::mod::prefork'] -> Class['apache::mod::cgi']
+  apache::mod { 'cgi': }
+}

data/modules/apache/manifests/mod/cgid.pp

@@ -0,0 +1,23 @@
+class apache::mod::cgid {
+  Class['apache::mod::worker'] -> Class['apache::mod::cgid']
+
+  # Debian specifies it's cgid sock path, but RedHat uses the default value
+  # with no config file
+  $cgisock_path = $::osfamily ? {
+    'debian'  => '${APACHE_RUN_DIR}/cgisock',
+    'freebsd' => 'cgisock',
+    default   => undef,
+  }
+  apache::mod { 'cgid': }
+  if $cgisock_path {
+    # Template uses $cgisock_path
+    file { 'cgid.conf':
+      ensure  => file,
+      path    => "${apache::mod_dir}/cgid.conf",
+      content => template('apache/mod/cgid.conf.erb'),
+      require => Exec["mkdir ${apache::mod_dir}"],
+      before  => File[$apache::mod_dir],
+      notify  => Service['httpd'],
+    }
+  }
+}

data/modules/apache/manifests/mod/dav.pp

@@ -0,0 +1,3 @@
+class apache::mod::dav {
+  apache::mod { 'dav': }
+}

data/modules/apache/manifests/mod/dav_fs.pp

@@ -0,0 +1,20 @@
+class apache::mod::dav_fs {
+  $dav_lock = $::osfamily ? {
+    'debian'  => '${APACHE_LOCK_DIR}/DAVLock',
+    'freebsd' => '/usr/local/var/DavLock',
+    default   => '/var/lib/dav/lockdb',
+  }
+
+  Class['apache::mod::dav'] -> Class['apache::mod::dav_fs']
+  apache::mod { 'dav_fs': }
+
+  # Template uses: $dav_lock
+  file { 'dav_fs.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/dav_fs.conf",
+    content => template('apache/mod/dav_fs.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/dav_svn.pp

@@ -0,0 +1,5 @@
+class apache::mod::dav_svn {
+  Class['apache::mod::dav'] -> Class['apache::mod::dav_svn']
+  include apache::mod::dav
+  apache::mod { 'dav_svn': }
+}

data/modules/apache/manifests/mod/deflate.pp

@@ -0,0 +1,12 @@
+class apache::mod::deflate {
+  apache::mod { 'deflate': }
+  # Template uses no variables
+  file { 'deflate.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/deflate.conf",
+    content => template('apache/mod/deflate.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/dev.pp

@@ -0,0 +1,5 @@
+class apache::mod::dev {
+  # Development packages are not apache modules
+  warning('apache::mod::dev is deprecated; please use apache::dev')
+  include apache::dev
+}

data/modules/apache/manifests/mod/dir.pp

@@ -0,0 +1,21 @@
+# Note: this sets the global DirectoryIndex directive, it may be necessary to consider being able to modify the apache::vhost to declare DirectoryIndex statements in a vhost configuration
+# Parameters:
+# - $indexes provides a string for the DirectoryIndex directive http://httpd.apache.org/docs/current/mod/mod_dir.html#directoryindex
+class apache::mod::dir (
+  $dir     = 'public_html',
+  $indexes = ['index.html','index.html.var','index.cgi','index.pl','index.php','index.xhtml'],
+) {
+  validate_array($indexes)
+  apache::mod { 'dir': }
+
+  # Template uses
+  # - $indexes
+  file { 'dir.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/dir.conf",
+    content => template('apache/mod/dir.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/disk_cache.pp

@@ -0,0 +1,24 @@
+class apache::mod::disk_cache {
+  $cache_root = $::osfamily ? {
+    'debian'  => '/var/cache/apache2/mod_disk_cache',
+    'redhat'  => '/var/cache/mod_proxy',
+    'freebsd' => '/var/cache/mod_disk_cache',
+  }
+  if $::osfamily != 'FreeBSD' {
+    # FIXME: investigate why disk_cache was dependent on proxy
+    # NOTE: on FreeBSD disk_cache is compiled by default but proxy is not
+    Class['apache::mod::proxy'] -> Class['apache::mod::disk_cache']
+  }
+  Class['apache::mod::cache'] -> Class['apache::mod::disk_cache']
+
+  apache::mod { 'disk_cache': }
+  # Template uses $cache_proxy
+  file { 'disk_cache.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/disk_cache.conf",
+    content => template('apache/mod/disk_cache.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/event.pp

@@ -0,0 +1,54 @@
+class apache::mod::event (
+  $startservers        = '2',
+  $maxclients          = '150',
+  $minsparethreads     = '25',
+  $maxsparethreads     = '75',
+  $threadsperchild     = '25',
+  $maxrequestsperchild = '0',
+  $serverlimit         = '25',
+) {
+  if defined(Class['apache::mod::itk']) {
+    fail('May not include both apache::mod::event and apache::mod::itk on the same node')
+  }
+  if defined(Class['apache::mod::peruser']) {
+    fail('May not include both apache::mod::event and apache::mod::peruser on the same node')
+  }
+  if defined(Class['apache::mod::prefork']) {
+    fail('May not include both apache::mod::event and apache::mod::prefork on the same node')
+  }
+  if defined(Class['apache::mod::worker']) {
+    fail('May not include both apache::mod::event and apache::mod::worker on the same node')
+  }
+  File {
+    owner => 'root',
+    group => $apache::params::root_group,
+    mode  => '0644',
+  }
+
+  # Template uses:
+  # - $startservers
+  # - $maxclients
+  # - $minsparethreads
+  # - $maxsparethreads
+  # - $threadsperchild
+  # - $maxrequestsperchild
+  # - $serverlimit
+  file { "${apache::mod_dir}/event.conf":
+    ensure  => file,
+    content => template('apache/mod/event.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+
+  case $::osfamily {
+    'freebsd' : {
+      class { 'apache::package':
+        mpm_module => 'event'
+      }
+    }
+    default: {
+      fail("Unsupported osfamily ${::osfamily}")
+    }
+  }
+}

data/modules/apache/manifests/mod/expires.pp

@@ -0,0 +1,3 @@
+class apache::mod::expires {
+  apache::mod { 'expires': }
+}

data/modules/apache/manifests/mod/fastcgi.pp

@@ -0,0 +1,24 @@
+class apache::mod::fastcgi {
+
+  # Debian specifies it's fastcgi lib path, but RedHat uses the default value
+  # with no config file
+  $fastcgi_lib_path = $apache::params::fastcgi_lib_path
+
+  apache::mod { 'fastcgi': }
+
+  if $fastcgi_lib_path {
+    # Template uses:
+    # - $fastcgi_server
+    # - $fastcgi_socket
+    # - $fastcgi_dir
+    file { 'fastcgi.conf':
+      ensure  => file,
+      path    => "${apache::mod_dir}/fastcgi.conf",
+      content => template('apache/mod/fastcgi.conf.erb'),
+      require => Exec["mkdir ${apache::mod_dir}"],
+      before  => File[$apache::mod_dir],
+      notify  => Service['httpd'],
+    }
+  }
+
+}

data/modules/apache/manifests/mod/fcgid.pp

@@ -0,0 +1,3 @@
+class apache::mod::fcgid {
+  apache::mod { 'fcgid': }
+}

data/modules/apache/manifests/mod/headers.pp

@@ -0,0 +1,3 @@
+class apache::mod::headers {
+  apache::mod { 'headers': }
+}

data/modules/apache/manifests/mod/include.pp

@@ -0,0 +1,3 @@
+class apache::mod::include {
+  apache::mod { 'include': }
+}

data/modules/apache/manifests/mod/info.pp

@@ -0,0 +1,14 @@
+class apache::mod::info (
+  $allow_from = ['127.0.0.1','::1'],
+){
+  apache::mod { 'info': }
+  # Template uses $allow_from
+  file { 'info.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/info.conf",
+    content => template('apache/mod/info.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}