Pratt 1.5.6

data/pkgs/tile-0.8.2/library/fonts.tcl

@@ -0,0 +1,153 @@
+#
+# fonts.tcl,v 1.16 2007/12/07 06:25:50 jenglish Exp
+#
+# Font specifications.
+#
+# This file, [source]d at initialization time, sets up the following
+# symbolic fonts based on the current platform:
+#
+# TkDefaultFont	-- default for GUI items not otherwise specified
+# TkTextFont	-- font for user text (entry, listbox, others)
+# TkFixedFont	-- standard fixed width font
+# TkHeadingFont	-- headings (column headings, etc)
+# TkCaptionFont -- dialog captions (primary text in alert dialogs, etc.)
+# TkTooltipFont	-- font to use for tooltip windows
+# TkIconFont	-- font to use for icon captions
+# TkMenuFont	-- used to use for menu items
+#
+# In Tk 8.5, some of these fonts may be provided by the TIP#145 implementation
+# (On Windows and Mac OS X as of Oct 2007).
+#
+# The TIP, fonts(n) manpage, and implementation do not as of yet agree.
+#
+# +++ Platform notes:
+#
+# Windows:
+#	The default system font changed from "MS Sans Serif" to "Tahoma"
+# 	in Windows XP/Windows 2000.
+#
+#	MS documentation says to use "Tahoma 8" in Windows 2000/XP,
+#	although many MS programs still use "MS Sans Serif 8"
+#
+#	Should use SystemParametersInfo() instead.
+#
+# Mac OSX / Aqua:
+#	Quoth the Apple HIG:
+#	The _system font_ (Lucida Grande Regular 13 pt) is used for text
+#	in menus, dialogs, and full-size controls.
+#	[...] Use the _view font_ (Lucida Grande Regular 12pt) as the default
+#	font of text in lists and tables.
+#	[...] Use the _emphasized system font_ (Lucida Grande Bold 13 pt)
+#	sparingly. It is used for the message text in alerts.
+#	[...] The _small system font_ (Lucida Grande Regular 11 pt) [...]
+#	is also the default font for column headings in lists, for help tags,
+#	and for small controls.
+#
+#	That document lies, however (see #780617).  The font sizes
+#	used below reflect what GetThemeFont() returns.
+#
+#	Note that the font for column headings (TkHeadingFont) is
+#	_smaller_ than the default font.
+#
+#	There does not appear to be any recommendations for fixed-width fonts.
+#
+# Mac classic:
+#	Don't know, can't find *anything* on the Web about Mac pre-OSX.
+#	Might have used Geneva.  Doesn't matter, this platform
+#	isn't supported anymore anyway.
+#
+# X11:
+#	Need a way to tell if Xft is enabled or not.
+#	For now, assume patch #971980 applied.
+#
+#	"Classic" look used Helvetica bold for everything except
+#	for entry widgets, which use Helvetica medium.
+#	Most other toolkits use medium weight for all UI elements,
+#	which is what we do now.
+#
+#	Font size specified in pixels on X11, not points.
+#	This is Theoretically Wrong, but in practice works better; using
+#	points leads to huge inconsistencies across different servers.
+#
+
+namespace eval ttk {
+
+catch {font create TkDefaultFont}
+catch {font create TkTextFont}
+catch {font create TkHeadingFont}
+catch {font create TkCaptionFont}
+catch {font create TkTooltipFont}
+catch {font create TkFixedFont}
+catch {font create TkIconFont}
+catch {font create TkMenuFont}
+
+variable F	;# miscellaneous platform-specific font parameters
+switch -- [tk windowingsystem] {
+    win32 {
+	if {$tcl_platform(osVersion) >= 5.0} {
+	    set F(family) "Tahoma"
+	} else {
+	    set F(family) "MS Sans Serif"
+	}
+	set F(size) 8
+
+	font configure TkDefaultFont -family $F(family) -size $F(size)
+	font configure TkTextFont    -family $F(family) -size $F(size)
+	font configure TkHeadingFont -family $F(family) -size $F(size)
+	font configure TkCaptionFont -family $F(family) -size $F(size) \
+					-weight bold
+	font configure TkTooltipFont -family $F(family) -size $F(size)
+	font configure TkFixedFont   -family Courier -size 10
+	font configure TkIconFont    -family $F(family) -size $F(size)
+	font configure TkMenuFont    -family $F(family) -size $F(size)
+    }
+    aqua {
+	set F(family) "Lucida Grande"
+	set F(fixed) "Monaco"
+	set F(menusize) 14
+	set F(size) 13
+	set F(viewsize) 12
+	set F(smallsize) 11
+	set F(fixedsize) 11
+
+	font configure TkDefaultFont -family $F(family) -size $F(size)
+	font configure TkTextFont    -family $F(family) -size $F(size)
+	font configure TkHeadingFont -family $F(family) -size $F(smallsize)
+	font configure TkCaptionFont -family $F(family) -size $F(size) \
+					-weight bold
+	font configure TkTooltipFont -family $F(family) -size $F(smallsize)
+	font configure TkFixedFont   -family $F(fixed)  -size $F(fixedsize)
+	font configure TkIconFont    -family $F(family) -size $F(size)
+	font configure TkMenuFont    -family $F(family) -size $F(menusize)
+    }
+    default -
+    x11 {
+	if {![catch {tk::pkgconfig get fontsystem} F(fs)] && $F(fs) eq "xft"} {
+	    set F(family) "sans-serif"
+	    set F(fixed)  "monospace"
+	} else {
+	    set F(family) "Helvetica"
+	    set F(fixed)  "courier"
+	}
+	set F(size) -12
+	set F(ttsize) -10
+	set F(capsize) -14
+	set F(fixedsize) -12
+
+	font configure TkDefaultFont -family $F(family) -size $F(size)
+	font configure TkTextFont    -family $F(family) -size $F(size)
+	font configure TkHeadingFont -family $F(family) -size $F(size) \
+			-weight bold
+	font configure TkCaptionFont -family $F(family) -size $F(capsize) \
+			-weight bold
+	font configure TkTooltipFont -family $F(family) -size $F(ttsize)
+	font configure TkFixedFont   -family $F(fixed)  -size $F(fixedsize)
+	font configure TkIconFont    -family $F(family) -size $F(size)
+	font configure TkMenuFont    -family $F(family) -size $F(size)
+    }
+}
+unset -nocomplain F
+
+}
+
+#*EOF*

data/pkgs/tile-0.8.2/library/icons.tcl

@@ -0,0 +1,105 @@
+#
+# icons.tcl,v 1.4 2006/11/06 14:46:42 jenglish Exp
+#
+# Tile package -- stock icons.
+# 
+# Usage:
+#	$w configure -image [ttk::stockIcon $context/$icon]
+#
+# At present, only includes icons for dialog boxes,
+# dialog/info, dialog/warning, dialog/error, etc.
+#
+# This list should be expanded.
+#
+# See the Icon Naming Specification from the Tango project:
+# http://standards.freedesktop.org/icon-naming-spec/
+# They've finally gotten around to publishing something.
+#
+
+namespace eval ttk {
+    variable Icons		;# Map: icon name -> image
+    namespace eval icons {}	;# container namespace for images
+}
+
+# stockIcon $name --
+#	Returns a Tk image for built-in icon $name. 
+#
+proc ttk::stockIcon {name} {
+    variable Icons
+    return $Icons($name)
+}
+
+# defineImage --
+#	Define a new stock icon.
+# 
+proc ttk::defineImage {name args} {
+    variable Icons
+    set iconName ::ttk::icons::$name
+    eval [linsert $args 0 image create photo $iconName]
+    set Icons($name) $iconName
+}
+
+#
+# Stock icons for dialogs 
+#
+# SOURCE: dialog icons taken from BWidget toolkit.
+#
+ttk::defineImage dialog/error -data {
+    R0lGODlhIAAgALMAAIQAAISEhPf/Mf8AAP//////////////////////////
+    /////////////////////yH5BAEAAAIALAAAAAAgACAAAASwUMhJBbj41s0n
+    HmAIYl0JiCgKlNWVvqHGnnA9mnY+rBytw4DAxhci2IwqoSdFaMKaSBFPQhxA
+    nahrdKS0MK8ibSoorBbBVvS4XNOKgey2e7sOmLPvGvkezsPtR3M2e3JzdFIB
+    gC9vfohxfVCQWI6PII1pkZReeIeWkzGJS1lHdV2bPy9koaKopUOtSatDfECq
+    phWKOra3G3YuqReJwiwUiRkZwsPEuMnNycslzrIdEQAAOw==
+}
+
+ttk::defineImage dialog/info -data {
+    R0lGODlhIAAgALMAAAAAAAAA/4SEhMbGxvf/Mf//////////////////////
+    /////////////////////yH5BAEAAAQALAAAAAAgACAAAAStkMhJibj41s0n
+    HkUoDljXXaCoqqRgUkK6zqP7CvQQ7IGsAiYcjcejFYAb4ZAYMB4rMaeO51sN
+    kBKlc/uzRbng0NWlnTF3XAAZzExj2ET3BV7cqufctv2Tj0vvFn11RndkVSt6
+    OYVZRmeDXRoTAGFOhTaSlDOWHACHW2MlHQCdYFebN6OkVqkZlzcXqTKWoS8w
+    GJMhs7WoIoC7v7i+v7uTwsO1o5HHu7TLtcodEQAAOw==
+}
+
+ttk::defineImage dialog/question -data {
+    R0lGODlhIAAgALMAAAAAAAAA/4SEhMbGxvf/Mf//////////////////////
+    /////////////////////yH5BAEAAAQALAAAAAAgACAAAAS2kMhJibj41s0n
+    HkUoDljXXaCoqqRgUkK6zqP7CnS+AiY+D4GgUKbibXwrYEoYIIqMHmcoqGLS
+    BlBLzlrgzgC22FZYAJKvYG3ODPLS0khd+awDX+Qieh2Dnzb7dnE6VIAffYdl
+    dmo6bHiBFlJVej+PizRuXyUTAIxBkSGBNpuImZoVAJ9roSYAqH1Yqzetrkmz
+    GaI3F7MyoaYvHhicoLe/sk8axcnCisnKBczNxa3I0cW+1bm/EQAAOw==
+}
+
+ttk::defineImage dialog/warning -data {
+    R0lGODlhIAAgALMAAAAAAISEAISEhMbGxv//AP//////////////////////
+    /////////////////////yH5BAEAAAUALAAAAAAgACAAAASrsMhJZ7g16y0D
+    IQPAjZr3gYBAroV5piq7uWcoxHJFv3eun0BUz9cJAmHElhFow8lcIQBgwHOu
+    aNJsDfk8ZgHH4TX4BW/Fo12ZjJ4Z10wuZ0cIZOny0jI6NTbnSwRaS3kUdCd2
+    h0JWRYEhVIGFSoEfZo6FipRvaJkfUZB7cp2Cg5FDo6RSmn+on5qCPaivYTey
+    s4sqtqswp2W+v743whTCxcbHyG0FyczJEhEAADs=
+}
+
+ttk::defineImage dialog/auth -data {
+    R0lGODlhIAAgAIQAAAAA/wAAAICAgICAAP///7CwsMDAwMjIAPjIAOjo6Pj4
+    AODg4HBwcMj4ANjY2JiYANDQ0MjIyPj4yKCgoMiYAMjImDAwAMjIMJiYmJCQ
+    kAAAAAAAAAAAAAAAAAAAAAAAACH5BAEAAAAALAAAAAAgACAAAAX+ICCOYmCa
+    ZKquZCCMQsDOqWC7NiAMvEyvAoLQVdgZCAfEAPWDERIJk8AwIJwUil5T91y4
+    GC6ry4RoKH2zYGLhnS5tMUNAcaAvaUF2m1A9GeQIAQeDaEAECw6IJlVYAmAK
+    AWZJD3gEDpeXOwRYnHOCCgcPhTWWDhAQQYydkGYIoaOkp6h8m1ieSYOvP0ER
+    EQwEEap0dWagok1BswmMdbiursfIBHnBQs10oKF30tQ8QkISuAcB25UGQQ4R
+    EzzsA4MU4+WGBkXo6hMTMQADFQfwFtHmFSlCAEKEU2jc+YsHy8nAML4iJKzQ
+    Dx65hiWKTIA4pRC7CxblORRA8E/HFfxfQo4KUiBfPgL0SDbkV0ElKZcmEjwE
+    wqPCgwMiAQTASQDDzhkD4IkMkg+DiwU4aSTVQiIIBgFXE+ATsPHHCRVWM8QI
+    oJUrxi04TCzA0PQsWh9kMVx1u6UFA3116zLJGwIAOw==
+}
+
+ttk::defineImage dialog/busy -data {
+    R0lGODlhIAAgALMAAAAAAIAAAACAAICAAAAAgIAAgACAgMDAwICAgP8AAAD/
+    AP//AAAA//8A/wD//////yH5BAEAAAsALAAAAAAgACAAAASAcMlJq7046827
+    /2AYBmRpkoC4BMlzvEkspypg3zitIsfjvgcEQifi+X7BoUpi9AGFxFATCV0u
+    eMEDQFu1GrdbpZXZC0e9LvF4gkifl8aX2tt7bIPvz/Q5l9btcn0gTWBJeR1G
+    bWBdO0EPPIuHHDmUSyxIMjM1lJVrnp+goaIfEQAAOw==
+}
+
+#*EOF*

data/pkgs/tile-0.8.2/library/keynav.tcl

@@ -0,0 +1,192 @@
+########################################################################
+# keynav package - Enhanced keyboard navigation
+# Copyright (C) 2003 Joe English
+# Freely redistributable; see the file license.terms for details.
+#
+# keynav.tcl,v 1.8 2006/04/07 19:30:48 jenglish Exp
+#
+########################################################################
+#
+# Usage:
+#
+# package require keynav
+#
+# keynav::enableMnemonics $toplevel --
+# 	Enable mnemonic accelerators for toplevel widget.
+#	Pressing Alt-K, where K is any alphanumeric key,
+#	will send an <<Invoke>> event to the widget with
+#	mnemonic K (as determined by the -underline and -text
+#	options).
+#
+#	Side effects: adds a binding for <Alt-KeyPress> to $toplevel
+#
+# keynav::defaultButton $button --
+#	Enables default activation for the toplevel window
+#	in which $button appears.  Pressing <Key-Return> invokes 
+#	the default widget.  The default widget is set to
+#	the widget with keyboard focus if it is defaultable,
+#	otherwise $button.  A widget is _defaultable_
+#	if it has a -default option which is not set to 
+#	"disabled".  
+#
+#	Side effects: adds <FocusIn> and <KeyPress-Return> bindings
+#	to the toplevel containing $button, and a <Destroy> binding
+#	to $button.
+#
+#	$button must be a defaultable widget.
+#
+
+namespace eval keynav {} 
+
+package require Tcl 8.4
+package require Tk 8.4
+package provide keynav 1.0
+
+event add <<Help>> <KeyPress-F1> 
+
+#
+# Bindings for stock Tk widgets: 
+# (NB: for 8.3 use tkButtonInvoke, tkMbPost instead)
+#
+bind Button <<Invoke>>		{ tk::ButtonInvoke %W }
+bind Checkbutton <<Invoke>>	{ tk::ButtonInvoke %W }
+bind Radiobutton <<Invoke>>	{ tk::ButtonInvoke %W }
+bind Menubutton <<Invoke>>	{ tk::MbPost %W }
+
+
+proc keynav::enableMnemonics {w} {
+    bind [winfo toplevel $w] <Alt-KeyPress> {+ keynav::Alt-KeyPress %W %K }
+}
+
+# mnemonic $w --
+#	Return the mnemonic character for widget $w, 
+#	as determined by the -text and -underline resources.
+#
+proc keynav::mnemonic {w} {
+    if {[catch {
+	set label [$w cget -text]
+	set underline [$w cget -underline]
+    }]} { return "" }
+    return [string index $label $underline]
+}
+
+# FindMnemonic $w $key --
+#	Locate the descendant of $w with mnemonic $key.
+#
+proc keynav::FindMnemonic {w key} {
+    if {[string length $key] != 1} { return }
+    set Q [list [set top [winfo toplevel $w]]]
+    while {[llength $Q]} {
+	set QN [list]
+	foreach w $Q {
+	    if {[string equal -nocase $key [mnemonic $w]]} {
+		return $w
+	    }
+	    foreach c [winfo children $w] {
+		if {[winfo ismapped $c] && [winfo toplevel $c] eq $top} {
+		    lappend QN $c
+		}
+	    }
+	}
+	set Q $QN
+    }
+    return {}
+}
+
+# Alt-KeyPress --
+#	Alt-KeyPress binding for toplevels with mnemonic accelerators enabled.
+#
+proc keynav::Alt-KeyPress {w k} {
+    set w [FindMnemonic $w $k]
+    if {$w ne ""} { 
+    	event generate $w <<Invoke>> 
+	return -code break
+    }
+}
+
+# defaultButton $w --
+#	Enable default activation for the toplevel containing $w,
+#	and make $w the default default widget.
+#
+proc keynav::defaultButton {w} {
+    variable DefaultButton
+
+    $w configure -default active 
+    set top [winfo toplevel $w]
+    set DefaultButton(current.$top) $w
+    set DefaultButton(default.$top) $w
+
+    bind $w <Destroy> [list keynav::CleanupDefault $top]
+    bind $top <FocusIn> [list keynav::ClaimDefault $top %W]
+    bind $top <KeyPress-Return> [list keynav::ActivateDefault $top]
+}
+
+proc keynav::CleanupDefault {top} {
+    variable DefaultButton
+    unset DefaultButton(current.$top)
+    unset DefaultButton(default.$top)
+}
+
+# ClaimDefault $top $w --
+#	<FocusIn> binding for default activation.
+#	Sets the default widget to $w if it is defaultable,
+#	otherwise set it to the default default.
+#
+proc keynav::ClaimDefault {top w} {
+    variable DefaultButton
+    if {![info exists DefaultButton(current.$top)]} {
+	# Someone destroyed the default default, but not
+	# the rest of the toplevel.
+	return;
+    }
+
+    set default $DefaultButton(default.$top)
+    if {![catch {$w cget -default} dstate] && $dstate ne "disabled"} {
+	set default $w
+    }
+
+    if {$default ne $DefaultButton(current.$top)} {
+	# Ignore errors -- someone may have destroyed the current default
+    	catch { $DefaultButton(current.$top) configure -default normal }
+	$default configure -default active
+	set DefaultButton(current.$top) $default
+    }
+}
+
+# ActivateDefault --
+#	Invoke the default widget for toplevel window, if any.  
+#
+proc keynav::ActivateDefault {top} {
+    variable DefaultButton
+    if {  [info exists DefaultButton(current.$top)]
+       && [winfo exists $DefaultButton(current.$top)]
+    } {
+	event generate $DefaultButton(current.$top) <<Invoke>>
+    }
+}
+
+# traverseTo $w --
+# 	Set the keyboard focus to the specified window,
+#	sending <<TraverseOut>> and <<TraverseIn>> virtual events
+#	as per TIP #204.
+#
+proc keynav::traverseTo {w} {
+    set focus [focus]
+    if {$focus ne ""} {
+	event generate $focus <<TraverseOut>>
+    }
+    focus $w
+    event generate $w <<TraverseIn>>
+}
+
+#
+# Provide TIP #204 functionality if we're running 8.4:
+#
+if {![package vsatisfies [package provide Tk] 8.5]} {
+    bind all <Tab> 		{ keynav::traverseTo [tk_focusNext %W] ; break}
+    bind all <<PrevWindow>>	{ keynav::traverseTo [tk_focusPrev %W] }
+    bind Entry <<TraverseIn>> 	{ %W selection range 0 end; %W icursor end }
+    bind Spinbox <<TraverseIn>> { %W selection range 0 end; %W icursor end }
+}
+
+#*EOF*