Pratt 1.5.6

data/pkgs/tile-0.8.2/demos/dirbrowser.tcl

@@ -0,0 +1,167 @@
+#
+# dirbrowser.tcl,v 1.2 2004/10/05 23:42:07 jenglish Exp
+#
+# treeview widget demonstration.
+#
+#
+
+lappend auto_path ../generic ..
+package require tile
+
+# Create a treeview widget:
+#
+set f [ttk::frame .f]
+ttk::scrollbar $f.vsb -orient vertical -command [list $f.tv yview]
+
+set tv [ttk::treeview $f.tv -columns {size mtime} \
+	-yscrollcommand [list $f.vsb set] ]
+
+grid $f.tv $f.vsb -sticky news
+grid columnconfigure $f 0 -weight 1
+grid rowconfigure $f 0 -weight 1
+
+#
+# Set column headings:
+#
+# Column #0 is the tree colum.
+#
+$tv heading #0 -text "Name" -command [list sortBy $tv #0]
+$tv heading size -text "Size" -command [list sortBy $tv size]
+$tv heading mtime -text "Modified" -command [list sortBy $tv mtime]
+
+$tv column size -anchor e
+$tv column mtime -anchor e
+
+#
+# Create some images to use as tree icons:
+# (images taken from tkfbox.tcl)
+#
+
+foreach {icon data} {
+    folder {R0lGODlhEAAMAKEAAAD//wAAAPD/gAAAACH5\
+	    BAEAAAAALAAAAAAQAAwAAAIghINhyycvVFsB\
+	    QtmS3rjaH1Hg141WaT5ouprt2HHcUgAAOw==}
+    file   {R0lGODlhDAAMAKEAALLA3AAAAP//8wAAACH5\
+    	    BAEAAAAALAAAAAAMAAwAAAIgRI4Ha+IfWHsO\
+	    rSASvJTGhnhcV3EJlo3kh53ltF5nAhQAOw==}
+} {
+    set Icons($icon) [image create photo -data $data]
+}
+
+# scanDirectory -- 
+#	Scan a directory and add items to the treeview widget.
+#
+#	To prevent a long initial delay, subdirectories are
+#	scanned "on demand" in the <<TreeviewOpen>> binding.
+#	The "Pending" array holds a script to be evaluated
+#	when an item is first opened.
+#
+proc scanDirectory {tv parent dir} {
+    variable Icons
+    variable Pending
+
+    foreach subdir [glob -nocomplain -type d -directory $dir *] {
+        set item [$tv insert $parent end \
+		-text [file tail $subdir] -image $Icons(folder) \
+		-values [list {} [datestamp [file mtime $subdir]] ] ]
+	set Pending($item) [list scanDirectory $tv $item $subdir]
+    }
+    foreach file [glob -nocomplain -type f -directory $dir *] {
+
+	set item [$tv insert $parent end \
+		-text [file tail $file] -image $Icons(file)]
+
+    	$tv set $item size [file size $file]
+    	$tv set $item mtime [datestamp [file mtime $file]]
+    }
+}
+
+bind $tv <<TreeviewOpen>> { itemOpened %W }
+
+proc itemOpened {w} {
+    variable Pending
+    set item [$w focus]
+    if {[info exists Pending($item)]} {
+    	uplevel #0 $Pending($item)
+	unset Pending($item)
+    }
+}
+
+# scanAll --
+#	Force the tree to be fully populated, by repeatedly
+#	evaluating the contents of the Pending array.
+#
+proc scanAll {} {
+    variable Pending
+    . configure -cursor watch
+    while {[llength [set pending [array get Pending]]]} {
+    	array unset Pending
+	foreach {_ script} $pending { uplevel #0 $script }
+    }
+    . configure -cursor {}
+}
+
+# openAll --
+#	Recursively open all nodes in the tree.
+#
+proc openAll {tv {item {}}} {
+    foreach child [$tv children $item] {
+	$tv item $child -open true
+	openAll $tv $child
+    }
+}
+
+# datestamp --
+#	Convert clock values to a human-readable format
+#
+proc datestamp {clockValue} {
+    variable clockfmt "%Y-%m-%d %H:%M"
+    clock format $clockValue -format $clockfmt
+}
+
+# sortBy --
+#	Sort the children of each item by the specified column,
+#	or by the -text label if $column is {}.
+#
+proc sortBy {tv column {parent {}}} {
+    foreach child [$tv children $parent] {
+	sortBy $tv $column $child
+    }
+    set items [list]
+    if {$column eq "#0"} {
+	# Sort by -text label:
+	foreach child [$tv children $parent] {
+	    lappend items [list $child [$tv item $child -text]]
+	}
+    } else {
+	foreach child [$tv children $parent] {
+	    lappend items [list $child [$tv set $child $column]]
+	}
+    }
+
+    set children [list]
+    foreach item [lsort -dictionary -index 1 $items] {
+	lappend children [lindex $item 0]
+    }
+    $tv children $parent $children
+}
+
+# Rest of GUI.
+#
+set cmd [ttk::frame .cmd]
+grid x \
+    [ttk::button $cmd.open -text "Open all" -command [list openAll $tv]] \
+    [ttk::button $cmd.scan -text "Scan all" -command {scanAll} ] \
+    [ttk::button $cmd.close -text "Close" -command [list destroy .]] \
+    -padx 6 ;
+grid columnconfigure $cmd 0 -weight 1
+
+bind . <KeyPress-Escape> [list event generate $cmd.close <<Invoke>>]
+
+pack $cmd -side bottom -expand false -fill x -padx 6 -pady 6
+pack $f -side top -expand true -fill both
+
+# Load the initial directory:
+#
+scanDirectory $tv {} ~
+

data/pkgs/tile-0.8.2/demos/dlgtest.tcl

@@ -0,0 +1,97 @@
+#
+# test/demo script for dialog.tcl
+#
+
+package require tile
+
+array set DLG {
+    icon	question
+    title	"Quit..."
+    message	"Are you sure you want to quit?"
+    detail	"Quitting the application will cause it to stop running. \
+    		 You will lose any unsaved data, and make the application \
+		 feel unloved.  Please consider leaving it open."
+}
+
+proc displayDialog {} {
+    variable DLG
+
+    if {[winfo exists .dlg]} { ttk::dialog::dismiss .dlg }
+
+    ttk::dialog .dlg \
+	-icon $DLG(icon) \
+	-title $DLG(title) \
+	-message $DLG(message) \
+	-detail $DLG(detail) \
+    	-type yesnocancel \
+	-default yes \
+	-cancel cancel \
+	;
+
+    if {0} {
+	set f [ttk::dialog::clientframe .dlg]
+	pack [ttk::progressbar $f.progress -value 50] -expand false -fill x
+	tile::progressbar::start $f.progress
+    }
+}
+
+# displayMessageBox --
+#	Display standard Tk mesageDialog, for comparison.
+#
+proc displayMessageBox {} {
+    variable DLG
+    tk_messageBox -parent . \
+	-type yesnocancel \
+	-icon $DLG(icon) \
+	-title $DLG(title) \
+	-message $DLG(message) \
+	-detail $DLG(detail) \
+	-default yes \
+	;
+}
+
+
+proc dialogDemo {t} {
+    variable DLG
+
+    ttk::frame $t
+    set f [ttk::frame $t.f]
+    foreach field {title message detail} { 
+	grid \
+	    [ttk::label $f.l$field -text "[string totitle $field]:" -anchor e] \
+	    [ttk::entry $f.$field -textvariable ::DLG($field) -width 60] \
+	-sticky new -padx 3
+    }
+
+    grid \
+    	[ttk::label $f.licon -text "Icon:" -anchor e] \
+        [ttk::combobox $f.icon -state readonly -textvariable DLG(icon) \
+		-values [list info question warning error]] \
+    -sticky new -padx 3
+
+    grid columnconfigure $f 0 -weight 1
+    grid columnconfigure $f 1 -weight 5
+    grid rowconfigure $f 99 -weight 1
+
+    set cmd [ttk::frame $t.cmd]
+    grid x \
+    	[ttk::button $cmd.go -text "Display" -command displayDialog] \
+    	[ttk::button $cmd.alt -text "Message" -command displayMessageBox] \
+	[ttk::button $cmd.quit -text "Close" \
+		-command [list destroy [winfo toplevel $t]]] \
+	-padx [list 6 0] -pady 6 -sticky ew;
+    grid columnconfigure $cmd 0 -weight 1
+    bind . <KeyPress-Escape> [list event generate $cmd.quit <<Invoke>>]
+    keynav::defaultButton $cmd.go
+
+    pack $t.cmd -side bottom -expand false -fill x -padx 6 -pady 6
+    pack $t.f -side top -expand true -fill both -padx 12 -pady 12
+
+    return $t
+}
+
+proc dlgtest-main {} {
+    pack [dialogDemo .t] -expand true -fill both
+}
+
+if {[info exists argv0] && $argv0 eq [info script]} { dlgtest-main }

data/pkgs/tile-0.8.2/demos/iconlib.tcl

@@ -0,0 +1,110 @@
+array set ImgData {
+bold {R0lGODlhEAAQAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAAQABAAAAI6hI+py60U3wj+
+RYQFJYRvEWFBCeFbRFhQQvhG8YPgX0RYUEL4FhEWlBC+RYQFJYQPFN8IPqYut/8hBQA7}
+copy {R0lGODlhEAAQAJEAANnZ2QAAAP///wAAhCH5BAEAAAAALAAAAAAQABAAAAJUhI8JFJ/gY4iI
+UEL4FyIiFIXgW0iEUDgfACBI9pzMAAGRiIghWSMDECR7JEKGtkFIRFBG+TIQKDQxtgzcDcmX
+IfgwQrFlCD4MyZch+EDzj+Bj6mYBADs=}
+cut {R0lGODlhEAAQAJEAANnZ2QAAAAAAhP///yH5BAEAAAAALAAAAAAQABAAAAJFhI+pcUHwEeIi
+E0gACIKPEAFBIXy0gMg8EhM+YmQiKSL4eAIiJMI/EQEhQGYGYiQIQAg+iAkIATIzECMBIgT/
+RBARERlSADs=}
+dragfile {R0lGODlhGAAYAKIAANnZ2TMzM////wAAAJmZmf///////////yH5BAEAAAAALAAAAAAYABgA
+AAPACBi63IqgC4GiyxwogaAbKLrMgSKBoBoousyBogEACIGiyxwoKgGAECI4uiyCExMTOACB
+osuNpDoAGCI4uiyCIkREOACBosutSDoAgSI4usyCIjQAGCi63Iw0ACEoOLrMgiI0ABgoutyM
+NAAhKDi6zIIiNAAYKLrcjDQAISg4usyCIjQAGCi63Iw0AIGiiqPLIyhCA4CBosvNSAMQKKo4
+ujyCIjQAGCi63Iw0AIGiy81IAxCBpMu9GAMAgKPL3QgJADs=}
+dragicon {R0lGODlhGAAYALMAANnZ2TMzM/////8zM8zMzGYAAAAAAJmZmQCZMwAzZgCZzGZmZv//////
+/////////yH5BAEAAAAALAAAAAAYABgAAAT/EMAgJ60SAjlBgEJOSoMIEMgZoJCT0iADBFIG
+KOSkNMwAAABhwiHnIEKIIIQQAQIZhBBwyDmKEMIEE0yABoAghIBDzlGEENDIaQAIQgg45BwF
+CinPOccAECYcUiKEEBFCiHPgMQAEIcQYYyABBUGIQCHlMQCEScZAAhKEEApCECGOARAEIQQp
+BRGIpAyCJCGOASBAISdEcqJAVBLiGABggELOAJGUKyiVhDgGABigkJMEhNAKSqkEhTgGgCCl
+FCQEGIJSSiUhjgEgQCEnJVBJmYQ4BoAAhZyTQCVnEuIYAAIUckoCk5xSiGMACFDISSs9BoBg
+rRXQMQAEKOSklR4DEUAI8MhJ6wwGAACgkZNWCkAEADs=}
+error {R0lGODlhIAAgAKIAANnZ2YQAAP8AAISEhP///////////////yH5BAEAAAAALAAAAAAgACAA
+AAP/CLoMGLqKoMvtGIqiqxEYCLrcioGiyxwIusyBgaLLLRiBoMsQKLrcjYGgu4Giy+2CAkFX
+A0WX2wXFIOgGii7trkCEohsDCACBoktEKLpKhISiGwAIECiqSKooukiqKKoxgACBooukKiIo
+SKooujGDECi6iqQqsopEV2MQAkV3kXQZRXdjEAJFl5F0FUWXY3ACRZcFSRdFlyVwJlB0WZB0
+UXRZAmcCRZeRdBVFl2NwAkV3kXQZRXdjcAJFV5FURVaR6GoMDgSKLpKqiKAgqaLoxgwOBIoq
+kiqKLpIqimrM4ECg6BIRiq4SIaHoxgyCBoou7a5AhKIbMzgAAIGiy+2CTWJmBhAAAkWX2wXF
+zCDoBooud2PMDIKuRqDocgtGzMwg6O4Eii5z4Kgi6DIMhqLoagQGjiqCLvPgYOgqji6CLrfi
+6DIj6HI7jq4i6DIkADs=}
+file {R0lGODlhCwANAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAALAA0AAAIyhI9G8Q0AguSH
+AMQdxQgxEyEFQfItICQokYgEBMm3gBCKLRIQJN8CQii2SECQfAug+FgAOw==}
+folder {R0lGODlhEAANAKIAANnZ2YSEhMbGxv//AP///wAAAP///////yH5BAEAAAAALAAAAAAQAA0A
+AANjCIqhiqDLITgyEgi6GoIjIyMYugCBpMsaWBA0giMjIzgyUYBBMjIoIyODEgVBODIygiMj
+E1gQJIMyMjIoI1GAQSMjODIyghMFQSgjI4MyMhJYEDSCIyMjODJRgKHLXAiApcucADs=}
+hourglass {R0lGODlhIAAgAKIAANnZ2YAAAAAAAP8AAP///8DAwICAgP///yH5BAEAAAAALAAAAAAgACAA
+AAPZCLrc/jDKSau9OGcUuqyCoMvNGENVhaMrCLrcjaLLgqDL7WhFVIVVZoKgy+1oRUSFVWaC
+oMvtaEVEhVVmgqDL7WhFRIVVZoKgy+1oVVaCJWaCoMvtgKxISrBMEHS5fZEVSRkKgi63NzIq
+EwRdbndkVCYIutzeyIqqDAVBl9sXWRFJYZkg6HI7ICsiKqwyEwRdbkcrIhKsMhMEXW5HKyIp
+lDITBF1uRysyEiwxEwRdbkcrIyuUEhMEXW5H0WVB0OVujKGqwtEVBF1uRtHlRdDl9odRTlrt
+xRmjBAA7}
+info {R0lGODlhIAAgAKIAANnZ2YSEhMbGxv///wAA/wAAAP///////yH5BAEAAAAALAAAAAAgACAA
+AAP/CLoMGLqKoMvtGCo4uhKBgaDLDRghOLqsghEIuryBgqPLPSiBoMsQOLojhEQkOLpTCLob
+OLqKpIujq4WgC4Gju0i6OLpbCKohOLorhEQkOLorhaAQOLrc3qgCIARHl9sbSQUEji4j6RKO
+Lk9hQODosiKp4ujyFIbi6LIiqeLo8hSG4uiyIqni6PIUhuLosiKp4ujyFIYKji4PkiqOLkth
+BASOLg+SKo4uV2AEhODoMpIqju5KYShA4Ogqku7i6E4FRgAAYOHocvugiohAUC0cXe7GiohA
+0IUSHF3uQamICATdrULB0WUVrIqIQNBlCCwVHF2pwsJQRdDlDYyoKsHRPMLQDQRdbsDQqBmc
+wlBF0OV2jJqZwggEXW5vVDMVgaDL7Y5qKgJBl9sfVUUg6HL7AxSKoMvtr1AEgi5DAgA7}
+italic {R0lGODlhEAAQAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAAQABAAAAIrhI+py+1A4hN8
+hIjINBITPlpEZBqJCR8tIjKNxISPFhGZQOITfExdbv9FCgA7}
+new {R0lGODlhEAAQAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAAQABAAAAJFhI95FN8IvgXJ
+jyD4ECQ/JAh+kPyICIIdJP+CYAfJvyDYQfIvCHaQ/AuCHST/gmAHyb8g2EHyLwh2kPwLgk3x
+MQg+pu4WADs=}
+open {R0lGODlhEAAQAKIAANnZ2QAAAP//AP///4SEAP///////////yH5BAEAAAAALAAAAAAQABAA
+AANZCLrczigUQZc1EDQgEHSZAwMgIhB0NQIDQkYwdANBNUZwZGQEJxBUQwZlZGRQAkE1RnAE
+Q5dVcCSQdDcAYySQdDcAISSQdDcAASKQdDcAAQBDlwNBl9sfApQAOw==}
+openfold {R0lGODlhEAANAKIAANnZ2YSEhP///8bGxv//AAAAAP///////yH5BAEAAAAALAAAAAAQAA0A
+AANgCIqhiqDLgaIaCLoagkNDIxi6AIFCQ0M4KKpRgCFDQzg0NIQThaHLSxgVKLochRMVMkhD
+Q4M0VBFYEDKEQ0NDOFFRgCE0NEhDQ4MVBRAoNDSEQ0NRWAAYuqyFBQBYurwJADs=}
+overstrike {R0lGODlhEAAQAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAAQABAAAAI3hI+py80Uh+Aj
+RFhQCP8iMILgWwRGEHyLwAiCbxEYQfCB4iPBhwiMIPgXYREEHyEiguBj6nI7FQA7}
+palette {R0lGODlhEAAQAKIAANnZ2QAAAP//AP////8A/4QAhP8AAAD//yH5BAEAAAAALAAAAAAQABAA
+AANtCLrcjqGBoMsRKCMTgaALMSgDAYMSCKoxgAFBITgSAIAQEhUIARCAEgAQOBAwghMQEwga
+MoIjIxAIEgCAEBEyKBAgg4GgGxAIYTGCgaALcRgQIIGgCwEYICODgaALITgyEoGguxiqCLrc
+/lChBAA7}
+passwd {R0lGODlhIAAgAMQAANnZ2QAAAICAgICAAP///7CwsMDAwMjIAPjIAOjo6Pj4AODg4HBwcMj4
+ANjY2JiYANDQ0MjIyPj4yKCgoMiYAMjImDAwAMjIMJiYmJCQkP//////////////////////
+/yH5BAEAAAAALAAAAAAgACAAAAX/ICCOIhiIIgiII1maZSCMQnCeJyAIQiAIAiAMwxCcJwkk
+EAQRCIUwGMSBDEEAAuJIlgKRJEEgGAMRBIGiDENQlqNAJAsYCEwgEEEgBAHSIEMAAuJIAgKR
+LEsgGEMgCEJgBMqhHENQlgJILMsSCMRABEFgGAESHMcRgIA4kgKxOIsTBAOhKAITKEGDHMhD
+kqIAEqAjisJAgIooBkpwNMcTgIA4jgLhOBAkEAOhKIoSKEGDIMcTkKQICgQEQQIxEIqiBEpw
+IMdxPAEIiCMJCEQUMUQ0EIqiHIfSIM3xBGUpCiABCUQyEMqhHMiBHMjxBCAgjuQoEAKxRANB
+HMqhHM1x/zxDUJajQIACsUTDQBAEIR3IcQRDAALiSIoCYQiEE03gII7HQR3BEICAOJICYRSC
+QDjRNE1CAAzVQR3WE5AkAAqEUQiFQEARBAUAAAzHQR3BEICAOI4CUQhFIBAREwXjUFUHdQRD
+QJJAABbCFAhEJBgBAADAMAwXdQRDAALiCAhEIRQCYRiCEZDjUFFHMAQkIBAFOAmTQBiFUAQg
+II7AUFXUEQwBCQjEJExBkBRCEZCjMIBD9RxDAALiGEzCFBBYIRTBOI7AQB1DMIoCMQkYGAjL
+JEwBCIgjOVDDEJCAQGACJiTTJEwBSY5BEJAiSCCwTAiCZBKmAATEkSzNQBCCYCDBJgELTNMk
+g0AMEgwTAhAQR7I0zYARgvM8TyAIznMMAQA7}
+paste {R0lGODlhEAAQAKIAANnZ2QAAAP//AISEAISEhP///wAAhP///yH5BAEAAAAALAAAAAAQABAA
+AANwCLrcjqGBoKsYqiKrCDSGBkMiJJCGAgCDKBB0gwYDIKYwdJUIAyBokIaGBmloAhBiaAgH
+TdcCEIKGBsmwVM0AIYaGcAxL1coQgoYGySoisMzMAoeGxrB01QJpaMiwMHTLAEPVsHTVEHTR
+dBlBlxswAQA7}
+print {R0lGODlhEAAQAKIAANnZ2QAAAP///4SEhP//AP///////////yH5BAEAAAAALAAAAAAQABAA
+AANZCLrcjqG7CLqBoquBoBuCoSqBoBsouhoIuiEYqrKBoIGiqwEYEIChyxAIEYGgywEYgKHL
+DAgRCLozgwABARgIukSEABEBGLq8gAEQCLobgAEAgKHLgaDLzZgAOw==}
+question {R0lGODlhIAAgAKIAANnZ2YSEhMbGxv///wAAAAAA/////////yH5BAEAAAAALAAAAAAgACAA
+AAP/CLoMGLqKoMvtGCo4uhKBgaDLDRghOLqsghEIuryBgqPLPSiBoMsQOLrcjYSgu4GjO4Kl
+Kzi6Qwi6EDi6I4UyU1VYgqM7hKAagqM7VTg6VYWFoztCCAqBo6tVWDVThVU4ukqBACE4ulqF
+VSNVWIWjq0IYEDi6K4UlU1VYOLpMgRA4uryCpTi6PIShOLq8hVU4uqyEoTi6vIUlOLqshKE4
+uryFhaPLSxgqOLrc3kgoAgJHl0ewSnB0eQhDIQRHl6uwCkeXhTAUIHB0uQqrcHSZAiMAAJBw
+dFcKS3B0lwIjAkGVcHS5GykiAkEXSHB0uQeFIiIQdJcIBUeXVZAoIgJBT5chkFRwdIUICUMV
+QZc3MIKIBEcJQzcQdLkBQ4NmcAhDFUGX2zFoZggjEHS5vRHNUASCLrc7oqEIBF1uf0QUgaDL
+7Q9QKIIut79CEQi6DAkAOw==}
+redo {R0lGODlhEAAQAJEAANnZ2QAAhP///////yH5BAEAAAAALAAAAAAQABAAAAIvhI+py+1vSByC
+jxAYQXDMwsyAggQAQBB8iwgMgg8REQgUwqbYBDsIPqYutz+MgBQAOw==}
+save {R0lGODlhEAAQAJEAANnZ2QAAAISEAP///yH5BAEAAAAALAAAAAAQABAAAAJWhI9pFB8RIIRC
++BYQFqQQvkWEBSmEbyFhQQrhW0hYkEL4FhIWpBC+hYQFSYxvIgFAoXy0AAiSGP8kAIIkxgcI
+CSBEQvEBQgIIkVB8gJAAAhgfj+BjWgEAOw==}
+underline {R0lGODlhEAAQAJEAANnZ2QAAAP///////yH5BAEAAAAALAAAAAAQABAAAAI3hI+py60UBy4I
+vkVcBMG/iIsg+BdxEQT/Ii6C4F/ERRD8i7gIgn8RF0HwkWITfExFin8EH1OXCwA7}
+undo {R0lGODlhEAAQAJEAANnZ2QAAhP///////yH5BAEAAAAALAAAAAAQABAAAAIuhI+py+2vSByC
+HxdxQCHsCIg7oAAAEUHwLTAiKIQPgRSbYMfd3VEIH1OX2x8mUgA7}
+warning {R0lGODlhIAAgAKIAANnZ2YSEAP//AMbGxgAAAISEhP///////yH5BAEAAAAALAAAAAAgACAA
+AAP/CLq8gREIutz+KESGEHS5vVGIiAxSIehy+6JAUaUqBF1uBxQoukOFhaDL7RgoukKFhaDL
+3RgoujqEVQi63IyBortUWAi63IuBostDWIWgy60YIjKERCMiSFUIutyAISKCpCoiOFSFoMsd
+KCpIqiKCQlUIusyBooqkKiIoQ1UIuryBooqkiqJKVQi6rIGii6SKojpUWAi6DIGiG0RIgaJL
+VQi6HCi6MoREg6I7VFgIuhsoukqEhKKrVFgIuhoouhuEgaKrQ1iFoAuBortDOCi6S4WFoBso
+uiyEostDWIWgGii63K6IqgAAIVB0WQaJBkV3h7AKAAJFl4WQiFB0mQoLRyBQdFkJiQhFl4ew
+CgJFl3WQaFB0WQirIFB0ud0RVVWg6HJ7o6GqAgwUXW5fNFRVhQCBpMvti0oVABCwdLndEehi
+6XI7I4AEADs=}
+}

data/pkgs/tile-0.8.2/demos/repeater.tcl

@@ -0,0 +1,117 @@
+#
+# repeater.tcl,v 1.1 2004/09/21 02:34:32 jenglish Exp
+#
+# Demonstration of custom classes.
+#
+# The Tile button doesn't have built-in support for autorepeat.
+# Instead of adding -repeatdelay and -repeatinterval options,
+# and all the extra binding scripts required to deal with them,
+# we create a custom widget class for autorepeating buttons.
+#
+# Usage:
+#	ttk::button .b -class Repeater [... other options ...]
+#
+# TODO:
+#	Use system settings for repeat interval and initial delay.
+#
+# Notes:
+#	Repeater buttons work more like scrollbar arrows than
+#	Tk repeating buttons: they fire once immediately when
+#	first pressed, and $State(delay) specifies the initial 
+#	interval before the button starts autorepeating.
+#
+
+namespace eval tile::Repeater {
+    variable State
+    set State(timer) 	{}	;# [after] id of repeat script
+    set State(interval)	100	;# interval between repetitions
+    set State(delay)	300	;# delay after initial invocation
+}
+
+### Class bindings.
+#
+
+bind Repeater <Enter>		{ %W state active }
+bind Repeater <Leave>		{ %W state !active }
+
+bind Repeater <Key-space> 	{ tile::Repeater::Activate %W }
+bind Repeater <<Invoke>> 	{ tile::Repeater::Activate %W }
+
+bind Repeater <ButtonPress-1> 	{ tile::Repeater::Press %W }
+bind Repeater <ButtonRelease-1> { tile::Repeater::Release %W }
+bind Repeater <B1-Leave> 	{ tile::Repeater::Pause %W }
+bind Repeater <B1-Enter> 	{ tile::Repeater::Resume %W } ;# @@@ see below
+
+# @@@ Workaround for metacity-induced bug:
+bind Repeater <B1-Enter> \
+    { if {"%d" ne "NotifyUngrab"} { tile::Repeater::Resume %W } }
+
+### Binding procedures.
+#
+
+## Activate -- Keyboard activation binding. 
+#	Simulate clicking the button, and invoke the command once. 
+#
+proc tile::Repeater::Activate {w} {
+    $w instate disabled { return }
+    set oldState [$w state pressed]
+    update idletasks; after 100
+    $w state $oldState
+    after idle [list $w invoke]
+}
+
+## Press -- ButtonPress-1 binding.
+#	Invoke the command once and start autorepeating after 
+#	$State(delay) milliseconds.
+#
+proc tile::Repeater::Press {w} {
+    variable State
+    $w instate disabled { return }
+    $w state pressed
+    $w invoke
+    after cancel $State(timer)
+    set State(timer) [after $State(delay) [list tile::Repeater::Repeat $w]]
+}
+
+## Release -- ButtonRelease binding.
+#	Stop repeating.
+#
+proc tile::Repeater::Release {w} {
+    variable State
+    $w state !pressed
+    after cancel $State(timer)
+}
+
+## Pause -- B1-Leave binding
+#	Temporarily suspend autorepeat.
+#
+proc tile::Repeater::Pause {w} {
+    variable State
+    $w state !pressed
+    after cancel $State(timer)
+}
+
+## Resume -- B1-Enter binding
+#	Resume autorepeat.
+#
+proc tile::Repeater::Resume {w} {
+    variable State
+    $w instate disabled { return }
+    $w state pressed
+    $w invoke
+    after cancel $State(timer)
+    set State(timer) [after $State(interval) [list tile::Repeater::Repeat $w]]
+}
+
+## Repeat -- Timer script
+#	Invoke the command and reschedule another repetition 
+#	after $State(interval) milliseconds.
+#
+proc tile::Repeater::Repeat {w} {
+    variable State
+    $w instate disabled { return }
+    $w invoke
+    set State(timer) [after $State(interval) [list tile::Repeater::Repeat $w]]
+}
+
+#*EOF*