couchbase-memcached 1.2.8

data/ext/libmemcached-0.50/m4/pandora_plugins.m4

@@ -0,0 +1,62 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+dnl--------------------------------------------------------------------
+dnl PANDORA_PLUGINS
+dnl Declare our plugin modules
+dnl--------------------------------------------------------------------
+
+AC_DEFUN([PANDORA_PLUGINS],[
+
+  dnl We do this to prime the files from a fresh checkout. Normally we want
+  dnl these commands to be executed by make. Perhaps we should split them into
+  dnl a few shell script snippets in config and make Make call them... we're
+  dnl going to get there...
+  dnl ANYWAY - syscmd gets called during aclocal - so before automake. It will
+  dnl get called probably during autoconf too, so it's important to protect
+  dnl with test -f ... if the files exist, we don't have the chicken/egg 
+  dnl problem and therefore don't need to do anything here
+  m4_syscmd([PYTHON=${PYTHON:-python} && $PYTHON config/pandora-plugin > /dev/null])
+  m4_syscmd([test -f config/plugin.stamp || touch config/plugin.stamp aclocal.m4])
+
+  m4_sinclude(config/pandora-plugin.ac)
+
+  dnl Add code here to read set plugin lists and  set drizzled_default_plugin_list
+  pandora_builtin_list=`echo $pandora_builtin_list | sed 's/, *$//'`
+  pandora_builtin_symbols_list=`echo $pandora_builtin_symbols_list | sed 's/, *$//'`
+  pandora_builtin_load_list=`echo $pandora_builtin_load_list | sed 's/, *$//'`
+  pandora_builtin_load_symbols_list=`echo $pandora_builtin_load_symbols_list | sed 's/, *$//'`
+  AS_IF([test "x$pandora_builtin_symbols_list" = "x"], pandora_builtin_symbols_list="NULL")
+  AS_IF([test "x$pandora_builtin_load_symbols_list" = "x"], pandora_builtin_load_symbols_list="NULL")
+  AC_SUBST([PANDORA_BUILTIN_LIST],[$pandora_builtin_list])
+  AC_SUBST([PANDORA_BUILTIN_SYMBOLS_LIST],[$pandora_builtin_symbols_list])
+  AC_SUBST([PANDORA_BUILTIN_LOAD_LIST],[$pandora_builtin_load_list])
+  AC_SUBST([PANDORA_BUILTIN_LOAD_SYMBOLS_LIST],[$pandora_builtin_load_symbols_list])
+  AC_SUBST([PANDORA_PLUGIN_LIST],[$pandora_default_plugin_list])
+  m4_ifval(m4_normalize([$1]),[
+    AC_CONFIG_FILES($*)
+    ],[
+    AC_DEFINE_UNQUOTED([PANDORA_BUILTIN_LIST],["$pandora_builtin_list"],
+                       [List of plugins to be built in])
+    AC_DEFINE_UNQUOTED([PANDORA_BUILTIN_SYMBOLS_LIST],["$pandora_builtin_symbols_list"],
+                       [List of builtin plugin symbols to be built in])
+    AC_DEFINE_UNQUOTED([PANDORA_PLUGIN_LIST],["$pandora_default_plugin_list"],
+                       [List of plugins that should be loaded on startup if no
+                        value is given for --plugin-load])
+  ])
+
+
+  AC_SUBST(pandora_plugin_test_list)
+  AC_SUBST(pandora_plugin_libs)
+
+  pandora_plugin_defs=`echo $pandora_plugin_defs | sed 's/, *$//'`
+  AC_SUBST(pandora_plugin_defs)
+
+  AC_SUBST(PANDORA_PLUGIN_DEP_LIBS)
+  AC_SUBST(pkgplugindir,"\$(pkglibdir)")
+])
+
+AC_DEFUN([PANDORA_ADD_PLUGIN_DEP_LIB],[
+  PANDORA_PLUGIN_DEP_LIBS="${PANDORA_PLUGIN_DEP_LIBS} $*"
+])

data/ext/libmemcached-0.50/m4/pandora_print_callstack.m4

@@ -0,0 +1,61 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl Try to define a macro to dump the current callstack.
+AC_DEFUN([PANDORA_PRINT_CALLSTACK],[
+  AC_CHECK_HEADERS([ucontext.h])
+  AS_IF([test "x$ac_cv_header_ucontext_h" = "xyes"],
+  	[ AC_CHECK_FUNCS([printstack]) ])
+
+
+  AS_IF([ test "x$ac_cv_func_printstack" != "xyes"],
+        [ AC_CHECK_HEADERS([dlfcn.h])
+          AC_CHECK_HEADERS([execinfo.h])
+          AC_CHECK_FUNCS([backtrace])
+          AC_CHECK_FUNCS([backtrace_symbols_fd]) ])
+
+  AH_BOTTOM([
+#ifdef __cplusplus
+#include <cstdio>
+#define PANDORA_PRINTSTACK_STD_PREFIX std::
+#else
+#include <stdio.h>
+#define PANDORA_PRINTSTACK_STD_PREFIX
+#endif
+
+#if defined(HAVE_UCONTEXT_H) && defined(HAVE_PRINTSTACK)
+#include <ucontext.h>
+#define pandora_print_callstack(a) \
+printstack(PANDORA_PRINTSTACK_STD_PREFIX fileno(a))
+#elif defined(HAVE_EXECINFO_H) && defined(HAVE_BACKTRACE) && defined(HAVE_BACKTRACE_SYMBOLS_FD)
+
+#include <execinfo.h>
+
+#define pandora_print_callstack(a) \
+{ \
+  void *stack[100];  \
+  int depth = backtrace(stack, 100); \
+  backtrace_symbols_fd(stack, depth, PANDORA_PRINTSTACK_STD_PREFIX fileno(a)); \
+}
+#elif defined(HAVE_EXECINFO_H) && defined(HAVE_BACKTRACE) && defined(HAVE_BACKTRACE_SYMBOLS) && !defined(HAVE_BACKTRACE_SYMBOLS_FD)
+
+#include <execinfo.h>
+
+#define pandora_print_callstack(a) \
+{ \
+  void *stack[100];  \
+  int depth= backtrace(stack, 100); \
+  char **symbol= backtrace_symbols(stack, depth); \
+  for (int x= 0; x < size; ++x) \
+    PANDORA_PRINTSTACK_STD_PREFIX fprintf(a, "%s\n", symbol[x]); \
+}
+#else
+#define pandora_print_callstack(a) \
+    PANDORA_PRINTSTACK_STD_PREFIX fprintf(a, \
+      "Stackdump not supported for this platform\n");
+#endif
+  ])
+
+])

data/ext/libmemcached-0.50/m4/pandora_pthread.m4

@@ -0,0 +1,258 @@
+dnl -*- mode: m4; c-basic-offset: 2; indent-tabs-mode: nil; -*-
+dnl vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
+dnl   
+dnl pandora-build: A pedantic build system
+dnl Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+dnl
+dnl From Monty Taylor
+
+
+dnl --------------------------------------------------------------------
+dnl  Check for libpthread
+dnl --------------------------------------------------------------------
+
+AC_DEFUN([PANDORA_PTHREAD_YIELD],[
+  AC_REQUIRE([ACX_PTHREAD])
+
+  save_CFLAGS="${CFLAGS}"
+  save_CXXFLAGS="${CXXFLAGS}"
+  CFLAGS="${PTHREAD_CFLAGS} ${CFLAGS}"
+  CXXFLAGS="${PTHREAD_CFLAGS} ${CXXFLAGS}"
+  dnl Some OSes like Mac OS X have that as a replacement for pthread_yield()
+  AC_CHECK_FUNCS(pthread_yield_np)
+  AC_CACHE_CHECK([if pthread_yield takes zero arguments],
+    [pandora_cv_pthread_yield_zero_arg],
+    [AC_LINK_IFELSE([
+      AC_LANG_PROGRAM([[
+#include <pthread.h>
+        ]],[[
+  pthread_yield();
+        ]])],
+      [pandora_cv_pthread_yield_zero_arg=yes],
+      [pandora_cv_pthread_yield_zero_arg=no])])
+  AS_IF([test "$pandora_cv_pthread_yield_zero_arg" = "yes"],[
+    AC_DEFINE([HAVE_PTHREAD_YIELD_ZERO_ARG], [1],
+              [pthread_yield that doesn't take any arguments])
+  ])
+
+  AC_CACHE_CHECK([if pthread_yield takes one argument],
+    [pandora_cv_pthread_yield_one_arg],
+    [AC_LINK_IFELSE([
+      AC_LANG_PROGRAM([[
+#include <pthread.h>
+        ]],[[
+  pthread_yield(0);
+        ]])],
+      [pandora_cv_pthread_yield_one_arg=yes],
+      [pandora_cv_pthread_yield_one_arg=no])])
+  AS_IF([test "$pandora_cv_pthread_yield_one_arg" = "yes"],[
+    AC_DEFINE([HAVE_PTHREAD_YIELD_ONE_ARG], [1],
+              [pthread_yield function with one argument])
+  ])
+
+  AC_CHECK_FUNCS(pthread_attr_getstacksize pthread_attr_setprio \
+    pthread_attr_setschedparam \
+    pthread_attr_setstacksize pthread_condattr_create pthread_getsequence_np \
+    pthread_key_delete pthread_rwlock_rdlock pthread_setprio \
+    pthread_setprio_np pthread_setschedparam pthread_sigmask \
+    pthread_attr_create rwlock_init
+)
+
+
+
+# Check definition of pthread_getspecific
+AC_CACHE_CHECK([args to pthread_getspecific], [pandora_cv_getspecific_args],
+  [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#if !defined(_REENTRANT)
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS 
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h>
+   ]], [[
+void *pthread_getspecific(pthread_key_t key);
+pthread_getspecific((pthread_key_t) NULL);
+   ]])],
+    [pandora_cv_getspecific_args=POSIX],
+    [pandora_cv_getspecific_args=other])])
+  if test "$pandora_cv_getspecific_args" = "other"
+  then
+    AC_DEFINE([HAVE_NONPOSIX_PTHREAD_GETSPECIFIC], [1],
+              [For some non posix threads])
+  fi
+
+  # Check definition of pthread_mutex_init
+  AC_CACHE_CHECK([args to pthread_mutex_init], [pandora_cv_mutex_init_args],
+    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#ifndef _REENTRANT
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h> ]], [[ 
+  pthread_mutexattr_t attr;
+  pthread_mutex_t mp;
+  pthread_mutex_init(&mp,&attr); ]])],
+      [pandora_cv_mutex_init_args=POSIX],
+      [pandora_cv_mutex_init_args=other])])
+  if test "$pandora_cv_mutex_init_args" = "other"
+  then
+    AC_DEFINE([HAVE_NONPOSIX_PTHREAD_MUTEX_INIT], [1],
+              [For some non posix threads])
+  fi
+#---END:
+
+#---START: Used in for client configure
+# Check definition of readdir_r
+AC_CACHE_CHECK([args to readdir_r], [pandora_cv_readdir_r],
+  [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#ifndef _REENTRANT
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS 
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h>
+#include <dirent.h>]], [[ int readdir_r(DIR *dirp, struct dirent *entry, struct dirent **result);
+readdir_r((DIR *) NULL, (struct dirent *) NULL, (struct dirent **) NULL); ]])],
+    [pandora_cv_readdir_r=POSIX],
+    [pandora_cv_readdir_r=other])])
+if test "$pandora_cv_readdir_r" = "POSIX"
+then
+  AC_DEFINE([HAVE_READDIR_R], [1], [POSIX readdir_r])
+fi
+
+# Check definition of posix sigwait()
+AC_CACHE_CHECK([style of sigwait], [pandora_cv_sigwait],
+  [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#ifndef _REENTRANT
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h>
+#include <signal.h>
+      ]], [[
+#ifndef _AIX
+sigset_t set;
+int sig;
+sigwait(&set,&sig);
+#endif
+      ]])],
+    [pandora_cv_sigwait=POSIX],
+    [pandora_cv_sigwait=other])])
+if test "$pandora_cv_sigwait" = "POSIX"
+then
+  AC_DEFINE([HAVE_SIGWAIT], [1], [POSIX sigwait])
+fi
+
+if test "$pandora_cv_sigwait" != "POSIX"
+then
+unset pandora_cv_sigwait
+# Check definition of posix sigwait()
+AC_CACHE_CHECK([style of sigwait], [pandora_cv_sigwait],
+  [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#ifndef _REENTRANT
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h>
+#include <signal.h>
+      ]], [[
+sigset_t set;
+int sig;
+sigwait(&set);
+      ]])],
+    [pandora_cv_sigwait=NONPOSIX],
+    [pandora_cv_sigwait=other])])
+if test "$pandora_cv_sigwait" = "NONPOSIX"
+then
+  AC_DEFINE([HAVE_NONPOSIX_SIGWAIT], [1], [sigwait with one argument])
+fi
+fi
+#---END:
+
+# Check if pthread_attr_setscope() exists
+AC_CACHE_CHECK([for pthread_attr_setscope], [pandora_cv_pthread_attr_setscope],
+  [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
+#ifndef _REENTRANT
+#define _REENTRANT
+#endif
+#ifndef _POSIX_PTHREAD_SEMANTICS
+#define _POSIX_PTHREAD_SEMANTICS 
+#endif
+#include <pthread.h>
+      ]], [[
+pthread_attr_t thr_attr;
+pthread_attr_setscope(&thr_attr,0);
+      ]])],
+    [pandora_cv_pthread_attr_setscope=yes],
+    [pandora_cv_pthread_attr_setscope=no])])
+if test "$pandora_cv_pthread_attr_setscope" = "yes"
+then
+  AC_DEFINE([HAVE_PTHREAD_ATTR_SETSCOPE], [1], [pthread_attr_setscope])
+fi
+
+
+AC_CACHE_CHECK([if pthread_yield takes zero arguments], ac_cv_pthread_yield_zero_arg,
+[AC_TRY_LINK([#define _GNU_SOURCE
+#include <pthread.h>
+#ifdef __cplusplus
+extern "C"
+#endif
+],
+[
+  pthread_yield();
+], ac_cv_pthread_yield_zero_arg=yes, ac_cv_pthread_yield_zero_arg=yeso)])
+if test "$ac_cv_pthread_yield_zero_arg" = "yes"
+then
+  AC_DEFINE([HAVE_PTHREAD_YIELD_ZERO_ARG], [1],
+            [pthread_yield that doesn't take any arguments])
+fi
+AC_CACHE_CHECK([if pthread_yield takes 1 argument], ac_cv_pthread_yield_one_arg,
+[AC_TRY_LINK([#define _GNU_SOURCE
+#include <pthread.h>
+#ifdef __cplusplus
+extern "C"
+#endif
+],
+[
+  pthread_yield(0);
+], ac_cv_pthread_yield_one_arg=yes, ac_cv_pthread_yield_one_arg=no)])
+if test "$ac_cv_pthread_yield_one_arg" = "yes"
+then
+  AC_DEFINE([HAVE_PTHREAD_YIELD_ONE_ARG], [1],
+            [pthread_yield function with one argument])
+fi
+
+  CFLAGS="${save_CFLAGS}"
+  CXXFLAGS="${save_CXXFLAGS}"
+])
+
+
+AC_DEFUN([_PANDORA_SEARCH_PTHREAD],[
+  AC_REQUIRE([ACX_PTHREAD])
+  LIBS="${PTHREAD_LIBS} ${LIBS}"
+  AM_CFLAGS="${PTHREAD_CFLAGS} ${AM_CFLAGS}"
+  AM_CXXFLAGS="${PTHREAD_CFLAGS} ${AM_CXXFLAGS}"
+  PANDORA_PTHREAD_YIELD
+])
+
+
+AC_DEFUN([PANDORA_HAVE_PTHREAD],[
+  AC_REQUIRE([_PANDORA_SEARCH_PTHREAD])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_PTHREAD],[
+  AC_REQUIRE([PANDORA_HAVE_PTHREAD])
+  AS_IF([test "x$acx_pthread_ok" != "xyes"],[
+    AC_MSG_ERROR(could not find libpthread)])
+])

data/ext/libmemcached-0.50/m4/pandora_python3_devel.m4

@@ -0,0 +1,236 @@
+dnl -*- mode: m4; c-basic-offset: 2; indent-tabs-mode: nil; -*-
+dnl vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
+dnl   
+dnl pandora-build: A pedantic build system
+dnl
+dnl   Copyright (C) 2009 Sun Microsystems, Inc.
+dnl   Copyright (C) 2008 Sebastian Huber <sebastian-huber@web.de>
+dnl   Copyright (C) 2008 Alan W. Irwin <irwin@beluga.phys.uvic.ca>
+dnl   Copyright (C) 2008 Rafael Laboissiere <rafael@laboissiere.net>
+dnl   Copyright (C) 2008 Andrew Collier <colliera@ukzn.ac.za>
+dnl   Copyright (C) 2008 Matteo Settenvini <matteo@member.fsf.org>
+dnl   Copyright (C) 2008 Horst Knorr <hk_classes@knoda.org>
+dnl
+dnl   This program is free software: you can redistribute it and/or modify it
+dnl   under the terms of the GNU General Public License as published by the
+dnl   Free Software Foundation, either version 3 of the License, or (at your
+dnl   option) any later version.
+dnl
+dnl   This program is distributed in the hope that it will be useful, but
+dnl   WITHOUT ANY WARRANTY; without even the implied warranty of
+dnl   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+dnl   Public License for more details.
+dnl
+dnl   You should have received a copy of the GNU General Public License along
+dnl   with this program. If not, see <http://www.gnu.org/licenses/>.
+dnl
+dnl   As a special exception, the respective Autoconf Macro's copyright owner
+dnl   gives unlimited permission to copy, distribute and modify the configure
+dnl   scripts that are the output of Autoconf when processing the Macro. You
+dnl   need not follow the terms of the GNU General Public License when using
+dnl   or distributing such scripts, even though portions of the text of the
+dnl   Macro appear in them. The GNU General Public License (GPL) does govern
+dnl   all other use of the material that constitutes the Autoconf Macro.
+dnl
+dnl   This special exception to the GPL applies to versions of the Autoconf
+dnl   Macro released by the Autoconf Macro Archive. When you make and
+dnl   distribute a modified version of the Autoconf Macro, you may extend this
+dnl   special exception to the GPL to apply to your modified version as well.
+
+dnl SYNOPSIS
+dnl
+dnl   PANDORA_PYTHON3_DEVEL([version])
+dnl
+dnl DESCRIPTION
+dnl
+dnl   Note: Defines as a precious variable "PYTHON3_VERSION". Don't override it
+dnl   in your configure.ac.
+dnl
+dnl   This macro checks for Python and tries to get the include path to
+dnl   'Python.h'. It provides the $(PYTHON3_CPPFLAGS) and $(PYTHON3_LDFLAGS)
+dnl   output variables. It also exports $(PYTHON3_EXTRA_LIBS) and
+dnl   $(PYTHON3_EXTRA_LDFLAGS) for embedding Python in your code.
+dnl
+dnl   You can search for some particular version of Python by passing a
+dnl   parameter to this macro, for example ">= '2.3.1'", or "== '2.4'". Please
+dnl   note that you *have* to pass also an operator along with the version to
+dnl   match, and pay special attention to the single quotes surrounding the
+dnl   version number. Don't use "PYTHON3_VERSION" for this: that environment
+dnl   variable is declared as precious and thus reserved for the end-user.
+dnl
+dnl LAST MODIFICATION
+dnl
+dnl   2009-08-23
+
+AC_DEFUN([PANDORA_PYTHON3_DEVEL],[
+	#
+	# Allow the use of a (user set) custom python version
+	#
+	AC_ARG_VAR([PYTHON3_VERSION],[The installed Python
+		version to use, for example '3.0'. This string
+		will be appended to the Python interpreter
+		canonical name.])
+
+
+  AS_IF([test -z "$PYTHON3"],[
+  	AC_PATH_PROG([PYTHON3],[python[$PYTHON3_VERSION]])
+  ])
+	AS_IF([test -z "$PYTHON3"],[
+	  AC_MSG_ERROR([Cannot find python$PYTHON3_VERSION in your system path])
+	  PYTHON3_VERSION=""
+  ])
+
+	#
+	# if the macro parameter ``version'' is set, honour it
+	#
+	if test -n "$1"; then
+		AC_MSG_CHECKING([for a version of Python $1])
+		ac_supports_python3_ver=`$PYTHON3 -c "import sys, string; \
+			ver = string.split(sys.version)[[0]]; \
+			print(ver $1)"`
+		if test "$ac_supports_python3_ver" = "True"; then
+	   	   AC_MSG_RESULT([yes])
+		else
+			AC_MSG_RESULT([no])
+			AC_MSG_ERROR([this package requires Python $1.
+If you have it installed, but it isn't the default Python
+interpreter in your system path, please pass the PYTHON3_VERSION
+variable to configure. See ``configure --help'' for reference.
+])
+			PYTHON_VERSION=""
+		fi
+	fi
+
+	#
+	# Check if you have distutils, else fail
+	#
+	AC_MSG_CHECKING([for Python3 distutils package])
+	ac_python3_distutils_result=`$PYTHON3 -c "import distutils" 2>&1`
+	if test -z "$ac_python3_distutils_result"; then
+		AC_MSG_RESULT([yes])
+	else
+		AC_MSG_RESULT([no])
+		AC_MSG_ERROR([cannot import Python3 module "distutils".
+Please check your Python3 installation. The error was:
+$ac_python3_distutils_result])
+		PYTHON3_VERSION=""
+	fi
+
+	#
+	# Check for Python include path
+	#
+	AC_MSG_CHECKING([for Python3 include path])
+	if test -z "$PYTHON3_CPPFLAGS"; then
+		python3_path=`$PYTHON3 -c "import distutils.sysconfig; \
+           		print(distutils.sysconfig.get_python_inc());"`
+		if test -n "${python3_path}"; then
+		   	python3_path="-I$python3_path"
+		fi
+		PYTHON3_CPPFLAGS=$python3_path
+	fi
+	AC_MSG_RESULT([$PYTHON3_CPPFLAGS])
+	AC_SUBST([PYTHON3_CPPFLAGS])
+
+	#
+	# Check for Python library path
+	#
+	AC_MSG_CHECKING([for Python3 library path])
+	if test -z "$PYTHON3_LDFLAGS"; then
+		# (makes two attempts to ensure we've got a version number
+		# from the interpreter)
+		py3_version=`$PYTHON3 -c "from distutils.sysconfig import *; \
+			print(' '.join(get_config_vars('VERSION')))"`
+		if test "$py3_version" == "[None]"; then
+			if test -n "$PYTHON3_VERSION"; then
+				py3_version=$PYTHON3_VERSION
+			else
+				py3_version=`$PYTHON3 -c "import sys; \
+					print(sys.version[[:3]])"`
+			fi
+		fi
+
+		PYTHON3_LDFLAGS=`$PYTHON3 -c "from distutils.sysconfig import *; \
+			print('-L' + get_python_lib(0,1), \
+		      	'-lpython');"`$py3_version
+	fi
+	AC_MSG_RESULT([$PYTHON3_LDFLAGS])
+	AC_SUBST([PYTHON3_LDFLAGS])
+
+	#
+	# Check for site packages
+	#
+	AC_MSG_CHECKING([for Python3 site-packages path])
+	if test -z "$PYTHON3_SITE_PKG"; then
+		PYTHON3_SITE_PKG=`$PYTHON3 -c "import distutils.sysconfig; \
+		        print(distutils.sysconfig.get_python_lib(0,0));"`
+	fi
+	AC_MSG_RESULT([$PYTHON3_SITE_PKG])
+	AC_SUBST([PYTHON3_SITE_PKG])
+
+	#
+	# libraries which must be linked in when embedding
+	#
+	AC_MSG_CHECKING(for Python3 embedding libraries)
+	if test -z "$PYTHON3_EMBED_LIBS"; then
+	   PYTHON3_EMBED_LIBS=`$PYTHON3 -c "import distutils.sysconfig; \
+                conf = distutils.sysconfig.get_config_var; \
+                print(conf('LOCALMODLIBS'), conf('LIBS'))"`
+	fi
+	AC_MSG_RESULT([$PYTHON3_EMBED_LIBS])
+	AC_SUBST(PYTHON3_EMBED_LIBS)
+
+	#
+	# linking flags needed when embedding
+	#
+	AC_MSG_CHECKING(for Python3 embedding linking flags)
+	if test -z "$PYTHON3_EMBED_LDFLAGS"; then
+		PYTHON3_EMBED_LDFLAGS=`$PYTHON3 -c "import distutils.sysconfig; \
+			conf = distutils.sysconfig.get_config_var; \
+			print(conf('LINKFORSHARED'))"`
+	fi
+	AC_MSG_RESULT([$PYTHON3_EMBED_LDFLAGS])
+	AC_SUBST(PYTHON3_EMBED_LDFLAGS)
+
+	#
+	# final check to see if everything compiles alright
+	#
+	AC_MSG_CHECKING([for Python3 development environment consistency])
+	AC_LANG_PUSH([C])
+	# save current global flags
+  ac_save_LIBS="$LIBS"
+  ac_save_CPPFLAGS="$CPPFLAGS"
+	LIBS="$ac_save_LIBS $PYTHON3_LDFLAGS"
+	CPPFLAGS="$ac_save_CPPFLAGS $PYTHON3_CPPFLAGS"
+	AC_TRY_LINK([
+		#include <Python.h>
+	],[
+		Py_Initialize();
+	],[python3exists=yes],[python3exists=no])
+
+	AC_MSG_RESULT([$python3exists])
+
+        if test ! "$python3exists" = "yes"; then
+	   AC_MSG_WARN([
+  Could not link test program to Python3.
+  Maybe the main Python3 library has been installed in some non-standard
+  library path. If so, pass it to configure, via the LDFLAGS environment
+  variable.
+  Example: ./configure LDFLAGS="-L/usr/non-standard-path/python3/lib"
+  ============================================================================
+   ERROR!
+   You probably have to install the development version of the Python3 package
+   for your distribution.  The exact name of this package varies among them.
+  ============================================================================
+	   ])
+	  PYTHON3_VERSION=""
+	fi
+	AC_LANG_POP
+	# turn back to default flags
+	CPPFLAGS="$ac_save_CPPFLAGS"
+	LIBS="$ac_save_LIBS"
+
+	#
+	# all done!
+	#
+])
+