couchbase-memcached 1.2.8

data/ext/libmemcached-0.50/m4/pandora_have_libdrizzle.m4

@@ -0,0 +1,61 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBDRIZZLE],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libdrizzle
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libdrizzle],
+    [AS_HELP_STRING([--disable-libdrizzle],
+      [Build with libdrizzle support @<:@default=on@:>@])],
+    [ac_enable_libdrizzle="$enableval"],
+    [ac_enable_libdrizzle="yes"])
+
+  AS_IF([test "x$ac_enable_libdrizzle" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(drizzle,,[
+      #include <libdrizzle/drizzle_client.h>
+    ],[
+      drizzle_st drizzle;
+      drizzle_version();
+    ])
+  ],[
+    ac_cv_libdrizzle="no"
+  ])
+  
+  AM_CONDITIONAL(HAVE_LIBDRIZZLE, [test "x${ac_cv_libdrizzle}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBDRIZZLE],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBDRIZZLE])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBDRIZZLE],[
+  AC_REQUIRE([PANDORA_HAVE_LIBDRIZZLE])
+  AS_IF([test "x${ac_cv_libdrizzle}" = "xno"],[
+    AC_MSG_ERROR([libdrizzle is required for ${PACKAGE}])
+  ],[
+    dnl We need at least 0.8 on Solaris non-sparc
+    AS_IF([test "$target_cpu" != "sparc" -a "x${TARGET_SOLARIS}" = "xtrue"],[
+      PANDORA_LIBDRIZZLE_RECENT
+    ])
+  ])
+])
+
+AC_DEFUN([PANDORA_LIBDRIZZLE_RECENT],[
+  AC_CACHE_CHECK([if libdrizzle is recent enough],
+    [pandora_cv_libdrizzle_recent],
+    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#include <libdrizzle/drizzle.h>
+drizzle_con_options_t foo= DRIZZLE_CON_EXPERIMENTAL;
+    ]])],
+    [pandora_cv_libdrizzle_recent=yes],
+    [pandora_cv_libdrizzle_recent=no])])
+  AS_IF([test "$pandora_cv_libdrizzle_recent" = "no"],[
+    AC_MSG_ERROR([Your version of libdrizzle is too old. ${PACKAGE} requires at least version 0.8])
+  ])
+])

data/ext/libmemcached-0.50/m4/pandora_have_libevent.m4

@@ -0,0 +1,66 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+#--------------------------------------------------------------------
+# Check for libevent
+#--------------------------------------------------------------------
+
+
+AC_DEFUN([_PANDORA_SEARCH_LIBEVENT],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  AC_LIB_HAVE_LINKFLAGS(event,,
+  [
+    #include <sys/types.h>
+    #include <sys/time.h>
+    #include <stdlib.h>
+    #include <event.h>
+  ],[
+    struct bufferevent bev;
+    bufferevent_settimeout(&bev, 1, 1);
+    event_init();
+    event_loop(EVLOOP_ONCE);
+  ]) 
+
+  AM_CONDITIONAL(HAVE_LIBEVENT, [test "x${ac_cv_libevent}" = "xyes"])
+
+  AS_IF([test "x${ac_cv_libevent}" = "xyes"],[
+    save_LIBS="${LIBS}"
+    LIBS="${LIBS} ${LTLIBEVENT}"
+    AC_CHECK_FUNCS(event_base_new)
+    AC_CHECK_FUNCS(event_base_free)
+    AC_CHECK_FUNCS(event_base_get_method)
+    LIBS="$save_LIBS"
+  ])
+])
+
+AC_DEFUN([_PANDORA_HAVE_LIBEVENT],[
+
+  AC_ARG_ENABLE([libevent],
+    [AS_HELP_STRING([--disable-libevent],
+      [Build with libevent support @<:@default=on@:>@])],
+    [ac_enable_libevent="$enableval"],
+    [ac_enable_libevent="yes"])
+
+  _PANDORA_SEARCH_LIBEVENT
+])
+
+
+AC_DEFUN([PANDORA_HAVE_LIBEVENT],[
+  AC_REQUIRE([_PANDORA_HAVE_LIBEVENT])
+])
+
+AC_DEFUN([_PANDORA_REQUIRE_LIBEVENT],[
+  ac_enable_libevent="yes"
+  _PANDORA_SEARCH_LIBEVENT
+
+  AS_IF([test x$ac_cv_libevent = xno],[
+    AC_MSG_ERROR([libevent is required for ${PACKAGE}. On Debian this can be found in libevent-dev. On RedHat this can be found in libevent-devel.])
+  ])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBEVENT],[
+  AC_REQUIRE([_PANDORA_REQUIRE_LIBEVENT])
+])

data/ext/libmemcached-0.50/m4/pandora_have_libgearman.m4

@@ -0,0 +1,41 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBGEARMAN],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libgearman
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libgearman],
+    [AS_HELP_STRING([--disable-libgearman],
+      [Build with libgearman support @<:@default=on@:>@])],
+    [ac_enable_libgearman="$enableval"],
+    [ac_enable_libgearman="yes"])
+
+  AS_IF([test "x$ac_enable_libgearman" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(gearman,,[
+      #include <libgearman/gearman.h>
+    ],[
+      gearman_client_st gearman_client;
+      gearman_client_context(&gearman_client);
+    ])
+  ],[
+    ac_cv_libgearman="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBGEARMAN, [test "x${ac_cv_libgearman}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBGEARMAN],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBGEARMAN])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBGEARMAN],[
+  AC_REQUIRE([PANDORA_HAVE_LIBGEARMAN])
+  AS_IF([test "x${ac_cv_libgearman}" = "xno"],
+      AC_MSG_ERROR([At least version 0.10 of libgearman is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_have_libgtest.m4

@@ -0,0 +1,47 @@
+dnl Copyright (C) 2010 Monty Taylor
+dnl This file is free software; Monty Taylor
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBGTEST],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libgtest
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libgtest],
+    [AS_HELP_STRING([--disable-libgtest],
+      [Build with libgtest support @<:@default=on@:>@])],
+    [ac_enable_libgtest="$enableval"],
+    [ac_enable_libgtest="yes"])
+
+  AS_IF([test "x$ac_enable_libgtest" = "xyes"],[
+    AC_LANG_PUSH(C++)
+    save_CXXFLAGS="${CXXFLAGS}"
+    CXXFLAGS="${AM_CXXFLAGS} ${CXXFLAGS}"
+    AC_LIB_HAVE_LINKFLAGS(gtest,,[
+      #include <gtest/gtest.h>
+TEST(pandora_test_libgtest, PandoraTest)
+{
+  ASSERT_EQ(1, 1);
+}
+    ],[])
+    CXXFLAGS="${save_CXXFLAGS}"
+    AC_LANG_POP()
+  ],[
+    ac_cv_libgtest="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBGTEST, [test "x${ac_cv_libgtest}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBGTEST],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBGTEST])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBGTEST],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBGTEST])
+  AS_IF([test "x${ac_cv_libgtest}" = "xno"],
+    AC_MSG_ERROR([libgtest is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_have_libhaildb.m4

@@ -0,0 +1,43 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBHAILDB],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libhaildb
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libhaildb],
+    [AS_HELP_STRING([--disable-libhaildb],
+      [Build with libhaildb support @<:@default=on@:>@])],
+    [ac_enable_libhaildb="$enableval"],
+    [ac_enable_libhaildb="yes"])
+
+
+  AS_IF([test "x$ac_enable_libhaildb" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(haildb,,[
+      #include <haildb.h>
+    ],[
+      ib_update_table_statistics(NULL);
+    ])
+    AS_IF([test "x${ac_cv_libhaildb}" = "xyes"],[
+      AC_DEFINE([HAVE_HAILDB_H],[1],[Do we have haildb.h])
+      ])
+  ],[
+    ac_cv_libhaildb="no"
+  ])
+  AM_CONDITIONAL(HAVE_LIBHAILDB, [test "x${ac_cv_libhaildb}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBHAILDB],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBHAILDB])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBHAILDB],[
+  AC_REQUIRE([PANDORA_HAVE_LIBHAILDB])
+  AS_IF([test "x${ac_cv_libhaildb}" = "xno"],
+      AC_MSG_ERROR([libhaildb 2.3.2 or later is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_have_libhashkit.m4

@@ -0,0 +1,42 @@
+dnl  Copyright (C) 2010 NorthScale
+dnl This file is free software; NorthScale
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBHASHKIT],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libhashkit
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libhashkit],
+    [AS_HELP_STRING([--disable-libhashkit],
+      [Build with libhashkit support @<:@default=on@:>@])],
+    [ac_enable_libhashkit="$enableval"],
+    [ac_enable_libhashkit="yes"])
+
+  AS_IF([test "x$ac_enable_libhashkit" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(hashkit,,[
+      #include <libhashkit/hashkit.h>
+    ],[
+      hashkit_st foo;
+      hashkit_st *kit = hashkit_create(&foo);
+      hashkit_free(kit);
+    ])
+  ],[
+    ac_cv_libhashkit="no"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBHASHKIT, [test "x${ac_cv_libhashkit}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBHASHKIT],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBHASHKIT])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBHASHKIT],[
+  AC_REQUIRE([PANDORA_HAVE_LIBHASHKIT])
+  AS_IF([test x$ac_cv_libhashkit = xno],
+      AC_MSG_ERROR([libhashkit is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_have_libinnodb.m4

@@ -0,0 +1,64 @@
+dnl  Copyright (C) 2009 Sun Microsystems
+dnl This file is free software; Sun Microsystems
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBINNODB],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libinnodb
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libinnodb],
+    [AS_HELP_STRING([--disable-libinnodb],
+      [Build with libinnodb support @<:@default=on@:>@])],
+    [ac_enable_libinnodb="$enableval"],
+    [ac_enable_libinnodb="yes"])
+
+  AS_IF([test "x$ac_enable_libinnodb" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(innodb,,[
+      #include <embedded_innodb-1.0/innodb.h>
+    ],[
+      ib_u64_t
+      ib_api_version(void);
+    ])
+  ],[
+    ac_cv_libinnodb="no"
+  ])
+
+
+  AC_CACHE_CHECK([if libinnodb is recent enough],
+    [ac_cv_recent_innodb_h],[
+      save_LIBS=${LIBS}
+      LIBS="${LIBS} ${LTLIBINNODB}"
+      AC_LINK_IFELSE(
+          [AC_LANG_PROGRAM([[
+      #include <embedded_innodb-1.0/innodb.h>
+        ]],[[
+      /* Make sure we have the two-arg version */
+      ib_table_drop(NULL, "nothing");
+        ]])],[
+        ac_cv_recent_innodb_h=yes
+      ],[
+        ac_cv_recent_innodb_h=no
+      ])
+      LIBS="${save_LIBS}"
+    ])
+  AS_IF([test "x${ac_cv_recent_innodb_h}" = "xno"],[
+    AC_MSG_WARN([${PACKAGE} requires at least version 1.0.6 of Embedded InnoDB])
+    ac_cv_libinnodb=no
+  ])
+        
+  AM_CONDITIONAL(HAVE_LIBINNODB, [test "x${ac_cv_libinnodb}" = "xyes"])
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBINNODB],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBINNODB])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBINNODB],[
+  AC_REQUIRE([PANDORA_HAVE_LIBINNODB])
+  AS_IF([test "x${ac_cv_libinnodb}" = "xno"],
+      AC_MSG_ERROR([libinnodb is required for ${PACKAGE}]))
+])

data/ext/libmemcached-0.50/m4/pandora_have_libldap.m4

@@ -0,0 +1,73 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+#--------------------------------------------------------------------
+# Check for libldap
+#--------------------------------------------------------------------
+
+
+AC_DEFUN([_PANDORA_SEARCH_LIBLDAP],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  AC_LIB_HAVE_LINKFLAGS(ldap,,
+  [#include <ldap.h>],
+  [
+    LDAP *ldap;
+    ldap_initialize(&ldap, "ldap://localhost/");
+  ])
+  AS_IF([test "x$ac_cv_libldap" = "xno"],
+  [
+    unset ac_cv_libldap
+    unset HAVE_LIBLDAP
+    unset LIBLDAP
+    unset LIBLDAP_PREFIX
+    unset LTLIBLDAP
+    AC_LIB_HAVE_LINKFLAGS(ldap,,
+    [#include <ldap/ldap.h>],
+    [
+      LDAP *ldap;
+      ldap_initialize(&ldap, "ldap://localhost/");
+    ])
+    AS_IF([test "x$ac_cv_libldap" = "xyes"], [
+      ac_cv_ldap_location="<ldap/ldap.h>"
+    ])
+  ],[
+    ac_cv_ldap_location="<ldap.h>"
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBLDAP, [test "x${ac_cv_libldap}" = "xyes"])
+])
+
+AC_DEFUN([_PANDORA_HAVE_LIBLDAP],[
+
+  AC_ARG_ENABLE([libldap],
+    [AS_HELP_STRING([--disable-libldap],
+      [Build with libldap support @<:@default=on@:>@])],
+    [ac_enable_libldap="$enableval"],
+    [ac_enable_libldap="yes"])
+
+  _PANDORA_SEARCH_LIBLDAP
+])
+
+
+AC_DEFUN([PANDORA_HAVE_LIBLDAP],[
+  AC_REQUIRE([_PANDORA_HAVE_LIBLDAP])
+])
+
+AC_DEFUN([_PANDORA_REQUIRE_LIBLDAP],[
+  ac_enable_libldap="yes"
+  _PANDORA_SEARCH_LIBLDAP
+
+  AS_IF([test x$ac_cv_libldap = xno],[
+    AC_MSG_ERROR([libldap is required for ${PACKAGE}. On Debian this can be found in libldap2-dev. On RedHat this can be found in openldap-devel.])
+  ],[
+    AC_DEFINE_UNQUOTED(LDAP_HEADER,[${ac_cv_ldap_location}],
+                       [Location of ldap header])
+  ])
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBLDAP],[
+  AC_REQUIRE([_PANDORA_REQUIRE_LIBLDAP])
+])

data/ext/libmemcached-0.50/m4/pandora_have_libmemcached.m4

@@ -0,0 +1,106 @@
+dnl  Copyright (C) 2009 Sun Microsystems, Inc.
+dnl This file is free software; Sun Microsystems, Inc.
+dnl gives unlimited permission to copy and/or distribute it,
+dnl with or without modifications, as long as this notice is preserved.
+
+AC_DEFUN([_PANDORA_SEARCH_LIBMEMCACHED],[
+  AC_REQUIRE([AC_LIB_PREFIX])
+
+  dnl --------------------------------------------------------------------
+  dnl  Check for libmemcached
+  dnl --------------------------------------------------------------------
+
+  AC_ARG_ENABLE([libmemcached],
+    [AS_HELP_STRING([--disable-libmemcached],
+      [Build with libmemcached support @<:@default=on@:>@])],
+    [ac_enable_libmemcached="$enableval"],
+    [ac_enable_libmemcached="yes"])
+
+  AS_IF([test "x$ac_enable_libmemcached" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(memcached,,[
+      #include <libmemcached/memcached.h>
+    ],[
+      memcached_st memc;
+      memcached_dump_func *df;
+      memcached_lib_version();
+    ])
+  ],[
+    ac_cv_libmemcached="no"
+  ])
+
+  AS_IF([test "x$ac_enable_libmemcached" = "xyes"],[
+    AC_LIB_HAVE_LINKFLAGS(memcachedprotocol,,[
+      #include <libmemcached/protocol_handler.h>
+    ],[
+      struct memcached_protocol_st *protocol_handle;
+      protocol_handle= memcached_protocol_create_instance();
+    ])
+  ],[
+    ac_cv_libmemcachedprotocol="no"
+  ])
+  
+  AC_CACHE_CHECK([if libmemcached has memcached_server_fn],
+    [pandora_cv_libmemcached_server_fn],
+    [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#include <libmemcached/memcached.h>
+memcached_server_fn callbacks[1];
+    ]])],
+    [pandora_cv_libmemcached_server_fn=yes],
+    [pandora_cv_libmemcached_server_fn=no])])
+
+  AS_IF([test "x$pandora_cv_libmemcached_server_fn" = "xyes"],[
+    AC_DEFINE([HAVE_MEMCACHED_SERVER_FN],[1],[If we have the new memcached_server_fn typedef])
+  ])
+])
+
+AC_DEFUN([_PANDORA_RECENT_LIBMEMCACHED],[
+
+  AC_CACHE_CHECK([if libmemcached is recent enough],
+    [pandora_cv_recent_libmemcached],[
+    AS_IF([test "x${ac_cv_libmemcached}" = "xno"],[
+      pandora_cv_recent_libmemcached=no
+    ],[
+      AS_IF([test "x$1" != "x"],[
+        pandora_need_libmemcached_version=`echo "$1" | perl -nle '/(\d+)\.(\d+)/; printf "%d%0.3d000", $[]1, $[]2 ;'`
+        AS_IF([test "x${pandora_need_libmemcached_version}" = "x0000000"],[
+          pandora_cv_recent_libmemcached=yes
+        ],[
+          AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
+#include <libmemcached/configure.h>
+
+#if !defined(LIBMEMCACHED_VERSION_HEX) || LIBMEMCACHED_VERSION_HEX < 0x]]${pandora_need_libmemcached_version}[[
+# error libmemcached too old!
+#endif
+            ]],[[]])
+          ],[
+            pandora_cv_recent_libmemcached=yes
+          ],[
+            pandora_cv_recent_libmemcached=no
+          ])
+        ])
+      ],[
+        pandora_cv_recent_libmemcached=yes
+      ])
+    ])
+  ])
+
+  AM_CONDITIONAL(HAVE_LIBMEMCACHED,[test "x${ac_cv_libmemcached}" = "xyes" -a "x${pandora_cv_recent_libmemcached}" = "xyes"])
+  
+])
+
+AC_DEFUN([PANDORA_HAVE_LIBMEMCACHED],[
+  AC_REQUIRE([_PANDORA_SEARCH_LIBMEMCACHED])
+  _PANDORA_RECENT_LIBMEMCACHED($1)
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBMEMCACHED],[
+  PANDORA_HAVE_LIBMEMCACHED($1)
+  AS_IF([test "x{$pandora_cv_recent_libmemcached}" = "xno"],
+      AC_MSG_ERROR([libmemcached is required for ${PACKAGE}]))
+])
+
+AC_DEFUN([PANDORA_REQUIRE_LIBMEMCACHEDPROTOCOL],[
+  PANDORA_HAVE_LIBMEMCACHED($1)
+  AS_IF([test x$ac_cv_libmemcachedprotocol = xno],
+      AC_MSG_ERROR([libmemcachedprotocol is required for ${PACKAGE}]))
+])