activeadmin-rb 1.4.0

data/app/assets/javascripts/active_admin/base.js.coffee

@@ -0,0 +1,13 @@
+#= require jquery3
+#= require jquery-ui/widgets/datepicker
+#= require jquery-ui/widgets/dialog
+#= require jquery-ui/widgets/sortable
+#= require jquery-ui/widgets/tabs
+#= require jquery-ui/widget
+#= require jquery_ujs
+#= require_self
+#= require_tree ./lib
+#= require_tree ./ext
+#= require_tree ./initializers
+
+window.ActiveAdmin = {}

data/app/assets/javascripts/active_admin/ext/jquery-ui.js.coffee

@@ -0,0 +1,6 @@
+# Short-circuits `_focusTabbable` to focus on the modal itself instead of
+# elements inside the modal. Without this, if a datepicker is the first input,
+# it'll immediately pop up when the modal opens.
+# See this ticket for more info: http://bugs.jqueryui.com/ticket/4731
+$.ui.dialog.prototype._focusTabbable = ->
+  @uiDialog.focus()

data/app/assets/javascripts/active_admin/ext/jquery.js.coffee

@@ -0,0 +1,7 @@
+# `serializeArray` generates => [{ name: 'foo', value: 'bar' }]
+# This function remaps it to => { foo: 'bar' }
+$.fn.serializeObject = ->
+  obj = {}
+  for o in @serializeArray()
+    obj[o.name] = o.value
+  obj

data/app/assets/javascripts/active_admin/initializers/batch_actions.js.coffee

@@ -0,0 +1,11 @@
+onDOMReady = ->
+  # In order for index scopes to overflow properly onto the next line, we have
+  # to manually set its width based on the width of the batch action button.
+  if (batch_actions_selector = $('.table_tools .batch_actions_selector')).length
+    batch_actions_selector.next().css
+      width: "calc(100% - 10px - #{batch_actions_selector.outerWidth()}px)"
+      'float': 'right'
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/initializers/datepicker.js.coffee

@@ -0,0 +1,14 @@
+onDOMReady = ->
+  $(document).on 'focus', 'input.datepicker:not(.hasDatepicker)', ->
+    input = $(@)
+
+    # Only create datepickers in compatible browsers
+    return if input[0].type is 'date'
+
+    defaults = dateFormat: 'yy-mm-dd'
+    options  = input.data 'datepicker-options'
+    input.datepicker $.extend(defaults, options)
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/initializers/filters.js.coffee

@@ -0,0 +1,26 @@
+onDOMReady = ->
+  # Clear Filters button
+  $('.clear_filters_btn').click (e) ->
+    params = window.location.search.slice(1).split('&')
+    regex = /^(q\[|q%5B|q%5b|page|commit)/
+    if typeof Turbolinks != 'undefined'
+      Turbolinks.visit(window.location.href.split('?')[0] + '?' + (param for param in params when not param.match(regex)).join('&'))
+      e.preventDefault()
+    else
+      window.location.search = (param for param in params when not param.match(regex)).join('&')
+
+  # Filter form: don't send any inputs that are empty
+  $('.filter_form').submit (e) ->
+    $(@).find(':input').filter(-> @value is '').prop 'disabled', true
+    if typeof Turbolinks != 'undefined'
+      Turbolinks.visit(window.location.href.split('?')[0] + '?' + $( this ).serialize())
+      e.preventDefault()
+
+  # Filter form: for filters that let you choose the query method from
+  # a dropdown, apply that choice to the filter input field.
+  $('.filter_form_field.select_and_search select').change ->
+    $(@).siblings('input').prop name: "q[#{@value}]"
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/initializers/tabs.js.coffee

@@ -0,0 +1,7 @@
+onDOMReady = ->
+  # Tab navigation
+  $('#active_admin_content .tabs').tabs()
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/lib/batch_actions.js.coffee

@@ -0,0 +1,42 @@
+onDOMReady = ->
+  #
+  # Use ActiveAdmin.modal_dialog to prompt user if confirmation is required for current Batch Action
+  #
+  $('.batch_actions_selector li a').click (e)->
+    e.stopPropagation() # prevent Rails UJS click event
+    e.preventDefault()
+    if message = $(@).data 'confirm'
+      ActiveAdmin.modal_dialog message, $(@).data('inputs'), (inputs)=>
+        $(@).trigger 'confirm:complete', inputs
+    else
+      $(@).trigger 'confirm:complete'
+
+  $('.batch_actions_selector li a').on 'confirm:complete', (e, inputs)->
+    if val = JSON.stringify inputs
+      $('#batch_action_inputs').removeAttr('disabled').val val
+    else
+      $('#batch_action_inputs').attr 'disabled', 'disabled'
+
+    $('#batch_action').val $(@).data 'action'
+    $('#collection_selection').submit()
+
+  #
+  # Add checkbox selection to resource tables and lists if batch actions are enabled
+  #
+
+  if $(".batch_actions_selector").length && $(":checkbox.toggle_all").length
+
+    if $(".paginated_collection table.index_table").length
+      $(".paginated_collection table.index_table").tableCheckboxToggler()
+    else
+      $(".paginated_collection").checkboxToggler()
+
+    $(document).on 'change', '.paginated_collection :checkbox', ->
+      if $(".paginated_collection :checkbox:checked").length
+        $(".batch_actions_selector").each -> $(@).aaDropdownMenu("enable")
+      else
+        $(".batch_actions_selector").each -> $(@).aaDropdownMenu("disable")
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/lib/checkbox-toggler.js.coffee

@@ -0,0 +1,46 @@
+class ActiveAdmin.CheckboxToggler
+  constructor: (@options, @container)->
+    defaults = {}
+    @options = $.extend defaults, @options
+    @_init()
+    @_bind()
+
+  _init: ->
+    if not @container
+      throw new Error('Container element not found')
+    else
+      @$container = $(@container)
+
+    if not @$container.find('.toggle_all').length
+      throw new Error('"toggle all" checkbox not found')
+    else
+      @toggle_all_checkbox = @$container.find '.toggle_all'
+
+    @checkboxes = @$container.find(':checkbox').not @toggle_all_checkbox
+
+  _bind: ->
+    @checkboxes.change       (e)=> @_didChangeCheckbox e.target
+    @toggle_all_checkbox.change => @_didChangeToggleAllCheckbox()
+
+  _didChangeCheckbox: (checkbox)->
+    numChecked = @checkboxes.filter(':checked').length
+
+    allChecked = numChecked == @checkboxes.length
+    someChecked = numChecked > 0 && numChecked < @checkboxes.length
+
+    @toggle_all_checkbox.prop checked: allChecked, indeterminate: someChecked
+
+  _didChangeToggleAllCheckbox: ->
+    setting = @toggle_all_checkbox.prop 'checked'
+    @checkboxes.prop checked: setting
+    setting
+
+  option: (key, value) ->
+    if $.isPlainObject(key)
+      @options = $.extend(true, @options, key)
+    else if key?
+      @options[key]
+    else
+      @options[key] = value
+
+$.widget.bridge 'checkboxToggler', ActiveAdmin.CheckboxToggler

data/app/assets/javascripts/active_admin/lib/dropdown-menu.js.coffee

@@ -0,0 +1,104 @@
+class ActiveAdmin.DropdownMenu
+
+  constructor: (@options, @element) ->
+    @$element = $(@element)
+
+    defaults = {
+      fadeInDuration: 20,
+      fadeOutDuration: 100,
+      onClickActionItemCallback: null
+    }
+
+    @options = $.extend defaults, @options
+    @isOpen  = false
+
+    @$menuButton = @$element.find '.dropdown_menu_button'
+    @$menuList   = @$element.find '.dropdown_menu_list_wrapper'
+
+    @_buildMenuList()
+    @_bind()
+
+  open: ->
+    @isOpen = true
+    @$menuList.fadeIn @options.fadeInDuration
+
+    @_position()
+    @
+
+
+  close: ->
+    @isOpen = false
+    @$menuList.fadeOut this.options.fadeOutDuration
+    @
+
+  destroy: ->
+    @$element = null
+    @
+
+  isDisabled: ->
+    @$menuButton.hasClass 'disabled'
+
+  disable: ->
+    @$menuButton.addClass 'disabled'
+
+  enable: ->
+    @$menuButton.removeClass 'disabled'
+
+  option: (key, value) ->
+    if $.isPlainObject(key)
+      @options = $.extend(true, @options, key)
+    else if key?
+      @options[key]
+    else
+      @options[key] = value
+
+  # Private
+
+  _buildMenuList: ->
+    @$nipple = $('<div class="dropdown_menu_nipple"></div>')
+    @$menuList.prepend @$nipple
+    @$menuList.hide()
+
+  _bind: ->
+    $('body').click =>
+      @close() if @isOpen
+
+    @$menuButton.click =>
+      unless @isDisabled()
+        if @isOpen then @close() else @open()
+      false
+
+  _position: ->
+    @$menuList.css 'top', @$menuButton.position().top + @$menuButton.outerHeight() + 10
+
+    button_left = @$menuButton.position().left
+    button_center =  @$menuButton.outerWidth() / 2
+    button_right = button_left + button_center * 2
+    menu_center = @$menuList.outerWidth() / 2
+    nipple_center = @$nipple.outerWidth() / 2
+    window_right = $(window).width()
+
+    centered_menu_left = button_left + button_center - menu_center
+    centered_menu_right = button_left + button_center + menu_center
+
+    if centered_menu_left < 0
+      # Left align with button
+      @$menuList.css 'left', button_left
+      @$nipple.css   'left', button_center - nipple_center
+    else if centered_menu_right > window_right
+      # Right align with button
+      @$menuList.css 'right', window_right - button_right
+      @$nipple.css   'right', button_center - nipple_center
+    else
+      # Center align under button
+      @$menuList.css 'left', centered_menu_left
+      @$nipple.css   'left', menu_center - nipple_center
+
+$.widget.bridge 'aaDropdownMenu', ActiveAdmin.DropdownMenu
+
+onDOMReady = ->
+  $('.dropdown_menu').aaDropdownMenu()
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady

data/app/assets/javascripts/active_admin/lib/flash.js.coffee

@@ -0,0 +1,19 @@
+ActiveAdmin.flash =
+  class Flash
+    @error: (message, close_after) ->
+      new @ message, "error", close_after
+    @notice: (message, close_after) ->
+      new @ message, "notice", close_after
+    reference: ->
+      @reference
+    constructor: (@message, @type = "notice", close_after) ->
+      @reference = jQuery("<div>").addClass("flash flash_#{@type}").text(@message)
+      jQuery ".flashes"
+        .append @reference
+      @close_after close_after if close_after?
+    close_after: (close_after) ->
+      setTimeout =>
+        @close()
+      , close_after * 1000
+    close: ->
+      @reference.remove()

data/app/assets/javascripts/active_admin/lib/has_many.js.coffee

@@ -0,0 +1,79 @@
+$ ->
+  # Provides a before-removal hook:
+  # $ ->
+  #   # This is a good place to tear down JS plugins to prevent memory leaks.
+  #   $(document).on 'has_many_remove:before', '.has_many_container', (e, fieldset, container)->
+  #     fieldset.find('.select2').select2 'destroy'
+  #
+  #   # If you need to do anything after removing the items you can use the
+  #   has_many_remove:after hook
+  #   $(document).on 'has_many_remove:after', '.has_many_container', (e, fieldset, container)->
+  #     list_item_count = container.find('.has_many_fields').length
+  #     alert("There are now #{list_item_count} items in the list")
+  #
+  $(document).on 'click', 'a.button.has_many_remove', (e)->
+    e.preventDefault()
+    parent    = $(@).closest '.has_many_container'
+    to_remove = $(@).closest 'fieldset'
+    recompute_positions parent
+
+    parent.trigger 'has_many_remove:before', [to_remove, parent]
+    to_remove.remove()
+    parent.trigger 'has_many_remove:after', [to_remove, parent]
+
+  # Provides before and after creation hooks:
+  # $ ->
+  #   # The before hook allows you to prevent the creation of new records.
+  #   $(document).on 'has_many_add:before', '.has_many_container', (e, container)->
+  #     if $(@).children('fieldset').length >= 3
+  #       alert "you've reached the maximum number of items"
+  #       e.preventDefault()
+  #
+  #   # The after hook is a good place to initialize JS plugins and the like.
+  #   $(document).on 'has_many_add:after', '.has_many_container', (e, fieldset, container)->
+  #     fieldset.find('select').chosen()
+  #
+  $(document).on 'click', 'a.button.has_many_add', (e)->
+    e.preventDefault()
+    parent = $(@).closest '.has_many_container'
+    parent.trigger before_add = $.Event('has_many_add:before'), [parent]
+
+    unless before_add.isDefaultPrevented()
+      index = parent.data('has_many_index') || parent.children('fieldset').length - 1
+      parent.data has_many_index: ++index
+
+      regex = new RegExp $(@).data('placeholder'), 'g'
+      html  = $(@).data('html').replace regex, index
+
+      fieldset = $(html).insertBefore(@)
+      recompute_positions parent
+      parent.trigger 'has_many_add:after', [fieldset, parent]
+
+  $(document).on 'change','.has_many_container[data-sortable] :input[name$="[_destroy]"]', ->
+    recompute_positions $(@).closest '.has_many'
+
+  init_sortable()
+  $(document).on 'has_many_add:after', '.has_many_container', init_sortable
+
+
+init_sortable = ->
+  elems = $('.has_many_container[data-sortable]:not(.ui-sortable)')
+  elems.sortable \
+    items: '> fieldset',
+    handle: '> ol > .handle',
+    stop:    recompute_positions
+  elems.each recompute_positions
+
+recompute_positions = (parent)->
+  parent     = if parent instanceof jQuery then parent else $(@)
+  input_name = parent.data 'sortable'
+  position   = parseInt(parent.data('sortable-start') || 0, 10)
+
+  parent.children('fieldset').each ->
+    # We ignore nested inputs, so when defining your has_many, be sure to keep
+    # your sortable input at the root of the has_many block.
+    destroy_input  = $(@).find "> ol > .input > :input[name$='[_destroy]']"
+    sortable_input = $(@).find "> ol > .input > :input[name$='[#{input_name}]']"
+
+    if sortable_input.length
+      sortable_input.val if destroy_input.is ':checked' then '' else position++

data/app/assets/javascripts/active_admin/lib/modal_dialog.js.coffee

@@ -0,0 +1,45 @@
+ActiveAdmin.modal_dialog = (message, inputs, callback)->
+  html = """<form id="dialog_confirm" title="#{message}"><ul>"""
+  for name, type of inputs
+    if /^(datepicker|checkbox|text|number)$/.test type
+      wrapper = 'input'
+    else if type is 'textarea'
+      wrapper = 'textarea'
+    else if $.isArray type
+      [wrapper, elem, opts, type] = ['select', 'option', type, '']
+    else
+      throw new Error "Unsupported input type: {#{name}: #{type}}"
+
+    klass = if type is 'datepicker' then type else ''
+    html += """<li>
+      <label>#{name.charAt(0).toUpperCase() + name.slice(1)}</label>
+      <#{wrapper} name="#{name}" class="#{klass}" type="#{type}">""" +
+        (if opts then (
+          for v in opts
+            $elem = $("<#{elem}/>")
+            if $.isArray v
+              $elem.text(v[0]).val(v[1])
+            else
+              $elem.text(v)
+            $elem.wrap('<div>').parent().html()
+        ).join '' else '') +
+      "</#{wrapper}>" +
+    "</li>"
+    [wrapper, elem, opts, type, klass] = [] # unset any temporary variables
+
+  html += "</ul></form>"
+
+  form = $(html).appendTo('body')
+  $('body').trigger 'modal_dialog:before_open', [form]
+
+  form.dialog
+    modal: true
+    open: (event, ui) ->
+      $('body').trigger 'modal_dialog:after_open', [form]
+    dialogClass: 'active_admin_dialog'
+    buttons:
+      OK: ->
+        callback $(@).serializeObject()
+        $(@).dialog('close')
+      Cancel: ->
+        $(@).dialog('close').remove()

data/app/assets/javascripts/active_admin/lib/per_page.js.coffee

@@ -0,0 +1,46 @@
+class ActiveAdmin.PerPage
+  constructor: (@options, @element)->
+    @$element = $(@element)
+    @_init()
+    @_bind()
+
+  _init: ->
+    @$params = @_queryParams()
+
+  _bind: ->
+    @$element.change =>
+      @$params['per_page'] = @$element.val()
+      delete @$params['page']
+      if typeof Turbolinks != 'undefined'
+        Turbolinks.visit(window.location.href.split('?')[0] + '?' + $.param(@$params))
+      else
+        location.search = $.param(@$params)
+
+  _queryParams: ->
+    query = window.location.search.substring(1)
+    params = {}
+    re = /([^&=]+)=([^&]*)/g
+    while m = re.exec(query)
+      params[@_decode(m[1])] = @_decode(m[2])
+    params
+
+  _decode: (value) ->
+    #replace "+" before decodeURIComponent
+    decodeURIComponent(value.replace(/\+/g, '%20'))
+
+  option: (key, value) ->
+    if $.isPlainObject(key)
+      @options = $.extend(true, @options, key)
+    else if key?
+      @options[key]
+    else
+      @options[key] = value
+
+$.widget.bridge 'perPage', ActiveAdmin.PerPage
+
+onDOMReady = ->
+  $('.pagination_per_page select').perPage()
+
+$(document).
+  ready(onDOMReady).
+  on 'page:load turbolinks:load', onDOMReady