freighthop 0.2.1 → 0.3.0

data/modules/apache/manifests/mod/itk.pp

@@ -0,0 +1,64 @@
+class apache::mod::itk (
+  $startservers        = '8',
+  $minspareservers     = '5',
+  $maxspareservers     = '20',
+  $serverlimit         = '256',
+  $maxclients          = '256',
+  $maxrequestsperchild = '4000',
+) {
+  if defined(Class['apache::mod::event']) {
+    fail('May not include both apache::mod::itk and apache::mod::event on the same node')
+  }
+  if defined(Class['apache::mod::peruser']) {
+    fail('May not include both apache::mod::itk and apache::mod::peruser on the same node')
+  }
+  if defined(Class['apache::mod::prefork']) {
+    fail('May not include both apache::mod::itk and apache::mod::prefork on the same node')
+  }
+  if defined(Class['apache::mod::worker']) {
+    fail('May not include both apache::mod::itk and apache::mod::worker on the same node')
+  }
+  File {
+    owner => 'root',
+    group => $apache::params::root_group,
+    mode  => '0644',
+  }
+
+  # Template uses:
+  # - $startservers
+  # - $minspareservers
+  # - $maxspareservers
+  # - $serverlimit
+  # - $maxclients
+  # - $maxrequestsperchild
+  file { "${apache::mod_dir}/itk.conf":
+    ensure  => file,
+    content => template('apache/mod/itk.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+
+  case $::osfamily {
+    'debian' : {
+      file { "${apache::mod_enable_dir}/itk.conf":
+        ensure  => link,
+        target  => "${apache::mod_dir}/itk.conf",
+        require => Exec["mkdir ${apache::mod_enable_dir}"],
+        before  => File[$apache::mod_enable_dir],
+        notify  => Service['httpd'],
+      }
+      package { 'apache2-mpm-itk':
+        ensure => present,
+      }
+    }
+    'freebsd' : {
+      class { 'apache::package':
+        mpm_module => 'itk'
+      }
+    }
+    default: {
+      fail("Unsupported osfamily ${::osfamily}")
+    }
+  }
+}

data/modules/apache/manifests/mod/ldap.pp

@@ -0,0 +1,12 @@
+class apache::mod::ldap {
+  apache::mod { 'ldap': }
+  # Template uses no variables
+  file { 'ldap.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/ldap.conf",
+    content => template('apache/mod/ldap.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/mime.pp

@@ -0,0 +1,21 @@
+class apache::mod::mime (
+  $mime_support_package = $apache::params::mime_support_package,
+  $mime_types_config    = $apache::params::mime_types_config,
+) {
+  apache::mod { 'mime': }
+  # Template uses $mime_types_config
+  file { 'mime.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/mime.conf",
+    content => template('apache/mod/mime.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+  if $mime_support_package {
+    package { $mime_support_package:
+      ensure => 'installed',
+      before => File["${apache::mod_dir}/mime.conf"],
+    }
+  }
+}

data/modules/apache/manifests/mod/mime_magic.pp

@@ -0,0 +1,14 @@
+class apache::mod::mime_magic (
+  $magic_file = "${apache::params::conf_dir}/magic"
+) {
+  apache::mod { 'mime_magic': }
+  # Template uses $magic_file
+  file { 'mime_magic.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/mime_magic.conf",
+    content => template('apache/mod/mime_magic.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/negotiation.pp

@@ -0,0 +1,12 @@
+class apache::mod::negotiation {
+  apache::mod { 'negotiation': }
+  # Template uses no variables
+  file { 'negotiation.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/negotiation.conf",
+    content => template('apache/mod/negotiation.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/nss.pp

@@ -0,0 +1,25 @@
+class apache::mod::nss (
+  $transfer_log = "${::apache::params::logroot}/access.log",
+  $error_log = "${::apache::params::logroot}/error.log",
+  $passwd_file = undef
+  ) {
+  include apache::mod::mime
+  
+  apache::mod { 'nss': }
+
+  $httpd_dir = $apache::httpd_dir
+  
+  # Template uses:
+  # $transfer_log
+  # $error_log
+  # $http_dir
+  # passwd_file
+  file { 'nss.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/nss.conf",
+    content => template('apache/mod/nss.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/passenger.pp

@@ -0,0 +1,38 @@
+class apache::mod::passenger (
+  $passenger_high_performance     = undef,
+  $passenger_pool_idle_time       = undef,
+  $passenger_max_requests         = undef,
+  $passenger_stat_throttle_rate   = undef,
+  $rack_autodetect                = undef,
+  $rails_autodetect               = undef,
+  $passenger_root                 = $apache::params::passenger_root,
+  $passenger_ruby                 = $apache::params::passenger_ruby,
+  $passenger_max_pool_size        = undef,
+  $passenger_use_global_queue     = undef,
+) {
+  if $::osfamily == 'FreeBSD' {
+    apache::mod { 'passenger':
+      lib_path => "${passenger_root}/buildout/apache2"
+    }
+  } else {
+    apache::mod { 'passenger': }
+  }
+  # Template uses:
+  # - $passenger_root
+  # - $passenger_ruby
+  # - $passenger_max_pool_size
+  # - $passenger_high_performance
+  # - $passenger_max_requests
+  # - $passenger_stat_throttle_rate
+  # - $passenger_use_global_queue
+  # - $rack_autodetect
+  # - $rails_autodetect
+  file { 'passenger.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/passenger.conf",
+    content => template('apache/mod/passenger.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/perl.pp

@@ -0,0 +1,3 @@
+class apache::mod::perl {
+  apache::mod { 'perl': }
+}

data/modules/apache/manifests/mod/peruser.pp

@@ -0,0 +1,73 @@
+class apache::mod::peruser (
+  $minspareprocessors = '2',
+  $minprocessors = '2',
+  $maxprocessors = '10',
+  $maxclients = '150',
+  $maxrequestsperchild = '1000',
+  $idletimeout = '120',
+  $expiretimeout = '120',
+  $keepalive = 'Off',
+) {
+  if defined(Class['apache::mod::event']) {
+    fail('May not include both apache::mod::peruser and apache::mod::event on the same node')
+  }
+  if defined(Class['apache::mod::itk']) {
+    fail('May not include both apache::mod::peruser and apache::mod::itk on the same node')
+  }
+  if defined(Class['apache::mod::prefork']) {
+    fail('May not include both apache::mod::peruser and apache::mod::prefork on the same node')
+  }
+  if defined(Class['apache::mod::worker']) {
+    fail('May not include both apache::mod::peruser and apache::mod::worker on the same node')
+  }
+  File {
+    owner => 'root',
+    group => $apache::params::root_group,
+    mode  => '0644',
+  }
+
+  $mod_dir = $apache::mod_dir
+
+  # Template uses:
+  # - $minspareprocessors
+  # - $minprocessors
+  # - $maxprocessors
+  # - $maxclients
+  # - $maxrequestsperchild
+  # - $idletimeout
+  # - $expiretimeout
+  # - $keepalive
+  # - $mod_dir
+  file { "${apache::mod_dir}/peruser.conf":
+    ensure  => file,
+    content => template('apache/mod/peruser.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+  file { "${apache::mod_dir}/peruser":
+    ensure  => directory,
+    require => File[$apache::mod_dir],
+  }
+  file { "${apache::mod_dir}/peruser/multiplexers":
+    ensure  => directory,
+    require => File["${apache::mod_dir}/peruser"],
+  }
+  file { "${apache::mod_dir}/peruser/processors":
+    ensure  => directory,
+    require => File["${apache::mod_dir}/peruser"],
+  }
+
+  apache::peruser::multiplexer { '01-default': }
+
+  case $::osfamily {
+    'freebsd' : {
+      class { 'apache::package':
+        mpm_module => 'peruser'
+      }
+    }
+    default: {
+      fail("Unsupported osfamily ${::osfamily}")
+    }
+  }
+}

data/modules/apache/manifests/mod/php.pp

@@ -0,0 +1,26 @@
+class apache::mod::php (
+  $package_ensure = 'present',
+) {
+  if ! defined(Class['apache::mod::prefork']) {
+    fail('apache::mod::php requires apache::mod::prefork; please enable mpm_module => \'prefork\' on Class[\'apache\']')
+  }
+  apache::mod { 'php5':
+    package_ensure => $package_ensure,
+  }
+
+  include apache::mod::mime
+  include apache::mod::dir
+  Class['apache::mod::mime'] -> Class['apache::mod::dir'] -> Class['apache::mod::php']
+
+  file { 'php5.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/php5.conf",
+    content => template('apache/mod/php5.conf.erb'),
+    require => [
+      Class['apache::mod::prefork'],
+      Exec["mkdir ${apache::mod_dir}"],
+    ],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/prefork.pp

@@ -0,0 +1,74 @@
+class apache::mod::prefork (
+  $startservers        = '8',
+  $minspareservers     = '5',
+  $maxspareservers     = '20',
+  $serverlimit         = '256',
+  $maxclients          = '256',
+  $maxrequestsperchild = '4000',
+) {
+  if defined(Class['apache::mod::event']) {
+    fail('May not include both apache::mod::prefork and apache::mod::event on the same node')
+  }
+  if defined(Class['apache::mod::itk']) {
+    fail('May not include both apache::mod::prefork and apache::mod::itk on the same node')
+  }
+  if defined(Class['apache::mod::peruser']) {
+    fail('May not include both apache::mod::prefork and apache::mod::peruser on the same node')
+  }
+  if defined(Class['apache::mod::worker']) {
+    fail('May not include both apache::mod::prefork and apache::mod::worker on the same node')
+  }
+  File {
+    owner => 'root',
+    group => $apache::params::root_group,
+    mode  => '0644',
+  }
+
+  # Template uses:
+  # - $startservers
+  # - $minspareservers
+  # - $maxspareservers
+  # - $serverlimit
+  # - $maxclients
+  # - $maxrequestsperchild
+  file { "${apache::mod_dir}/prefork.conf":
+    ensure  => file,
+    content => template('apache/mod/prefork.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+
+  case $::osfamily {
+    'redhat': {
+      file_line { '/etc/sysconfig/httpd prefork enable':
+        ensure  => present,
+        path    => '/etc/sysconfig/httpd',
+        line    => '#HTTPD=/usr/sbin/httpd.worker',
+        match   => '#?HTTPD=/usr/sbin/httpd.worker',
+        require => Package['httpd'],
+        notify  => Service['httpd'],
+      }
+    }
+    'debian': {
+      file { "${apache::mod_enable_dir}/prefork.conf":
+        ensure  => link,
+        target  => "${apache::mod_dir}/prefork.conf",
+        require => Exec["mkdir ${apache::mod_enable_dir}"],
+        before  => File[$apache::mod_enable_dir],
+        notify  => Service['httpd'],
+      }
+      package { 'apache2-mpm-prefork':
+        ensure => present,
+      }
+    }
+    'freebsd' : {
+      class { 'apache::package':
+        mpm_module => 'prefork'
+      }
+    }
+    default: {
+      fail("Unsupported osfamily ${::osfamily}")
+    }
+  }
+}

data/modules/apache/manifests/mod/proxy.pp

@@ -0,0 +1,15 @@
+class apache::mod::proxy (
+  $proxy_requests = 'Off',
+  $allow_from = undef,
+) {
+  apache::mod { 'proxy': }
+  # Template uses $proxy_requests
+  file { 'proxy.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/proxy.conf",
+    content => template('apache/mod/proxy.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/proxy_ajp.pp

@@ -0,0 +1,4 @@
+class apache::mod::proxy_ajp {
+  Class['apache::mod::proxy'] -> Class['apache::mod::proxy_ajp']
+  apache::mod { 'proxy_ajp': }
+}

data/modules/apache/manifests/mod/proxy_balancer.pp

@@ -0,0 +1,10 @@
+class apache::mod::proxy_balancer {
+  
+  include apache::mod::proxy
+  include apache::mod::proxy_http
+  
+  Class['apache::mod::proxy'] -> Class['apache::mod::proxy_balancer']
+  Class['apache::mod::proxy_http'] -> Class['apache::mod::proxy_balancer']
+  apache::mod { 'proxy_balancer': }
+
+}

data/modules/apache/manifests/mod/proxy_html.pp

@@ -0,0 +1,28 @@
+class apache::mod::proxy_html {
+  Class['apache::mod::proxy'] -> Class['apache::mod::proxy_html']
+  Class['apache::mod::proxy_http'] -> Class['apache::mod::proxy_html']
+  apache::mod { 'proxy_html': }
+  case $::osfamily {
+    'RedHat': {
+      apache::mod { 'xml2enc': }
+    }
+    'Debian': {
+      $proxy_html_loadfiles = $apache::params::distrelease ? {
+        '6'     => '/usr/lib/libxml2.so.2',
+        default => "/usr/lib/${::hardwaremodel}-linux-gnu/libxml2.so.2",
+      }
+    }
+    'FreeBSD': {
+      apache::mod { 'xml2enc': }
+    }
+  }
+  # Template uses $icons_path
+  file { 'proxy_html.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/proxy_html.conf",
+    content => template('apache/mod/proxy_html.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/proxy_http.pp

@@ -0,0 +1,4 @@
+class apache::mod::proxy_http {
+  Class['apache::mod::proxy'] -> Class['apache::mod::proxy_http']
+  apache::mod { 'proxy_http': }
+}

data/modules/apache/manifests/mod/python.pp

@@ -0,0 +1,5 @@
+class apache::mod::python {
+  apache::mod { 'python': }
+}
+
+

data/modules/apache/manifests/mod/reqtimeout.pp

@@ -0,0 +1,12 @@
+class apache::mod::reqtimeout {
+  apache::mod { 'reqtimeout': }
+  # Template uses no variables
+  file { 'reqtimeout.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/reqtimeout.conf",
+    content => template('apache/mod/reqtimeout.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/rewrite.pp

@@ -0,0 +1,4 @@
+class apache::mod::rewrite {
+  include apache::params
+  apache::mod { 'rewrite': }
+}

data/modules/apache/manifests/mod/rpaf.pp

@@ -0,0 +1,20 @@
+class apache::mod::rpaf (
+  $sethostname = true,
+  $proxy_ips   = [ '127.0.0.1' ],
+  $header      = 'X-Forwarded-For'
+) {
+  apache::mod { 'rpaf': }
+
+  # Template uses:
+  # - $sethostname
+  # - $proxy_ips
+  # - $header
+  file { 'rpaf.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/rpaf.conf",
+    content => template('apache/mod/rpaf.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/setenvif.pp

@@ -0,0 +1,12 @@
+class apache::mod::setenvif {
+  apache::mod { 'setenvif': }
+  # Template uses no variables
+  file { 'setenvif.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/setenvif.conf",
+    content => template('apache/mod/setenvif.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/ssl.pp

@@ -0,0 +1,26 @@
+class apache::mod::ssl (
+  $ssl_compression = false,
+  $ssl_options     = [ 'StdEnvVars' ],
+) {
+  $session_cache = $::osfamily ? {
+    'debian'  => '${APACHE_RUN_DIR}/ssl_scache(512000)',
+    'redhat'  => '/var/cache/mod_ssl/scache(512000)',
+    'freebsd' => '/var/run/ssl_scache(512000)',
+  }
+  $ssl_mutex = $::osfamily ? {
+    'debian'  => 'file:${APACHE_RUN_DIR}/ssl_mutex',
+    'redhat'  => 'default',
+    'freebsd' => 'default',
+  }
+  apache::mod { 'ssl': }
+
+  # Template uses $ssl_compression, $ssl_options, $session_cache, $ssl_mutex
+  file { 'ssl.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/ssl.conf",
+    content => template('apache/mod/ssl.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/status.pp

@@ -0,0 +1,42 @@
+# Class: apache::mod::status
+#
+# This class enables and configures Apache mod_status
+# See: http://httpd.apache.org/docs/current/mod/mod_status.html
+#
+# Parameters:
+# - $allow_from is an array of hosts, ip addresses, partial network numbers
+#   or networks in CIDR notation specifying what hosts can view the special
+#   /server-status URL.  Defaults to ['127.0.0.1', '::1'].
+# - $extended_status track and display extended status information. Valid
+#   values are 'On' or 'Off'.  Defaults to 'On'.
+#
+# Actions:
+# - Enable and configure Apache mod_status
+#
+# Requires:
+# - The apache class
+#
+# Sample Usage:
+#
+#  # Simple usage allowing access from localhost and a private subnet
+#  class { 'apache::mod::status':
+#    $allow_from => ['127.0.0.1', '10.10.10.10/24'],
+#  }
+#
+class apache::mod::status (
+  $allow_from      = ['127.0.0.1','::1'],
+  $extended_status = 'On',
+){
+  validate_array($allow_from)
+  validate_re(downcase($extended_status), '^(on|off)$', "${extended_status} is not supported for extended_status.  Allowed values are 'On' and 'Off'.")
+  apache::mod { 'status': }
+  # Template uses $allow_from, $extended_status
+  file { 'status.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/status.conf",
+    content => template('apache/mod/status.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/suphp.pp

@@ -0,0 +1,14 @@
+class apache::mod::suphp (
+){
+  apache::mod { 'suphp': }
+
+  file {'suphp.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/suphp.conf",
+    content => template('apache/mod/suphp.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd']
+  }
+}
+

data/modules/apache/manifests/mod/userdir.pp

@@ -0,0 +1,17 @@
+class apache::mod::userdir (
+  $home = '/home',
+  $dir = 'public_html',
+  $disable_root = true,
+) {
+  apache::mod { 'userdir': }
+
+  # Template uses $home, $dir, $disable_root
+  file { 'userdir.conf':
+    ensure  => file,
+    path    => "${apache::mod_dir}/userdir.conf",
+    content => template('apache/mod/userdir.conf.erb'),
+    require => Exec["mkdir ${apache::mod_dir}"],
+    before  => File[$apache::mod_dir],
+    notify  => Service['httpd'],
+  }
+}

data/modules/apache/manifests/mod/vhost_alias.pp

@@ -0,0 +1,3 @@
+class apache::mod::vhost_alias {
+  apache::mod { 'vhost_alias': }
+}