couchbase-memcached 1.2.8

data/ext/libmemcached-0.50/m4/pandora_run_cpplint.m4

@@ -0,0 +1,8 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_RUN_CPPLINT],[
+  m4_syscmd([python config/make-lint.py])
+])

data/ext/libmemcached-0.50/m4/pandora_sasl.m4

@@ -0,0 +1,133 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_SASL],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for sasl
+  dnl --------------------------------------------------------------------
+  AC_ARG_ENABLE([sasl],
+    [AS_HELP_STRING([--disable-sasl],
+      [Build with sasl support @<:@default=on@:>@])],
+    [ac_enable_sasl="$enableval"],
+    [ac_enable_sasl="yes"])
+
+  AS_IF([test "x$ac_enable_sasl" = "xyes"],
+    [
+      AC_LIB_HAVE_LINKFLAGS(sasl,,[
+        #include <stdlib.h>
+        #include <sasl/sasl.h>
+      ],[
+        sasl_server_init(NULL, NULL);
+      ])
+
+      AS_IF([test "x${ac_cv_libsasl}" != "xyes" ],
+            [
+              AC_LIB_HAVE_LINKFLAGS(sasl2,,[
+                #include <stdlib.h>
+                #include <sasl/sasl.h>
+              ],[
+                sasl_server_init(NULL, NULL);
+              ])
+              HAVE_LIBSASL="$HAVE_LIBSASL2"
+              LIBSASL="$LIBSASL2"
+              LIBSASL_PREFIX="$LIBSASL2_PREFIX"
+	      LTLIBSASL="$LT_LIBSASL2"
+            ])
+    ])
+
+  AS_IF([test "x${ac_cv_libsasl}" = "xyes" -o "x${ac_cv_libsasl2}" = "xyes"],
+        [ac_cv_sasl=yes],
+        [ac_cv_sasl=no])
+
+  AM_CONDITIONAL(HAVE_LIBSASL, [test "x${ac_cv_libsasl}" = "xyes"])
+  AM_CONDITIONAL(HAVE_LIBSASL2, [test "x${ac_cv_libsasl2}" = "xyes"])
+  AM_CONDITIONAL(HAVE_SASL, [test "x${ac_cv_sasl}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_SASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_SASL])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_SASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_SASL])
+  AS_IF([test "x${ac_cv_sasl}" = "xno"],
+    AC_MSG_ERROR([SASL (libsasl or libsasl2) is required for ${PACKAGE}]))
+])
+
+AC_DEFUN([_PANDORA_SEARCH_LIBSASL],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libsasl
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libsasl],
+    [AS_HELP_STRING([--disable-libsasl],
+      [Build with libsasl support @<:@default=on@:>@])],
+    [ac_enable_libsasl="$enableval"],
+    [ac_enable_libsasl="yes"])
+
+  AS_IF([test "x$ac_enable_libsasl" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(sasl,,[
+      #include <stdlib.h>
+      #include <sasl/sasl.h>
+    ],[
+      sasl_server_init(NULL, NULL);
+    ])
+  ],[
+    ac_cv_libsasl="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBSASL, [test "x${ac_cv_libsasl}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBSASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBSASL],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL])
+  AS_IF([test "x${ac_cv_libsasl}" = "xno"],
+    AC_MSG_ERROR([libsasl is required for ${PACKAGE}]))
+])
+
+AC_DEFUN([_PANDORA_SEARCH_LIBSASL2],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libsasl2
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libsasl2],
+    [AS_HELP_STRING([--disable-libsasl2],
+      [Build with libsasl2 support @<:@default=on@:>@])],
+    [ac_enable_libsasl2="$enableval"],
+    [ac_enable_libsasl2="yes"])
+
+  AS_IF([test "x$ac_enable_libsasl2" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(sasl2,,[
+      #include <stdlib.h>
+      #include <sasl2/sasl2.h>
+    ],[
+      sasl2_server_init(NULL, NULL);
+    ])
+  ],[
+    ac_cv_libsasl2="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBSASL2, [test "x${ac_cv_libsasl2}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBSASL2],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL2])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBSASL2],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBSASL2])
+  AS_IF([test "x${ac_cv_libsasl2}" = "xno"],
+    AC_MSG_ERROR([libsasl2 is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_shared_ptr.m4

@@ -0,0 +1,59 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+dnl We check two things: where is the memory include file, and in what
+dnl namespace does shared_ptr reside.
+dnl We include AC_COMPILE_IFELSE for all the combinations we've seen in the
+dnl wild:
+dnl 
+dnl  GCC 4.3: namespace: std::  #include <memory>
+dnl  GCC 4.2: namespace: tr1::  #include <tr1/memory>
+dnl  GCC 4.2: namespace: boost::  #include <boost/shared_ptr.hpp>
+dnl
+dnl We define one of HAVE_HAVE_TR1_SHARED_PTR or HAVE_BOOST_SHARED_PTR
+dnl depending on location, and SHARED_PTR_NAMESPACE to be the namespace in
+dnl which shared_ptr is defined.
+dnl 
+
+AC_DEFUN([PANDORA_SHARED_PTR],[
+  AC_REQUIRE([PANDORA_CHECK_CXX_STANDARD])
+  AC_LANG_PUSH(C++)
+  save_CXXFLAGS="${CXXFLAGS}"
+  CXXFLAGS="${CXX_STANDARD} ${CXXFLAGS}"
+  AC_CHECK_HEADERS(memory tr1/memory boost/shared_ptr.hpp)
+  AC_CACHE_CHECK([the location of shared_ptr header file],
+    [ac_cv_shared_ptr_h],[
+      for namespace in std tr1 std::tr1 boost
+      do
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM([[
+#if defined(HAVE_MEMORY)
+# include <memory>
+#endif
+#if defined(HAVE_TR1_MEMORY)
+# include <tr1/memory>
+#endif
+#if defined(HAVE_BOOST_SHARED_PTR_HPP)
+# include <boost/shared_ptr.hpp>
+#endif
+#include <string>
+
+using $namespace::shared_ptr;
+using namespace std;
+            ]],[[
+shared_ptr<string> test_ptr(new string("test string"));
+            ]])],
+            [
+              ac_cv_shared_ptr_namespace="${namespace}"
+              break
+            ],[ac_cv_shared_ptr_namespace=missing])
+       done
+  ])
+  AC_DEFINE_UNQUOTED([SHARED_PTR_NAMESPACE],
+                     ${ac_cv_shared_ptr_namespace},
+                     [The namespace in which SHARED_PTR can be found])
+  CXXFLAGS="${save_CXXFLAGS}"
+  AC_LANG_POP()
+])

data/ext/libmemcached-0.50/m4/pandora_stack_direction.m4

@@ -0,0 +1,39 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+#--------------------------------------------------------------------
+# Check what direction the stack runs in
+#--------------------------------------------------------------------
+
+AC_DEFUN([PANDORA_STACK_DIRECTION],[
+ AC_REQUIRE([AC_FUNC_ALLOCA])
+ AC_CACHE_CHECK([stack direction], [ac_cv_c_stack_direction],[
+  AC_RUN_IFELSE([AC_LANG_PROGRAM([[
+#include <stdlib.h>
+ int find_stack_direction ()
+ {
+   static char *addr = 0;
+   auto char dummy;
+   if (addr == 0)
+     {
+       addr = &dummy;
+       return find_stack_direction ();
+     }
+   else
+     return (&dummy > addr) ? 1 : -1;
+ }
+  ]],[[
+    exit (find_stack_direction() < 0);
+  ]])],[
+   ac_cv_c_stack_direction=1
+  ],[
+   ac_cv_c_stack_direction=-1
+  ])
+ ])
+ AC_DEFINE_UNQUOTED(STACK_DIRECTION, $ac_cv_c_stack_direction)
+])
+
+
+

data/ext/libmemcached-0.50/m4/pandora_stl_hash.m4

@@ -0,0 +1,94 @@
+# Copyright (C) 2008 Sun Microsystems, Inc.
+# This file is free software; Sun Microsystems, Inc.
+# gives unlimited permission to copy and/or distribute it,
+# with or without modifications, as long as this notice is preserved.
+
+# We check two things: where the include file is for unordered_map, and
+# what namespace unordered_map lives in within that include file.  We
+# include AC_COMPILE_IFELSE for all the combinations we've seen in the
+# wild.  We define HAVE_UNORDERED_MAP and HAVE_UNORDERED_SET if we have
+# them, UNORDERED_MAP_H and UNORDERED_SET_H to their location and
+# UNORDERED_NAMESPACE to be the namespace unordered_map is defined in.
+
+AC_DEFUN([PANDORA_CXX_STL_UNORDERED],[
+  save_CXXFLAGS="${CXXFLAGS}"
+  CXXFLAGS="${AM_CXXFLAGS} ${CXXFLAGS}"
+  AC_LANG_PUSH(C++)
+  AC_CACHE_CHECK([for STL unordered_map],
+    [pandora_cv_stl_unordered],[
+      AC_COMPILE_IFELSE(
+        [AC_LANG_PROGRAM([[#include <unordered_map>]],
+                         [[std::unordered_map<int, int> t]])],
+        [pandora_cv_stl_unordered="yes"],
+        [pandora_cv_stl_unordered="no"])])
+
+  AS_IF([test "x${pandora_cv_stl_unordered}" != "xyes"],[
+    AC_CACHE_CHECK([for tr1 unordered_map],
+      [pandora_cv_tr1_unordered],[
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM([[
+/* We put in this define because of a YACC symbol clash in Drizzle.
+   Seriously... I cannot believe the GCC guys defined a piece of the internals
+   of this named IF - and I can't believe that YACC generates a token define
+   called IF. Really?
+*/
+#define IF 21;
+#include <tr1/unordered_map>
+            ]],[[
+std::tr1::unordered_map<int, int> t
+          ]])],
+          [pandora_cv_tr1_unordered="yes"],
+          [pandora_cv_tr1_unordered="no"])])
+  ])
+
+  AS_IF([test "x${pandora_cv_stl_unordered}" != "xyes" -a "x${pandora_cv_tr1_unordered}" != "xyes"],[
+    AC_CACHE_CHECK([for boost unordered_map],
+      [pandora_cv_boost_unordered],[
+        AC_COMPILE_IFELSE(
+          [AC_LANG_PROGRAM([[#include <boost/unordered_map.hpp>]],
+                           [[boost::unordered_map<int, int> t]])],
+          [pandora_cv_boost_unordered="yes"],
+          [pandora_cv_boost_unordered="no"])])
+  ])
+
+  CXXFLAGS="${save_CXXFLAGS}"
+  AC_LANG_POP()
+
+  AS_IF([test "x${pandora_cv_stl_unordered}" = "xyes"],[
+    AC_DEFINE(HAVE_STD_UNORDERED_MAP, 1,
+              [if the compiler has std::unordered_map])
+    AC_DEFINE(HAVE_STD_UNORDERED_SET, 1,
+              [if the compiler has std::unordered_set])
+    pandora_has_unordered=yes
+  ])
+  AS_IF([test "x${pandora_cv_tr1_unordered}" = "xyes"],[
+    AC_DEFINE(HAVE_TR1_UNORDERED_MAP, 1,
+              [if the compiler has std::tr1::unordered_map])
+    AC_DEFINE(HAVE_TR1_UNORDERED_SET, 1,
+              [if the compiler has std::tr1::unordered_set])
+    pandora_has_unordered=yes
+  ])
+  AS_IF([test "x${pandora_cv_boost_unordered}" = "xyes"],[
+    AC_DEFINE(HAVE_BOOST_UNORDERED_MAP, 1,
+              [if the compiler has boost::unordered_map])
+    AC_DEFINE(HAVE_BOOST_UNORDERED_SET, 1,
+              [if the compiler has boost::unordered_set])
+    pandora_has_unordered=yes
+  ])
+    
+  AS_IF([test "x${pandora_has_unordered}" != "xyes"],[
+    AC_MSG_WARN([could not find an STL unordered_map])
+  ])
+])
+
+AC_DEFUN([PANDORA_HAVE_CXX_UNORDERED],[
+  AC_REQUIRE([PANDORA_CXX_STL_UNORDERED])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_CXX_UNORDERED],[
+  AC_REQUIRE([PANDORA_HAVE_CXX_UNORDERED])
+  AS_IF([test "x${pandora_has_unordered}" != "xyes"],[
+    AC_MSG_ERROR([An STL compliant unordered_map is required for ${PACKAGE}.
+    Implementations can be found in Recent versions of gcc and in boost])
+  ])
+])

data/ext/libmemcached-0.50/m4/pandora_swig.m4

@@ -0,0 +1,39 @@
+dnl -*- mode: m4; c-basic-offset: 2; indent-tabs-mode: nil; -*-
+dnl vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
+dnl   
+dnl pandora-build: A pedantic build system
+dnl Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystem
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+dnl
+dnl From Monty Taylor
+
+AC_DEFUN([PANDORA_SWIG],[
+
+  AC_PROG_SWIG(1.3.31)
+  
+  AC_DEFINE_UNQUOTED([SWIG_TYPE_TABLE],
+    [$PACKAGE],
+    [Type Table name for SWIG symbol table])
+
+  dnl Have to hard-code /usr/local/include and /usr/include into the path.
+  dnl I hate this. Why is swig sucking me
+  SWIG="$SWIG \${DEFS} -I\${top_srcdir} -I\${top_builddir} -I/usr/local/include -I/usr/include"
+  AC_SUBST([SWIG])
+
+
+])
+
+AC_DEFUN([PANDORA_SWIG_PYTHON3],[
+  AC_REQUIRE([PANDORA_SWIG])
+  AS_IF([test "x$SWIG" != "x"],[
+    AC_CACHE_CHECK([if swig supports Python3],
+      [ac_cv_swig_has_python3_],
+      [
+        AS_IF([$SWIG -python -help 2>&1 | grep py3 > /dev/null],
+          [ac_cv_swig_has_python3_=yes],
+          [ac_cv_swig_has_python3_=no])
+      ])
+  ])
+])

data/ext/libmemcached-0.50/m4/pandora_use_pipe.m4

@@ -0,0 +1,36 @@
+dnl -*- mode: m4; c-basic-offset: 2; indent-tabs-mode: nil; -*-
+dnl vim:expandtab:shiftwidth=2:tabstop=2:smarttab:
+dnl   
+dnl pandora-build: A pedantic build system
+dnl Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystem
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+dnl
+dnl From Monty Taylor
+dnl
+dnl Test if we can Use -pipe to avoid making temp files during the compile.
+dnl Should speed up compile on slower disks
+
+AC_DEFUN([PANDORA_USE_PIPE],[
+
+  AS_IF([test "$GCC" = "yes"],[
+    AC_CACHE_CHECK([for working -pipe], [pandora_cv_use_pipe], [
+      AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+#include <stdio.h>
+
+int main(int argc, char** argv)
+{
+  (void) argc; (void) argv;
+  return 0;
+}
+      ]])],
+      [pandora_cv_use_pipe=yes],
+      [pandora_cv_use_pipe=no])
+    ])
+    AS_IF([test "$pandora_cv_use_pipe" = "yes"],[
+      AM_CFLAGS="-pipe ${AM_CFLAGS}"
+      AM_CXXFLAGS="-pipe ${AM_CXXFLAGS}"
+    ])
+  ])
+])

data/ext/libmemcached-0.50/m4/pandora_vc_build.m4

@@ -0,0 +1,168 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([PANDORA_TEST_VC_DIR],[
+  pandora_building_from_vc=no
+
+  if test -d ".bzr" ; then
+    pandora_building_from_bzr=yes
+    pandora_building_from_vc=yes
+  else
+    pandora_building_from_bzr=no
+  fi
+
+  if test -d ".svn" ; then
+    pandora_building_from_svn=yes
+    pandora_building_from_vc=yes
+  else
+    pandora_building_from_svn=no
+  fi
+
+  if test -d ".hg" ; then
+    pandora_building_from_hg=yes
+    pandora_building_from_vc=yes
+  else
+    pandora_building_from_hg=no
+  fi
+
+  if test -d ".git" ; then
+    pandora_building_from_git=yes
+    pandora_building_from_vc=yes
+  else
+    pandora_building_from_git=no
+  fi
+])
+
+AC_DEFUN([PANDORA_BUILDING_FROM_VC],[
+  m4_syscmd(PANDORA_TEST_VC_DIR
+    m4_if(PCT_NO_VC_CHANGELOG,yes,[
+      vc_changelog=no
+      ],[
+      vc_changelog=yes
+      ])
+  
+    [
+
+    PANDORA_RELEASE_DATE=`date +%Y.%m`
+    PANDORA_RELEASE_NODOTS_DATE=`date +%Y%m`
+
+    # Set some defaults
+    PANDORA_VC_REVNO="0"
+    PANDORA_VC_REVID="unknown"
+    PANDORA_VC_BRANCH="bzr-export"
+
+    if test "${pandora_building_from_bzr}" = "yes"; then
+      echo "# Grabbing changelog and version information from bzr"
+      PANDORA_BZR_REVNO=`bzr revno`
+      if test "x$PANDORA_BZR_REVNO" != "x${PANDORA_VC_REVNO}" ; then
+        PANDORA_VC_REVNO="${PANDORA_BZR_REVNO}"
+        PANDORA_VC_REVID=`bzr log -r-1 --show-ids | grep revision-id | cut -f2 -d' ' | head -1`
+        PANDORA_VC_BRANCH=`bzr nick`
+        PANDORA_VC_TAG=`bzr tags -r-1 | cut -f1 -d' ' | head -1`
+        PANDORA_VC_LATEST_TAG=`bzr tags --sort=time | grep -v '\?'| cut -f1 -d' '  | tail -1`
+        if test "x${vc_changelog}" = "xyes"; then
+          bzr log --gnu > ChangeLog
+        fi
+      fi
+    elif test "${pandora_building_from_git}" = "yes"; then
+      echo "# Grabbing changelog and version information from git"
+      PANDORA_GIT_REVID=`git --no-pager log --max-count=1 | cut -f2 -d' ' | head -1`
+      if test "x$PANDORA_GIT_REVID" != "x${PANDORA_VC_REVNO}" ; then
+         PANDORA_VC_REVID="${PANDORA_GIT_REVID}"
+         PANDORA_VC_BRANCH=`git branch | grep -Ei "\* (.*)" | cut -f2 -d' '`
+      fi
+    fi
+
+    if ! test -d config ; then
+      mkdir -p config
+    fi
+
+    if test "${pandora_building_from_bzr}" = "yes" -o ! -f config/pandora_vc_revinfo ; then 
+      cat > config/pandora_vc_revinfo.tmp <<EOF
+PANDORA_VC_REVNO=${PANDORA_VC_REVNO}
+PANDORA_VC_REVID=${PANDORA_VC_REVID}
+PANDORA_VC_BRANCH=${PANDORA_VC_BRANCH}
+PANDORA_VC_TAG=${PANDORA_VC_TAG}
+PANDORA_VC_LATEST_TAG=${PANDORA_VC_LATEST_TAG}
+PANDORA_RELEASE_DATE=${PANDORA_RELEASE_DATE}
+PANDORA_RELEASE_NODOTS_DATE=${PANDORA_RELEASE_NODOTS_DATE}
+EOF
+      if ! diff config/pandora_vc_revinfo.tmp config/pandora_vc_revinfo >/dev/null 2>&1 ; then
+        mv config/pandora_vc_revinfo.tmp config/pandora_vc_revinfo
+      fi
+      rm -f config/pandora_vc_revinfo.tmp
+    fi
+  ])
+])
+  
+AC_DEFUN([_PANDORA_READ_FROM_FILE],[
+  $1=`grep $1 $2 | cut -f2 -d=`
+])
+
+AC_DEFUN([PANDORA_VC_VERSION],[
+  AC_REQUIRE([PANDORA_BUILDING_FROM_VC])
+
+  PANDORA_TEST_VC_DIR
+
+  AS_IF([test -f ${srcdir}/config/pandora_vc_revinfo],[
+    _PANDORA_READ_FROM_FILE([PANDORA_VC_REVNO],${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_VC_REVID],${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_VC_BRANCH],
+                            ${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_VC_TAG],
+                            ${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_VC_LATEST_TAG],
+                            ${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_RELEASE_DATE],
+                            ${srcdir}/config/pandora_vc_revinfo)
+    _PANDORA_READ_FROM_FILE([PANDORA_RELEASE_NODOTS_DATE],
+                            ${srcdir}/config/pandora_vc_revinfo)
+  ])
+  AS_IF([test "x${PANDORA_VC_BRANCH}" != x"${PACKAGE}"],[
+    PANDORA_RELEASE_COMMENT="${PANDORA_VC_BRANCH}"
+  ],[
+    PANDORA_RELEASE_COMMENT="trunk"
+  ])
+    
+  AS_IF([test "x${PANDORA_VC_TAG}" != "x"],[
+    PANDORA_RELEASE_VERSION="${PANDORA_VC_TAG}"
+  ],[
+    AS_IF([test "x${PANDORA_VC_LATEST_TAG}" != "x"],[
+      PANDORA_RELEASE_VERSION="${PANDORA_VC_LATEST_TAG}.${PANDORA_VC_REVNO}"
+    ],[
+      PANDORA_RELEASE_VERSION="${PANDORA_RELEASE_DATE}.${PANDORA_VC_REVNO}"
+    ])
+  ])
+  changequote(<<, >>)dnl
+  PANDORA_RELEASE_ID=`echo ${PANDORA_RELEASE_VERSION} | sed 's/[^0-9]//g'`
+  changequote([, ])dnl
+
+
+  VERSION="${PANDORA_RELEASE_VERSION}"
+  AC_DEFINE_UNQUOTED([PANDORA_RELEASE_VERSION],["${PANDORA_RELEASE_VERSION}"],
+                     [The real version of the software])
+  AC_SUBST(PANDORA_VC_REVNO)
+  AC_SUBST(PANDORA_VC_REVID)
+  AC_SUBST(PANDORA_VC_BRANCH)
+  AC_SUBST(PANDORA_RELEASE_DATE)
+  AC_SUBST(PANDORA_RELEASE_NODOTS_DATE)
+  AC_SUBST(PANDORA_RELEASE_COMMENT)
+  AC_SUBST(PANDORA_RELEASE_VERSION)
+  AC_SUBST(PANDORA_RELEASE_ID)
+])
+
+AC_DEFUN([PANDORA_VC_INFO_HEADER],[
+  AC_REQUIRE([PANDORA_VC_VERSION])
+  m4_define([PANDORA_VC_PREFIX],m4_toupper(m4_normalize(AC_PACKAGE_NAME))[_])
+
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_REVNO], [$PANDORA_VC_REVNO], [Version control revision number])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_REVID], ["$PANDORA_VC_REVID"], [Version control revision ID])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[VC_BRANCH], ["$PANDORA_VC_BRANCH"], [Version control branch name])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_DATE], ["$PANDORA_RELEASE_DATE"], [Release date of version control checkout])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_NODOTS_DATE], [$PANDORA_RELEASE_NODOTS_DATE], [Numeric formatted release date of checkout])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_COMMENT], ["$PANDORA_RELEASE_COMMENT"], [Set to trunk if the branch is the main $PACKAGE branch])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_VERSION], ["$PANDORA_RELEASE_VERSION"], [Release date and revision number of checkout])
+  AC_DEFINE_UNQUOTED(PANDORA_VC_PREFIX[RELEASE_ID], [$PANDORA_RELEASE_ID], [Numeric formatted release date and revision number of checkout])
+])