Pratt 1.5.6

data/pkgs/tile-0.8.2/library/clamTheme.tcl

@@ -0,0 +1,139 @@
+#
+# clamTheme.tcl,v 1.31 2007/11/18 18:09:26 jenglish Exp
+#
+# "Clam" theme.
+#
+# Inspired by the XFCE family of Gnome themes.
+#
+
+namespace eval ttk::theme::clam {
+    variable colors 
+    array set colors {
+	-disabledfg	"#999999"
+	-frame  	"#dcdad5"
+	-window  	"#ffffff"
+	-dark		"#cfcdc8"
+	-darker 	"#bab5ab"
+	-darkest	"#9e9a91"
+	-lighter	"#eeebe7"
+	-lightest 	"#ffffff"
+	-selectbg	"#4a6984"
+	-selectfg	"#ffffff"
+    }
+
+    ttk::style theme settings clam {
+
+	ttk::style configure "." \
+	    -background $colors(-frame) \
+	    -foreground black \
+	    -bordercolor $colors(-darkest) \
+	    -darkcolor $colors(-dark) \
+	    -lightcolor $colors(-lighter) \
+	    -troughcolor $colors(-darker) \
+	    -selectbackground $colors(-selectbg) \
+	    -selectforeground $colors(-selectfg) \
+	    -selectborderwidth 0 \
+	    -font TkDefaultFont \
+	    ;
+
+	ttk::style map "." \
+	    -background [list disabled $colors(-frame) \
+			     active $colors(-lighter)] \
+	    -foreground [list disabled $colors(-disabledfg)] \
+	    -selectbackground [list  !focus $colors(-darkest)] \
+	    -selectforeground [list  !focus white] \
+	    ;
+	# -selectbackground [list  !focus "#847d73"]
+
+	ttk::style configure TButton \
+	    -anchor center -width -11 -padding 5 -relief raised
+	ttk::style map TButton \
+	    -background [list \
+			     disabled $colors(-frame) \
+			     pressed $colors(-darker) \
+			     active $colors(-lighter)] \
+	    -lightcolor [list pressed $colors(-darker)] \
+	    -darkcolor [list pressed $colors(-darker)] \
+	    -bordercolor [list alternate "#000000"] \
+	    ;
+
+	ttk::style configure Toolbutton \
+	    -anchor center -padding 2 -relief flat
+	ttk::style map Toolbutton \
+	    -relief [list \
+		    disabled flat \
+		    selected sunken \
+		    pressed sunken \
+		    active raised] \
+	    -background [list \
+		    disabled $colors(-frame) \
+		    pressed $colors(-darker) \
+		    active $colors(-lighter)] \
+	    -lightcolor [list pressed $colors(-darker)] \
+	    -darkcolor [list pressed $colors(-darker)] \
+	    ;
+
+	ttk::style configure TCheckbutton \
+	    -indicatorbackground "#ffffff" \
+	    -indicatormargin {1 1 4 1} \
+	    -padding 2 ;
+	ttk::style configure TRadiobutton \
+	    -indicatorbackground "#ffffff" \
+	    -indicatormargin {1 1 4 1} \
+	    -padding 2 ;
+	ttk::style map TCheckbutton -indicatorbackground \
+	    [list  disabled $colors(-frame)  pressed $colors(-frame)]
+	ttk::style map TRadiobutton -indicatorbackground \
+	    [list  disabled $colors(-frame)  pressed $colors(-frame)]
+
+	ttk::style configure TMenubutton \
+	    -width -11 -padding 5 -relief raised
+
+	ttk::style configure TEntry -padding 1 -insertwidth 1
+	ttk::style map TEntry \
+	    -background [list  readonly $colors(-frame)] \
+	    -bordercolor [list  focus $colors(-selectbg)] \
+	    -lightcolor [list  focus "#6f9dc6"] \
+	    -darkcolor [list  focus "#6f9dc6"] \
+	    ;
+
+	ttk::style configure TCombobox -padding 1 -insertwidth 1
+	ttk::style map TCombobox \
+	    -background [list active $colors(-lighter) \
+			     pressed $colors(-lighter)] \
+	    -fieldbackground [list {readonly focus} $colors(-selectbg) \
+				  readonly $colors(-frame)] \
+	    -foreground [list {readonly focus} $colors(-selectfg)] \
+	    ;
+
+	ttk::style configure TNotebook.Tab -padding {6 2 6 2}
+	ttk::style map TNotebook.Tab \
+	    -padding [list selected {6 4 6 2}] \
+	    -background [list selected $colors(-frame) {} $colors(-darker)] \
+	    -lightcolor [list selected $colors(-lighter) {} $colors(-dark)] \
+	    ;
+
+	# Treeview:
+	ttk::style configure Heading \
+	    -font TkHeadingFont -relief raised -padding {3}
+	ttk::style configure Row -background $colors(-window)
+	ttk::style configure Cell -background $colors(-window)
+	ttk::style map Row \
+	    -background [list selected $colors(-selectbg)] \
+	    -foreground [list selected $colors(-selectfg)] ;
+	ttk::style map Cell \
+	    -background [list selected $colors(-selectbg)] \
+	    -foreground [list selected $colors(-selectfg)] ;
+	ttk::style map Item \
+	    -background [list selected $colors(-selectbg)] \
+	    -foreground [list selected $colors(-selectfg)] ;
+
+    	ttk::style configure TLabelframe \
+	    -labeloutside true -labelmargins {0 0 0 4} \
+	    -borderwidth 2 -relief raised
+
+	ttk::style configure TProgressbar -background $colors(-frame)
+
+	ttk::style configure Sash -sashthickness 6 -gripcount 10
+    }
+}

data/pkgs/tile-0.8.2/library/classicTheme.tcl

@@ -0,0 +1,108 @@
+#
+# classicTheme.tcl,v 1.19 2007/12/08 03:52:01 jenglish Exp
+#
+# "classic" Tk theme.
+#
+# Implements Tk's traditional Motif-like look and feel.
+#
+
+namespace eval ttk::theme::classic {
+
+    variable colors; array set colors {
+	-frame		"#d9d9d9"
+	-window		"#ffffff"
+	-activebg	"#ececec"
+	-troughbg	"#c3c3c3"
+	-selectbg	"#c3c3c3"
+	-selectfg	"#000000"
+	-disabledfg	"#a3a3a3"
+	-indicator	"#b03060"
+    }
+
+    ttk::style theme settings classic {
+	ttk::style configure "." \
+	    -font		TkDefaultFont \
+	    -background		$colors(-frame) \
+	    -foreground		black \
+	    -selectbackground	$colors(-selectbg) \
+	    -selectforeground	$colors(-selectfg) \
+	    -troughcolor	$colors(-troughbg) \
+	    -indicatorcolor	$colors(-frame) \
+	    -highlightcolor	$colors(-frame) \
+	    -highlightthickness	1 \
+	    -selectborderwidth	1 \
+	    -insertwidth	2 \
+	    ;
+
+	# To match pre-Xft X11 appearance, use:
+	#	ttk::style configure . -font {Helvetica 12 bold}
+
+	ttk::style map "." -background \
+	    [list disabled $colors(-frame) active $colors(-activebg)]
+	ttk::style map "." -foreground \
+	    [list disabled $colors(-disabledfg)]
+
+	ttk::style map "." -highlightcolor [list focus black]
+
+	ttk::style configure TButton \
+	    -anchor center -padding "3m 1m" -relief raised -shiftrelief 1
+	ttk::style map TButton -relief [list {!disabled pressed} sunken]
+
+	ttk::style configure TCheckbutton -indicatorrelief raised
+	ttk::style map TCheckbutton \
+	    -indicatorcolor [list \
+		pressed $colors(-frame)  selected $colors(-indicator)] \
+	    -indicatorrelief {selected sunken  pressed sunken} \
+	    ;
+
+	ttk::style configure TRadiobutton -indicatorrelief raised
+	ttk::style map TRadiobutton \
+	    -indicatorcolor [list \
+		pressed $colors(-frame)  selected $colors(-indicator)] \
+	    -indicatorrelief {selected sunken  pressed sunken} \
+	    ;
+
+	ttk::style configure TMenubutton -relief raised -padding "3m 1m"
+
+	ttk::style configure TEntry -relief sunken -padding 1 -font TkTextFont
+	ttk::style map TEntry -fieldbackground \
+		[list readonly $colors(-frame) disabled $colors(-frame)]
+	ttk::style configure TCombobox -padding 1
+	ttk::style map TCombobox -fieldbackground \
+		[list readonly $colors(-frame) disabled $colors(-frame)]
+
+	ttk::style configure TLabelframe -borderwidth 2 -relief groove
+
+	ttk::style configure TScrollbar -relief raised
+	ttk::style map TScrollbar -relief {{pressed !disabled} sunken}
+
+	ttk::style configure TScale -sliderrelief raised
+	ttk::style map TScale -sliderrelief {{pressed !disabled} sunken}
+
+	ttk::style configure TProgressbar -background SteelBlue
+	ttk::style configure TNotebook.Tab \
+	    -padding {3m 1m} \
+	    -background $colors(-troughbg)
+	ttk::style map TNotebook.Tab -background [list selected $colors(-frame)]
+
+	# Treeview:
+	ttk::style configure Heading -font TkHeadingFont -relief raised
+	ttk::style configure Row -background $colors(-window)
+	ttk::style configure Cell -background $colors(-window)
+	ttk::style map Row \
+	    -background [list selected $colors(-selectbg)] \
+	    -foreground [list selected $colors(-selectfg)] ;
+	ttk::style map Cell \
+	    -background [list selected $colors(-selectbg)] \
+	    -foreground [list selected $colors(-selectfg)] ;
+
+	#
+	# Toolbar buttons:
+	#
+	ttk::style configure Toolbutton -padding 2 -relief flat -shiftrelief 2
+	ttk::style map Toolbutton -relief \
+	    {disabled flat selected sunken pressed sunken active raised}
+	ttk::style map Toolbutton -background \
+	    [list pressed $colors(-troughbg)  active $colors(-activebg)]
+    }
+}

data/pkgs/tile-0.8.2/library/combobox.tcl

@@ -0,0 +1,439 @@
+#
+# combobox.tcl,v 1.47 2007/11/06 02:14:20 jenglish Exp
+#
+# Combobox bindings.
+#
+# Each combobox $cb has a child $cb.popdown, which contains
+# a listbox $cb.popdown.l and a scrollbar.  The listbox -listvariable
+# is set to a namespace variable, which is used to synchronize the
+# combobox values with the listbox values.
+#
+# <<NOTE-WM-TRANSIENT>>:
+#
+#	Need to set [wm transient] just before mapping the popdown
+#	instead of when it's created, in case a containing frame
+#	has been reparented [#1818441].
+#
+#	On Windows: setting [wm transient] prevents the parent
+#	toplevel from becoming inactive when the popdown is posted
+#	(Tk 8.4.8+)
+#
+#	On X11: WM_TRANSIENT_FOR on override-redirect windows
+#	may be used by compositing managers and by EWMH-aware
+#	window managers (even though the older ICCCM spec says
+#	it's meaningless).
+#
+#	On OSX: [wm transient] does utterly the wrong thing.
+#	Instead, we use [MacWindowStyle "help" "noActivates hideOnSuspend"].
+#	The "noActivates" attribute prevents the parent toplevel
+#	from deactivating when the popdown is posted, and is also
+#	necessary for "help" windows to receive mouse events.
+#	"hideOnSuspend" makes the popdown disappear (resp. reappear)
+#	when the parent toplevel is deactivated (resp. reactivated).
+#	(see [#1814778]).  Also set [wm resizable 0 0], to prevent
+#	TkAqua from shrinking the scrollbar to make room for a grow box
+#	that isn't there.
+#
+#	In order to work around other platform quirks in TkAqua,
+#	[grab] and [focus] are set in <Map> bindings instead of
+#	immediately after deiconifying the window.
+#
+
+namespace eval ttk::combobox {
+    variable Values	;# Values($cb) is -listvariable of listbox widget
+    variable State
+    set State(entryPress) 0
+}
+
+### Combobox bindings.
+#
+# Duplicate the Entry bindings, override if needed:
+#
+
+ttk::copyBindings TEntry TCombobox
+
+bind TCombobox <KeyPress-Down> 		{ ttk::combobox::Post %W }
+bind TCombobox <KeyPress-Escape> 	{ ttk::combobox::Unpost %W }
+
+bind TCombobox <ButtonPress-1> 		{ ttk::combobox::Press "" %W %x %y }
+bind TCombobox <Shift-ButtonPress-1>	{ ttk::combobox::Press "s" %W %x %y }
+bind TCombobox <Double-ButtonPress-1> 	{ ttk::combobox::Press "2" %W %x %y }
+bind TCombobox <Triple-ButtonPress-1> 	{ ttk::combobox::Press "3" %W %x %y }
+bind TCombobox <B1-Motion>		{ ttk::combobox::Drag %W %x }
+
+bind TCombobox <MouseWheel> 	{ ttk::combobox::Scroll %W [expr {%D/-120}] }
+if {[tk windowingsystem] eq "x11"} {
+    bind TCombobox <ButtonPress-4>	{ ttk::combobox::Scroll %W -1 }
+    bind TCombobox <ButtonPress-5>	{ ttk::combobox::Scroll %W  1 }
+}
+
+bind TCombobox <<TraverseIn>> 		{ ttk::combobox::TraverseIn %W }
+
+### Combobox listbox bindings.
+#
+bind ComboboxListbox <ButtonRelease-1>	{ ttk::combobox::LBSelected %W }
+bind ComboboxListbox <KeyPress-Return>	{ ttk::combobox::LBSelected %W }
+bind ComboboxListbox <KeyPress-Escape>  { ttk::combobox::LBCancel %W }
+bind ComboboxListbox <KeyPress-Tab>	{ ttk::combobox::LBTab %W next }
+bind ComboboxListbox <<PrevWindow>>	{ ttk::combobox::LBTab %W prev }
+bind ComboboxListbox <Destroy>		{ ttk::combobox::LBCleanup %W }
+bind ComboboxListbox <Motion>		{ ttk::combobox::LBHover %W %x %y }
+bind ComboboxListbox <Map>		{ focus -force %W }
+
+switch -- [tk windowingsystem] {
+    win32 {
+	# Dismiss listbox when user switches to a different application.
+	# NB: *only* do this on Windows (see #1814778)
+	bind ComboboxListbox <FocusOut>		{ ttk::combobox::LBCancel %W }
+    }
+}
+
+### Combobox popdown window bindings.
+#
+bind ComboboxPopdown	<Map>		{ ttk::combobox::MapPopdown %W }
+bind ComboboxPopdown	<Unmap>		{ ttk::combobox::UnmapPopdown %W }
+bind ComboboxPopdown	<ButtonPress> \
+			{ ttk::combobox::Unpost [winfo parent %W] }
+
+### Option database settings.
+#
+
+option add *TCombobox*Listbox.font TkTextFont
+option add *TCombobox*Listbox.relief flat
+option add *TCombobox*Listbox.highlightThickness 0
+
+## Platform-specific settings.
+#
+switch -- [tk windowingsystem] {
+    x11 {
+	option add *TCombobox*Listbox.background white
+    }
+    aqua {
+	option add *TCombobox*Listbox.borderWidth 0
+    }
+}
+
+### Binding procedures.
+#
+
+## Press $mode $x $y -- ButtonPress binding for comboboxes.
+#	Either post/unpost the listbox, or perform Entry widget binding,
+#	depending on widget state and location of button press.
+#
+proc ttk::combobox::Press {mode w x y} {
+    variable State
+    set State(entryPress) [expr {
+	   [$w instate {!readonly !disabled}]
+	&& [string match *textarea [$w identify $x $y]]
+    }]
+
+    focus $w
+    if {$State(entryPress)} {
+	switch -- $mode {
+	    s 	{ ttk::entry::Shift-Press $w $x 	; # Shift }
+	    2	{ ttk::entry::Select $w $x word 	; # Double click}
+	    3	{ ttk::entry::Select $w $x line 	; # Triple click }
+	    ""	-
+	    default { ttk::entry::Press $w $x }
+	}
+    } else {
+	Post $w
+    }
+}
+
+## Drag -- B1-Motion binding for comboboxes.
+#	If the initial ButtonPress event was handled by Entry binding,
+#	perform Entry widget drag binding; otherwise nothing.
+#
+proc ttk::combobox::Drag {w x}  {
+    variable State
+    if {$State(entryPress)} {
+	ttk::entry::Drag $w $x
+    }
+}
+
+## TraverseIn -- receive focus due to keyboard navigation
+#	For editable comboboxes, set the selection and insert cursor.
+#
+proc ttk::combobox::TraverseIn {w} {
+    $w instate {!readonly !disabled} {
+	$w selection range 0 end
+	$w icursor end
+    }
+}
+
+## SelectEntry $cb $index --
+#	Set the combobox selection in response to a user action.
+#
+proc ttk::combobox::SelectEntry {cb index} {
+    $cb current $index
+    $cb selection range 0 end
+    $cb icursor end
+    event generate $cb <<ComboboxSelected>>
+}
+
+## Scroll -- Mousewheel binding
+#
+proc ttk::combobox::Scroll {cb dir} {
+    $cb instate disabled { return }
+    set max [llength [$cb cget -values]]
+    set current [$cb current]
+    incr current $dir
+    if {$max != 0 && $current == $current % $max} {
+	SelectEntry $cb $current
+    }
+}
+
+## LBSelected $lb -- Activation binding for listbox
+#	Set the combobox value to the currently-selected listbox value
+#	and unpost the listbox.
+#
+proc ttk::combobox::LBSelected {lb} {
+    set cb [LBMaster $lb]
+    LBSelect $lb
+    Unpost $cb
+    focus $cb
+}
+
+## LBCancel --
+#	Unpost the listbox.
+#
+proc ttk::combobox::LBCancel {lb} {
+    Unpost [LBMaster $lb]
+}
+
+## LBTab -- Tab key binding for combobox listbox.
+#	Set the selection, and navigate to next/prev widget.
+#
+proc ttk::combobox::LBTab {lb dir} {
+    set cb [LBMaster $lb]
+    switch -- $dir {
+	next	{ set newFocus [tk_focusNext $cb] }
+	prev	{ set newFocus [tk_focusPrev $cb] }
+    }
+
+    if {$newFocus ne ""} {
+	LBSelect $lb
+	Unpost $cb
+	# The [grab release] call in [Unpost] queues events that later
+	# re-set the focus.  [update] to make sure these get processed first:
+	update
+	ttk::traverseTo $newFocus
+    }
+}
+
+## LBHover -- <Motion> binding for combobox listbox.
+#	Follow selection on mouseover.
+#
+proc ttk::combobox::LBHover {w x y} {
+    $w selection clear 0 end
+    $w activate @$x,$y
+    $w selection set @$x,$y
+}
+
+## MapPopdown -- <Map> binding for ComboboxPopdown
+#
+proc ttk::combobox::MapPopdown {w} {
+    [winfo parent $w] state pressed
+    ttk::globalGrab $w
+}
+
+## UnmapPopdown -- <Unmap> binding for ComboboxPopdown
+#
+proc ttk::combobox::UnmapPopdown {w} {
+    [winfo parent $w] state !pressed
+    ttk::releaseGrab $w
+}
+
+###
+#
+
+namespace eval ::ttk::combobox {
+    # @@@ Until we have a proper native scrollbar on Aqua, use
+    # @@@ the regular Tk one.  Use ttk::scrollbar on other platforms.
+    variable scrollbar ttk::scrollbar
+    if {[tk windowingsystem] eq "aqua"} {
+	set scrollbar ::scrollbar
+    }
+}
+
+## PopdownWindow --
+#	Returns the popdown widget associated with a combobox,
+#	creating it if necessary.
+#
+proc ttk::combobox::PopdownWindow {cb} {
+    variable scrollbar
+
+    if {![winfo exists $cb.popdown]} {
+	set popdown [PopdownToplevel $cb.popdown]
+
+	$scrollbar $popdown.sb \
+	    -orient vertical -command [list $popdown.l yview]
+	listbox $popdown.l \
+	    -listvariable ttk::combobox::Values($cb) \
+	    -yscrollcommand [list $popdown.sb set] \
+	    -exportselection false \
+	    -selectmode browse \
+	    -activestyle none \
+	    ;
+
+	bindtags $popdown.l \
+	    [list $popdown.l ComboboxListbox Listbox $popdown all]
+
+	grid $popdown.l $popdown.sb -sticky news
+	grid columnconfigure $popdown 0 -weight 1
+	grid rowconfigure $popdown 0 -weight 1
+    }
+    return $cb.popdown
+}
+
+## PopdownToplevel -- Create toplevel window for the combobox popdown
+#
+#	See also <<NOTE-WM-TRANSIENT>>
+#
+proc ttk::combobox::PopdownToplevel {w} {
+    toplevel $w -class ComboboxPopdown
+    wm withdraw $w
+    switch -- [tk windowingsystem] {
+	default -
+	x11 {
+	    $w configure -relief solid -borderwidth 1
+	    wm overrideredirect $w true
+	}
+	win32 {
+	    $w configure -relief solid -borderwidth 1
+	    wm overrideredirect $w true
+	}
+	aqua {
+	    $w configure -relief solid -borderwidth 0
+	    tk::unsupported::MacWindowStyle style $w \
+	    	help {noActivates hideOnSuspend}
+	    wm resizable $w 0 0
+	}
+    }
+    return $w
+}
+
+## ConfigureListbox --
+#	Set listbox values, selection, height, and scrollbar visibility
+#	from current combobox values.
+#
+proc ttk::combobox::ConfigureListbox {cb} {
+    variable Values
+
+    set popdown [PopdownWindow $cb]
+    set values [$cb cget -values]
+    set current [$cb current]
+    if {$current < 0} {
+	set current 0 		;# no current entry, highlight first one
+    }
+    set Values($cb) $values
+    $popdown.l selection clear 0 end
+    $popdown.l selection set $current
+    $popdown.l activate $current
+    $popdown.l see $current
+    set height [llength $values]
+    if {$height > [$cb cget -height]} {
+	set height [$cb cget -height]
+    	grid $popdown.sb
+    } else {
+	grid remove $popdown.sb
+    }
+    $popdown.l configure -height $height
+}
+
+## PlacePopdown --
+#	Set popdown window geometry.
+#
+# @@@TODO: factor with menubutton::PostPosition
+#
+proc ttk::combobox::PlacePopdown {cb popdown} {
+    set x [winfo rootx $cb]
+    set y [winfo rooty $cb]
+    set w [winfo width $cb]
+    set h [winfo height $cb]
+    set postoffset [ttk::style lookup TCombobox -postoffset {} {0 0 0 0}]
+    foreach var {x y w h} delta $postoffset {
+    	incr $var $delta
+    }
+
+    set H [winfo reqheight $popdown]
+    if {$y + $h + $H > [winfo screenheight $popdown]} {
+	set Y [expr {$y - $H}]
+    } else {
+	set Y [expr {$y + $h}]
+    }
+    wm geometry $popdown ${w}x${H}+${x}+${Y}
+}
+
+## Post $cb --
+#	Pop down the associated listbox.
+#
+proc ttk::combobox::Post {cb} {
+    # Don't do anything if disabled:
+    #
+    $cb instate disabled { return }
+
+    # ASSERT: ![$cb instate pressed]
+
+    # Run -postcommand callback:
+    #
+    uplevel #0 [$cb cget -postcommand]
+
+    set popdown [PopdownWindow $cb]
+    ConfigureListbox $cb
+    update idletasks
+    PlacePopdown $cb $popdown
+    # See <<NOTE-WM-TRANSIENT>>
+    switch -- [tk windowingsystem] {
+	x11 - win32 { wm transient $popdown [winfo toplevel $cb] }
+    }
+
+    # Post the listbox:
+    #
+    wm deiconify $popdown
+    raise $popdown
+}
+
+## Unpost $cb --
+#	Unpost the listbox.
+#
+proc ttk::combobox::Unpost {cb} {
+    if {[winfo exists $cb.popdown]} {
+	wm withdraw $cb.popdown
+    }
+    grab release $cb.popdown ;# in case of stuck or unexpected grab [#1239190]
+}
+
+## LBMaster $lb --
+#	Return the combobox main widget that owns the listbox.
+#
+proc ttk::combobox::LBMaster {lb} {
+    winfo parent [winfo parent $lb]
+}
+
+## LBSelect $lb --
+#	Transfer listbox selection to combobox value.
+#
+proc ttk::combobox::LBSelect {lb} {
+    set cb [LBMaster $lb]
+    set selection [$lb curselection]
+    if {[llength $selection] == 1} {
+	SelectEntry $cb [lindex $selection 0]
+    }
+}
+
+## LBCleanup $lb --
+#	<Destroy> binding for combobox listboxes.
+#	Cleans up by unsetting the linked textvariable.
+#
+#	Note: we can't just use { unset [%W cget -listvariable] }
+#	because the widget command is already gone when this binding fires).
+#	[winfo parent] still works, fortunately.
+#
+proc ttk::combobox::LBCleanup {lb} {
+    variable Values
+    unset Values([LBMaster $lb])
+}
+
+#*EOF*