character 0.1.0 → 1.0.0

data/app/assets/javascripts/character/dashboard/module.coffee

@@ -0,0 +1,51 @@
+#= require raphael
+#= require raphael.morris
+
+#= require_self
+#= require ./layout
+
+@Character.Dashboard ||= {}
+
+#
+# Marionette.js Router Documentation
+# https://github.com/marionettejs/backbone.marionette/blob/master/docs/marionette.router.md
+#
+@Character.Dashboard.Router = Backbone.Marionette.AppRouter.extend
+  initialize: (options) ->
+    @appRoutes ||= {}
+    @appRoutes["#{ options.path }(/:scope)"] = "index"
+
+#
+# Marionette.js Controller Documentation
+# https://github.com/marionettejs/backbone.marionette/blob/master/docs/marionette.controller.md
+#
+@Character.Dashboard.Controller = Backbone.Marionette.Controller.extend
+  initialize: ->
+    @module = @options.module
+
+  index: (scope, callback) ->
+    chr.execute('showModule', @module)
+
+    path = @options.moduleName + ( if scope then "/#{ scope }" else '' )
+    if chr.currentPath != path
+      chr.currentPath = path
+      @module.layout.setDateRange()
+      @module.layout.updateScope(scope, callback)
+    else
+      callback?()
+
+chr.dashboardModule = ->
+  moduleName = 'dashboard'
+
+  chr.module moduleName, (module) ->
+    module = _(module).extend(Character.Dashboard)
+
+    options =
+      module:     module
+      moduleName: moduleName
+
+    module.on 'start', ->
+      @controller = new @Controller(options)
+      @layout     = new @Layout(options)
+      @router     = new @Router({ path: moduleName, controller: @controller })
+      chr.execute('addMenuItem', moduleName, 'bar-chart-o', 'Dashboard')

data/app/assets/javascripts/character/generic/details.coffee

@@ -0,0 +1,233 @@
+
+#
+# Marionette.js Item View Documentation
+# https://github.com/marionettejs/backbone.marionette/blob/master/docs/marionette.itemview.md
+#
+@Character.Generic.DetailsHeaderView = Backbone.Marionette.ItemView.extend
+  template: -> "<button id=save class='save invert' title='Save changes'>Save</button>
+                <button id=cancel class=cancel title='Cancel changes'>Cancel</button>
+                <span id=published class=published><i class='fa fa-eye'></i><i class='fa fa-eye-slash'></i></span>
+                <div id=details_title class=title></div>
+                <a id=delete class=delete href='#' title='Delete this item'>
+                  <i class='fa fa-trash-o'></i>
+                </a>
+                <span id=details_meta class=meta></span>"
+
+  ui:
+    title:           '#details_title'
+    meta:            '#details_meta'
+    actionSave:      '#save'
+    actionCancel:    '#cancel'
+    actionPublished: '#published'
+    actionDelete:    '#delete'
+
+  initialize: ->
+    if @model
+      @listenTo(@model, 'change', @render, @)
+
+  togglePublished: ($input) ->
+    @ui.actionPublished.toggleClass 'off'
+    $input.val @ui.actionPublished.hasClass('off')
+
+  onRender: ->
+    if @model
+      title = @model.getTitle()
+      updatedFromNow = moment(@model.get('updated_at')).fromNow()
+      @ui.meta.html("updated #{ updatedFromNow }")
+
+      if @model.has('hidden')
+        @ui.actionPublished.show()
+        @ui.actionPublished.addClass 'off' if @model.get('hidden')
+
+    else
+      title = @options.title
+
+    @ui.title.html(title)
+
+    if not @options.deletable
+      @ui.actionDelete.hide()
+
+  updateState: (state) ->
+    if @ui
+      if state == 'saving'
+        @ui.actionSave.addClass('disabled')
+        @ui.actionSave.html 'Saving...'
+      else
+        setTimeout ( =>
+          # need these checks when create new object, view is recreated
+          @ui.actionSave.removeClass?('disabled')
+          @ui.actionSave.html?('Save')
+        ), 500
+
+
+#
+# Marionette.js Layout Documentation
+# https://github.com/marionettejs/backbone.marionette/blob/master/docs/marionette.layout.md
+#
+@Character.Generic.DetailsLayout = Backbone.Marionette.LayoutView.extend
+  className: 'chr-details'
+  template: -> "<header id=details_header class='chr-details-header'></header>
+                <section id=details_content class='chr-details-content'></section>"
+
+  regions:
+    header: '#details_header'
+
+  ui:
+    content: '#details_content'
+
+  events:
+    'click #cancel':    '_cancel'
+    'click #save':      '_save'
+    'click #delete':    '_delete'
+    'click #published': '_togglePublished'
+
+  initialize: ->
+    @module            = @options.module
+    @DetailsHeaderView = @module.DetailsHeaderView
+
+  _togglePublished: ->
+    hiddenInput = _.find @ui.form.find('input[type=hidden]'), (input) -> _( $(input).attr('name') ).endsWith '[hidden]'
+    if hiddenInput
+      @headerView.togglePublished($(hiddenInput))
+
+  _save: ->
+    @beforeSave?()
+
+    if @ui.form.length
+      Character.Generic.Helpers.serializeDataInputs(@ui.content, @ui.form)
+
+      if @collection
+        # include fields to properly update item in a list and sort
+        params = _.clone(@collection.options.constantParams)
+        if @collection.sortField
+          params.f = _([ params.f, @collection.sortField ]).uniq().join(',')
+
+      @ui.form.ajaxSubmit
+        data: params
+        beforeSubmit: (arr, $form, options) =>
+          @beforeFormSubmit?(arr, $form, options)
+          @headerView.updateState('saving')
+          return true
+        error: (xhr) =>
+          chr.execute('showError', xhr)
+          @headerView.updateState()
+        success: (responseText, statusText, xhr, $form) =>
+          @headerView.updateState()
+          @_updateModel(responseText)
+          @afterFormSubmitSuccess?(responseText, statusText, xhr, $form)
+
+    return false
+
+  _updateModel: (resp) ->
+    # string means form errors returned
+    if typeof(resp) == 'string'
+      return @_renderContent(resp)
+
+    # assuming response is json
+    if @model
+      @model.set(resp)
+      @collection.sort()
+    else
+      @collection.fetchPage 1, ->
+        Backbone.history.navigate("#/#{chr.currentPath}/edit/#{resp._id}", { trigger: true })
+
+  _delete: ->
+    if confirm("""Delete "#{ @model.getTitle() }"?""")
+      # @close()
+      #@destroy()
+      @model.destroy
+        success: ->
+          Backbone.history.navigate("#/#{chr.currentPath}", { trigger: true })
+        error: (model, response, options) ->
+          chr.execute('error', response)
+    return false
+
+  _cancel: ->
+    Backbone.history.navigate("#/#{chr.currentPath}", { trigger: true })
+
+  _toggleFullscreen: ->
+    @$el.parent().toggleClass('fullscreen')
+
+  _bindReorderableItems: ->
+    @ui.reorderableItems = @ui.form.find('.sortable')
+    options =
+      delay:  150
+      items:  '> .fields'
+      update: (e, ui) =>
+        # # TODO: seems like this could be done much simpler with regex
+        positionFields = _.select @ui.reorderableItems.find("input[type=hidden]"), (f) ->
+          _( $(f).attr('name') ).endsWith('[_position]')
+        _.each positionFields, (el, index, list) ->
+          $(el).val(positionFields.length - index)
+
+    @ui.reorderableItems.sortable(options).disableSelection()
+
+  _renderContent: (html) ->
+    if @ui
+      @beforeRenderContent?()
+
+      @ui.content.html(html)
+      @ui.form = @ui.content.find('form.simple_form')
+
+      beforeFormHelpersStart?()
+
+      if @ui.form.length
+        # form related helpers
+        Character.Generic.Helpers.startDateSelect(@ui.form)
+        Character.Generic.Helpers.startEditor(@ui.content, @options.editorOptions)
+        Character.Generic.Helpers.startRedactor(@ui.content, @options.redactorOptions)
+        @_bindReorderableItems()
+
+      $(document).trigger("chr-details-content.rendered", [ @ui.content ])
+      $(document).trigger("chr-#{ @module.moduleName }-details-content.rendered", [ @ui.content ])
+
+      @afterRenderContent?()
+
+  onRender: ->
+    window.shortcuts.register_combo { keys: 'meta s', is_exclusive: true, on_keyup: (event) => @_save() }
+
+    if @options.fullscreen
+      window.shortcuts.register_combo { keys: 'meta e', is_exclusive: true, on_keyup: (event) => @_toggleFullscreen() }
+
+    @headerView = new @DetailsHeaderView
+      model:     @model
+      title:     "New #{ @options.objectName }"
+      deletable: @options.deletable
+
+    @header.show(@headerView)
+
+    if @model then @$el.addClass('update')
+
+    @beforeContentRequest?()
+
+    $.ajax
+      type: 'get'
+      url:  @options.formUrl
+      success: (data) =>
+        @_renderContent(data)
+      error: (xhr, ajaxOptions, thrownError) =>
+        chr.execute('showError', xhr)
+
+  onDestroy: ->
+    window.closeDetailsView = null
+    if @ui
+      @beforeOnClose?()
+
+      # unbind save
+      window.shortcuts.unregister_combo 'meta s'
+
+      # unbind fullscreen
+      @$el.parent().removeClass('fullscreen')
+      window.shortcuts.unregister_combo 'meta e'
+
+      if @ui.form
+        # form related helpers
+        Character.Generic.Helpers.stopDateSelect(@ui.form)
+        Character.Generic.Helpers.stopEditor(@ui.content)
+        Character.Generic.Helpers.stopRedactor(@ui.content)
+        @ui.reorderableItems.sortable('destroy') if @ui.reorderableItems
+
+      $(document).trigger("chr-details-content.closed", [ @ui.content ])
+      $(document).trigger("chr-#{ @module.moduleName }-details-content.closed", [ @ui.content ])
+
+      @afterOnClose?()

data/app/assets/javascripts/character/generic/helpers/compact_object.coffee

@@ -0,0 +1,7 @@
+# ---------------------------------------------------------
+# COMPACT OBJECT  (used in generic model)
+# ---------------------------------------------------------
+
+_.mixin
+  compactObject: (o) ->
+    _.each o, (v, k) -> if !v then delete o[k] else o

data/app/assets/javascripts/character/generic/helpers/data_inputs.coffee

@@ -0,0 +1,21 @@
+# ---------------------------------------------------------
+# SERIALIZE INPUTS
+# ---------------------------------------------------------
+
+@Character.Generic.Helpers.serializeDataInputs = ($content, $form) ->
+  if $content and $form
+    $content.find('[data-input-name]').each (i, el) ->
+      dataInputName = $(el).attr('data-input-name')
+      if dataInputName
+        if $(el).hasClass('character-editor')
+          value = $(el).data('editor').serialize()
+        else
+          value = $(el).html().trim()
+
+        $hiddenInput = $form.find("input[name='#{ dataInputName }']")
+
+        if $hiddenInput.length == 0
+          $hiddenInput = $("<input type='hidden' name='#{ dataInputName }'>")
+          $hiddenInput.appendTo($form)
+
+        $hiddenInput.val(value)

data/app/assets/javascripts/character/generic/helpers/date_select.coffee

@@ -0,0 +1,45 @@
+# ---------------------------------------------------------
+# DATE SELECT (rails fix)
+# ---------------------------------------------------------
+
+@Character.Generic.Helpers.startDateSelect = ($form)->
+  updateDateValue = ($wrapper, $input) ->
+    selects = $wrapper.children('select')
+
+    day   = $(selects[0]).val()
+    month = $(selects[1]).val()
+    year  = $(selects[2]).val()
+
+    $input.val("#{ year }-#{ month }-#{ day }")
+
+
+  # initialize hiddin input and start value
+  $form.find('.chr-date-dmy').each (i, el) ->
+
+    $el          = $(this)
+    $hiddenInput = $el.children('input[type="hidden"]')
+
+    if $hiddenInput.length == 0
+      dateFieldName = $el.children('select').first()
+        .attr('name').replace('(3i)', '')
+        .replace('(2i)', '')
+        .replace('(1i)', '')
+      $hiddenInput = $("<input type='hidden' name='#{ dateFieldName }' />").appendTo($el)
+
+    updateDateValue($el, $hiddenInput)
+
+
+  # remove bad field names
+  $form.find('.chr-date-dmy select').attr('name', '')
+
+
+  # update date on select change
+  $form.find('.chr-date-dmy select').on 'change', (e) ->
+    $parentDiv   = $(this).parent()
+    $hiddenInput = $parentDiv.children('input[type="hidden"]').first()
+
+    updateDateValue($parentDiv, $hiddenInput)
+
+
+@Character.Generic.Helpers.stopDateSelect = ($form) ->
+  $form.find('.chr-date-dmy select').off 'change'

data/app/assets/javascripts/character/generic/helpers/editor.coffee

@@ -0,0 +1,11 @@
+# ---------------------------------------------------------
+# EDITOR
+# ---------------------------------------------------------
+
+@Character.Generic.Helpers.startEditor = ($content, editorOptions) ->
+  options = { viewSelector: '#details_content' }
+  _(options).extend(editorOptions)
+  $content.find('.character-editor').editor options
+
+@Character.Generic.Helpers.stopEditor = ($content) ->
+  $content.find('.character-editor').each (i, el) -> $(el).data('editor').destroy()

data/app/assets/javascripts/character/generic/helpers/redactor.coffee

@@ -0,0 +1,38 @@
+# ---------------------------------------------------------
+# REDACTOR
+# ---------------------------------------------------------
+
+window.RedactorPlugins ||= {}
+
+RedactorPlugins.gallery =
+  init: ->
+    @buttonAddBefore('video', 'image', 'Insert Images', @insertImages)
+
+  insertImages: ->
+    @selectionSave()
+    chr.execute 'showImages', true, (images) =>
+      _.each images.reverse(), (model) =>
+        # HACK: this workaround sometimes Rails includes image mount_uploader
+        image = model.get('image')
+        image = image.image if image.image
+        data = { filelink: image.regular.url, filename: '' }
+        @imageInsert(data, false)
+      @observeImages()
+
+@Character.Generic.Helpers.startRedactor = ($content, redactorOptions) ->
+  if $.fn.redactor
+    $('#details_header').prepend "<div id='redactor_toolbar' class='chr-redactor-toolbar'></div>"
+    options =
+      formattingPre:  false
+      convertLinks:   false
+      cleanup:        false
+      pastePlainText: true
+      plugins: [ 'gallery' ]
+      buttons: ['html', 'formatting', 'bold', 'italic', 'deleted', 'unorderedlist', 'orderedlist', 'outdent', 'indent', 'video', 'file', 'table', 'link', 'alignment', 'horizontalrule']
+    _(options).extend(redactorOptions)
+    $content.find('.character-redactor').redactor(options)
+
+@Character.Generic.Helpers.stopRedactor = ($content) ->
+  if $.fn.redactor
+    $content.find('.character-redactor').redactor('destroy')
+    $('#redactor_toolbar').remove()

data/app/assets/javascripts/character/generic/helpers/reorder.coffee

@@ -0,0 +1,36 @@
+# ---------------------------------------------------------
+# REORDER LIST ITEMS
+# ---------------------------------------------------------
+
+@Character.Generic.Helpers.stopReorder = (el) ->
+  el.sortable( "destroy" )
+
+@Character.Generic.Helpers.startReorder = (el, collection) ->
+  updateModelPosition = ($el, position) ->
+    object_id = $el.attr('data-id')
+    object    = collection.get(object_id)
+    object.save({ _position: position }, { patch: true })
+
+  options =
+    delay: 150
+    placeholder: 'placeholder'
+    update: (e, ui) =>
+      prev = ui.item.prev()
+      next = ui.item.next()
+
+      if prev.length > 0 and next.length > 0
+        prevPosition = parseFloat prev.attr('data-position')
+        nextPosition = parseFloat next.attr('data-position')
+        newPosition  = (prevPosition + nextPosition) / 2
+
+      else if prev.length > 0 # bottom of the list
+        lastPosition = parseFloat prev.attr('data-position')
+        newPosition  = lastPosition - 10
+
+      else if next.length > 0 # top of the list
+        firstPosition = parseFloat next.attr('data-position')
+        newPosition   = firstPosition + 10
+
+      updateModelPosition(ui.item, newPosition)
+
+  el.sortable(options).disableSelection()